lib/PublicInbox/LeiSearch.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # read-only counterpart for PublicInbox::LeiStore
   5 package PublicInbox::LeiSearch;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::ExtSearch);
   9 use PublicInbox::Search qw(xap_terms);
  10 use PublicInbox::ContentHash qw(content_digest content_hash);
  11 use PublicInbox::MID qw(mids mids_for_index);
  12
  13 # get combined docid from over.num:
  14 # (not generic Xapian, only works with our sharding scheme)
  15 sub num2docid ($$) {
  16         my ($self, $num) = @_;
  17         my $nshard = $self->{nshard};
  18         ($num - 1) * $nshard + $num % $nshard + 1;
  19 }
  20
  21 sub msg_keywords {
  22         my ($self, $num) = @_; # num_or_mitem
  23         my $xdb = $self->xdb; # set {nshard};
  24         my $docid = ref($num) ? $num->get_docid : num2docid($self, $num);
  25         my $kw = xap_terms('K', $xdb, $docid);
  26         warn "E: #$docid ($num): $@\n" if $@;
  27         wantarray ? sort(keys(%$kw)) : $kw;
  28 }
  29
  30 # lookup keywords+labels for external messages
  31 sub xsmsg_vmd {
  32         my ($self, $smsg, $want_label) = @_;
  33         return if $smsg->{kw};
  34         my $xdb = $self->xdb; # set {nshard};
  35         my (%kw, %L, $doc, $x);
  36         $kw{flagged} = 1 if delete($smsg->{lei_q_tt_flagged});
  37         my @num = $self->over->blob_exists($smsg->{blob});
  38         for my $num (@num) { # there should only be one...
  39                 $doc = $xdb->get_document(num2docid($self, $num));
  40                 $x = xap_terms('K', $doc);
  41                 %kw = (%kw, %$x);
  42                 if ($want_label) { # JSON/JMAP only
  43                         $x = xap_terms('L', $doc);
  44                         %L = (%L, %$x);
  45                 }
  46         }
  47         $smsg->{kw} = [ sort keys %kw ] if scalar(keys(%kw));
  48         $smsg->{L} = [ sort keys %L ] if scalar(keys(%L));
  49 }
  50
  51 # when a message has no Message-IDs at all, this is needed for
  52 # unsent Draft messages, at least
  53 sub content_key ($) {
  54         my ($eml) = @_;
  55         my $dig = content_digest($eml);
  56         my $chash = $dig->clone->digest;
  57         my $mids = mids_for_index($eml);
  58         unless (@$mids) {
  59                 $eml->{-lei_fake_mid} = $mids->[0] =
  60                                 PublicInbox::Import::digest2mid($dig, $eml, 0);
  61         }
  62         ($chash, $mids);
  63 }
  64
  65 sub _cmp_1st { # git->cat_async callback
  66         my ($bref, $oid, $type, $size, $cmp) = @_;
  67         # cmp: [chash, xoids, smsg, lms]
  68         $bref //= $cmp->[3] ? $cmp->[3]->local_blob($oid, 1) : undef;
  69         if ($bref && content_hash(PublicInbox::Eml->new($bref)) eq $cmp->[0]) {
  70                 $cmp->[1]->{$oid} = $cmp->[2]->{num};
  71         }
  72 }
  73
  74 # returns { OID => num } mapping for $eml matches
  75 # The `num' hash value only makes sense from LeiSearch itself
  76 # and is nonsense from the PublicInbox::LeiALE subclass
  77 sub xoids_for {
  78         my ($self, $eml, $min) = @_;
  79         my ($chash, $mids) = content_key($eml);
  80         my @overs = ($self->over // $self->overs_all);
  81         my $git = $self->git;
  82         my $xoids = {};
  83         # no lms when used via {ale}:
  84         my $lms = $self->{-lms_ro} //= lms($self) if defined($self->{topdir});
  85         for my $mid (@$mids) {
  86                 for my $o (@overs) {
  87                         my ($id, $prev);
  88                         while (my $cur = $o->next_by_mid($mid, \$id, \$prev)) {
  89                                 next if $cur->{bytes} == 0 ||
  90                                         $xoids->{$cur->{blob}};
  91                                 $git->cat_async($cur->{blob}, \&_cmp_1st,
  92                                                 [$chash, $xoids, $cur, $lms]);
  93                                 if ($min && scalar(keys %$xoids) >= $min) {
  94                                         $git->cat_async_wait;
  95                                         return $xoids;
  96                                 }
  97                         }
  98                 }
  99         }
 100         $git->cat_async_wait;
 101         scalar(keys %$xoids) ? $xoids : undef;
 102 }
 103
 104 # returns true if $eml is indexed by lei/store and keywords don't match
 105 sub kw_changed {
 106         my ($self, $eml, $new_kw_sorted, $docids) = @_;
 107         my $xoids = xoids_for($self, $eml) // return;
 108         $docids //= [];
 109         @$docids = sort { $a <=> $b } values %$xoids;
 110         my $cur_kw = msg_keywords($self, $docids->[0]);
 111
 112         # RFC 5550 sec 5.9 on the $Forwarded keyword states:
 113         # "Once set, the flag SHOULD NOT be cleared"
 114         if (exists($cur_kw->{forwarded}) &&
 115                         !grep(/\Aforwarded\z/, @$new_kw_sorted)) {
 116                 delete $cur_kw->{forwarded};
 117         }
 118         $cur_kw = join("\0", sort keys %$cur_kw);
 119         join("\0", @$new_kw_sorted) eq $cur_kw ? 0 : 1;
 120 }
 121
 122 sub all_terms {
 123         my ($self, $pfx) = @_;
 124         my $xdb = $self->xdb;
 125         my $cur = $xdb->allterms_begin($pfx);
 126         my $end = $xdb->allterms_end($pfx);
 127         my %ret;
 128         for (; $cur != $end; $cur++) {
 129                 my $tn = $cur->get_termname;
 130                 index($tn, $pfx) == 0 and
 131                         $ret{substr($tn, length($pfx))} = undef;
 132         }
 133         wantarray ? (sort keys %ret) : \%ret;
 134 }
 135
 136 sub qparse_new {
 137         my ($self) = @_;
 138         my $qp = $self->SUPER::qparse_new; # PublicInbox::Search
 139         $qp->add_boolean_prefix('kw', 'K');
 140         $qp->add_boolean_prefix('L', 'L');
 141         $qp
 142 }
 143
 144 sub lms {
 145         my ($self) = @_;
 146         require PublicInbox::LeiMailSync;
 147         my $f = "$self->{topdir}/mail_sync.sqlite3";
 148         -f $f ? PublicInbox::LeiMailSync->new($f) : undef;
 149 }
 150
 151 # allow SolverGit->resolve_patch to work with "lei index"
 152 sub smsg_eml {
 153         my ($self, $smsg) = @_;
 154         PublicInbox::Inbox::smsg_eml($self, $smsg) // do {
 155                 my $lms = lms($self);
 156                 my $bref = $lms ? $lms->local_blob($smsg->{blob}, 1) : undef;
 157                 $bref ? PublicInbox::Eml->new($bref) : undef;
 158         };
 159 }
 160
 161 1;