lib/PublicInbox/LeiStore.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Local storage (cache/memo) for lei(1), suitable for personal/private
   5 # mail iff on encrypted device/FS.  Based on v2, but only deduplicates
   6 # git storage based on git OID (index deduplication is done in ContentHash)
   7 #
   8 # for xref3, the following are constant: $eidx_key = '.', $xnum = -1
   9 #
  10 # We rely on the synchronous IPC API for this in lei-daemon and
  11 # multiple lei clients to write to it at once.  This allows the
  12 # lei/store IPC process to be decoupled from network latency in
  13 # lei WQ workers.
  14 package PublicInbox::LeiStore;
  15 use strict;
  16 use v5.10.1;
  17 use parent qw(PublicInbox::Lock PublicInbox::IPC);
  18 use PublicInbox::ExtSearchIdx;
  19 use PublicInbox::Eml;
  20 use PublicInbox::Import;
  21 use PublicInbox::InboxWritable qw(eml_from_path);
  22 use PublicInbox::V2Writable;
  23 use PublicInbox::ContentHash qw(content_hash);
  24 use PublicInbox::MID qw(mids);
  25 use PublicInbox::LeiSearch;
  26 use PublicInbox::MDA;
  27 use PublicInbox::Spawn qw(spawn);
  28 use PublicInbox::MdirReader;
  29 use PublicInbox::LeiToMail;
  30 use File::Temp ();
  31 use POSIX ();
  32 use IO::Handle (); # ->autoflush
  33 use Sys::Syslog qw(syslog openlog);
  34 use Errno qw(EEXIST ENOENT);
  35
  36 sub new {
  37         my (undef, $dir, $opt) = @_;
  38         my $eidx = PublicInbox::ExtSearchIdx->new($dir, $opt);
  39         my $self = bless { priv_eidx => $eidx }, __PACKAGE__;
  40         eidx_init($self)->done if $opt->{creat};
  41         $self;
  42 }
  43
  44 sub git { $_[0]->{priv_eidx}->git } # read-only
  45
  46 sub packing_factor { $PublicInbox::V2Writable::PACKING_FACTOR }
  47
  48 sub rotate_bytes {
  49         $_[0]->{rotate_bytes} // ((1024 * 1024 * 1024) / $_[0]->packing_factor)
  50 }
  51
  52 sub git_ident ($) {
  53         my ($git) = @_;
  54         my $rdr = {};
  55         open $rdr->{2}, '>', '/dev/null' or die "open /dev/null: $!";
  56         chomp(my $i = $git->qx([qw(var GIT_COMMITTER_IDENT)], undef, $rdr));
  57         $i =~ /\A(.+) <([^>]+)> [0-9]+ [-\+]?[0-9]+$/ and return ($1, $2);
  58         my ($user, undef, undef, undef, undef, undef, $gecos) = getpwuid($<);
  59         ($user) = (($user // $ENV{USER} // '') =~ /([\w\-\.\+]+)/);
  60         $user //= 'lei-user';
  61         ($gecos) = (($gecos // '') =~ /([\w\-\.\+ \t]+)/);
  62         $gecos //= 'lei user';
  63         require Sys::Hostname;
  64         my ($host) = (Sys::Hostname::hostname() =~ /([\w\-\.]+)/);
  65         $host //= 'localhost';
  66         ($gecos, "$user\@$host")
  67 }
  68
  69 sub importer {
  70         my ($self) = @_;
  71         my $max;
  72         my $im = $self->{im};
  73         if ($im) {
  74                 return $im if $im->{bytes_added} < $self->rotate_bytes;
  75
  76                 delete $self->{im};
  77                 $im->done;
  78                 undef $im;
  79                 $self->checkpoint;
  80                 $max = $self->{priv_eidx}->{mg}->git_epochs + 1;
  81         }
  82         my (undef, $tl) = eidx_init($self); # acquire lock
  83         $max //= $self->{priv_eidx}->{mg}->git_epochs;
  84         while (1) {
  85                 my $latest = $self->{priv_eidx}->{mg}->add_epoch($max);
  86                 my $git = PublicInbox::Git->new($latest);
  87                 $self->done; # unlock
  88                 # re-acquire lock, update alternates for new epoch
  89                 (undef, $tl) = eidx_init($self);
  90                 my $packed_bytes = $git->packed_bytes;
  91                 my $unpacked_bytes = $packed_bytes / $self->packing_factor;
  92                 if ($unpacked_bytes >= $self->rotate_bytes) {
  93                         $max++;
  94                         next;
  95                 }
  96                 my ($n, $e) = git_ident($git);
  97                 $self->{im} = $im = PublicInbox::Import->new($git, $n, $e);
  98                 $im->{bytes_added} = int($packed_bytes / $self->packing_factor);
  99                 $im->{lock_path} = undef;
 100                 $im->{path_type} = 'v2';
 101                 return $im;
 102         }
 103 }
 104
 105 sub search {
 106         PublicInbox::LeiSearch->new($_[0]->{priv_eidx}->{topdir});
 107 }
 108
 109 # follows the stderr file
 110 sub _tail_err {
 111         my ($self) = @_;
 112         print { $self->{-err_wr} } readline($self->{-tmp_err});
 113 }
 114
 115 sub eidx_init {
 116         my ($self) = @_;
 117         my $eidx = $self->{priv_eidx};
 118         my $tl = wantarray && $self->{-err_wr} ?
 119                         PublicInbox::OnDestroy->new($$, \&_tail_err, $self) :
 120                         undef;
 121         $eidx->idx_init({-private => 1}); # acquires lock
 122         wantarray ? ($eidx, $tl) : $eidx;
 123 }
 124
 125 sub _docids_for ($$) {
 126         my ($self, $eml) = @_;
 127         my %docids;
 128         my $eidx = $self->{priv_eidx};
 129         my ($chash, $mids) = PublicInbox::LeiSearch::content_key($eml);
 130         my $oidx = $eidx->{oidx};
 131         my $im = $self->{im};
 132         for my $mid (@$mids) {
 133                 my ($id, $prev);
 134                 while (my $cur = $oidx->next_by_mid($mid, \$id, \$prev)) {
 135                         next if $cur->{bytes} == 0; # external-only message
 136                         my $oid = $cur->{blob};
 137                         my $docid = $cur->{num};
 138                         my $bref = $im ? $im->cat_blob($oid) : undef;
 139                         $bref //= $eidx->git->cat_file($oid) //
 140                                 _lms_rw($self)->local_blob($oid, 1) // do {
 141                                 warn "W: $oid (#$docid) <$mid> not found\n";
 142                                 next;
 143                         };
 144                         local $self->{current_info} = $oid;
 145                         my $x = PublicInbox::Eml->new($bref);
 146                         $docids{$docid} = $docid if content_hash($x) eq $chash;
 147                 }
 148         }
 149         sort { $a <=> $b } values %docids;
 150 }
 151
 152 # n.b. similar to LeiExportKw->export_kw_md, but this is for a single eml
 153 sub export1_kw_md ($$$$$) {
 154         my ($self, $mdir, $bn, $oidbin, $vmdish) = @_; # vmd/vmd_mod
 155         my $orig = $bn;
 156         my (@try, $unkn, $kw);
 157         if ($bn =~ s/:2,([a-zA-Z]*)\z//) {
 158                 ($kw, $unkn) = PublicInbox::MdirReader::flags2kw($1);
 159                 if (my $set = $vmdish->{kw}) {
 160                         $kw = $set;
 161                 } elsif (my $add = $vmdish->{'+kw'}) {
 162                         @$kw{@$add} = ();
 163                 } elsif (my $del = $vmdish->{-kw}) {
 164                         delete @$kw{@$del};
 165                 } # else no changes...
 166                 @try = qw(cur new);
 167         } else { # no keywords, yet, could be in new/
 168                 @try = qw(new cur);
 169                 $unkn = [];
 170                 if (my $set = $vmdish->{kw}) {
 171                         $kw = $set;
 172                 } elsif (my $add = $vmdish->{'+kw'}) {
 173                         @$kw{@$add} = (); # auto-vivify
 174                 } else { # ignore $vmdish->{-kw}
 175                         $kw = [];
 176                 }
 177         }
 178         $kw = [ keys %$kw ] if ref($kw) eq 'HASH';
 179         $bn .= ':2,'. PublicInbox::LeiToMail::kw2suffix($kw, @$unkn);
 180         return if $orig eq $bn; # no change
 181
 182         # we use link(2) + unlink(2) since rename(2) may
 183         # inadvertently clobber if the "uniquefilename" part wasn't
 184         # actually unique.
 185         my $dst = "$mdir/cur/$bn";
 186         for my $d (@try) {
 187                 my $src = "$mdir/$d/$orig";
 188                 if (link($src, $dst)) {
 189                         if (!unlink($src) and $! != ENOENT) {
 190                                 syslog('warning', "unlink($src): $!");
 191                         }
 192                         # TODO: verify oidbin?
 193                         $self->{lms}->mv_src("maildir:$mdir",
 194                                         $oidbin, \$orig, $bn);
 195                         return;
 196                 } elsif ($! == EEXIST) { # lost race with "lei export-kw"?
 197                         return;
 198                 } elsif ($! != ENOENT) {
 199                         syslog('warning', "link($src -> $dst): $!");
 200                 }
 201         }
 202         for (@try) { return if -e "$mdir/$_/$orig" };
 203         $self->{lms}->clear_src("maildir:$mdir", \$orig);
 204 }
 205
 206 sub sto_export_kw ($$$) {
 207         my ($self, $docid, $vmdish) = @_; # vmdish (vmd or vmd_mod)
 208         my ($eidx, $tl) = eidx_init($self);
 209         my $lms = _lms_rw($self) // return;
 210         my $xr3 = $eidx->{oidx}->get_xref3($docid, 1);
 211         for my $row (@$xr3) {
 212                 my (undef, undef, $oidbin) = @$row;
 213                 my $locs = $lms->locations_for($oidbin) // next;
 214                 while (my ($loc, $ids) = each %$locs) {
 215                         if ($loc =~ s!\Amaildir:!!i) {
 216                                 for my $id (@$ids) {
 217                                         export1_kw_md($self, $loc, $id,
 218                                                         $oidbin, $vmdish);
 219                                 }
 220                         }
 221                         # TODO: IMAP
 222                 }
 223         }
 224 }
 225
 226 # vmd = { kw => [ qw(seen ...) ], L => [ qw(inbox ...) ] }
 227 sub set_eml_vmd {
 228         my ($self, $eml, $vmd, $docids) = @_;
 229         my ($eidx, $tl) = eidx_init($self);
 230         $docids //= [ _docids_for($self, $eml) ];
 231         for my $docid (@$docids) {
 232                 $eidx->idx_shard($docid)->ipc_do('set_vmd', $docid, $vmd);
 233                 sto_export_kw($self, $docid, $vmd);
 234         }
 235         $docids;
 236 }
 237
 238 sub add_eml_vmd {
 239         my ($self, $eml, $vmd) = @_;
 240         my ($eidx, $tl) = eidx_init($self);
 241         my @docids = _docids_for($self, $eml);
 242         for my $docid (@docids) {
 243                 $eidx->idx_shard($docid)->ipc_do('add_vmd', $docid, $vmd);
 244         }
 245         \@docids;
 246 }
 247
 248 sub remove_eml_vmd { # remove just the VMD
 249         my ($self, $eml, $vmd) = @_;
 250         my ($eidx, $tl) = eidx_init($self);
 251         my @docids = _docids_for($self, $eml);
 252         for my $docid (@docids) {
 253                 $eidx->idx_shard($docid)->ipc_do('remove_vmd', $docid, $vmd);
 254         }
 255         \@docids;
 256 }
 257
 258 sub _lms_rw ($) { # it is important to have eidx processes open before lms
 259         my ($self) = @_;
 260         my ($eidx, $tl) = eidx_init($self);
 261         $self->{lms} //= do {
 262                 require PublicInbox::LeiMailSync;
 263                 my $f = "$self->{priv_eidx}->{topdir}/mail_sync.sqlite3";
 264                 my $lms = PublicInbox::LeiMailSync->new($f);
 265                 $lms->lms_write_prepare;
 266                 $lms;
 267         };
 268 }
 269
 270 sub set_sync_info {
 271         my ($self, $oidhex, $folder, $id) = @_;
 272         _lms_rw($self)->set_src(pack('H*', $oidhex), $folder, $id);
 273 }
 274
 275 sub _remove_if_local { # git->cat_async arg
 276         my ($bref, $oidhex, $type, $size, $self) = @_;
 277         $self->{im}->remove($bref) if $bref;
 278 }
 279
 280 sub remove_docids ($;@) {
 281         my ($self, @docids) = @_;
 282         my $eidx = eidx_init($self);
 283         for my $docid (@docids) {
 284                 $eidx->remove_doc($docid);
 285                 $eidx->{oidx}->{dbh}->do(<<EOF, undef, $docid);
 286 DELETE FROM xref3 WHERE docid = ?
 287 EOF
 288         }
 289 }
 290
 291 # remove the entire message from the index, does not touch mail_sync.sqlite3
 292 sub remove_eml {
 293         my ($self, $eml) = @_;
 294         my $im = $self->importer; # may create new epoch
 295         my ($eidx, $tl) = eidx_init($self);
 296         my $oidx = $eidx->{oidx};
 297         my @docids = _docids_for($self, $eml);
 298         my $git = $eidx->git;
 299         for my $docid (@docids) {
 300                 my $xr3 = $oidx->get_xref3($docid, 1);
 301                 for my $row (@$xr3) {
 302                         my (undef, undef, $oidbin) = @$row;
 303                         my $oidhex = unpack('H*', $oidbin);
 304                         $git->cat_async($oidhex, \&_remove_if_local, $self);
 305                 }
 306         }
 307         $git->async_wait_all;
 308         remove_docids($self, @docids);
 309         \@docids;
 310 }
 311
 312 sub oid2docid ($$) {
 313         my ($self, $oid) = @_;
 314         my $eidx = eidx_init($self);
 315         my ($docid, @cull) = $eidx->{oidx}->blob_exists($oid);
 316         if (@cull) { # fixup old bugs...
 317                 warn <<EOF;
 318 W: $oid indexed as multiple docids: $docid @cull, culling to fixup old bugs
 319 EOF
 320                 remove_docids($self, @cull);
 321         }
 322         $docid;
 323 }
 324
 325 sub _add_vmd ($$$$) {
 326         my ($self, $idx, $docid, $vmd) = @_;
 327         $idx->ipc_do('add_vmd', $docid, $vmd);
 328         sto_export_kw($self, $docid, $vmd);
 329 }
 330
 331 sub add_eml {
 332         my ($self, $eml, $vmd, $xoids) = @_;
 333         my $im = $self->{-fake_im} // $self->importer; # may create new epoch
 334         my ($eidx, $tl) = eidx_init($self);
 335         my $oidx = $eidx->{oidx}; # PublicInbox::Import::add checks this
 336         my $smsg = bless { -oidx => $oidx }, 'PublicInbox::Smsg';
 337         $smsg->{-eidx_git} = $eidx->git if !$self->{-fake_im};
 338         my $im_mark = $im->add($eml, undef, $smsg);
 339         if ($vmd && $vmd->{sync_info}) {
 340                 set_sync_info($self, $smsg->{blob}, @{$vmd->{sync_info}});
 341         }
 342         $im_mark or return; # duplicate blob returns undef
 343
 344         local $self->{current_info} = $smsg->{blob};
 345         my $vivify_xvmd = delete($smsg->{-vivify_xvmd}) // []; # exact matches
 346         if ($xoids) { # fuzzy matches from externals in ale->xoids_for
 347                 delete $xoids->{$smsg->{blob}}; # added later
 348                 if (scalar keys %$xoids) {
 349                         my %docids = map { $_ => 1 } @$vivify_xvmd;
 350                         for my $oid (keys %$xoids) {
 351                                 my $docid = oid2docid($self, $oid);
 352                                 $docids{$docid} = $docid if defined($docid);
 353                         }
 354                         @$vivify_xvmd = sort { $a <=> $b } keys(%docids);
 355                 }
 356         }
 357         if (@$vivify_xvmd) { # docids list
 358                 $xoids //= {};
 359                 $xoids->{$smsg->{blob}} = 1;
 360                 for my $docid (@$vivify_xvmd) {
 361                         my $cur = $oidx->get_art($docid);
 362                         my $idx = $eidx->idx_shard($docid);
 363                         if (!$cur || $cur->{bytes} == 0) { # really vivifying
 364                                 $smsg->{num} = $docid;
 365                                 $oidx->add_overview($eml, $smsg);
 366                                 $smsg->{-merge_vmd} = 1;
 367                                 $idx->index_eml($eml, $smsg);
 368                         } else { # lse fuzzy hit off ale
 369                                 $idx->ipc_do('add_eidx_info', $docid, '.', $eml);
 370                         }
 371                         for my $oid (keys %$xoids) {
 372                                 $oidx->add_xref3($docid, -1, $oid, '.');
 373                         }
 374                         _add_vmd($self, $idx, $docid, $vmd) if $vmd;
 375                 }
 376                 $vivify_xvmd;
 377         } elsif (my @docids = _docids_for($self, $eml)) {
 378                 # fuzzy match from within lei/store
 379                 for my $docid (@docids) {
 380                         my $idx = $eidx->idx_shard($docid);
 381                         $oidx->add_xref3($docid, -1, $smsg->{blob}, '.');
 382                         # add_eidx_info for List-Id
 383                         $idx->ipc_do('add_eidx_info', $docid, '.', $eml);
 384                         _add_vmd($self, $idx, $docid, $vmd) if $vmd;
 385                 }
 386                 \@docids;
 387         } else { # totally new message
 388                 delete $smsg->{-oidx}; # for IPC-friendliness
 389                 $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 390                 $oidx->add_overview($eml, $smsg);
 391                 $oidx->add_xref3($smsg->{num}, -1, $smsg->{blob}, '.');
 392                 my $idx = $eidx->idx_shard($smsg->{num});
 393                 $idx->index_eml($eml, $smsg);
 394                 _add_vmd($self, $idx, $smsg->{num}, $vmd) if $vmd;
 395                 $smsg;
 396         }
 397 }
 398
 399 sub set_eml {
 400         my ($self, $eml, $vmd, $xoids) = @_;
 401         add_eml($self, $eml, $vmd, $xoids) //
 402                 set_eml_vmd($self, $eml, $vmd);
 403 }
 404
 405 sub index_eml_only {
 406         my ($self, $eml, $vmd, $xoids) = @_;
 407         require PublicInbox::FakeImport;
 408         local $self->{-fake_im} = PublicInbox::FakeImport->new;
 409         set_eml($self, $eml, $vmd, $xoids);
 410 }
 411
 412 # store {kw} / {L} info for a message which is only in an external
 413 sub _external_only ($$$) {
 414         my ($self, $xoids, $eml) = @_;
 415         my $eidx = $self->{priv_eidx};
 416         my $oidx = $eidx->{oidx} // die 'BUG: {oidx} missing';
 417         my $smsg = bless { blob => '' }, 'PublicInbox::Smsg';
 418         $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 419         # save space for an externals-only message
 420         my $hdr = $eml->header_obj;
 421         $smsg->populate($hdr); # sets lines == 0
 422         $smsg->{bytes} = 0;
 423         delete @$smsg{qw(From Subject)};
 424         $smsg->{to} = $smsg->{cc} = $smsg->{from} = '';
 425         $oidx->add_overview($hdr, $smsg); # subject+references for threading
 426         $smsg->{subject} = '';
 427         for my $oid (keys %$xoids) {
 428                 $oidx->add_xref3($smsg->{num}, -1, $oid, '.');
 429         }
 430         my $idx = $eidx->idx_shard($smsg->{num});
 431         $idx->index_eml(PublicInbox::Eml->new("\n\n"), $smsg);
 432         ($smsg, $idx);
 433 }
 434
 435 sub update_xvmd {
 436         my ($self, $xoids, $eml, $vmd_mod) = @_;
 437         my ($eidx, $tl) = eidx_init($self);
 438         my $oidx = $eidx->{oidx};
 439         my %seen;
 440         for my $oid (keys %$xoids) {
 441                 my $docid = oid2docid($self, $oid) // next;
 442                 delete $xoids->{$oid};
 443                 next if $seen{$docid}++;
 444                 my $idx = $eidx->idx_shard($docid);
 445                 $idx->ipc_do('update_vmd', $docid, $vmd_mod);
 446                 sto_export_kw($self, $docid, $vmd_mod);
 447         }
 448         return unless scalar(keys(%$xoids));
 449
 450         # see if it was indexed, but with different OID(s)
 451         if (my @docids = _docids_for($self, $eml)) {
 452                 for my $docid (@docids) {
 453                         next if $seen{$docid};
 454                         for my $oid (keys %$xoids) {
 455                                 $oidx->add_xref3($docid, -1, $oid, '.');
 456                         }
 457                         my $idx = $eidx->idx_shard($docid);
 458                         $idx->ipc_do('update_vmd', $docid, $vmd_mod);
 459                         sto_export_kw($self, $docid, $vmd_mod);
 460                 }
 461                 return;
 462         }
 463         # totally unseen
 464         my ($smsg, $idx) = _external_only($self, $xoids, $eml);
 465         $idx->ipc_do('update_vmd', $smsg->{num}, $vmd_mod);
 466         sto_export_kw($self, $smsg->{num}, $vmd_mod);
 467 }
 468
 469 # set or update keywords for external message, called via ipc_do
 470 sub set_xvmd {
 471         my ($self, $xoids, $eml, $vmd) = @_;
 472
 473         my ($eidx, $tl) = eidx_init($self);
 474         my $oidx = $eidx->{oidx};
 475         my %seen;
 476
 477         # see if we can just update existing docs
 478         for my $oid (keys %$xoids) {
 479                 my $docid = oid2docid($self, $oid) // next;
 480                 delete $xoids->{$oid}; # all done with this oid
 481                 next if $seen{$docid}++;
 482                 my $idx = $eidx->idx_shard($docid);
 483                 $idx->ipc_do('set_vmd', $docid, $vmd);
 484                 sto_export_kw($self, $docid, $vmd);
 485         }
 486         return unless scalar(keys(%$xoids));
 487
 488         # n.b. we don't do _docids_for here, we expect the caller
 489         # already checked $lse->kw_changed before calling this sub
 490
 491         return unless (@{$vmd->{kw} // []}) || (@{$vmd->{L} // []});
 492         # totally unseen:
 493         my ($smsg, $idx) = _external_only($self, $xoids, $eml);
 494         $idx->ipc_do('add_vmd', $smsg->{num}, $vmd);
 495         sto_export_kw($self, $smsg->{num}, $vmd);
 496 }
 497
 498 sub checkpoint {
 499         my ($self, $wait) = @_;
 500         if (my $im = $self->{im}) {
 501                 $wait ? $im->barrier : $im->checkpoint;
 502         }
 503         delete $self->{lms};
 504         $self->{priv_eidx}->checkpoint($wait);
 505 }
 506
 507 sub xchg_stderr {
 508         my ($self) = @_;
 509         _tail_err($self) if $self->{-err_wr};
 510         my $dir = $self->{priv_eidx}->{topdir};
 511         return unless -e $dir;
 512         my $old = delete $self->{-tmp_err};
 513         my $pfx = POSIX::strftime('%Y%m%d%H%M%S', gmtime(time));
 514         my $err = File::Temp->new(TEMPLATE => "$pfx.$$.err-XXXX",
 515                                 SUFFIX => '.err', DIR => $dir);
 516         open STDERR, '>>', $err->filename or die "dup2: $!";
 517         STDERR->autoflush(1); # shared with shard subprocesses
 518         $self->{-tmp_err} = $err; # separate file description for RO access
 519         undef;
 520 }
 521
 522 sub done {
 523         my ($self, $sock_ref) = @_;
 524         my $err = '';
 525         if (my $im = delete($self->{im})) {
 526                 eval { $im->done };
 527                 if ($@) {
 528                         $err .= "import done: $@\n";
 529                         warn $err;
 530                 }
 531         }
 532         delete $self->{lms};
 533         $self->{priv_eidx}->done; # V2Writable::done
 534         xchg_stderr($self);
 535         die $err if $err;
 536 }
 537
 538 sub ipc_atfork_child {
 539         my ($self) = @_;
 540         my $lei = $self->{lei};
 541         $lei->_lei_atfork_child(1) if $lei;
 542         xchg_stderr($self);
 543         if (my $to_close = delete($self->{to_close})) {
 544                 close($_) for @$to_close;
 545         }
 546         openlog('lei/store', 'pid,nowait,nofatal,ndelay', 'user');
 547         $self->SUPER::ipc_atfork_child;
 548 }
 549
 550 sub recv_and_run {
 551         my ($self, @args) = @_;
 552         local $PublicInbox::DS::in_loop = 0; # waitpid synchronously
 553         $self->SUPER::recv_and_run(@args);
 554 }
 555
 556 sub write_prepare {
 557         my ($self, $lei) = @_;
 558         $lei // die 'BUG: $lei not passed';
 559         unless ($self->{-ipc_req}) {
 560                 my $dir = $lei->store_path;
 561                 substr($dir, -length('/lei/store'), 10, '');
 562                 pipe(my ($r, $w)) or die "pipe: $!";
 563                 $w->autoflush(1);
 564                 # Mail we import into lei are private, so headers filtered out
 565                 # by -mda for public mail are not appropriate
 566                 local @PublicInbox::MDA::BAD_HEADERS = ();
 567                 $self->wq_workers_start("lei/store $dir", 1, $lei->oldset, {
 568                                         lei => $lei,
 569                                         -err_wr => $w,
 570                                         to_close => [ $r ],
 571                                 });
 572                 require PublicInbox::LeiStoreErr;
 573                 PublicInbox::LeiStoreErr->new($r, $lei);
 574         }
 575         $lei->{sto} = $self;
 576 }
 577
 578 1;