lib/PublicInbox/LeiStore.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Local storage (cache/memo) for lei(1), suitable for personal/private
   5 # mail iff on encrypted device/FS.  Based on v2, but only deduplicates
   6 # git storage based on git OID (index deduplication is done in ContentHash)
   7 #
   8 # for xref3, the following are constant: $eidx_key = '.', $xnum = -1
   9 #
  10 # We rely on the synchronous IPC API for this in lei-daemon and
  11 # multiple lei clients to write to it at once.  This allows the
  12 # lei/store IPC process to be decoupled from network latency in
  13 # lei WQ workers.
  14 package PublicInbox::LeiStore;
  15 use strict;
  16 use v5.10.1;
  17 use parent qw(PublicInbox::Lock PublicInbox::IPC);
  18 use PublicInbox::ExtSearchIdx;
  19 use PublicInbox::Eml;
  20 use PublicInbox::Import;
  21 use PublicInbox::InboxWritable qw(eml_from_path);
  22 use PublicInbox::V2Writable;
  23 use PublicInbox::ContentHash qw(content_hash);
  24 use PublicInbox::MID qw(mids);
  25 use PublicInbox::LeiSearch;
  26 use PublicInbox::MDA;
  27 use PublicInbox::Spawn qw(spawn);
  28 use List::Util qw(max);
  29 use File::Temp ();
  30 use POSIX ();
  31
  32 sub new {
  33         my (undef, $dir, $opt) = @_;
  34         my $eidx = PublicInbox::ExtSearchIdx->new($dir, $opt);
  35         my $self = bless { priv_eidx => $eidx }, __PACKAGE__;
  36         eidx_init($self)->done if $opt->{creat};
  37         $self;
  38 }
  39
  40 sub git { $_[0]->{priv_eidx}->git } # read-only
  41
  42 sub packing_factor { $PublicInbox::V2Writable::PACKING_FACTOR }
  43
  44 sub rotate_bytes {
  45         $_[0]->{rotate_bytes} // ((1024 * 1024 * 1024) / $_[0]->packing_factor)
  46 }
  47
  48 sub git_pfx { "$_[0]->{priv_eidx}->{topdir}/local" };
  49
  50 sub git_epoch_max  {
  51         my ($self) = @_;
  52         if (opendir(my $dh, $self->git_pfx)) {
  53                 max(map {
  54                         substr($_, 0, -4) + 0; # drop ".git" suffix
  55                 } grep(/\A[0-9]+\.git\z/, readdir($dh))) // 0;
  56         } else {
  57                 $!{ENOENT} ? 0 : die("opendir ${\$self->git_pfx}: $!\n");
  58         }
  59 }
  60
  61 sub git_ident ($) {
  62         my ($git) = @_;
  63         my $rdr = {};
  64         open $rdr->{2}, '>', '/dev/null' or die "open /dev/null: $!";
  65         chomp(my $i = $git->qx([qw(var GIT_COMMITTER_IDENT)], undef, $rdr));
  66         $i =~ /\A(.+) <([^>]+)> [0-9]+ [-\+]?[0-9]+$/ and return ($1, $2);
  67         my ($user, undef, undef, undef, undef, undef, $gecos) = getpwuid($<);
  68         ($user) = (($user // $ENV{USER} // '') =~ /([\w\-\.\+]+)/);
  69         $user //= 'lei-user';
  70         ($gecos) = (($gecos // '') =~ /([\w\-\.\+ \t]+)/);
  71         $gecos //= 'lei user';
  72         require Sys::Hostname;
  73         my ($host) = (Sys::Hostname::hostname() =~ /([\w\-\.]+)/);
  74         $host //= 'localhost';
  75         ($gecos, "$user\@$host")
  76 }
  77
  78 sub importer {
  79         my ($self) = @_;
  80         my $max;
  81         my $im = $self->{im};
  82         if ($im) {
  83                 return $im if $im->{bytes_added} < $self->rotate_bytes;
  84
  85                 delete $self->{im};
  86                 $im->done;
  87                 undef $im;
  88                 $self->checkpoint;
  89                 $max = $self->git_epoch_max + 1;
  90         }
  91         my (undef, $tl) = eidx_init($self); # acquire lock
  92         my $pfx = $self->git_pfx;
  93         $max //= $self->git_epoch_max;
  94         while (1) {
  95                 my $latest = "$pfx/$max.git";
  96                 my $old = -e $latest;
  97                 PublicInbox::Import::init_bare($latest);
  98                 my $git = PublicInbox::Git->new($latest);
  99                 if (!$old) {
 100                         $git->qx(qw(config core.sharedRepository 0600));
 101                         $self->done; # unlock
 102                         # re-acquire lock, update alternates for new epoch
 103                         (undef, $tl) = eidx_init($self);
 104                 }
 105                 my $packed_bytes = $git->packed_bytes;
 106                 my $unpacked_bytes = $packed_bytes / $self->packing_factor;
 107                 if ($unpacked_bytes >= $self->rotate_bytes) {
 108                         $max++;
 109                         next;
 110                 }
 111                 my ($n, $e) = git_ident($git);
 112                 $self->{im} = $im = PublicInbox::Import->new($git, $n, $e);
 113                 $im->{bytes_added} = int($packed_bytes / $self->packing_factor);
 114                 $im->{lock_path} = undef;
 115                 $im->{path_type} = 'v2';
 116                 return $im;
 117         }
 118 }
 119
 120 sub search {
 121         PublicInbox::LeiSearch->new($_[0]->{priv_eidx}->{topdir});
 122 }
 123
 124 # follows the stderr file
 125 sub _tail_err {
 126         my ($self) = @_;
 127         print { $self->{-err_wr} } readline($self->{-tmp_err});
 128 }
 129
 130 sub eidx_init {
 131         my ($self) = @_;
 132         my $eidx = $self->{priv_eidx};
 133         my $tl = wantarray && $self->{-err_wr} ?
 134                         PublicInbox::OnDestroy->new($$, \&_tail_err, $self) :
 135                         undef;
 136         $eidx->idx_init({-private => 1}); # acquires lock
 137         wantarray ? ($eidx, $tl) : $eidx;
 138 }
 139
 140 sub _docids_for ($$) {
 141         my ($self, $eml) = @_;
 142         my %docids;
 143         my $eidx = $self->{priv_eidx};
 144         my ($chash, $mids) = PublicInbox::LeiSearch::content_key($eml);
 145         my $oidx = $eidx->{oidx};
 146         my $im = $self->{im};
 147         for my $mid (@$mids) {
 148                 my ($id, $prev);
 149                 while (my $cur = $oidx->next_by_mid($mid, \$id, \$prev)) {
 150                         next if $cur->{bytes} == 0; # external-only message
 151                         my $oid = $cur->{blob};
 152                         my $docid = $cur->{num};
 153                         my $bref = $im ? $im->cat_blob($oid) : undef;
 154                         $bref //= $eidx->git->cat_file($oid) // do {
 155                                 warn "W: $oid (#$docid) <$mid> not found\n";
 156                                 next;
 157                         };
 158                         local $self->{current_info} = $oid;
 159                         my $x = PublicInbox::Eml->new($bref);
 160                         $docids{$docid} = $docid if content_hash($x) eq $chash;
 161                 }
 162         }
 163         sort { $a <=> $b } values %docids;
 164 }
 165
 166 sub set_eml_vmd {
 167         my ($self, $eml, $vmd, $docids) = @_;
 168         my ($eidx, $tl) = eidx_init($self);
 169         $docids //= [ _docids_for($self, $eml) ];
 170         for my $docid (@$docids) {
 171                 $eidx->idx_shard($docid)->ipc_do('set_vmd', $docid, $vmd);
 172         }
 173         $docids;
 174 }
 175
 176 sub add_eml_vmd {
 177         my ($self, $eml, $vmd) = @_;
 178         my ($eidx, $tl) = eidx_init($self);
 179         my @docids = _docids_for($self, $eml);
 180         for my $docid (@docids) {
 181                 $eidx->idx_shard($docid)->ipc_do('add_vmd', $docid, $vmd);
 182         }
 183         \@docids;
 184 }
 185
 186 sub remove_eml_vmd { # remove just the VMD
 187         my ($self, $eml, $vmd) = @_;
 188         my ($eidx, $tl) = eidx_init($self);
 189         my @docids = _docids_for($self, $eml);
 190         for my $docid (@docids) {
 191                 $eidx->idx_shard($docid)->ipc_do('remove_vmd', $docid, $vmd);
 192         }
 193         \@docids;
 194 }
 195
 196 sub _lms_rw ($) {
 197         my ($self) = @_;
 198         my ($eidx, $tl) = eidx_init($self);
 199         $self->{lms} //= do {
 200                 require PublicInbox::LeiMailSync;
 201                 my $f = "$self->{priv_eidx}->{topdir}/mail_sync.sqlite3";
 202                 my $lms = PublicInbox::LeiMailSync->new($f);
 203                 $lms->lms_begin;
 204                 $lms;
 205         };
 206 }
 207
 208 sub lms_clear_src {
 209         my ($self, $folder, $id) = @_;
 210         _lms_rw($self)->clear_src($folder, $id);
 211 }
 212
 213 sub lms_mv_src {
 214         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 215         _lms_rw($self)->mv_src($folder, $oidbin, $id, $newbn);
 216 }
 217
 218 sub set_sync_info {
 219         my ($self, $oidhex, $folder, $id) = @_;
 220         _lms_rw($self)->set_src($oidhex, $folder, $id);
 221 }
 222
 223 sub _remove_if_local { # git->cat_async arg
 224         my ($bref, $oidhex, $type, $size, $self) = @_;
 225         $self->{im}->remove($bref) if $bref;
 226 }
 227
 228 # remove the entire message from the index, does not touch mail_sync.sqlite3
 229 sub remove_eml {
 230         my ($self, $eml) = @_;
 231         my $im = $self->importer; # may create new epoch
 232         my ($eidx, $tl) = eidx_init($self);
 233         my $oidx = $eidx->{oidx};
 234         my @docids = _docids_for($self, $eml);
 235         my $git = $eidx->git;
 236         for my $docid (@docids) {
 237                 my $xr3 = $oidx->get_xref3($docid, 1);
 238                 for my $row (@$xr3) {
 239                         my (undef, undef, $oidbin) = @$row;
 240                         my $oidhex = unpack('H*', $oidbin);
 241                         $git->cat_async($oidhex, \&_remove_if_local, $self);
 242                 }
 243                 $eidx->idx_shard($docid)->ipc_do('xdb_remove', $docid);
 244                 $oidx->delete_by_num($docid);
 245         }
 246         $git->cat_async_wait;
 247         \@docids;
 248 }
 249
 250 sub add_eml {
 251         my ($self, $eml, $vmd, $xoids) = @_;
 252         my $im = $self->{-fake_im} // $self->importer; # may create new epoch
 253         my ($eidx, $tl) = eidx_init($self);
 254         my $oidx = $eidx->{oidx}; # PublicInbox::Import::add checks this
 255         my $smsg = bless { -oidx => $oidx }, 'PublicInbox::Smsg';
 256         $smsg->{-eidx_git} = $eidx->git if !$self->{-fake_im};
 257         my $im_mark = $im->add($eml, undef, $smsg);
 258         if ($vmd && $vmd->{sync_info}) {
 259                 set_sync_info($self, $smsg->{blob}, @{$vmd->{sync_info}});
 260         }
 261         $im_mark or return; # duplicate blob returns undef
 262
 263         local $self->{current_info} = $smsg->{blob};
 264         my $vivify_xvmd = delete($smsg->{-vivify_xvmd}) // []; # exact matches
 265         if ($xoids) { # fuzzy matches from externals in ale->xoids_for
 266                 delete $xoids->{$smsg->{blob}}; # added later
 267                 if (scalar keys %$xoids) {
 268                         my %docids = map { $_ => 1 } @$vivify_xvmd;
 269                         for my $oid (keys %$xoids) {
 270                                 my @id = $oidx->blob_exists($oid);
 271                                 @docids{@id} = @id;
 272                         }
 273                         @$vivify_xvmd = sort { $a <=> $b } keys(%docids);
 274                 }
 275         }
 276         if (@$vivify_xvmd) {
 277                 $xoids //= {};
 278                 $xoids->{$smsg->{blob}} = 1;
 279                 for my $docid (@$vivify_xvmd) {
 280                         my $cur = $oidx->get_art($docid);
 281                         my $idx = $eidx->idx_shard($docid);
 282                         if (!$cur || $cur->{bytes} == 0) { # really vivifying
 283                                 $smsg->{num} = $docid;
 284                                 $oidx->add_overview($eml, $smsg);
 285                                 $smsg->{-merge_vmd} = 1;
 286                                 $idx->index_eml($eml, $smsg);
 287                         } else { # lse fuzzy hit off ale
 288                                 $idx->ipc_do('add_eidx_info', $docid, '.', $eml);
 289                         }
 290                         for my $oid (keys %$xoids) {
 291                                 $oidx->add_xref3($docid, -1, $oid, '.');
 292                         }
 293                         $idx->ipc_do('add_vmd', $docid, $vmd) if $vmd;
 294                 }
 295                 $vivify_xvmd;
 296         } elsif (my @docids = _docids_for($self, $eml)) {
 297                 # fuzzy match from within lei/store
 298                 for my $docid (@docids) {
 299                         my $idx = $eidx->idx_shard($docid);
 300                         $oidx->add_xref3($docid, -1, $smsg->{blob}, '.');
 301                         # add_eidx_info for List-Id
 302                         $idx->ipc_do('add_eidx_info', $docid, '.', $eml);
 303                         $idx->ipc_do('add_vmd', $docid, $vmd) if $vmd;
 304                 }
 305                 \@docids;
 306         } else { # totally new message
 307                 $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 308                 $oidx->add_overview($eml, $smsg);
 309                 $oidx->add_xref3($smsg->{num}, -1, $smsg->{blob}, '.');
 310                 my $idx = $eidx->idx_shard($smsg->{num});
 311                 $idx->index_eml($eml, $smsg);
 312                 $idx->ipc_do('add_vmd', $smsg->{num}, $vmd) if $vmd;
 313                 $smsg;
 314         }
 315 }
 316
 317 sub set_eml {
 318         my ($self, $eml, $vmd, $xoids) = @_;
 319         add_eml($self, $eml, $vmd, $xoids) //
 320                 set_eml_vmd($self, $eml, $vmd);
 321 }
 322
 323 sub index_eml_only {
 324         my ($self, $eml, $vmd, $xoids) = @_;
 325         require PublicInbox::FakeImport;
 326         local $self->{-fake_im} = PublicInbox::FakeImport->new;
 327         set_eml($self, $eml, $vmd, $xoids);
 328 }
 329
 330 sub _external_only ($$$) {
 331         my ($self, $xoids, $eml) = @_;
 332         my $eidx = $self->{priv_eidx};
 333         my $oidx = $eidx->{oidx} // die 'BUG: {oidx} missing';
 334         my $smsg = bless { blob => '' }, 'PublicInbox::Smsg';
 335         $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 336         # save space for an externals-only message
 337         my $hdr = $eml->header_obj;
 338         $smsg->populate($hdr); # sets lines == 0
 339         $smsg->{bytes} = 0;
 340         delete @$smsg{qw(From Subject)};
 341         $smsg->{to} = $smsg->{cc} = $smsg->{from} = '';
 342         $oidx->add_overview($hdr, $smsg); # subject+references for threading
 343         $smsg->{subject} = '';
 344         for my $oid (keys %$xoids) {
 345                 $oidx->add_xref3($smsg->{num}, -1, $oid, '.');
 346         }
 347         my $idx = $eidx->idx_shard($smsg->{num});
 348         $idx->index_eml(PublicInbox::Eml->new("\n\n"), $smsg);
 349         ($smsg, $idx);
 350 }
 351
 352 sub update_xvmd {
 353         my ($self, $xoids, $eml, $vmd_mod) = @_;
 354         my ($eidx, $tl) = eidx_init($self);
 355         my $oidx = $eidx->{oidx};
 356         my %seen;
 357         for my $oid (keys %$xoids) {
 358                 my @docids = $oidx->blob_exists($oid) or next;
 359                 scalar(@docids) > 1 and
 360                         warn "W: $oid indexed as multiple docids: @docids\n";
 361                 for my $docid (@docids) {
 362                         next if $seen{$docid}++;
 363                         my $idx = $eidx->idx_shard($docid);
 364                         $idx->ipc_do('update_vmd', $docid, $vmd_mod);
 365                 }
 366                 delete $xoids->{$oid};
 367         }
 368         return unless scalar(keys(%$xoids));
 369
 370         # see if it was indexed, but with different OID(s)
 371         if (my @docids = _docids_for($self, $eml)) {
 372                 for my $docid (@docids) {
 373                         next if $seen{$docid};
 374                         for my $oid (keys %$xoids) {
 375                                 $oidx->add_xref3($docid, -1, $oid, '.');
 376                         }
 377                         my $idx = $eidx->idx_shard($docid);
 378                         $idx->ipc_do('update_vmd', $docid, $vmd_mod);
 379                 }
 380                 return;
 381         }
 382         # totally unseen
 383         my ($smsg, $idx) = _external_only($self, $xoids, $eml);
 384         $idx->ipc_do('update_vmd', $smsg->{num}, $vmd_mod);
 385 }
 386
 387 # set or update keywords for external message, called via ipc_do
 388 sub set_xvmd {
 389         my ($self, $xoids, $eml, $vmd) = @_;
 390
 391         my ($eidx, $tl) = eidx_init($self);
 392         my $oidx = $eidx->{oidx};
 393         my %seen;
 394
 395         # see if we can just update existing docs
 396         for my $oid (keys %$xoids) {
 397                 my @docids = $oidx->blob_exists($oid) or next;
 398                 scalar(@docids) > 1 and
 399                         warn "W: $oid indexed as multiple docids: @docids\n";
 400                 for my $docid (@docids) {
 401                         next if $seen{$docid}++;
 402                         my $idx = $eidx->idx_shard($docid);
 403                         $idx->ipc_do('set_vmd', $docid, $vmd);
 404                 }
 405                 delete $xoids->{$oid}; # all done with this oid
 406         }
 407         return unless scalar(keys(%$xoids));
 408
 409         # n.b. we don't do _docids_for here, we expect the caller
 410         # already checked $lse->kw_changed before calling this sub
 411
 412         return unless (@{$vmd->{kw} // []}) || (@{$vmd->{L} // []});
 413         # totally unseen:
 414         my ($smsg, $idx) = _external_only($self, $xoids, $eml);
 415         $idx->ipc_do('add_vmd', $smsg->{num}, $vmd);
 416 }
 417
 418 sub checkpoint {
 419         my ($self, $wait) = @_;
 420         if (my $im = $self->{im}) {
 421                 $wait ? $im->barrier : $im->checkpoint;
 422         }
 423         if (my $lms = delete $self->{lms}) {
 424                 $lms->lms_commit;
 425         }
 426         $self->{priv_eidx}->checkpoint($wait);
 427 }
 428
 429 sub xchg_stderr {
 430         my ($self) = @_;
 431         _tail_err($self) if $self->{-err_wr};
 432         my $dir = $self->{priv_eidx}->{topdir};
 433         return unless -e $dir;
 434         my $old = delete $self->{-tmp_err};
 435         my $pfx = POSIX::strftime('%Y%m%d%H%M%S', gmtime(time));
 436         my $err = File::Temp->new(TEMPLATE => "$pfx.$$.lei_storeXXXX",
 437                                 SUFFIX => '.err', DIR => $dir);
 438         open STDERR, '>>', $err->filename or die "dup2: $!";
 439         STDERR->autoflush(1); # shared with shard subprocesses
 440         $self->{-tmp_err} = $err; # separate file description for RO access
 441         undef;
 442 }
 443
 444 sub done {
 445         my ($self) = @_;
 446         my $err = '';
 447         if (my $im = delete($self->{im})) {
 448                 eval { $im->done };
 449                 if ($@) {
 450                         $err .= "import done: $@\n";
 451                         warn $err;
 452                 }
 453         }
 454         if (my $lms = delete $self->{lms}) {
 455                 $lms->lms_commit;
 456         }
 457         $self->{priv_eidx}->done; # V2Writable::done
 458         xchg_stderr($self);
 459         die $err if $err;
 460 }
 461
 462 sub ipc_atfork_child {
 463         my ($self) = @_;
 464         my $lei = $self->{lei};
 465         $lei->_lei_atfork_child(1) if $lei;
 466         xchg_stderr($self);
 467         if (my $err = delete($self->{err_pipe})) {
 468                 close $err->[0];
 469                 $self->{-err_wr} = $err->[1];
 470         }
 471         $self->SUPER::ipc_atfork_child;
 472 }
 473
 474 sub write_prepare {
 475         my ($self, $lei) = @_;
 476         unless ($self->{-ipc_req}) {
 477                 my $d = $lei->store_path;
 478                 $self->ipc_lock_init("$d/ipc.lock");
 479                 substr($d, -length('/lei/store'), 10, '');
 480                 pipe(my ($r, $w)) or die "pipe: $!";
 481                 my $err_pipe = [ $r, $w ];
 482                 # Mail we import into lei are private, so headers filtered out
 483                 # by -mda for public mail are not appropriate
 484                 local @PublicInbox::MDA::BAD_HEADERS = ();
 485                 $self->ipc_worker_spawn("lei/store $d", $lei->oldset,
 486                                         { lei => $lei, err_pipe => $err_pipe });
 487                 require PublicInbox::LeiStoreErr;
 488                 PublicInbox::LeiStoreErr->new($err_pipe->[0], $lei);
 489         }
 490         $lei->{sto} = $self;
 491 }
 492
 493 1;