lib/PublicInbox/LeiStore.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Local storage (cache/memo) for lei(1), suitable for personal/private
   5 # mail iff on encrypted device/FS.  Based on v2, but only deduplicates
   6 # git storage based on git OID (index deduplication is done in ContentHash)
   7 #
   8 # for xref3, the following are constant: $eidx_key = '.', $xnum = -1
   9 #
  10 # We rely on the synchronous IPC API for this in lei-daemon and
  11 # multiple lei clients to write to it at once.  This allows the
  12 # lei/store IPC process to be decoupled from network latency in
  13 # lei WQ workers.
  14 package PublicInbox::LeiStore;
  15 use strict;
  16 use v5.10.1;
  17 use parent qw(PublicInbox::Lock PublicInbox::IPC);
  18 use PublicInbox::ExtSearchIdx;
  19 use PublicInbox::Eml;
  20 use PublicInbox::Import;
  21 use PublicInbox::InboxWritable qw(eml_from_path);
  22 use PublicInbox::V2Writable;
  23 use PublicInbox::ContentHash qw(content_hash);
  24 use PublicInbox::MID qw(mids);
  25 use PublicInbox::LeiSearch;
  26 use PublicInbox::MDA;
  27 use PublicInbox::Spawn qw(spawn);
  28 use List::Util qw(max);
  29 use File::Temp ();
  30 use POSIX ();
  31
  32 sub new {
  33         my (undef, $dir, $opt) = @_;
  34         my $eidx = PublicInbox::ExtSearchIdx->new($dir, $opt);
  35         my $self = bless { priv_eidx => $eidx }, __PACKAGE__;
  36         eidx_init($self)->done if $opt->{creat};
  37         $self;
  38 }
  39
  40 sub git { $_[0]->{priv_eidx}->git } # read-only
  41
  42 sub packing_factor { $PublicInbox::V2Writable::PACKING_FACTOR }
  43
  44 sub rotate_bytes {
  45         $_[0]->{rotate_bytes} // ((1024 * 1024 * 1024) / $_[0]->packing_factor)
  46 }
  47
  48 sub git_pfx { "$_[0]->{priv_eidx}->{topdir}/local" };
  49
  50 sub git_epoch_max  {
  51         my ($self) = @_;
  52         if (opendir(my $dh, $self->git_pfx)) {
  53                 max(map {
  54                         substr($_, 0, -4) + 0; # drop ".git" suffix
  55                 } grep(/\A[0-9]+\.git\z/, readdir($dh))) // 0;
  56         } else {
  57                 $!{ENOENT} ? 0 : die("opendir ${\$self->git_pfx}: $!\n");
  58         }
  59 }
  60
  61 sub git_ident ($) {
  62         my ($git) = @_;
  63         my $rdr = {};
  64         open $rdr->{2}, '>', '/dev/null' or die "open /dev/null: $!";
  65         chomp(my $i = $git->qx([qw(var GIT_COMMITTER_IDENT)], undef, $rdr));
  66         $i =~ /\A(.+) <([^>]+)> [0-9]+ [-\+]?[0-9]+$/ and return ($1, $2);
  67         my ($user, undef, undef, undef, undef, undef, $gecos) = getpwuid($<);
  68         ($user) = (($user // $ENV{USER} // '') =~ /([\w\-\.\+]+)/);
  69         $user //= 'lei-user';
  70         ($gecos) = (($gecos // '') =~ /([\w\-\.\+ \t]+)/);
  71         $gecos //= 'lei user';
  72         require Sys::Hostname;
  73         my ($host) = (Sys::Hostname::hostname() =~ /([\w\-\.]+)/);
  74         $host //= 'localhost';
  75         ($gecos, "$user\@$host")
  76 }
  77
  78 sub importer {
  79         my ($self) = @_;
  80         my $max;
  81         my $im = $self->{im};
  82         if ($im) {
  83                 return $im if $im->{bytes_added} < $self->rotate_bytes;
  84
  85                 delete $self->{im};
  86                 $im->done;
  87                 undef $im;
  88                 $self->checkpoint;
  89                 $max = $self->git_epoch_max + 1;
  90         }
  91         my (undef, $tl) = eidx_init($self); # acquire lock
  92         my $pfx = $self->git_pfx;
  93         $max //= $self->git_epoch_max;
  94         while (1) {
  95                 my $latest = "$pfx/$max.git";
  96                 my $old = -e $latest;
  97                 PublicInbox::Import::init_bare($latest);
  98                 my $git = PublicInbox::Git->new($latest);
  99                 if (!$old) {
 100                         $git->qx(qw(config core.sharedRepository 0600));
 101                         $self->done; # unlock
 102                         # re-acquire lock, update alternates for new epoch
 103                         (undef, $tl) = eidx_init($self);
 104                 }
 105                 my $packed_bytes = $git->packed_bytes;
 106                 my $unpacked_bytes = $packed_bytes / $self->packing_factor;
 107                 if ($unpacked_bytes >= $self->rotate_bytes) {
 108                         $max++;
 109                         next;
 110                 }
 111                 my ($n, $e) = git_ident($git);
 112                 $self->{im} = $im = PublicInbox::Import->new($git, $n, $e);
 113                 $im->{bytes_added} = int($packed_bytes / $self->packing_factor);
 114                 $im->{lock_path} = undef;
 115                 $im->{path_type} = 'v2';
 116                 return $im;
 117         }
 118 }
 119
 120 sub search {
 121         PublicInbox::LeiSearch->new($_[0]->{priv_eidx}->{topdir});
 122 }
 123
 124 # follows the stderr file
 125 sub _tail_err {
 126         my ($self) = @_;
 127         print { $self->{-err_wr} } readline($self->{-tmp_err});
 128 }
 129
 130 sub eidx_init {
 131         my ($self) = @_;
 132         my $eidx = $self->{priv_eidx};
 133         my $tl = wantarray && $self->{-err_wr} ?
 134                         PublicInbox::OnDestroy->new($$, \&_tail_err, $self) :
 135                         undef;
 136         $eidx->idx_init({-private => 1}); # acquires lock
 137         wantarray ? ($eidx, $tl) : $eidx;
 138 }
 139
 140 sub _docids_for ($$) {
 141         my ($self, $eml) = @_;
 142         my %docids;
 143         my $eidx = $self->{priv_eidx};
 144         my ($chash, $mids) = PublicInbox::LeiSearch::content_key($eml);
 145         my $oidx = $eidx->{oidx};
 146         my $im = $self->{im};
 147         for my $mid (@$mids) {
 148                 my ($id, $prev);
 149                 while (my $cur = $oidx->next_by_mid($mid, \$id, \$prev)) {
 150                         next if $cur->{bytes} == 0; # external-only message
 151                         my $oid = $cur->{blob};
 152                         my $docid = $cur->{num};
 153                         my $bref = $im ? $im->cat_blob($oid) : undef;
 154                         $bref //= $eidx->git->cat_file($oid) // do {
 155                                 warn "W: $oid (#$docid) <$mid> not found\n";
 156                                 next;
 157                         };
 158                         local $self->{current_info} = $oid;
 159                         my $x = PublicInbox::Eml->new($bref);
 160                         $docids{$docid} = $docid if content_hash($x) eq $chash;
 161                 }
 162         }
 163         sort { $a <=> $b } values %docids;
 164 }
 165
 166 sub set_eml_vmd {
 167         my ($self, $eml, $vmd, $docids) = @_;
 168         my ($eidx, $tl) = eidx_init($self);
 169         $docids //= [ _docids_for($self, $eml) ];
 170         for my $docid (@$docids) {
 171                 $eidx->idx_shard($docid)->ipc_do('set_vmd', $docid, $vmd);
 172         }
 173         $docids;
 174 }
 175
 176 sub add_eml_vmd {
 177         my ($self, $eml, $vmd) = @_;
 178         my ($eidx, $tl) = eidx_init($self);
 179         my @docids = _docids_for($self, $eml);
 180         for my $docid (@docids) {
 181                 $eidx->idx_shard($docid)->ipc_do('add_vmd', $docid, $vmd);
 182         }
 183         \@docids;
 184 }
 185
 186 sub remove_eml_vmd {
 187         my ($self, $eml, $vmd) = @_;
 188         my ($eidx, $tl) = eidx_init($self);
 189         my @docids = _docids_for($self, $eml);
 190         for my $docid (@docids) {
 191                 $eidx->idx_shard($docid)->ipc_do('remove_vmd', $docid, $vmd);
 192         }
 193         \@docids;
 194 }
 195
 196 sub set_sync_info ($$$) {
 197         my ($self, $oidhex, $sync_info) = @_;
 198         ($self->{lms} //= do {
 199                 require PublicInbox::LeiMailSync;
 200                 my $f = "$self->{priv_eidx}->{topdir}/mail_sync.sqlite3";
 201                 my $lms = PublicInbox::LeiMailSync->new($f);
 202                 $lms->lms_begin;
 203                 $lms;
 204         })->set_src($oidhex, @$sync_info);
 205 }
 206
 207 sub add_eml {
 208         my ($self, $eml, $vmd, $xoids) = @_;
 209         my $im = $self->importer; # may create new epoch
 210         my ($eidx, $tl) = eidx_init($self);
 211         my $oidx = $eidx->{oidx}; # PublicInbox::Import::add checks this
 212         my $smsg = bless { -oidx => $oidx }, 'PublicInbox::Smsg';
 213         my $im_mark = $im->add($eml, undef, $smsg);
 214         if ($vmd && $vmd->{sync_info}) {
 215                 set_sync_info($self, $smsg->{blob}, $vmd->{sync_info});
 216         }
 217         $im_mark or return; # duplicate blob returns undef
 218
 219         local $self->{current_info} = $smsg->{blob};
 220         my $vivify_xvmd = delete($smsg->{-vivify_xvmd}) // []; # exact matches
 221         if ($xoids) { # fuzzy matches from externals in ale->xoids_for
 222                 delete $xoids->{$smsg->{blob}}; # added later
 223                 if (scalar keys %$xoids) {
 224                         my %docids = map { $_ => 1 } @$vivify_xvmd;
 225                         for my $oid (keys %$xoids) {
 226                                 my @id = $oidx->blob_exists($oid);
 227                                 @docids{@id} = @id;
 228                         }
 229                         @$vivify_xvmd = sort { $a <=> $b } keys(%docids);
 230                 }
 231         }
 232         if (@$vivify_xvmd) {
 233                 $xoids //= {};
 234                 $xoids->{$smsg->{blob}} = 1;
 235                 for my $docid (@$vivify_xvmd) {
 236                         my $cur = $oidx->get_art($docid);
 237                         my $idx = $eidx->idx_shard($docid);
 238                         if (!$cur || $cur->{bytes} == 0) { # really vivifying
 239                                 $smsg->{num} = $docid;
 240                                 $oidx->add_overview($eml, $smsg);
 241                                 $smsg->{-merge_vmd} = 1;
 242                                 $idx->index_eml($eml, $smsg);
 243                         } else { # lse fuzzy hit off ale
 244                                 $idx->ipc_do('add_eidx_info', $docid, '.', $eml);
 245                         }
 246                         for my $oid (keys %$xoids) {
 247                                 $oidx->add_xref3($docid, -1, $oid, '.');
 248                         }
 249                         $idx->ipc_do('add_vmd', $docid, $vmd) if $vmd;
 250                 }
 251                 $vivify_xvmd;
 252         } elsif (my @docids = _docids_for($self, $eml)) {
 253                 # fuzzy match from within lei/store
 254                 for my $docid (@docids) {
 255                         my $idx = $eidx->idx_shard($docid);
 256                         $oidx->add_xref3($docid, -1, $smsg->{blob}, '.');
 257                         # add_eidx_info for List-Id
 258                         $idx->ipc_do('add_eidx_info', $docid, '.', $eml);
 259                         $idx->ipc_do('add_vmd', $docid, $vmd) if $vmd;
 260                 }
 261                 \@docids;
 262         } else { # totally new message
 263                 $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 264                 $oidx->add_overview($eml, $smsg);
 265                 $oidx->add_xref3($smsg->{num}, -1, $smsg->{blob}, '.');
 266                 my $idx = $eidx->idx_shard($smsg->{num});
 267                 $idx->index_eml($eml, $smsg);
 268                 $idx->ipc_do('add_vmd', $smsg->{num}, $vmd) if $vmd;
 269                 $smsg;
 270         }
 271 }
 272
 273 sub set_eml {
 274         my ($self, $eml, $vmd, $xoids) = @_;
 275         add_eml($self, $eml, $vmd, $xoids) //
 276                 set_eml_vmd($self, $eml, $vmd);
 277 }
 278
 279 sub _external_only ($$$) {
 280         my ($self, $xoids, $eml) = @_;
 281         my $eidx = $self->{priv_eidx};
 282         my $oidx = $eidx->{oidx} // die 'BUG: {oidx} missing';
 283         my $smsg = bless { blob => '' }, 'PublicInbox::Smsg';
 284         $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 285         # save space for an externals-only message
 286         my $hdr = $eml->header_obj;
 287         $smsg->populate($hdr); # sets lines == 0
 288         $smsg->{bytes} = 0;
 289         delete @$smsg{qw(From Subject)};
 290         $smsg->{to} = $smsg->{cc} = $smsg->{from} = '';
 291         $oidx->add_overview($hdr, $smsg); # subject+references for threading
 292         $smsg->{subject} = '';
 293         for my $oid (keys %$xoids) {
 294                 $oidx->add_xref3($smsg->{num}, -1, $oid, '.');
 295         }
 296         my $idx = $eidx->idx_shard($smsg->{num});
 297         $idx->index_eml(PublicInbox::Eml->new("\n\n"), $smsg);
 298         ($smsg, $idx);
 299 }
 300
 301 sub update_xvmd {
 302         my ($self, $xoids, $eml, $vmd_mod) = @_;
 303         my ($eidx, $tl) = eidx_init($self);
 304         my $oidx = $eidx->{oidx};
 305         my %seen;
 306         for my $oid (keys %$xoids) {
 307                 my @docids = $oidx->blob_exists($oid) or next;
 308                 scalar(@docids) > 1 and
 309                         warn "W: $oid indexed as multiple docids: @docids\n";
 310                 for my $docid (@docids) {
 311                         next if $seen{$docid}++;
 312                         my $idx = $eidx->idx_shard($docid);
 313                         $idx->ipc_do('update_vmd', $docid, $vmd_mod);
 314                 }
 315                 delete $xoids->{$oid};
 316         }
 317         return unless scalar(keys(%$xoids));
 318
 319         # see if it was indexed, but with different OID(s)
 320         if (my @docids = _docids_for($self, $eml)) {
 321                 for my $docid (@docids) {
 322                         next if $seen{$docid};
 323                         for my $oid (keys %$xoids) {
 324                                 $oidx->add_xref3($docid, -1, $oid, '.');
 325                         }
 326                         my $idx = $eidx->idx_shard($docid);
 327                         $idx->ipc_do('update_vmd', $docid, $vmd_mod);
 328                 }
 329                 return;
 330         }
 331         # totally unseen
 332         my ($smsg, $idx) = _external_only($self, $xoids, $eml);
 333         $idx->ipc_do('update_vmd', $smsg->{num}, $vmd_mod);
 334 }
 335
 336 # set or update keywords for external message, called via ipc_do
 337 sub set_xvmd {
 338         my ($self, $xoids, $eml, $vmd) = @_;
 339
 340         my ($eidx, $tl) = eidx_init($self);
 341         my $oidx = $eidx->{oidx};
 342         my %seen;
 343
 344         # see if we can just update existing docs
 345         for my $oid (keys %$xoids) {
 346                 my @docids = $oidx->blob_exists($oid) or next;
 347                 scalar(@docids) > 1 and
 348                         warn "W: $oid indexed as multiple docids: @docids\n";
 349                 for my $docid (@docids) {
 350                         next if $seen{$docid}++;
 351                         my $idx = $eidx->idx_shard($docid);
 352                         $idx->ipc_do('set_vmd', $docid, $vmd);
 353                 }
 354                 delete $xoids->{$oid}; # all done with this oid
 355         }
 356         return unless scalar(keys(%$xoids));
 357
 358         # n.b. we don't do _docids_for here, we expect the caller
 359         # already checked $lse->kw_changed before calling this sub
 360
 361         return unless (@{$vmd->{kw} // []}) || (@{$vmd->{L} // []});
 362         # totally unseen:
 363         my ($smsg, $idx) = _external_only($self, $xoids, $eml);
 364         $idx->ipc_do('add_vmd', $smsg->{num}, $vmd);
 365 }
 366
 367 sub checkpoint {
 368         my ($self, $wait) = @_;
 369         if (my $im = $self->{im}) {
 370                 $wait ? $im->barrier : $im->checkpoint;
 371         }
 372         $self->{priv_eidx}->checkpoint($wait);
 373 }
 374
 375 sub xchg_stderr {
 376         my ($self) = @_;
 377         _tail_err($self) if $self->{-err_wr};
 378         my $dir = $self->{priv_eidx}->{topdir};
 379         return unless -e $dir;
 380         my $old = delete $self->{-tmp_err};
 381         my $pfx = POSIX::strftime('%Y%m%d%H%M%S', gmtime(time));
 382         my $err = File::Temp->new(TEMPLATE => "$pfx.$$.lei_storeXXXX",
 383                                 SUFFIX => '.err', DIR => $dir);
 384         open STDERR, '>>', $err->filename or die "dup2: $!";
 385         STDERR->autoflush(1); # shared with shard subprocesses
 386         $self->{-tmp_err} = $err; # separate file description for RO access
 387         undef;
 388 }
 389
 390 sub done {
 391         my ($self) = @_;
 392         my $err = '';
 393         if (my $im = delete($self->{im})) {
 394                 eval { $im->done };
 395                 if ($@) {
 396                         $err .= "import done: $@\n";
 397                         warn $err;
 398                 }
 399         }
 400         if (my $lms = delete $self->{lms}) {
 401                 $lms->lms_commit;
 402         }
 403         $self->{priv_eidx}->done; # V2Writable::done
 404         xchg_stderr($self);
 405         die $err if $err;
 406 }
 407
 408 sub ipc_atfork_child {
 409         my ($self) = @_;
 410         my $lei = $self->{lei};
 411         $lei->_lei_atfork_child(1) if $lei;
 412         xchg_stderr($self);
 413         if (my $err = delete($self->{err_pipe})) {
 414                 close $err->[0];
 415                 $self->{-err_wr} = $err->[1];
 416         }
 417         $self->SUPER::ipc_atfork_child;
 418 }
 419
 420 sub write_prepare {
 421         my ($self, $lei) = @_;
 422         unless ($self->{-ipc_req}) {
 423                 my $d = $lei->store_path;
 424                 $self->ipc_lock_init("$d/ipc.lock");
 425                 substr($d, -length('/lei/store'), 10, '');
 426                 my $err_pipe;
 427                 unless ($lei->{oneshot}) {
 428                         pipe(my ($r, $w)) or die "pipe: $!";
 429                         $err_pipe = [ $r, $w ];
 430                 }
 431                 # Mail we import into lei are private, so headers filtered out
 432                 # by -mda for public mail are not appropriate
 433                 local @PublicInbox::MDA::BAD_HEADERS = ();
 434                 $self->ipc_worker_spawn("lei/store $d", $lei->oldset,
 435                                         { lei => $lei, err_pipe => $err_pipe });
 436                 if ($err_pipe) {
 437                         require PublicInbox::LeiStoreErr;
 438                         PublicInbox::LeiStoreErr->new($err_pipe->[0], $lei);
 439                 }
 440         }
 441         $lei->{sto} = $self;
 442 }
 443
 444 1;