lib/PublicInbox/LeiStore.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Local storage (cache/memo) for lei(1), suitable for personal/private
   5 # mail iff on encrypted device/FS.  Based on v2, but only deduplicates
   6 # git storage based on git OID (index deduplication is done in ContentHash)
   7 #
   8 # for xref3, the following are constant: $eidx_key = '.', $xnum = -1
   9 #
  10 # We rely on the synchronous IPC API for this in lei-daemon and
  11 # multiple lei clients to write to it at once.  This allows the
  12 # lei/store IPC process to be decoupled from network latency in
  13 # lei WQ workers.
  14 package PublicInbox::LeiStore;
  15 use strict;
  16 use v5.10.1;
  17 use parent qw(PublicInbox::Lock PublicInbox::IPC);
  18 use PublicInbox::ExtSearchIdx;
  19 use PublicInbox::Eml;
  20 use PublicInbox::Import;
  21 use PublicInbox::InboxWritable qw(eml_from_path);
  22 use PublicInbox::V2Writable;
  23 use PublicInbox::ContentHash qw(content_hash);
  24 use PublicInbox::MID qw(mids);
  25 use PublicInbox::LeiSearch;
  26 use PublicInbox::MDA;
  27 use PublicInbox::Spawn qw(spawn);
  28 use List::Util qw(max);
  29 use File::Temp ();
  30 use POSIX ();
  31
  32 sub new {
  33         my (undef, $dir, $opt) = @_;
  34         my $eidx = PublicInbox::ExtSearchIdx->new($dir, $opt);
  35         my $self = bless { priv_eidx => $eidx }, __PACKAGE__;
  36         eidx_init($self)->done if $opt->{creat};
  37         $self;
  38 }
  39
  40 sub git { $_[0]->{priv_eidx}->git } # read-only
  41
  42 sub packing_factor { $PublicInbox::V2Writable::PACKING_FACTOR }
  43
  44 sub rotate_bytes {
  45         $_[0]->{rotate_bytes} // ((1024 * 1024 * 1024) / $_[0]->packing_factor)
  46 }
  47
  48 sub git_pfx { "$_[0]->{priv_eidx}->{topdir}/local" };
  49
  50 sub git_epoch_max  {
  51         my ($self) = @_;
  52         if (opendir(my $dh, $self->git_pfx)) {
  53                 max(map {
  54                         substr($_, 0, -4) + 0; # drop ".git" suffix
  55                 } grep(/\A[0-9]+\.git\z/, readdir($dh))) // 0;
  56         } else {
  57                 $!{ENOENT} ? 0 : die("opendir ${\$self->git_pfx}: $!\n");
  58         }
  59 }
  60
  61 sub git_ident ($) {
  62         my ($git) = @_;
  63         my $rdr = {};
  64         open $rdr->{2}, '>', '/dev/null' or die "open /dev/null: $!";
  65         chomp(my $i = $git->qx([qw(var GIT_COMMITTER_IDENT)], undef, $rdr));
  66         $i =~ /\A(.+) <([^>]+)> [0-9]+ [-\+]?[0-9]+$/ and return ($1, $2);
  67         my ($user, undef, undef, undef, undef, undef, $gecos) = getpwuid($<);
  68         ($user) = (($user // $ENV{USER} // '') =~ /([\w\-\.\+]+)/);
  69         $user //= 'lei-user';
  70         ($gecos) = (($gecos // '') =~ /([\w\-\.\+ \t]+)/);
  71         $gecos //= 'lei user';
  72         require Sys::Hostname;
  73         my ($host) = (Sys::Hostname::hostname() =~ /([\w\-\.]+)/);
  74         $host //= 'localhost';
  75         ($gecos, "$user\@$host")
  76 }
  77
  78 sub importer {
  79         my ($self) = @_;
  80         my $max;
  81         my $im = $self->{im};
  82         if ($im) {
  83                 return $im if $im->{bytes_added} < $self->rotate_bytes;
  84
  85                 delete $self->{im};
  86                 $im->done;
  87                 undef $im;
  88                 $self->checkpoint;
  89                 $max = $self->git_epoch_max + 1;
  90         }
  91         my (undef, $tl) = eidx_init($self); # acquire lock
  92         my $pfx = $self->git_pfx;
  93         $max //= $self->git_epoch_max;
  94         while (1) {
  95                 my $latest = "$pfx/$max.git";
  96                 my $old = -e $latest;
  97                 PublicInbox::Import::init_bare($latest);
  98                 my $git = PublicInbox::Git->new($latest);
  99                 if (!$old) {
 100                         $git->qx(qw(config core.sharedRepository 0600));
 101                         $self->done; # unlock
 102                         # re-acquire lock, update alternates for new epoch
 103                         (undef, $tl) = eidx_init($self);
 104                 }
 105                 my $packed_bytes = $git->packed_bytes;
 106                 my $unpacked_bytes = $packed_bytes / $self->packing_factor;
 107                 if ($unpacked_bytes >= $self->rotate_bytes) {
 108                         $max++;
 109                         next;
 110                 }
 111                 my ($n, $e) = git_ident($git);
 112                 $self->{im} = $im = PublicInbox::Import->new($git, $n, $e);
 113                 $im->{bytes_added} = int($packed_bytes / $self->packing_factor);
 114                 $im->{lock_path} = undef;
 115                 $im->{path_type} = 'v2';
 116                 return $im;
 117         }
 118 }
 119
 120 sub search {
 121         PublicInbox::LeiSearch->new($_[0]->{priv_eidx}->{topdir});
 122 }
 123
 124 # follows the stderr file
 125 sub _tail_err {
 126         my ($self) = @_;
 127         print { $self->{-err_wr} } readline($self->{-tmp_err});
 128 }
 129
 130 sub eidx_init {
 131         my ($self) = @_;
 132         my $eidx = $self->{priv_eidx};
 133         my $tl = wantarray && $self->{-err_wr} ?
 134                         PublicInbox::OnDestroy->new($$, \&_tail_err, $self) :
 135                         undef;
 136         $eidx->idx_init({-private => 1}); # acquires lock
 137         wantarray ? ($eidx, $tl) : $eidx;
 138 }
 139
 140 sub _docids_for ($$) {
 141         my ($self, $eml) = @_;
 142         my %docids;
 143         my $eidx = $self->{priv_eidx};
 144         my ($chash, $mids) = PublicInbox::LeiSearch::content_key($eml);
 145         my $oidx = $eidx->{oidx};
 146         my $im = $self->{im};
 147         for my $mid (@$mids) {
 148                 my ($id, $prev);
 149                 while (my $cur = $oidx->next_by_mid($mid, \$id, \$prev)) {
 150                         next if $cur->{bytes} == 0; # external-only message
 151                         my $oid = $cur->{blob};
 152                         my $docid = $cur->{num};
 153                         my $bref = $im ? $im->cat_blob($oid) : undef;
 154                         $bref //= $eidx->git->cat_file($oid) // do {
 155                                 warn "W: $oid (#$docid) <$mid> not found\n";
 156                                 next;
 157                         };
 158                         local $self->{current_info} = $oid;
 159                         my $x = PublicInbox::Eml->new($bref);
 160                         $docids{$docid} = $docid if content_hash($x) eq $chash;
 161                 }
 162         }
 163         sort { $a <=> $b } values %docids;
 164 }
 165
 166 sub set_eml_vmd {
 167         my ($self, $eml, $vmd, $docids) = @_;
 168         my ($eidx, $tl) = eidx_init($self);
 169         $docids //= [ _docids_for($self, $eml) ];
 170         for my $docid (@$docids) {
 171                 $eidx->idx_shard($docid)->ipc_do('set_vmd', $docid, $vmd);
 172         }
 173         $docids;
 174 }
 175
 176 sub add_eml_vmd {
 177         my ($self, $eml, $vmd) = @_;
 178         my ($eidx, $tl) = eidx_init($self);
 179         my @docids = _docids_for($self, $eml);
 180         for my $docid (@docids) {
 181                 $eidx->idx_shard($docid)->ipc_do('add_vmd', $docid, $vmd);
 182         }
 183         \@docids;
 184 }
 185
 186 sub remove_eml_vmd { # remove just the VMD
 187         my ($self, $eml, $vmd) = @_;
 188         my ($eidx, $tl) = eidx_init($self);
 189         my @docids = _docids_for($self, $eml);
 190         for my $docid (@docids) {
 191                 $eidx->idx_shard($docid)->ipc_do('remove_vmd', $docid, $vmd);
 192         }
 193         \@docids;
 194 }
 195
 196 sub set_sync_info {
 197         my ($self, $oidhex, $folder, $id) = @_;
 198         ($self->{lms} //= do {
 199                 require PublicInbox::LeiMailSync;
 200                 my $f = "$self->{priv_eidx}->{topdir}/mail_sync.sqlite3";
 201                 my $lms = PublicInbox::LeiMailSync->new($f);
 202                 $lms->lms_begin;
 203                 $lms;
 204         })->set_src($oidhex, $folder, $id);
 205 }
 206
 207 sub _remove_if_local { # git->cat_async arg
 208         my ($bref, $oidhex, $type, $size, $self) = @_;
 209         $self->{im}->remove($bref) if $bref;
 210 }
 211
 212 # remove the entire message from the index, does not touch mail_sync.sqlite3
 213 sub remove_eml {
 214         my ($self, $eml) = @_;
 215         my $im = $self->importer; # may create new epoch
 216         my ($eidx, $tl) = eidx_init($self);
 217         my $oidx = $eidx->{oidx};
 218         my @docids = _docids_for($self, $eml);
 219         my $git = $eidx->git;
 220         for my $docid (@docids) {
 221                 my $xr3 = $oidx->get_xref3($docid, 1);
 222                 for my $row (@$xr3) {
 223                         my (undef, undef, $oidbin) = @$row;
 224                         my $oidhex = unpack('H*', $oidbin);
 225                         $git->cat_async($oidhex, \&_remove_if_local, $self);
 226                 }
 227                 $eidx->idx_shard($docid)->ipc_do('xdb_remove', $docid);
 228                 $oidx->delete_by_num($docid);
 229         }
 230         $git->cat_async_wait;
 231         \@docids;
 232 }
 233
 234 sub add_eml {
 235         my ($self, $eml, $vmd, $xoids) = @_;
 236         my $im = $self->{-fake_im} // $self->importer; # may create new epoch
 237         my ($eidx, $tl) = eidx_init($self);
 238         my $oidx = $eidx->{oidx}; # PublicInbox::Import::add checks this
 239         my $smsg = bless { -oidx => $oidx }, 'PublicInbox::Smsg';
 240         $smsg->{-eidx_git} = $eidx->git if !$self->{-fake_im};
 241         my $im_mark = $im->add($eml, undef, $smsg);
 242         if ($vmd && $vmd->{sync_info}) {
 243                 set_sync_info($self, $smsg->{blob}, @{$vmd->{sync_info}});
 244         }
 245         $im_mark or return; # duplicate blob returns undef
 246
 247         local $self->{current_info} = $smsg->{blob};
 248         my $vivify_xvmd = delete($smsg->{-vivify_xvmd}) // []; # exact matches
 249         if ($xoids) { # fuzzy matches from externals in ale->xoids_for
 250                 delete $xoids->{$smsg->{blob}}; # added later
 251                 if (scalar keys %$xoids) {
 252                         my %docids = map { $_ => 1 } @$vivify_xvmd;
 253                         for my $oid (keys %$xoids) {
 254                                 my @id = $oidx->blob_exists($oid);
 255                                 @docids{@id} = @id;
 256                         }
 257                         @$vivify_xvmd = sort { $a <=> $b } keys(%docids);
 258                 }
 259         }
 260         if (@$vivify_xvmd) {
 261                 $xoids //= {};
 262                 $xoids->{$smsg->{blob}} = 1;
 263                 for my $docid (@$vivify_xvmd) {
 264                         my $cur = $oidx->get_art($docid);
 265                         my $idx = $eidx->idx_shard($docid);
 266                         if (!$cur || $cur->{bytes} == 0) { # really vivifying
 267                                 $smsg->{num} = $docid;
 268                                 $oidx->add_overview($eml, $smsg);
 269                                 $smsg->{-merge_vmd} = 1;
 270                                 $idx->index_eml($eml, $smsg);
 271                         } else { # lse fuzzy hit off ale
 272                                 $idx->ipc_do('add_eidx_info', $docid, '.', $eml);
 273                         }
 274                         for my $oid (keys %$xoids) {
 275                                 $oidx->add_xref3($docid, -1, $oid, '.');
 276                         }
 277                         $idx->ipc_do('add_vmd', $docid, $vmd) if $vmd;
 278                 }
 279                 $vivify_xvmd;
 280         } elsif (my @docids = _docids_for($self, $eml)) {
 281                 # fuzzy match from within lei/store
 282                 for my $docid (@docids) {
 283                         my $idx = $eidx->idx_shard($docid);
 284                         $oidx->add_xref3($docid, -1, $smsg->{blob}, '.');
 285                         # add_eidx_info for List-Id
 286                         $idx->ipc_do('add_eidx_info', $docid, '.', $eml);
 287                         $idx->ipc_do('add_vmd', $docid, $vmd) if $vmd;
 288                 }
 289                 \@docids;
 290         } else { # totally new message
 291                 $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 292                 $oidx->add_overview($eml, $smsg);
 293                 $oidx->add_xref3($smsg->{num}, -1, $smsg->{blob}, '.');
 294                 my $idx = $eidx->idx_shard($smsg->{num});
 295                 $idx->index_eml($eml, $smsg);
 296                 $idx->ipc_do('add_vmd', $smsg->{num}, $vmd) if $vmd;
 297                 $smsg;
 298         }
 299 }
 300
 301 sub set_eml {
 302         my ($self, $eml, $vmd, $xoids) = @_;
 303         add_eml($self, $eml, $vmd, $xoids) //
 304                 set_eml_vmd($self, $eml, $vmd);
 305 }
 306
 307 sub index_eml_only {
 308         my ($self, $eml, $vmd, $xoids) = @_;
 309         require PublicInbox::FakeImport;
 310         local $self->{-fake_im} = PublicInbox::FakeImport->new;
 311         set_eml($self, $eml, $vmd, $xoids);
 312 }
 313
 314 sub _external_only ($$$) {
 315         my ($self, $xoids, $eml) = @_;
 316         my $eidx = $self->{priv_eidx};
 317         my $oidx = $eidx->{oidx} // die 'BUG: {oidx} missing';
 318         my $smsg = bless { blob => '' }, 'PublicInbox::Smsg';
 319         $smsg->{num} = $oidx->adj_counter('eidx_docid', '+');
 320         # save space for an externals-only message
 321         my $hdr = $eml->header_obj;
 322         $smsg->populate($hdr); # sets lines == 0
 323         $smsg->{bytes} = 0;
 324         delete @$smsg{qw(From Subject)};
 325         $smsg->{to} = $smsg->{cc} = $smsg->{from} = '';
 326         $oidx->add_overview($hdr, $smsg); # subject+references for threading
 327         $smsg->{subject} = '';
 328         for my $oid (keys %$xoids) {
 329                 $oidx->add_xref3($smsg->{num}, -1, $oid, '.');
 330         }
 331         my $idx = $eidx->idx_shard($smsg->{num});
 332         $idx->index_eml(PublicInbox::Eml->new("\n\n"), $smsg);
 333         ($smsg, $idx);
 334 }
 335
 336 sub update_xvmd {
 337         my ($self, $xoids, $eml, $vmd_mod) = @_;
 338         my ($eidx, $tl) = eidx_init($self);
 339         my $oidx = $eidx->{oidx};
 340         my %seen;
 341         for my $oid (keys %$xoids) {
 342                 my @docids = $oidx->blob_exists($oid) or next;
 343                 scalar(@docids) > 1 and
 344                         warn "W: $oid indexed as multiple docids: @docids\n";
 345                 for my $docid (@docids) {
 346                         next if $seen{$docid}++;
 347                         my $idx = $eidx->idx_shard($docid);
 348                         $idx->ipc_do('update_vmd', $docid, $vmd_mod);
 349                 }
 350                 delete $xoids->{$oid};
 351         }
 352         return unless scalar(keys(%$xoids));
 353
 354         # see if it was indexed, but with different OID(s)
 355         if (my @docids = _docids_for($self, $eml)) {
 356                 for my $docid (@docids) {
 357                         next if $seen{$docid};
 358                         for my $oid (keys %$xoids) {
 359                                 $oidx->add_xref3($docid, -1, $oid, '.');
 360                         }
 361                         my $idx = $eidx->idx_shard($docid);
 362                         $idx->ipc_do('update_vmd', $docid, $vmd_mod);
 363                 }
 364                 return;
 365         }
 366         # totally unseen
 367         my ($smsg, $idx) = _external_only($self, $xoids, $eml);
 368         $idx->ipc_do('update_vmd', $smsg->{num}, $vmd_mod);
 369 }
 370
 371 # set or update keywords for external message, called via ipc_do
 372 sub set_xvmd {
 373         my ($self, $xoids, $eml, $vmd) = @_;
 374
 375         my ($eidx, $tl) = eidx_init($self);
 376         my $oidx = $eidx->{oidx};
 377         my %seen;
 378
 379         # see if we can just update existing docs
 380         for my $oid (keys %$xoids) {
 381                 my @docids = $oidx->blob_exists($oid) or next;
 382                 scalar(@docids) > 1 and
 383                         warn "W: $oid indexed as multiple docids: @docids\n";
 384                 for my $docid (@docids) {
 385                         next if $seen{$docid}++;
 386                         my $idx = $eidx->idx_shard($docid);
 387                         $idx->ipc_do('set_vmd', $docid, $vmd);
 388                 }
 389                 delete $xoids->{$oid}; # all done with this oid
 390         }
 391         return unless scalar(keys(%$xoids));
 392
 393         # n.b. we don't do _docids_for here, we expect the caller
 394         # already checked $lse->kw_changed before calling this sub
 395
 396         return unless (@{$vmd->{kw} // []}) || (@{$vmd->{L} // []});
 397         # totally unseen:
 398         my ($smsg, $idx) = _external_only($self, $xoids, $eml);
 399         $idx->ipc_do('add_vmd', $smsg->{num}, $vmd);
 400 }
 401
 402 sub checkpoint {
 403         my ($self, $wait) = @_;
 404         if (my $im = $self->{im}) {
 405                 $wait ? $im->barrier : $im->checkpoint;
 406         }
 407         $self->{priv_eidx}->checkpoint($wait);
 408 }
 409
 410 sub xchg_stderr {
 411         my ($self) = @_;
 412         _tail_err($self) if $self->{-err_wr};
 413         my $dir = $self->{priv_eidx}->{topdir};
 414         return unless -e $dir;
 415         my $old = delete $self->{-tmp_err};
 416         my $pfx = POSIX::strftime('%Y%m%d%H%M%S', gmtime(time));
 417         my $err = File::Temp->new(TEMPLATE => "$pfx.$$.lei_storeXXXX",
 418                                 SUFFIX => '.err', DIR => $dir);
 419         open STDERR, '>>', $err->filename or die "dup2: $!";
 420         STDERR->autoflush(1); # shared with shard subprocesses
 421         $self->{-tmp_err} = $err; # separate file description for RO access
 422         undef;
 423 }
 424
 425 sub done {
 426         my ($self) = @_;
 427         my $err = '';
 428         if (my $im = delete($self->{im})) {
 429                 eval { $im->done };
 430                 if ($@) {
 431                         $err .= "import done: $@\n";
 432                         warn $err;
 433                 }
 434         }
 435         if (my $lms = delete $self->{lms}) {
 436                 $lms->lms_commit;
 437         }
 438         $self->{priv_eidx}->done; # V2Writable::done
 439         xchg_stderr($self);
 440         die $err if $err;
 441 }
 442
 443 sub ipc_atfork_child {
 444         my ($self) = @_;
 445         my $lei = $self->{lei};
 446         $lei->_lei_atfork_child(1) if $lei;
 447         xchg_stderr($self);
 448         if (my $err = delete($self->{err_pipe})) {
 449                 close $err->[0];
 450                 $self->{-err_wr} = $err->[1];
 451         }
 452         $self->SUPER::ipc_atfork_child;
 453 }
 454
 455 sub write_prepare {
 456         my ($self, $lei) = @_;
 457         unless ($self->{-ipc_req}) {
 458                 my $d = $lei->store_path;
 459                 $self->ipc_lock_init("$d/ipc.lock");
 460                 substr($d, -length('/lei/store'), 10, '');
 461                 pipe(my ($r, $w)) or die "pipe: $!";
 462                 my $err_pipe = [ $r, $w ];
 463                 # Mail we import into lei are private, so headers filtered out
 464                 # by -mda for public mail are not appropriate
 465                 local @PublicInbox::MDA::BAD_HEADERS = ();
 466                 $self->ipc_worker_spawn("lei/store $d", $lei->oldset,
 467                                         { lei => $lei, err_pipe => $err_pipe });
 468                 require PublicInbox::LeiStoreErr;
 469                 PublicInbox::LeiStoreErr->new($err_pipe->[0], $lei);
 470         }
 471         $lei->{sto} = $self;
 472 }
 473
 474 1;