lib/PublicInbox/LeiSucks.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Undocumented hidden command somebody might discover if they're
   5 # frustrated and need to report a bug.  There's no manpage and
   6 # it won't show up in tab completions or help.
   7 package PublicInbox::LeiSucks;
   8 use strict;
   9 use v5.10.1;
  10 use Digest::SHA ();
  11 use Config;
  12 use POSIX ();
  13 use PublicInbox::Config;
  14 use PublicInbox::Search;
  15
  16 sub lei_sucks {
  17         my ($lei, @argv) = @_;
  18         $lei->start_pager if -t $lei->{1};
  19         my ($os, undef, $rel, undef, $mac)= POSIX::uname();
  20         if ($mac eq 'x86_64' && $Config{ptrsize} == 4) {
  21                 $mac .= $Config{cppsymbols} =~ /\b__ILP32__=1\b/ ?
  22                         ',u=x32' : ',u=x86';
  23         }
  24         eval { require PublicInbox };
  25         my $pi_ver = eval('$PublicInbox::VERSION') // '(???)';
  26         my $daemon = $lei->{oneshot} ? 'oneshot' : 'daemon';
  27         my @out = ("lei $pi_ver mode=$daemon\n",
  28                 "perl $Config{version} / $os $rel / $mac ".
  29                 "ptrsize=$Config{ptrsize}\n");
  30         chomp(my $gv = `git --version` || "git missing");
  31         $gv =~ s/ version / /;
  32         my $json = ref(PublicInbox::Config->json);
  33         $json .= ' ' . eval('$'.$json.'::VERSION') if $json;
  34         $json ||= '(no JSON)';
  35         push @out, "$gv / $json\n";
  36         if (eval { require PublicInbox::Over }) {
  37                 push @out, 'SQLite '.
  38                         (eval('$DBD::SQLite::sqlite_version') // '(undef)') .
  39                         ', DBI '.(eval('$DBI::VERSION') // '(undef)') .
  40                         ', DBD::SQLite '.
  41                         (eval('$DBD::SQLite::VERSION') // '(undef)')."\n";
  42         } else {
  43                 push @out, "Unable to load DBI / DBD::SQLite: $@\n";
  44         }
  45         if (PublicInbox::Search::load_xapian()) {
  46                 push @out, 'Xapian '.
  47                         join('.', map {
  48                                 $PublicInbox::Search::Xap->can($_)->();
  49                         } qw(major_version minor_version revision)) .
  50                         ", bindings: $PublicInbox::Search::Xap";
  51                 my $xs_ver = eval '$'."$PublicInbox::Search::Xap".'::VERSION';
  52                 push @out, $xs_ver ? " $xs_ver\n" : " SWIG\n";
  53         } else {
  54                 push @out, "Xapian not available: $@\n";
  55         }
  56         my $dig = Digest::SHA->new(1);
  57         push @out, "public-inbox blob OIDs of loaded features:\n";
  58         for my $m (grep(m{^PublicInbox/}, sort keys %INC)) {
  59                 my $f = $INC{$m};
  60                 $dig->add('blob '.(-s $f)."\0");
  61                 $dig->addfile($f);
  62                 push @out, '  '.$dig->hexdigest.' '.$m."\n";
  63         }
  64         push @out, <<'EOM';
  65 Let us know how it sucks!  Please include the above and any other
  66 relevant information when sending plain-text mail to us at:
  67 meta@public-inbox.org -- archives: https://public-inbox.org/meta/
  68 EOM
  69         $lei->out(@out);
  70 }
  71
  72 1;