lib/PublicInbox/LeiStore.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Local storage (cache/memo) for lei(1), suitable for personal/private
   5 # mail iff on encrypted device/FS.  Based on v2, but only deduplicates
   6 # based on git OID.
   7 #
   8 # for xref3, the following are constant: $eidx_key = '.', $xnum = -1
   9 package PublicInbox::LeiStore;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Lock PublicInbox::IPC);
  13 use PublicInbox::ExtSearchIdx;
  14 use PublicInbox::Import;
  15 use PublicInbox::InboxWritable qw(eml_from_path);
  16 use PublicInbox::V2Writable;
  17 use PublicInbox::ContentHash qw(content_hash);
  18 use PublicInbox::MID qw(mids);
  19 use PublicInbox::LeiSearch;
  20 use PublicInbox::MDA;
  21 use List::Util qw(max);
  22
  23 sub new {
  24         my (undef, $dir, $opt) = @_;
  25         my $eidx = PublicInbox::ExtSearchIdx->new($dir, $opt);
  26         my $self = bless { priv_eidx => $eidx }, __PACKAGE__;
  27         eidx_init($self)->done if $opt->{creat};
  28         $self;
  29 }
  30
  31 sub git { $_[0]->{priv_eidx}->git } # read-only
  32
  33 sub packing_factor { $PublicInbox::V2Writable::PACKING_FACTOR }
  34
  35 sub rotate_bytes {
  36         $_[0]->{rotate_bytes} // ((1024 * 1024 * 1024) / $_[0]->packing_factor)
  37 }
  38
  39 sub git_pfx { "$_[0]->{priv_eidx}->{topdir}/local" };
  40
  41 sub git_epoch_max  {
  42         my ($self) = @_;
  43         if (opendir(my $dh, $self->git_pfx)) {
  44                 max(map {
  45                         substr($_, 0, -4) + 0; # drop ".git" suffix
  46                 } grep(/\A[0-9]+\.git\z/, readdir($dh))) // 0;
  47         } else {
  48                 $!{ENOENT} ? 0 : die("opendir ${\$self->git_pfx}: $!\n");
  49         }
  50 }
  51
  52 sub git_ident ($) {
  53         my ($git) = @_;
  54         chomp(my $i = $git->qx(qw(var GIT_COMMITTER_IDENT)));
  55         warn "$git->{git_dir} GIT_COMMITTER_IDENT failed\n" if $?;
  56         $i =~ /\A(.+) <([^>]+)> [0-9]+ [-\+]?[0-9]+$/ ? ($1, $2) :
  57                 ('lei user', 'x@example.com')
  58 }
  59
  60 sub importer {
  61         my ($self) = @_;
  62         my $max;
  63         my $im = $self->{im};
  64         if ($im) {
  65                 return $im if $im->{bytes_added} < $self->rotate_bytes;
  66
  67                 delete $self->{im};
  68                 $im->done;
  69                 undef $im;
  70                 $self->checkpoint;
  71                 $max = $self->git_epoch_max + 1;
  72         }
  73         my $pfx = $self->git_pfx;
  74         $max //= $self->git_epoch_max;
  75         while (1) {
  76                 my $latest = "$pfx/$max.git";
  77                 my $old = -e $latest;
  78                 PublicInbox::Import::init_bare($latest);
  79                 my $git = PublicInbox::Git->new($latest);
  80                 $git->qx(qw(config core.sharedRepository 0600)) if !$old;
  81                 my $packed_bytes = $git->packed_bytes;
  82                 my $unpacked_bytes = $packed_bytes / $self->packing_factor;
  83                 if ($unpacked_bytes >= $self->rotate_bytes) {
  84                         $max++;
  85                         next;
  86                 }
  87                 my ($n, $e) = git_ident($git);
  88                 $self->{im} = $im = PublicInbox::Import->new($git, $n, $e);
  89                 $im->{bytes_added} = int($packed_bytes / $self->packing_factor);
  90                 $im->{lock_path} = undef;
  91                 $im->{path_type} = 'v2';
  92                 return $im;
  93         }
  94 }
  95
  96 sub search {
  97         PublicInbox::LeiSearch->new($_[0]->{priv_eidx}->{topdir});
  98 }
  99
 100 sub eidx_init {
 101         my ($self) = @_;
 102         my $eidx = $self->{priv_eidx};
 103         $eidx->idx_init({-private => 1});
 104         $eidx;
 105 }
 106
 107 sub _docids_for ($$) {
 108         my ($self, $eml) = @_;
 109         my %docids;
 110         my ($chash, $mids) = PublicInbox::LeiSearch::content_key($eml);
 111         my $eidx = eidx_init($self);
 112         my $oidx = $eidx->{oidx};
 113         my $im = $self->{im};
 114         for my $mid (@$mids) {
 115                 my ($id, $prev);
 116                 while (my $cur = $oidx->next_by_mid($mid, \$id, \$prev)) {
 117                         my $oid = $cur->{blob};
 118                         my $docid = $cur->{num};
 119                         my $bref = $im ? $im->cat_blob($oid) : undef;
 120                         $bref //= $eidx->git->cat_file($oid) // do {
 121                                 warn "W: $oid (#$docid) <$mid> not found\n";
 122                                 next;
 123                         };
 124                         local $self->{current_info} = $oid;
 125                         my $x = PublicInbox::Eml->new($bref);
 126                         $docids{$docid} = $docid if content_hash($x) eq $chash;
 127                 }
 128         }
 129         sort { $a <=> $b } values %docids;
 130 }
 131
 132 sub set_eml_keywords {
 133         my ($self, $eml, @kw) = @_;
 134         my $eidx = eidx_init($self);
 135         my @docids = _docids_for($self, $eml);
 136         for my $docid (@docids) {
 137                 $eidx->idx_shard($docid)->ipc_do('set_keywords', $docid, @kw);
 138         }
 139         \@docids;
 140 }
 141
 142 sub add_eml_keywords {
 143         my ($self, $eml, @kw) = @_;
 144         my $eidx = eidx_init($self);
 145         my @docids = _docids_for($self, $eml);
 146         for my $docid (@docids) {
 147                 $eidx->idx_shard($docid)->ipc_do('add_keywords', $docid, @kw);
 148         }
 149         \@docids;
 150 }
 151
 152 sub remove_eml_keywords {
 153         my ($self, $eml, @kw) = @_;
 154         my $eidx = eidx_init($self);
 155         my @docids = _docids_for($self, $eml);
 156         for my $docid (@docids) {
 157                 $eidx->idx_shard($docid)->ipc_do('remove_keywords', $docid, @kw)
 158         }
 159         \@docids;
 160 }
 161
 162 # TODO: move this to MdirReader, maybe...
 163 # cf: https://cr.yp.to/proto/maildir.html
 164 my %c2kw = ('D' => 'draft', F => 'flagged', R => 'answered', S => 'seen');
 165 sub maildir_keywords {
 166         $_[-1] =~ /:2,([A-Z]+)\z/i ?
 167                 sort(map { $c2kw{$_} // () } split(//, $1)) : ();
 168 }
 169
 170 sub add_eml {
 171         my ($self, $eml, @kw) = @_;
 172         my $im = $self->importer; # may create new epoch
 173         my $eidx = eidx_init($self); # writes ALL.git/objects/info/alternates
 174         my $oidx = $eidx->{oidx};
 175         my $smsg = bless { -oidx => $oidx }, 'PublicInbox::Smsg';
 176         $im->add($eml, undef, $smsg) or return; # duplicate returns undef
 177
 178         local $self->{current_info} = $smsg->{blob};
 179         if (my @docids = _docids_for($self, $eml)) {
 180                 for my $docid (@docids) {
 181                         my $idx = $eidx->idx_shard($docid);
 182                         $oidx->add_xref3($docid, -1, $smsg->{blob}, '.');
 183                         # add_eidx_info for List-Id
 184                         $idx->ipc_do('add_eidx_info', $docid, '.', $eml);
 185                         $idx->ipc_do('add_keywords', $docid, @kw) if @kw;
 186                 }
 187                 \@docids;
 188         } else {
 189                 $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 190                 $oidx->add_overview($eml, $smsg);
 191                 $oidx->add_xref3($smsg->{num}, -1, $smsg->{blob}, '.');
 192                 my $idx = $eidx->idx_shard($smsg->{num});
 193                 $idx->index_eml($eml, $smsg);
 194                 $idx->ipc_do('add_keywords', $smsg->{num}, @kw) if @kw;
 195                 $smsg;
 196         }
 197 }
 198
 199 sub set_eml {
 200         my ($self, $eml, @kw) = @_;
 201         add_eml($self, $eml, @kw) // set_eml_keywords($self, $eml, @kw);
 202 }
 203
 204 sub add_eml_maybe {
 205         my ($self, $eml) = @_;
 206         my $lxs = $self->{lxs_all_local} // die 'BUG: no {lxs_all_local}';
 207         return if $lxs->xids_for($eml, 1);
 208         add_eml($self, $eml);
 209 }
 210
 211 # set or update keywords for external message, called via ipc_do
 212 sub set_xkw {
 213         my ($self, $eml, $kw) = @_;
 214         my $lxs = $self->{lxs_all_local} // die 'BUG: no {lxs_all_local}';
 215         if ($lxs->xids_for($eml, 1)) { # is it in a local external?
 216                 # TODO: index keywords only
 217         } else {
 218                 set_eml($self, $eml, @$kw);
 219         }
 220 }
 221
 222 sub checkpoint {
 223         my ($self, $wait) = @_;
 224         if (my $im = $self->{im}) {
 225                 $wait ? $im->barrier : $im->checkpoint;
 226         }
 227         $self->{priv_eidx}->checkpoint($wait);
 228 }
 229
 230 sub done {
 231         my ($self) = @_;
 232         my $err = '';
 233         if (my $im = delete($self->{im})) {
 234                 eval { $im->done };
 235                 if ($@) {
 236                         $err .= "import done: $@\n";
 237                         warn $err;
 238                 }
 239         }
 240         $self->{priv_eidx}->done;
 241         die $err if $err;
 242 }
 243
 244 sub ipc_atfork_child {
 245         my ($self) = @_;
 246         my $lei = $self->{lei};
 247         $lei->lei_atfork_child(1) if $lei;
 248         $self->SUPER::ipc_atfork_child;
 249 }
 250
 251 sub refresh_local_externals {
 252         my ($self) = @_;
 253         my $cfg = $self->{lei}->_lei_cfg or return;
 254         my $cur_cfg = $self->{cur_cfg} // -1;
 255         my $lxs = $self->{lxs_all_local};
 256         if ($cfg != $cur_cfg || !$lxs) {
 257                 $lxs = PublicInbox::LeiXSearch->new;
 258                 my @loc = $self->{lei}->externals_each;
 259                 for my $loc (@loc) { # locals only
 260                         $lxs->prepare_external($loc) if -d $loc;
 261                 }
 262                 $self->{lxs_all_local} = $lxs;
 263                 $self->{cur_cfg} = $cfg;
 264         }
 265         ($lxs->{git_tmp} //= $lxs->git_tmp)->{git_dir};
 266 }
 267
 268 sub write_prepare {
 269         my ($self, $lei) = @_;
 270         unless ($self->{-ipc_req}) {
 271                 require PublicInbox::LeiXSearch;
 272                 $self->ipc_lock_init;
 273                 # Mail we import into lei are private, so headers filtered out
 274                 # by -mda for public mail are not appropriate
 275                 local @PublicInbox::MDA::BAD_HEADERS = ();
 276                 $self->ipc_worker_spawn('lei_store', $lei->oldset,
 277                                         { lei => $lei });
 278         }
 279         $lei->{all_ext_git_dir} = $self->ipc_do('refresh_local_externals');
 280         $lei->{sto} = $self;
 281 }
 282
 283 1;