lib/PublicInbox/LeiSearch.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # read-only counterpart for PublicInbox::LeiStore
   5 package PublicInbox::LeiSearch;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::ExtSearch);
   9 use PublicInbox::Search qw(xap_terms);
  10 use PublicInbox::ContentHash qw(content_digest content_hash);
  11 use PublicInbox::MID qw(mids mids_in);
  12
  13 # get combined docid from over.num:
  14 # (not generic Xapian, only works with our sharding scheme)
  15 sub num2docid ($$) {
  16         my ($self, $num) = @_;
  17         my $nshard = $self->{nshard};
  18         ($num - 1) * $nshard + $num % $nshard + 1;
  19 }
  20
  21 sub msg_keywords {
  22         my ($self, $num) = @_; # num_or_mitem
  23         my $xdb = $self->xdb; # set {nshard};
  24         my $docid = ref($num) ? $num->get_docid : num2docid($self, $num);
  25         my $kw = xap_terms('K', $xdb, $docid);
  26         warn "E: #$docid ($num): $@\n" if $@;
  27         wantarray ? sort(keys(%$kw)) : $kw;
  28 }
  29
  30 # lookup keywords+labels for external messages
  31 sub xsmsg_vmd {
  32         my ($self, $smsg, $want_label) = @_;
  33         return if $smsg->{kw};
  34         my $xdb = $self->xdb; # set {nshard};
  35         my (%kw, %L, $doc, $x);
  36         $kw{flagged} = 1 if delete($smsg->{lei_q_tt_flagged});
  37         my @num = $self->over->blob_exists($smsg->{blob});
  38         for my $num (@num) { # there should only be one...
  39                 $doc = $xdb->get_document(num2docid($self, $num));
  40                 $x = xap_terms('K', $doc);
  41                 %kw = (%kw, %$x);
  42                 if ($want_label) { # JSON/JMAP only
  43                         $x = xap_terms('L', $doc);
  44                         %L = (%L, %$x);
  45                 }
  46         }
  47         $smsg->{kw} = [ sort keys %kw ] if scalar(keys(%kw));
  48         $smsg->{L} = [ sort keys %L ] if scalar(keys(%L));
  49 }
  50
  51 # when a message has no Message-IDs at all, this is needed for
  52 # unsent Draft messages, at least
  53 sub content_key ($) {
  54         my ($eml) = @_;
  55         my $dig = content_digest($eml);
  56         my $chash = $dig->clone->digest;
  57         my $mids = mids_in($eml,
  58                         qw(Message-ID X-Alt-Message-ID Resent-Message-ID));
  59         unless (@$mids) {
  60                 $eml->{-lei_fake_mid} = $mids->[0] =
  61                                 PublicInbox::Import::digest2mid($dig, $eml);
  62         }
  63         ($chash, $mids);
  64 }
  65
  66 sub _cmp_1st { # git->cat_async callback
  67         my ($bref, $oid, $type, $size, $cmp) = @_; # cmp: [chash, xoids, smsg]
  68         if ($bref && content_hash(PublicInbox::Eml->new($bref)) eq $cmp->[0]) {
  69                 $cmp->[1]->{$oid} = $cmp->[2]->{num};
  70         }
  71 }
  72
  73 # returns { OID => num } mapping for $eml matches
  74 # The `num' hash value only makes sense from LeiSearch itself
  75 # and is nonsense from the PublicInbox::LeiALE subclass
  76 sub xoids_for {
  77         my ($self, $eml, $min) = @_;
  78         my ($chash, $mids) = content_key($eml);
  79         my @overs = ($self->over // $self->overs_all);
  80         my $git = $self->git;
  81         my $xoids = {};
  82         for my $mid (@$mids) {
  83                 for my $o (@overs) {
  84                         my ($id, $prev);
  85                         while (my $cur = $o->next_by_mid($mid, \$id, \$prev)) {
  86                                 next if $cur->{bytes} == 0 ||
  87                                         $xoids->{$cur->{blob}};
  88                                 $git->cat_async($cur->{blob}, \&_cmp_1st,
  89                                                 [ $chash, $xoids, $cur ]);
  90                                 if ($min && scalar(keys %$xoids) >= $min) {
  91                                         $git->cat_async_wait;
  92                                         return $xoids;
  93                                 }
  94                         }
  95                 }
  96         }
  97         $git->cat_async_wait;
  98         scalar(keys %$xoids) ? $xoids : undef;
  99 }
 100
 101 # returns true if $eml is indexed by lei/store and keywords don't match
 102 sub kw_changed {
 103         my ($self, $eml, $new_kw_sorted) = @_;
 104         my $xoids = xoids_for($self, $eml, 1) // return;
 105         my ($num) = values %$xoids;
 106         my @cur_kw = msg_keywords($self, $num);
 107         join("\0", @$new_kw_sorted) eq join("\0", @cur_kw) ? 0 : 1;
 108 }
 109
 110 sub all_terms {
 111         my ($self, $pfx) = @_;
 112         my $xdb = $self->xdb;
 113         my $cur = $xdb->allterms_begin($pfx);
 114         my $end = $xdb->allterms_end($pfx);
 115         my %ret;
 116         for (; $cur != $end; $cur++) {
 117                 my $tn = $cur->get_termname;
 118                 index($tn, $pfx) == 0 and
 119                         $ret{substr($tn, length($pfx))} = undef;
 120         }
 121         wantarray ? (sort keys %ret) : \%ret;
 122 }
 123
 124 sub qparse_new {
 125         my ($self) = @_;
 126         my $qp = $self->SUPER::qparse_new; # PublicInbox::Search
 127         $qp->add_boolean_prefix('kw', 'K');
 128         $qp->add_boolean_prefix('L', 'L');
 129         $qp
 130 }
 131
 132 1;