lib/PublicInbox/LeiSavedSearch.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # pretends to be like LeiDedupe and also PublicInbox::Inbox
   5 package PublicInbox::LeiSavedSearch;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::Lock);
   9 use PublicInbox::Git;
  10 use PublicInbox::OverIdx;
  11 use PublicInbox::LeiSearch;
  12 use PublicInbox::Config;
  13 use PublicInbox::Spawn qw(run_die);
  14 use PublicInbox::ContentHash qw(git_sha);
  15 use PublicInbox::MID qw(mids_for_index);
  16 use Digest::SHA qw(sha256_hex);
  17 my $LOCAL_PFX = qr!\A(?:maildir|mh|mbox.+|mmdf):!i; # TODO: put in LeiToMail?
  18
  19 # move this to PublicInbox::Config if other things use it:
  20 my %cquote = ("\n" => '\\n', "\t" => '\\t', "\b" => '\\b');
  21 sub cquote_val ($) { # cf. git-config(1)
  22         my ($val) = @_;
  23         $val =~ s/([\n\t\b])/$cquote{$1}/g;
  24         $val;
  25 }
  26
  27 sub ARRAY_FIELDS () { qw(only include exclude) }
  28 sub BOOL_FIELDS () {
  29         qw(external local remote import-remote import-before threads)
  30 }
  31
  32 sub lss_dir_for ($$;$) {
  33         my ($lei, $dstref, $on_fs) = @_;
  34         my @n;
  35         if ($$dstref =~ m,\Aimaps?://,i) { # already canonicalized
  36                 require PublicInbox::URIimap;
  37                 my $uri = PublicInbox::URIimap->new($$dstref)->canonical;
  38                 $$dstref = $$uri;
  39                 @n = ($uri->mailbox);
  40         } else {
  41                 # can't use Cwd::abs_path since dirname($$dstref) may not exist
  42                 $$dstref = $lei->rel2abs($$dstref);
  43                 # Maildirs have trailing '/' internally
  44                 $$dstref .= '/' if -d $$dstref;
  45                 $$dstref =~ tr!/!/!s;
  46                 @n = ($$dstref =~ m{([^/]+)/*\z}); # basename
  47         }
  48         push @n, sha256_hex($$dstref);
  49         my $lss_dir = $lei->share_path . '/saved-searches/';
  50         my $d = $lss_dir . join('-', @n);
  51
  52         # fall-back to looking up by st_ino + st_dev in case we're in
  53         # a symlinked or bind-mounted path
  54         if ($on_fs && !-d $d && -e $$dstref) {
  55                 my @cur = stat(_);
  56                 my $want = pack('dd', @cur[1,0]); # st_ino + st_dev
  57                 my ($c, $o, @st);
  58                 for my $g ("$n[0]-*", '*') {
  59                         my @maybe = glob("$lss_dir$g/lei.saved-search");
  60                         for my $f (@maybe) {
  61                                 $c = PublicInbox::Config->git_config_dump($f);
  62                                 $o = $c->{'lei.q.output'} // next;
  63                                 $o =~ s!$LOCAL_PFX!! or next;
  64                                 @st = stat($o) or next;
  65                                 next if pack('dd', @st[1,0]) ne $want;
  66                                 $f =~ m!\A(.+?)/[^/]+\z! and return $1;
  67                         }
  68                 }
  69         }
  70         $d;
  71 }
  72
  73 sub list {
  74         my ($lei, $pfx) = @_;
  75         my $lss_dir = $lei->share_path.'/saved-searches';
  76         return () unless -d $lss_dir;
  77         # TODO: persist the cache?  Use another format?
  78         my $f = $lei->cache_dir."/saved-tmp.$$.".time.'.config';
  79         open my $fh, '>', $f or die "open $f: $!";
  80         print $fh "[include]\n";
  81         for my $p (glob("$lss_dir/*/lei.saved-search")) {
  82                 print $fh "\tpath = ", cquote_val($p), "\n";
  83         }
  84         close $fh or die "close $f: $!";
  85         my $cfg = PublicInbox::Config->git_config_dump($f);
  86         unlink($f);
  87         my $out = $cfg->get_all('lei.q.output') or return ();
  88         map {;
  89                 s!$LOCAL_PFX!!;
  90                 $_;
  91         } @$out
  92 }
  93
  94 sub translate_dedupe ($$$) {
  95         my ($self, $lei, $dd) = @_;
  96         $dd //= 'content';
  97         return 1 if $dd eq 'content'; # the default
  98         return $self->{"-dedupe_$dd"} = 1 if ($dd eq 'oid' || $dd eq 'mid');
  99         $lei->fail("--dedupe=$dd unsupported with --save");
 100 }
 101
 102 sub up { # updating existing saved search via "lei up"
 103         my ($cls, $lei, $dst) = @_;
 104         my $f;
 105         my $self = bless { ale => $lei->ale }, $cls;
 106         my $dir = $dst;
 107         output2lssdir($self, $lei, \$dir, \$f) or
 108                 return $lei->fail("--save was not used with $dst cwd=".
 109                                         $lei->rel2abs('.'));
 110         $self->{-cfg} = PublicInbox::Config->git_config_dump($f);
 111         $self->{-ovf} = "$dir/over.sqlite3";
 112         $self->{'-f'} = $f;
 113         $self->{lock_path} = "$self->{-f}.flock";
 114         $self;
 115 }
 116
 117 sub new { # new saved search "lei q --save"
 118         my ($cls, $lei) = @_;
 119         my $self = bless { ale => $lei->ale }, $cls;
 120         my $dst = $lei->{ovv}->{dst};
 121         my $dir = lss_dir_for($lei, \$dst);
 122         require File::Path;
 123         File::Path::make_path($dir); # raises on error
 124         $self->{-cfg} = {};
 125         my $f = $self->{'-f'} = "$dir/lei.saved-search";
 126         my $dd = $lei->{opt}->{dedupe};
 127         translate_dedupe($self, $lei, $dd) or return;
 128         open my $fh, '>', $f or return $lei->fail("open $f: $!");
 129         my $sq_dst = PublicInbox::Config::squote_maybe($dst);
 130         my $q = $lei->{mset_opt}->{q_raw} // die 'BUG: {q_raw} missing';
 131         if (ref $q) {
 132                 $q = join("\n", map { "\tq = ".cquote_val($_) } @$q);
 133         } else {
 134                 $q = "\tq = ".cquote_val($q);
 135         }
 136         $dst = "$lei->{ovv}->{fmt}:$dst" if $dst !~ m!\Aimaps?://!i;
 137         print $fh <<EOM;
 138 ; to refresh with new results, run: lei up $sq_dst
 139 [lei]
 140 $q
 141 [lei "q"]
 142         output = $dst
 143 EOM
 144         print $fh "\tdedupe = $dd\n" if $dd;
 145         for my $k (ARRAY_FIELDS) {
 146                 my $ary = $lei->{opt}->{$k} // next;
 147                 for my $x (@$ary) {
 148                         print $fh "\t$k = ".cquote_val($x)."\n";
 149                 }
 150         }
 151         for my $k (BOOL_FIELDS) {
 152                 my $val = $lei->{opt}->{$k} // next;
 153                 print $fh "\t$k = ".($val ? 1 : 0)."\n";
 154         }
 155         close($fh) or return $lei->fail("close $f: $!");
 156         $self->{lock_path} = "$self->{-f}.flock";
 157         $self->{-ovf} = "$dir/over.sqlite3";
 158         $self;
 159 }
 160
 161 sub description { $_[0]->{qstr} } # for WWW
 162
 163 sub cfg_set { # called by LeiXSearch
 164         my ($self, @args) = @_;
 165         my $lk = $self->lock_for_scope; # git-config doesn't wait
 166         run_die([qw(git config -f), $self->{'-f'}, @args]);
 167 }
 168
 169 # drop-in for LeiDedupe API
 170 sub is_dup {
 171         my ($self, $eml, $smsg) = @_;
 172         my $oidx = $self->{oidx} // die 'BUG: no {oidx}';
 173         my $lk;
 174         if ($self->{-dedupe_mid}) {
 175                 $lk //= $self->lock_for_scope_fast;
 176                 for my $mid (@{mids_for_index($eml)}) {
 177                         my ($id, $prv);
 178                         return 1 if $oidx->next_by_mid($mid, \$id, \$prv);
 179                 }
 180         }
 181         my $blob = $smsg ? $smsg->{blob} : git_sha(1, $eml)->hexdigest;
 182         $lk //= $self->lock_for_scope_fast;
 183         return 1 if $oidx->blob_exists($blob);
 184         if (my $xoids = PublicInbox::LeiSearch::xoids_for($self, $eml, 1)) {
 185                 for my $docid (values %$xoids) {
 186                         $oidx->add_xref3($docid, -1, $blob, '.');
 187                 }
 188                 $oidx->commit_lazy;
 189                 if ($self->{-dedupe_oid}) {
 190                         exists $xoids->{$blob} ? 1 : undef;
 191                 } else {
 192                         1;
 193                 }
 194         } else {
 195                 # n.b. above xoids_for fills out eml->{-lei_fake_mid} if needed
 196                 unless ($smsg) {
 197                         $smsg = bless {}, 'PublicInbox::Smsg';
 198                         $smsg->{bytes} = 0;
 199                         $smsg->populate($eml);
 200                 }
 201                 $smsg->{blob} //= $blob;
 202                 $oidx->begin_lazy;
 203                 $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 204                 $oidx->add_overview($eml, $smsg);
 205                 $oidx->add_xref3($smsg->{num}, -1, $blob, '.');
 206                 $oidx->commit_lazy;
 207                 undef;
 208         }
 209 }
 210
 211 sub prepare_dedupe {
 212         my ($self) = @_;
 213         $self->{oidx} //= do {
 214                 my $creat = !-f $self->{-ovf};
 215                 my $lk = $self->lock_for_scope; # git-config doesn't wait
 216                 my $oidx = PublicInbox::OverIdx->new($self->{-ovf});
 217                 $oidx->{-no_fsync} = 1;
 218                 $oidx->dbh;
 219                 if ($creat) {
 220                         $oidx->{dbh}->do('PRAGMA journal_mode = WAL');
 221                         $oidx->eidx_prep; # for xref3
 222                 }
 223                 $oidx
 224         };
 225 }
 226
 227 sub over { $_[0]->{oidx} } # for xoids_for
 228
 229 # don't use ale->git directly since is_dup is called inside
 230 # ale->git->cat_async callbacks
 231 sub git { $_[0]->{git} //= PublicInbox::Git->new($_[0]->{ale}->git->{git_dir}) }
 232
 233 sub pause_dedupe {
 234         my ($self) = @_;
 235         git($self)->cleanup;
 236         my $lockfh = delete $self->{lockfh}; # from lock_for_scope_fast;
 237         my $oidx = delete($self->{oidx}) // return;
 238         $oidx->commit_lazy;
 239 }
 240
 241 sub mm { undef }
 242
 243 sub altid_map { {} }
 244
 245 sub cloneurl { [] }
 246
 247 # find existing directory containing a `lei.saved-search' file based on
 248 # $dir_ref which is an output
 249 sub output2lssdir {
 250         my ($self, $lei, $dir_ref, $fn_ref) = @_;
 251         my $dst = $$dir_ref; # imap://$MAILBOX, /path/to/maildir, /path/to/mbox
 252         my $dir = lss_dir_for($lei, \$dst, 1);
 253         my $f = "$dir/lei.saved-search";
 254         if (-f $f && -r _) {
 255                 $self->{-cfg} = PublicInbox::Config->git_config_dump($f);
 256                 $$dir_ref = $dir;
 257                 $$fn_ref = $f;
 258                 return 1;
 259         }
 260         undef;
 261 }
 262
 263 sub edit_begin {
 264         my ($self, $lei) = @_;
 265         if (ref($self->{-cfg}->{'lei.q.output'})) {
 266                 delete $self->{-cfg}->{'lei.q.output'}; # invalid
 267                 $lei->err(<<EOM);
 268 $self->{-f} has multiple values of lei.q.output
 269 please remove redundant ones
 270 EOM
 271         }
 272         $lei->{-lss_for_edit} = $self;
 273 }
 274
 275 sub edit_done {
 276         my ($self, $lei) = @_;
 277         my $cfg = PublicInbox::Config->git_config_dump($self->{'-f'});
 278         my $new_out = $cfg->{'lei.q.output'} // '';
 279         return $lei->fail(<<EOM) if ref $new_out;
 280 $self->{-f} has multiple values of lei.q.output
 281 please edit again
 282 EOM
 283         return $lei->fail(<<EOM) if $new_out eq '';
 284 $self->{-f} needs lei.q.output
 285 please edit again
 286 EOM
 287         my $old_out = $self->{-cfg}->{'lei.q.output'} // '';
 288         return if $old_out eq $new_out;
 289         my $old_path = $old_out;
 290         my $new_path = $new_out;
 291         s!$LOCAL_PFX!! for ($old_path, $new_path);
 292         my $dir_old = lss_dir_for($lei, \$old_path, 1);
 293         my $dir_new = lss_dir_for($lei, \$new_path);
 294         return if $dir_new eq $dir_old; # no change, likely
 295         return $lei->fail(<<EOM) if -e $dir_new;
 296 lei.q.output changed from `$old_out' to `$new_out'
 297 However, $dir_new exists
 298 EOM
 299         # start the conversion asynchronously
 300         my $old_sq = PublicInbox::Config::squote_maybe($old_out);
 301         my $new_sq = PublicInbox::Config::squote_maybe($new_out);
 302         $lei->puts("lei.q.output changed from $old_sq to $new_sq");
 303         $lei->qerr("# lei convert $old_sq -o $new_sq");
 304         my $v = !$lei->{opt}->{quiet};
 305         $lei->{opt} = { output => $new_out, verbose => $v };
 306         require PublicInbox::LeiConvert;
 307         PublicInbox::LeiConvert::lei_convert($lei, $old_out);
 308
 309         $lei->fail(<<EOM) if -e $dir_old && !rename($dir_old, $dir_new);
 310 E: rename($dir_old, $dir_new) error: $!
 311 EOM
 312 }
 313
 314 no warnings 'once';
 315 *nntp_url = \&cloneurl;
 316 *base_url = \&PublicInbox::Inbox::base_url;
 317 *smsg_eml = \&PublicInbox::Inbox::smsg_eml;
 318 *smsg_by_mid = \&PublicInbox::Inbox::smsg_by_mid;
 319 *msg_by_mid = \&PublicInbox::Inbox::msg_by_mid;
 320 *modified = \&PublicInbox::Inbox::modified;
 321 *recent = \&PublicInbox::Inbox::recent;
 322 *max_git_epoch = *nntp_usable = *msg_by_path = \&mm; # undef
 323 *isrch = *search = \&mm; # TODO
 324 *DESTROY = \&pause_dedupe;
 325
 326 1;