lib/PublicInbox/LeiStore.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Local storage (cache/memo) for lei(1), suitable for personal/private
   5 # mail iff on encrypted device/FS.  Based on v2, but only deduplicates
   6 # git storage based on git OID (index deduplication is done in ContentHash)
   7 #
   8 # for xref3, the following are constant: $eidx_key = '.', $xnum = -1
   9 #
  10 # We rely on the synchronous IPC API for this in lei-daemon and
  11 # multiple lei clients to write to it at once.  This allows the
  12 # lei/store IPC process to be decoupled from network latency in
  13 # lei WQ workers.
  14 package PublicInbox::LeiStore;
  15 use strict;
  16 use v5.10.1;
  17 use parent qw(PublicInbox::Lock PublicInbox::IPC);
  18 use PublicInbox::ExtSearchIdx;
  19 use PublicInbox::Eml;
  20 use PublicInbox::Import;
  21 use PublicInbox::InboxWritable qw(eml_from_path);
  22 use PublicInbox::V2Writable;
  23 use PublicInbox::ContentHash qw(content_hash);
  24 use PublicInbox::MID qw(mids);
  25 use PublicInbox::LeiSearch;
  26 use PublicInbox::MDA;
  27 use PublicInbox::Spawn qw(spawn);
  28 use PublicInbox::MdirReader;
  29 use PublicInbox::LeiToMail;
  30 use File::Temp ();
  31 use POSIX ();
  32 use IO::Handle (); # ->autoflush
  33 use Sys::Syslog qw(syslog openlog);
  34 use Errno qw(EEXIST ENOENT);
  35
  36 sub new {
  37         my (undef, $dir, $opt) = @_;
  38         my $eidx = PublicInbox::ExtSearchIdx->new($dir, $opt);
  39         my $self = bless { priv_eidx => $eidx }, __PACKAGE__;
  40         eidx_init($self)->done if $opt->{creat};
  41         $self;
  42 }
  43
  44 sub git { $_[0]->{priv_eidx}->git } # read-only
  45
  46 sub packing_factor { $PublicInbox::V2Writable::PACKING_FACTOR }
  47
  48 sub rotate_bytes {
  49         $_[0]->{rotate_bytes} // ((1024 * 1024 * 1024) / $_[0]->packing_factor)
  50 }
  51
  52 sub git_ident ($) {
  53         my ($git) = @_;
  54         my $rdr = {};
  55         open $rdr->{2}, '>', '/dev/null' or die "open /dev/null: $!";
  56         chomp(my $i = $git->qx([qw(var GIT_COMMITTER_IDENT)], undef, $rdr));
  57         $i =~ /\A(.+) <([^>]+)> [0-9]+ [-\+]?[0-9]+$/ and return ($1, $2);
  58         my ($user, undef, undef, undef, undef, undef, $gecos) = getpwuid($<);
  59         ($user) = (($user // $ENV{USER} // '') =~ /([\w\-\.\+]+)/);
  60         $user //= 'lei-user';
  61         ($gecos) = (($gecos // '') =~ /([\w\-\.\+ \t]+)/);
  62         $gecos //= 'lei user';
  63         require Sys::Hostname;
  64         my ($host) = (Sys::Hostname::hostname() =~ /([\w\-\.]+)/);
  65         $host //= 'localhost';
  66         ($gecos, "$user\@$host")
  67 }
  68
  69 sub importer {
  70         my ($self) = @_;
  71         my $max;
  72         my $im = $self->{im};
  73         if ($im) {
  74                 return $im if $im->{bytes_added} < $self->rotate_bytes;
  75
  76                 delete $self->{im};
  77                 $im->done;
  78                 undef $im;
  79                 $self->checkpoint;
  80                 $max = $self->{priv_eidx}->{mg}->git_epochs + 1;
  81         }
  82         my (undef, $tl) = eidx_init($self); # acquire lock
  83         $max //= $self->{priv_eidx}->{mg}->git_epochs;
  84         while (1) {
  85                 my $latest = $self->{priv_eidx}->{mg}->add_epoch($max);
  86                 my $git = PublicInbox::Git->new($latest);
  87                 $self->done; # unlock
  88                 # re-acquire lock, update alternates for new epoch
  89                 (undef, $tl) = eidx_init($self);
  90                 my $packed_bytes = $git->packed_bytes;
  91                 my $unpacked_bytes = $packed_bytes / $self->packing_factor;
  92                 if ($unpacked_bytes >= $self->rotate_bytes) {
  93                         $max++;
  94                         next;
  95                 }
  96                 my ($n, $e) = git_ident($git);
  97                 $self->{im} = $im = PublicInbox::Import->new($git, $n, $e);
  98                 $im->{bytes_added} = int($packed_bytes / $self->packing_factor);
  99                 $im->{lock_path} = undef;
 100                 $im->{path_type} = 'v2';
 101                 return $im;
 102         }
 103 }
 104
 105 sub search {
 106         PublicInbox::LeiSearch->new($_[0]->{priv_eidx}->{topdir});
 107 }
 108
 109 # follows the stderr file
 110 sub _tail_err {
 111         my ($self) = @_;
 112         print { $self->{-err_wr} } readline($self->{-tmp_err});
 113 }
 114
 115 sub eidx_init {
 116         my ($self) = @_;
 117         my $eidx = $self->{priv_eidx};
 118         my $tl = wantarray && $self->{-err_wr} ?
 119                         PublicInbox::OnDestroy->new($$, \&_tail_err, $self) :
 120                         undef;
 121         $eidx->idx_init({-private => 1}); # acquires lock
 122         wantarray ? ($eidx, $tl) : $eidx;
 123 }
 124
 125 sub _docids_for ($$) {
 126         my ($self, $eml) = @_;
 127         my %docids;
 128         my $eidx = $self->{priv_eidx};
 129         my ($chash, $mids) = PublicInbox::LeiSearch::content_key($eml);
 130         my $oidx = $eidx->{oidx};
 131         my $im = $self->{im};
 132         for my $mid (@$mids) {
 133                 my ($id, $prev);
 134                 while (my $cur = $oidx->next_by_mid($mid, \$id, \$prev)) {
 135                         next if $cur->{bytes} == 0; # external-only message
 136                         my $oid = $cur->{blob};
 137                         my $docid = $cur->{num};
 138                         my $bref = $im ? $im->cat_blob($oid) : undef;
 139                         $bref //= $eidx->git->cat_file($oid) //
 140                                 _lms_rw($self)->local_blob($oid, 1) // do {
 141                                 warn "W: $oid (#$docid) <$mid> not found\n";
 142                                 next;
 143                         };
 144                         local $self->{current_info} = $oid;
 145                         my $x = PublicInbox::Eml->new($bref);
 146                         $docids{$docid} = $docid if content_hash($x) eq $chash;
 147                 }
 148         }
 149         sort { $a <=> $b } values %docids;
 150 }
 151
 152 # n.b. similar to LeiExportKw->export_kw_md, but this is for a single eml
 153 sub export1_kw_md ($$$$$) {
 154         my ($self, $mdir, $bn, $oidbin, $vmdish) = @_; # vmd/vmd_mod
 155         my $orig = $bn;
 156         my (@try, $unkn, $kw);
 157         if ($bn =~ s/:2,([a-zA-Z]*)\z//) {
 158                 ($kw, $unkn) = PublicInbox::MdirReader::flags2kw($1);
 159                 if (my $set = $vmdish->{kw}) {
 160                         $kw = $set;
 161                 } elsif (my $add = $vmdish->{'+kw'}) {
 162                         @$kw{@$add} = ();
 163                 } elsif (my $del = $vmdish->{-kw}) {
 164                         delete @$kw{@$del};
 165                 } # else no changes...
 166                 @try = qw(cur new);
 167         } else { # no keywords, yet, could be in new/
 168                 @try = qw(new cur);
 169                 $unkn = [];
 170                 if (my $set = $vmdish->{kw}) {
 171                         $kw = $set;
 172                 } elsif (my $add = $vmdish->{'+kw'}) {
 173                         @$kw{@$add} = (); # auto-vivify
 174                 } else { # ignore $vmdish->{-kw}
 175                         $kw = [];
 176                 }
 177         }
 178         $kw = [ keys %$kw ] if ref($kw) eq 'HASH';
 179         $bn .= ':2,'. PublicInbox::LeiToMail::kw2suffix($kw, @$unkn);
 180         return if $orig eq $bn; # no change
 181
 182         # we use link(2) + unlink(2) since rename(2) may
 183         # inadvertently clobber if the "uniquefilename" part wasn't
 184         # actually unique.
 185         my $dst = "$mdir/cur/$bn";
 186         for my $d (@try) {
 187                 my $src = "$mdir/$d/$orig";
 188                 if (link($src, $dst)) {
 189                         if (!unlink($src) and $! != ENOENT) {
 190                                 syslog('warning', "unlink($src): $!");
 191                         }
 192                         # TODO: verify oidbin?
 193                         $self->{lms}->mv_src("maildir:$mdir",
 194                                         $oidbin, \$orig, $bn);
 195                         return;
 196                 } elsif ($! == EEXIST) { # lost race with "lei export-kw"?
 197                         return;
 198                 } elsif ($! != ENOENT) {
 199                         syslog('warning', "link($src -> $dst): $!");
 200                 }
 201         }
 202         for (@try) { return if -e "$mdir/$_/$orig" };
 203         $self->{lms}->clear_src("maildir:$mdir", \$orig);
 204 }
 205
 206 sub sto_export_kw ($$$) {
 207         my ($self, $docid, $vmdish) = @_; # vmdish (vmd or vmd_mod)
 208         my ($eidx, $tl) = eidx_init($self);
 209         my $lms = _lms_rw($self) // return;
 210         my $xr3 = $eidx->{oidx}->get_xref3($docid, 1);
 211         for my $row (@$xr3) {
 212                 my (undef, undef, $oidbin) = @$row;
 213                 my $locs = $lms->locations_for($oidbin) // next;
 214                 while (my ($loc, $ids) = each %$locs) {
 215                         if ($loc =~ s!\Amaildir:!!i) {
 216                                 for my $id (@$ids) {
 217                                         export1_kw_md($self, $loc, $id,
 218                                                         $oidbin, $vmdish);
 219                                 }
 220                         }
 221                         # TODO: IMAP
 222                 }
 223         }
 224 }
 225
 226 # vmd = { kw => [ qw(seen ...) ], L => [ qw(inbox ...) ] }
 227 sub set_eml_vmd {
 228         my ($self, $eml, $vmd, $docids) = @_;
 229         my ($eidx, $tl) = eidx_init($self);
 230         $docids //= [ _docids_for($self, $eml) ];
 231         for my $docid (@$docids) {
 232                 $eidx->idx_shard($docid)->ipc_do('set_vmd', $docid, $vmd);
 233                 sto_export_kw($self, $docid, $vmd);
 234         }
 235         $docids;
 236 }
 237
 238 sub add_eml_vmd {
 239         my ($self, $eml, $vmd) = @_;
 240         my ($eidx, $tl) = eidx_init($self);
 241         my @docids = _docids_for($self, $eml);
 242         for my $docid (@docids) {
 243                 $eidx->idx_shard($docid)->ipc_do('add_vmd', $docid, $vmd);
 244         }
 245         \@docids;
 246 }
 247
 248 sub remove_eml_vmd { # remove just the VMD
 249         my ($self, $eml, $vmd) = @_;
 250         my ($eidx, $tl) = eidx_init($self);
 251         my @docids = _docids_for($self, $eml);
 252         for my $docid (@docids) {
 253                 $eidx->idx_shard($docid)->ipc_do('remove_vmd', $docid, $vmd);
 254         }
 255         \@docids;
 256 }
 257
 258 sub _lms_rw ($) { # it is important to have eidx processes open before lms
 259         my ($self) = @_;
 260         my ($eidx, $tl) = eidx_init($self);
 261         $self->{lms} //= do {
 262                 require PublicInbox::LeiMailSync;
 263                 my $f = "$self->{priv_eidx}->{topdir}/mail_sync.sqlite3";
 264                 my $lms = PublicInbox::LeiMailSync->new($f);
 265                 $lms->lms_write_prepare;
 266                 $lms;
 267         };
 268 }
 269
 270 sub set_sync_info {
 271         my ($self, $oidhex, $folder, $id) = @_;
 272         _lms_rw($self)->set_src(pack('H*', $oidhex), $folder, $id);
 273 }
 274
 275 sub _remove_if_local { # git->cat_async arg
 276         my ($bref, $oidhex, $type, $size, $self) = @_;
 277         $self->{im}->remove($bref) if $bref;
 278 }
 279
 280 sub remove_docids ($;@) {
 281         my ($self, @docids) = @_;
 282         my $eidx = eidx_init($self);
 283         for my $docid (@docids) {
 284                 $eidx->idx_shard($docid)->ipc_do('xdb_remove', $docid);
 285                 $eidx->{oidx}->delete_by_num($docid);
 286                 $eidx->{oidx}->{dbh}->do(<<EOF, undef, $docid);
 287 DELETE FROM xref3 WHERE docid = ?
 288 EOF
 289         }
 290 }
 291
 292 # remove the entire message from the index, does not touch mail_sync.sqlite3
 293 sub remove_eml {
 294         my ($self, $eml) = @_;
 295         my $im = $self->importer; # may create new epoch
 296         my ($eidx, $tl) = eidx_init($self);
 297         my $oidx = $eidx->{oidx};
 298         my @docids = _docids_for($self, $eml);
 299         my $git = $eidx->git;
 300         for my $docid (@docids) {
 301                 my $xr3 = $oidx->get_xref3($docid, 1);
 302                 for my $row (@$xr3) {
 303                         my (undef, undef, $oidbin) = @$row;
 304                         my $oidhex = unpack('H*', $oidbin);
 305                         $git->cat_async($oidhex, \&_remove_if_local, $self);
 306                 }
 307         }
 308         $git->cat_async_wait;
 309         remove_docids($self, @docids);
 310         \@docids;
 311 }
 312
 313 sub oid2docid ($$) {
 314         my ($self, $oid) = @_;
 315         my $eidx = eidx_init($self);
 316         my ($docid, @cull) = $eidx->{oidx}->blob_exists($oid);
 317         if (@cull) { # fixup old bugs...
 318                 warn <<EOF;
 319 W: $oid indexed as multiple docids: $docid @cull, culling to fixup old bugs
 320 EOF
 321                 remove_docids($self, @cull);
 322         }
 323         $docid;
 324 }
 325
 326 sub _add_vmd ($$$$) {
 327         my ($self, $idx, $docid, $vmd) = @_;
 328         $idx->ipc_do('add_vmd', $docid, $vmd);
 329         sto_export_kw($self, $docid, $vmd);
 330 }
 331
 332 sub add_eml {
 333         my ($self, $eml, $vmd, $xoids) = @_;
 334         my $im = $self->{-fake_im} // $self->importer; # may create new epoch
 335         my ($eidx, $tl) = eidx_init($self);
 336         my $oidx = $eidx->{oidx}; # PublicInbox::Import::add checks this
 337         my $smsg = bless { -oidx => $oidx }, 'PublicInbox::Smsg';
 338         $smsg->{-eidx_git} = $eidx->git if !$self->{-fake_im};
 339         my $im_mark = $im->add($eml, undef, $smsg);
 340         if ($vmd && $vmd->{sync_info}) {
 341                 set_sync_info($self, $smsg->{blob}, @{$vmd->{sync_info}});
 342         }
 343         $im_mark or return; # duplicate blob returns undef
 344
 345         local $self->{current_info} = $smsg->{blob};
 346         my $vivify_xvmd = delete($smsg->{-vivify_xvmd}) // []; # exact matches
 347         if ($xoids) { # fuzzy matches from externals in ale->xoids_for
 348                 delete $xoids->{$smsg->{blob}}; # added later
 349                 if (scalar keys %$xoids) {
 350                         my %docids = map { $_ => 1 } @$vivify_xvmd;
 351                         for my $oid (keys %$xoids) {
 352                                 my $docid = oid2docid($self, $oid);
 353                                 $docids{$docid} = $docid if defined($docid);
 354                         }
 355                         @$vivify_xvmd = sort { $a <=> $b } keys(%docids);
 356                 }
 357         }
 358         if (@$vivify_xvmd) { # docids list
 359                 $xoids //= {};
 360                 $xoids->{$smsg->{blob}} = 1;
 361                 for my $docid (@$vivify_xvmd) {
 362                         my $cur = $oidx->get_art($docid);
 363                         my $idx = $eidx->idx_shard($docid);
 364                         if (!$cur || $cur->{bytes} == 0) { # really vivifying
 365                                 $smsg->{num} = $docid;
 366                                 $oidx->add_overview($eml, $smsg);
 367                                 $smsg->{-merge_vmd} = 1;
 368                                 $idx->index_eml($eml, $smsg);
 369                         } else { # lse fuzzy hit off ale
 370                                 $idx->ipc_do('add_eidx_info', $docid, '.', $eml);
 371                         }
 372                         for my $oid (keys %$xoids) {
 373                                 $oidx->add_xref3($docid, -1, $oid, '.');
 374                         }
 375                         _add_vmd($self, $idx, $docid, $vmd) if $vmd;
 376                 }
 377                 $vivify_xvmd;
 378         } elsif (my @docids = _docids_for($self, $eml)) {
 379                 # fuzzy match from within lei/store
 380                 for my $docid (@docids) {
 381                         my $idx = $eidx->idx_shard($docid);
 382                         $oidx->add_xref3($docid, -1, $smsg->{blob}, '.');
 383                         # add_eidx_info for List-Id
 384                         $idx->ipc_do('add_eidx_info', $docid, '.', $eml);
 385                         _add_vmd($self, $idx, $docid, $vmd) if $vmd;
 386                 }
 387                 \@docids;
 388         } else { # totally new message
 389                 delete $smsg->{-oidx}; # for IPC-friendliness
 390                 $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 391                 $oidx->add_overview($eml, $smsg);
 392                 $oidx->add_xref3($smsg->{num}, -1, $smsg->{blob}, '.');
 393                 my $idx = $eidx->idx_shard($smsg->{num});
 394                 $idx->index_eml($eml, $smsg);
 395                 _add_vmd($self, $idx, $smsg->{num}, $vmd) if $vmd;
 396                 $smsg;
 397         }
 398 }
 399
 400 sub set_eml {
 401         my ($self, $eml, $vmd, $xoids) = @_;
 402         add_eml($self, $eml, $vmd, $xoids) //
 403                 set_eml_vmd($self, $eml, $vmd);
 404 }
 405
 406 sub index_eml_only {
 407         my ($self, $eml, $vmd, $xoids) = @_;
 408         require PublicInbox::FakeImport;
 409         local $self->{-fake_im} = PublicInbox::FakeImport->new;
 410         set_eml($self, $eml, $vmd, $xoids);
 411 }
 412
 413 # store {kw} / {L} info for a message which is only in an external
 414 sub _external_only ($$$) {
 415         my ($self, $xoids, $eml) = @_;
 416         my $eidx = $self->{priv_eidx};
 417         my $oidx = $eidx->{oidx} // die 'BUG: {oidx} missing';
 418         my $smsg = bless { blob => '' }, 'PublicInbox::Smsg';
 419         $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 420         # save space for an externals-only message
 421         my $hdr = $eml->header_obj;
 422         $smsg->populate($hdr); # sets lines == 0
 423         $smsg->{bytes} = 0;
 424         delete @$smsg{qw(From Subject)};
 425         $smsg->{to} = $smsg->{cc} = $smsg->{from} = '';
 426         $oidx->add_overview($hdr, $smsg); # subject+references for threading
 427         $smsg->{subject} = '';
 428         for my $oid (keys %$xoids) {
 429                 $oidx->add_xref3($smsg->{num}, -1, $oid, '.');
 430         }
 431         my $idx = $eidx->idx_shard($smsg->{num});
 432         $idx->index_eml(PublicInbox::Eml->new("\n\n"), $smsg);
 433         ($smsg, $idx);
 434 }
 435
 436 sub update_xvmd {
 437         my ($self, $xoids, $eml, $vmd_mod) = @_;
 438         my ($eidx, $tl) = eidx_init($self);
 439         my $oidx = $eidx->{oidx};
 440         my %seen;
 441         for my $oid (keys %$xoids) {
 442                 my $docid = oid2docid($self, $oid) // next;
 443                 delete $xoids->{$oid};
 444                 next if $seen{$docid}++;
 445                 my $idx = $eidx->idx_shard($docid);
 446                 $idx->ipc_do('update_vmd', $docid, $vmd_mod);
 447                 sto_export_kw($self, $docid, $vmd_mod);
 448         }
 449         return unless scalar(keys(%$xoids));
 450
 451         # see if it was indexed, but with different OID(s)
 452         if (my @docids = _docids_for($self, $eml)) {
 453                 for my $docid (@docids) {
 454                         next if $seen{$docid};
 455                         for my $oid (keys %$xoids) {
 456                                 $oidx->add_xref3($docid, -1, $oid, '.');
 457                         }
 458                         my $idx = $eidx->idx_shard($docid);
 459                         $idx->ipc_do('update_vmd', $docid, $vmd_mod);
 460                         sto_export_kw($self, $docid, $vmd_mod);
 461                 }
 462                 return;
 463         }
 464         # totally unseen
 465         my ($smsg, $idx) = _external_only($self, $xoids, $eml);
 466         $idx->ipc_do('update_vmd', $smsg->{num}, $vmd_mod);
 467         sto_export_kw($self, $smsg->{num}, $vmd_mod);
 468 }
 469
 470 # set or update keywords for external message, called via ipc_do
 471 sub set_xvmd {
 472         my ($self, $xoids, $eml, $vmd) = @_;
 473
 474         my ($eidx, $tl) = eidx_init($self);
 475         my $oidx = $eidx->{oidx};
 476         my %seen;
 477
 478         # see if we can just update existing docs
 479         for my $oid (keys %$xoids) {
 480                 my $docid = oid2docid($self, $oid) // next;
 481                 delete $xoids->{$oid}; # all done with this oid
 482                 next if $seen{$docid}++;
 483                 my $idx = $eidx->idx_shard($docid);
 484                 $idx->ipc_do('set_vmd', $docid, $vmd);
 485                 sto_export_kw($self, $docid, $vmd);
 486         }
 487         return unless scalar(keys(%$xoids));
 488
 489         # n.b. we don't do _docids_for here, we expect the caller
 490         # already checked $lse->kw_changed before calling this sub
 491
 492         return unless (@{$vmd->{kw} // []}) || (@{$vmd->{L} // []});
 493         # totally unseen:
 494         my ($smsg, $idx) = _external_only($self, $xoids, $eml);
 495         $idx->ipc_do('add_vmd', $smsg->{num}, $vmd);
 496         sto_export_kw($self, $smsg->{num}, $vmd);
 497 }
 498
 499 sub checkpoint {
 500         my ($self, $wait) = @_;
 501         if (my $im = $self->{im}) {
 502                 $wait ? $im->barrier : $im->checkpoint;
 503         }
 504         delete $self->{lms};
 505         $self->{priv_eidx}->checkpoint($wait);
 506 }
 507
 508 sub xchg_stderr {
 509         my ($self) = @_;
 510         _tail_err($self) if $self->{-err_wr};
 511         my $dir = $self->{priv_eidx}->{topdir};
 512         return unless -e $dir;
 513         my $old = delete $self->{-tmp_err};
 514         my $pfx = POSIX::strftime('%Y%m%d%H%M%S', gmtime(time));
 515         my $err = File::Temp->new(TEMPLATE => "$pfx.$$.lei_storeXXXX",
 516                                 SUFFIX => '.err', DIR => $dir);
 517         open STDERR, '>>', $err->filename or die "dup2: $!";
 518         STDERR->autoflush(1); # shared with shard subprocesses
 519         $self->{-tmp_err} = $err; # separate file description for RO access
 520         undef;
 521 }
 522
 523 sub done {
 524         my ($self, $sock_ref) = @_;
 525         my $err = '';
 526         if (my $im = delete($self->{im})) {
 527                 eval { $im->done };
 528                 if ($@) {
 529                         $err .= "import done: $@\n";
 530                         warn $err;
 531                 }
 532         }
 533         delete $self->{lms};
 534         $self->{priv_eidx}->done; # V2Writable::done
 535         xchg_stderr($self);
 536         die $err if $err;
 537
 538         # notify clients ->done has been issued
 539         defined($sock_ref) and
 540                 $self->{s2d_op_p}->pkt_do('sto_done_complete', $sock_ref);
 541 }
 542
 543 sub ipc_atfork_child {
 544         my ($self) = @_;
 545         my $lei = $self->{lei};
 546         $lei->_lei_atfork_child(1) if $lei;
 547         xchg_stderr($self);
 548         if (my $to_close = delete($self->{to_close})) {
 549                 close($_) for @$to_close;
 550         }
 551         openlog('lei/store', 'pid,nowait,nofatal,ndelay', 'user');
 552         $self->SUPER::ipc_atfork_child;
 553 }
 554
 555 sub write_prepare {
 556         my ($self, $lei) = @_;
 557         $lei // die 'BUG: $lei not passed';
 558         unless ($self->{-ipc_req}) {
 559                 # s2d => store-to-daemon messages
 560                 require PublicInbox::PktOp;
 561                 my ($s2d_op_c, $s2d_op_p) = PublicInbox::PktOp->pair;
 562                 my $dir = $lei->store_path;
 563                 $self->ipc_lock_init("$dir/ipc.lock");
 564                 substr($dir, -length('/lei/store'), 10, '');
 565                 pipe(my ($r, $w)) or die "pipe: $!";
 566                 $w->autoflush(1);
 567                 # Mail we import into lei are private, so headers filtered out
 568                 # by -mda for public mail are not appropriate
 569                 local @PublicInbox::MDA::BAD_HEADERS = ();
 570                 $self->ipc_worker_spawn("lei/store $dir", $lei->oldset, {
 571                                         lei => $lei,
 572                                         -err_wr => $w,
 573                                         to_close => [ $r, $s2d_op_c->{sock} ],
 574                                         s2d_op_p => $s2d_op_p,
 575                                 });
 576                 require PublicInbox::LeiStoreErr;
 577                 PublicInbox::LeiStoreErr->new($r, $lei);
 578                 $s2d_op_c->{ops} = {
 579                         sto_done_complete => [ $lei->can('sto_done_complete') ]
 580                 };
 581         }
 582         $lei->{sto} = $self;
 583 }
 584
 585 1;