lib/PublicInbox/LeiToMail.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Writes PublicInbox::Eml objects atomically to a mbox variant or Maildir
   5 package PublicInbox::LeiToMail;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::ProcessPipe;
  11 use PublicInbox::Spawn qw(spawn);
  12 use PublicInbox::PktOp qw(pkt_do);
  13 use Symbol qw(gensym);
  14 use IO::Handle; # ->autoflush
  15 use Fcntl qw(SEEK_SET SEEK_END O_CREAT O_EXCL O_WRONLY);
  16
  17 my %kw2char = ( # Maildir characters
  18         draft => 'D',
  19         flagged => 'F',
  20         forwarded => 'P', # passed
  21         answered => 'R',
  22         seen => 'S',
  23 );
  24
  25 my %kw2status = (
  26         flagged => [ 'X-Status' => 'F' ],
  27         answered => [ 'X-Status' => 'A' ],
  28         seen => [ 'Status' => 'R' ],
  29         draft => [ 'X-Status' => 'T' ],
  30 );
  31
  32 sub _mbox_hdr_buf ($$$) {
  33         my ($eml, $type, $smsg) = @_;
  34         $eml->header_set($_) for (qw(Lines Bytes Content-Length));
  35
  36         my %hdr = (Status => []); # set Status, X-Status
  37         for my $k (@{$smsg->{kw} // []}) {
  38                 if (my $ent = $kw2status{$k}) {
  39                         push @{$hdr{$ent->[0]}}, $ent->[1];
  40                 } else { # X-Label?
  41                         warn "# keyword `$k' not supported for mbox\n";
  42                 }
  43         }
  44         # Messages are always 'O' (non-\Recent in IMAP), it saves
  45         # MUAs the trouble of rewriting the mbox if no other
  46         # changes are made.  We put 'O' at the end (e.g. "Status: RO")
  47         # to match mutt(1) output.
  48         $eml->header_set('Status', join('', sort(@{$hdr{Status}})). 'O');
  49         if (my $chars = delete $hdr{'X-Status'}) {
  50                 $eml->header_set('X-Status', join('', sort(@$chars)));
  51         }
  52         my $buf = delete $eml->{hdr};
  53
  54         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
  55         $$buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  56         my $ident = $smsg->{blob} // 'lei';
  57         if (defined(my $pct = $smsg->{pct})) { $ident .= "=$pct" }
  58
  59         substr($$buf, 0, 0, # prepend From line
  60                 "From $ident\@$type Thu Jan  1 00:00:00 1970$eml->{crlf}");
  61         $buf;
  62 }
  63
  64 sub atomic_append { # for on-disk destinations (O_APPEND, or O_EXCL)
  65         my ($lei, $buf) = @_;
  66         if (defined(my $w = syswrite($lei->{1} // return, $$buf))) {
  67                 return if $w == length($$buf);
  68                 $buf = "short atomic write: $w != ".length($$buf);
  69         } elsif ($!{EPIPE}) {
  70                 return $lei->note_sigpipe(1);
  71         } else {
  72                 $buf = "atomic write: $!";
  73         }
  74         $lei->fail($buf);
  75 }
  76
  77 sub eml2mboxrd ($;$) {
  78         my ($eml, $smsg) = @_;
  79         my $buf = _mbox_hdr_buf($eml, 'mboxrd', $smsg);
  80         if (my $bdy = delete $eml->{bdy}) {
  81                 $$bdy =~ s/^(>*From )/>$1/gm;
  82                 $$buf .= $eml->{crlf};
  83                 substr($$bdy, 0, 0, $$buf); # prepend header
  84                 $buf = $bdy;
  85         }
  86         $$buf .= $eml->{crlf};
  87         $buf;
  88 }
  89
  90 sub eml2mboxo {
  91         my ($eml, $smsg) = @_;
  92         my $buf = _mbox_hdr_buf($eml, 'mboxo', $smsg);
  93         if (my $bdy = delete $eml->{bdy}) {
  94                 $$bdy =~ s/^From />From /gm;
  95                 $$buf .= $eml->{crlf};
  96                 substr($$bdy, 0, 0, $$buf); # prepend header
  97                 $buf = $bdy;
  98         }
  99         $$buf .= $eml->{crlf};
 100         $buf;
 101 }
 102
 103 sub _mboxcl_common ($$$) {
 104         my ($buf, $bdy, $crlf) = @_;
 105         # add Lines: so mutt won't have to add it on MUA close
 106         my $lines = $$bdy =~ tr!\n!\n!;
 107         $$buf .= 'Content-Length: '.length($$bdy).$crlf.
 108                 'Lines: '.$lines.$crlf.$crlf;
 109         substr($$bdy, 0, 0, $$buf); # prepend header
 110         $_[0] = $bdy;
 111 }
 112
 113 # mboxcl still escapes "From " lines
 114 sub eml2mboxcl {
 115         my ($eml, $smsg) = @_;
 116         my $buf = _mbox_hdr_buf($eml, 'mboxcl', $smsg);
 117         my $crlf = $eml->{crlf};
 118         if (my $bdy = delete $eml->{bdy}) {
 119                 $$bdy =~ s/^From />From /gm;
 120                 _mboxcl_common($buf, $bdy, $crlf);
 121         }
 122         $$buf .= $crlf;
 123         $buf;
 124 }
 125
 126 # mboxcl2 has no "From " escaping
 127 sub eml2mboxcl2 {
 128         my ($eml, $smsg) = @_;
 129         my $buf = _mbox_hdr_buf($eml, 'mboxcl2', $smsg);
 130         my $crlf = $eml->{crlf};
 131         if (my $bdy = delete $eml->{bdy}) {
 132                 _mboxcl_common($buf, $bdy, $crlf);
 133         }
 134         $$buf .= $crlf;
 135         $buf;
 136 }
 137
 138 sub git_to_mail { # git->cat_async callback
 139         my ($bref, $oid, $type, $size, $arg) = @_;
 140         my ($write_cb, $smsg) = @$arg;
 141         if ($type eq 'missing' && $smsg->{-lms_ro}) {
 142                 if ($bref = $smsg->{-lms_ro}->local_blob($oid, 1)) {
 143                         $type = 'blob';
 144                         $size = length($$bref);
 145                 }
 146         }
 147         return warn("W: $oid is $type (!= blob)\n") if $type ne 'blob';
 148         return warn("E: $oid is empty\n") unless $size;
 149         die "BUG: expected=$smsg->{blob} got=$oid" if $smsg->{blob} ne $oid;
 150         $write_cb->($bref, $smsg);
 151 }
 152
 153 sub reap_compress { # dwaitpid callback
 154         my ($lei, $pid) = @_;
 155         my $cmd = delete $lei->{"pid.$pid"};
 156         return if $? == 0;
 157         $lei->fail("@$cmd failed", $? >> 8);
 158 }
 159
 160 sub _post_augment_mbox { # open a compressor process from top-level process
 161         my ($self, $lei) = @_;
 162         my $zsfx = $self->{zsfx} or return;
 163         my $cmd = PublicInbox::MboxReader::zsfx2cmd($zsfx, undef, $lei);
 164         my ($r, $w) = @{delete $lei->{zpipe}};
 165         my $rdr = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 166         my $pid = spawn($cmd, undef, $rdr);
 167         my $pp = gensym;
 168         my $dup = bless { "pid.$pid" => $cmd }, ref($lei);
 169         $dup->{$_} = $lei->{$_} for qw(2 sock);
 170         tie *$pp, 'PublicInbox::ProcessPipe', $pid, $w, \&reap_compress, $dup;
 171         $lei->{1} = $pp;
 172 }
 173
 174 # --augment existing output destination, with deduplication
 175 sub _augment { # MboxReader eml_cb
 176         my ($eml, $lei) = @_;
 177         # ignore return value, just populate the skv
 178         $lei->{dedupe}->is_dup($eml);
 179 }
 180
 181 sub _mbox_augment_kw_maybe {
 182         my ($eml, $lei, $lse, $augment) = @_;
 183         my $kw = PublicInbox::MboxReader::mbox_keywords($eml);
 184         update_kw_maybe($lei, $lse, $eml, $kw);
 185         _augment($eml, $lei) if $augment;
 186 }
 187
 188 sub _mbox_write_cb ($$) {
 189         my ($self, $lei) = @_;
 190         my $ovv = $lei->{ovv};
 191         my $m = 'eml2'.$ovv->{fmt};
 192         my $eml2mbox = $self->can($m) or die "$self->$m missing";
 193         $lei->{1} // die "no stdout ($m, $ovv->{dst})"; # redirected earlier
 194         $lei->{1}->autoflush(1);
 195         my $atomic_append = !defined($ovv->{lock_path});
 196         my $dedupe = $lei->{dedupe};
 197         $dedupe->prepare_dedupe;
 198         my $lse = $lei->{lse}; # may be undef
 199         sub { # for git_to_mail
 200                 my ($buf, $smsg, $eml) = @_;
 201                 $eml //= PublicInbox::Eml->new($buf);
 202                 return if $dedupe->is_dup($eml, $smsg);
 203                 $lse->xsmsg_vmd($smsg) if $lse;
 204                 $buf = $eml2mbox->($eml, $smsg);
 205                 if ($atomic_append) {
 206                         atomic_append($lei, $buf);
 207                 } else {
 208                         my $lk = $ovv->lock_for_scope;
 209                         $lei->out($$buf);
 210                 }
 211                 ++$lei->{-nr_write};
 212         }
 213 }
 214
 215 sub update_kw_maybe ($$$$) {
 216         my ($lei, $lse, $eml, $kw) = @_;
 217         return unless $lse;
 218         my $c = $lse->kw_changed($eml, $kw, my $docids = []);
 219         my $vmd = { kw => $kw };
 220         if (scalar @$docids) { # already in lei/store
 221                 $lei->{sto}->ipc_do('set_eml_vmd', undef, $vmd, $docids) if $c;
 222         } elsif (my $xoids = $lei->{ale}->xoids_for($eml)) {
 223                 # it's in an external, only set kw, here
 224                 $lei->{sto}->ipc_do('set_xvmd', $xoids, $eml, $vmd);
 225         } else { # never-before-seen, import the whole thing
 226                 # XXX this is critical in protecting against accidental
 227                 # data loss without --augment
 228                 $lei->{sto}->ipc_do('set_eml', $eml, $vmd);
 229         }
 230 }
 231
 232 sub _md_update { # maildir_each_eml cb
 233         my ($f, $kw, $eml, $lei, $lse, $unlink) = @_;
 234         update_kw_maybe($lei, $lse, $eml, $kw);
 235         $unlink ? unlink($f) : _augment($eml, $lei);
 236 }
 237
 238 # maildir_each_file callback, \&CORE::unlink doesn't work with it
 239 sub _unlink { unlink($_[0]) }
 240
 241 sub _rand () {
 242         state $seq = 0;
 243         sprintf('%x,%x,%x,%x', rand(0xffffffff), time, $$, ++$seq);
 244 }
 245
 246 sub _buf2maildir {
 247         my ($dst, $buf, $smsg) = @_;
 248         my $kw = $smsg->{kw} // [];
 249         my $sfx = join('', sort(map { $kw2char{$_} // () } @$kw));
 250         my $rand = ''; # chosen by die roll :P
 251         my ($tmp, $fh, $base, $ok);
 252         my $common = $smsg->{blob} // _rand;
 253         if (defined(my $pct = $smsg->{pct})) { $common .= "=$pct" }
 254         do {
 255                 $tmp = $dst.'tmp/'.$rand.$common;
 256         } while (!($ok = sysopen($fh, $tmp, O_CREAT|O_EXCL|O_WRONLY)) &&
 257                 $!{EEXIST} && ($rand = _rand.','));
 258         if ($ok && print $fh $$buf and close($fh)) {
 259                 # ignore new/ and write only to cur/, otherwise MUAs
 260                 # with R/W access to the Maildir will end up doing
 261                 # a mass rename which can take a while with thousands
 262                 # of messages.
 263                 $dst .= 'cur/';
 264                 $rand = '';
 265                 do {
 266                         $base = $rand.$common.':2,'.$sfx
 267                 } while (!($ok = link($tmp, $dst.$base)) && $!{EEXIST} &&
 268                         ($rand = _rand.','));
 269                 die "link($tmp, $dst$base): $!" unless $ok;
 270                 unlink($tmp) or warn "W: failed to unlink $tmp: $!\n";
 271                 \$base;
 272         } else {
 273                 my $err = "Error writing $smsg->{blob} to $dst: $!\n";
 274                 $_[0] = undef; # clobber dst
 275                 unlink($tmp);
 276                 die $err;
 277         }
 278 }
 279
 280 sub _maildir_write_cb ($$) {
 281         my ($self, $lei) = @_;
 282         my $dedupe = $lei->{dedupe};
 283         $dedupe->prepare_dedupe if $dedupe;
 284         my $dst = $lei->{ovv}->{dst};
 285         my $lse = $lei->{lse}; # may be undef
 286         my $sto = $lei->{opt}->{'mail-sync'} ? $lei->{sto} : undef;
 287         my $out = $sto ? 'maildir:'.$lei->rel2abs($dst) : undef;
 288         sub { # for git_to_mail
 289                 my ($bref, $smsg, $eml) = @_;
 290                 $dst // return $lei->fail; # dst may be undef-ed in last run
 291                 return if $dedupe && $dedupe->is_dup($eml //
 292                                                 PublicInbox::Eml->new($$bref),
 293                                                 $smsg);
 294                 $lse->xsmsg_vmd($smsg) if $lse;
 295                 my $n = _buf2maildir($dst, $bref // \($eml->as_string), $smsg);
 296                 $sto->ipc_do('set_sync_info', $smsg->{blob}, $out, $n) if $sto;
 297                 ++$lei->{-nr_write};
 298         }
 299 }
 300
 301 sub _imap_write_cb ($$) {
 302         my ($self, $lei) = @_;
 303         my $dedupe = $lei->{dedupe};
 304         $dedupe->prepare_dedupe if $dedupe;
 305         my $append = $lei->{net}->can('imap_append');
 306         my $mic = $lei->{net}->mic_get($self->{uri});
 307         my $folder = $self->{uri}->mailbox;
 308         my $lse = $lei->{lse}; # may be undef
 309         my $sto = $lei->{opt}->{'mail-sync'} ? $lei->{sto} : undef;
 310         my $out = $lei->{ovv}->{dst};
 311         sub { # for git_to_mail
 312                 my ($bref, $smsg, $eml) = @_;
 313                 $mic // return $lei->fail; # mic may be undef-ed in last run
 314                 return if $dedupe && $dedupe->is_dup($eml //
 315                                                 PublicInbox::Eml->new($$bref),
 316                                                 $smsg);
 317                 $lse->xsmsg_vmd($smsg) if $lse;
 318                 my $uid = eval { $append->($mic, $folder, $bref, $smsg, $eml) };
 319                 if (my $err = $@) {
 320                         undef $mic;
 321                         die $err;
 322                 }
 323                 # imap_append returns UID if IMAP server has UIDPLUS extension
 324                 ($sto && $uid =~ /\A[0-9]+\z/) and
 325                         $sto->ipc_do('set_sync_info',
 326                                         $smsg->{blob}, $out, $uid + 0);
 327                 ++$lei->{-nr_write};
 328         }
 329 }
 330
 331 sub _text_write_cb ($$) {
 332         my ($self, $lei) = @_;
 333         my $dedupe = $lei->{dedupe};
 334         $dedupe->prepare_dedupe if $dedupe;
 335         my $lvt = $lei->{lvt};
 336         my $ovv = $lei->{ovv};
 337         $lei->{1} // die "no stdout ($ovv->{dst})"; # redirected earlier
 338         $lei->{1}->autoflush(1);
 339         binmode $lei->{1}, ':utf8';
 340         my $lse = $lei->{lse}; # may be undef
 341         sub { # for git_to_mail
 342                 my ($bref, $smsg, $eml) = @_;
 343                 $lse->xsmsg_vmd($smsg) if $lse;
 344                 $eml //= PublicInbox::Eml->new($bref); # copy bref
 345                 return if $dedupe && $dedupe->is_dup($eml, $smsg);
 346                 my $lk = $ovv->lock_for_scope;
 347                 $lei->out(${$lvt->eml_to_text($smsg, $eml)}, "\n");
 348         }
 349 }
 350
 351 sub write_cb { # returns a callback for git_to_mail
 352         my ($self, $lei) = @_;
 353         # _mbox_write_cb, _maildir_write_cb or _imap_write_cb
 354         my $m = "_$self->{base_type}_write_cb";
 355         $self->$m($lei);
 356 }
 357
 358 sub new {
 359         my ($cls, $lei) = @_;
 360         my $fmt = $lei->{ovv}->{fmt};
 361         my $dst = $lei->{ovv}->{dst};
 362         my $self = bless {}, $cls;
 363         if ($fmt eq 'maildir') {
 364                 require PublicInbox::MdirReader;
 365                 $self->{base_type} = 'maildir';
 366                 -e $dst && !-d _ and die
 367                                 "$dst exists and is not a directory\n";
 368                 $lei->{ovv}->{dst} = $dst .= '/' if substr($dst, -1) ne '/';
 369         } elsif (substr($fmt, 0, 4) eq 'mbox') {
 370                 require PublicInbox::MboxReader;
 371                 $self->can("eml2$fmt") or die "bad mbox format: $fmt\n";
 372                 $self->{base_type} = 'mbox';
 373         } elsif ($fmt =~ /\Aimaps?\z/) {
 374                 require PublicInbox::NetWriter;
 375                 require PublicInbox::URIimap;
 376                 my $net = PublicInbox::NetWriter->new;
 377                 $net->{quiet} = $lei->{opt}->{quiet};
 378                 my $uri = PublicInbox::URIimap->new($dst)->canonical;
 379                 $net->add_url($uri);
 380                 my $err = $net->errors($lei);
 381                 return $lei->fail($err) if $err;
 382                 $uri->mailbox or return $lei->fail("No mailbox: $dst");
 383                 $self->{uri} = $uri;
 384                 $dst = $lei->{ovv}->{dst} = $$uri; # canonicalized
 385                 $lei->{net} = $net;
 386                 $self->{base_type} = 'imap';
 387         } elsif ($fmt eq 'text') {
 388                 require PublicInbox::LeiViewText;
 389                 $lei->{lvt} = PublicInbox::LeiViewText->new($lei);
 390                 $self->{base_type} = 'text';
 391         } else {
 392                 die "bad mail --format=$fmt\n";
 393         }
 394         if ($self->{base_type} =~ /\A(?:text|mbox)\z/) {
 395                 (-d $dst || (-e _ && !-w _)) and die
 396                         "$dst exists and is not a writable file\n";
 397         }
 398         if ($self->{base_type} eq 'text') {
 399                 my @err = map {
 400                         defined($lei->{opt}->{$_}) ? "--$_" : ();
 401                 } (qw(mua save));
 402                 die "@err incompatible with $fmt\n" if @err;
 403         }
 404         $self->{dst} = $dst;
 405         $lei->{dedupe} = $lei->{lss} // do {
 406                 my $dd_cls = 'PublicInbox::'.
 407                         ($lei->{opt}->{save} ? 'LeiSavedSearch' : 'LeiDedupe');
 408                 eval "require $dd_cls";
 409                 die "$dd_cls: $@" if $@;
 410                 $dd_cls->new($lei);
 411         };
 412         $self;
 413 }
 414
 415 sub _pre_augment_maildir {
 416         my ($self, $lei) = @_;
 417         my $dst = $lei->{ovv}->{dst};
 418         for my $x (qw(tmp new cur)) {
 419                 my $d = $dst.$x;
 420                 next if -d $d;
 421                 require File::Path;
 422                 File::Path::mkpath($d);
 423                 -d $d or die "$d is not a directory";
 424         }
 425         # for utime, so no opendir
 426         open $self->{poke_dh}, '<', "${dst}cur" or die "open ${dst}cur: $!";
 427 }
 428
 429 sub _do_augment_maildir {
 430         my ($self, $lei) = @_;
 431         return if ($lei->{opt}->{save} // 0) < 0;
 432         my $dst = $lei->{ovv}->{dst};
 433         my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
 434         my $mdr = PublicInbox::MdirReader->new;
 435         if ($lei->{opt}->{augment}) {
 436                 my $dedupe = $lei->{dedupe};
 437                 if ($dedupe && $dedupe->prepare_dedupe) {
 438                         $mdr->{shard_info} = $self->{shard_info};
 439                         $mdr->maildir_each_eml($dst, \&_md_update, $lei, $lse);
 440                         $dedupe->pause_dedupe;
 441                 }
 442         } elsif ($lse) {
 443                 $mdr->{shard_info} = $self->{shard_info};
 444                 $mdr->maildir_each_eml($dst, \&_md_update, $lei, $lse, 1);
 445         } else {# clobber existing Maildir
 446                 $mdr->maildir_each_file($dst, \&_unlink);
 447         }
 448 }
 449
 450 sub _imap_augment_or_delete { # PublicInbox::NetReader::imap_each cb
 451         my ($url, $uid, $kw, $eml, $lei, $lse, $delete_mic) = @_;
 452         update_kw_maybe($lei, $lse, $eml, $kw);
 453         if ($delete_mic) {
 454                 $lei->{net}->imap_delete_1($url, $uid, $delete_mic);
 455         } else {
 456                 _augment($eml, $lei);
 457         }
 458 }
 459
 460 sub _do_augment_imap {
 461         my ($self, $lei) = @_;
 462         return if ($lei->{opt}->{save} // 0) < 0;
 463         my $net = $lei->{net};
 464         my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
 465         if ($lei->{opt}->{augment}) {
 466                 my $dedupe = $lei->{dedupe};
 467                 if ($dedupe && $dedupe->prepare_dedupe) {
 468                         $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 469                                         $lei, $lse);
 470                         $dedupe->pause_dedupe;
 471                 }
 472         } elsif ($lse) {
 473                 my $delete_mic;
 474                 $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 475                                         $lei, $lse, \$delete_mic);
 476                 $delete_mic->expunge if $delete_mic;
 477         } elsif (!$self->{-wq_worker_nr}) { # undef or 0
 478                 # clobber existing IMAP folder
 479                 $net->imap_delete_all($self->{uri});
 480         }
 481 }
 482
 483 sub _pre_augment_text {
 484         my ($self, $lei) = @_;
 485         my $dst = $lei->{ovv}->{dst};
 486         my $out;
 487         my $devfd = $lei->path_to_fd($dst) // die "bad $dst";
 488         if ($devfd >= 0) {
 489                 $out = $lei->{$devfd};
 490         } else { # normal-looking path
 491                 if (-p $dst) {
 492                         open $out, '>', $dst or die "open($dst): $!";
 493                 } elsif (-f _ || !-e _) {
 494                         # text allows augment, HTML/Atom won't
 495                         my $mode = $lei->{opt}->{augment} ? '>>' : '>';
 496                         open $out, $mode, $dst or die "open($mode, $dst): $!";
 497                 } else {
 498                         die "$dst is not a file or FIFO\n";
 499                 }
 500         }
 501         $lei->{ovv}->ovv_out_lk_init if !$lei->{ovv}->{lock_path};
 502         $lei->{1} = $out;
 503         undef;
 504 }
 505
 506 sub _pre_augment_mbox {
 507         my ($self, $lei) = @_;
 508         my $dst = $lei->{ovv}->{dst};
 509         my $out;
 510         my $devfd = $lei->path_to_fd($dst) // die "bad $dst";
 511         if ($devfd >= 0) {
 512                 $out = $lei->{$devfd};
 513         } else { # normal-looking path
 514                 if (-p $dst) {
 515                         open $out, '>', $dst or die "open($dst): $!";
 516                 } elsif (-f _ || !-e _) {
 517                         require PublicInbox::MboxLock;
 518                         my $m = $lei->{opt}->{'lock'} //
 519                                         PublicInbox::MboxLock->defaults;
 520                         $self->{mbl} = PublicInbox::MboxLock->acq($dst, 1, $m);
 521                         $out = $self->{mbl}->{fh};
 522                 } else {
 523                         die "$dst is not a file or FIFO\n";
 524                 }
 525                 $lei->{old_1} = $lei->{1}; # keep for spawning MUA
 526         }
 527         # Perl does SEEK_END even with O_APPEND :<
 528         $self->{seekable} = seek($out, 0, SEEK_SET);
 529         if (!$self->{seekable} && !$!{ESPIPE} && !defined($devfd)) {
 530                 die "seek($dst): $!\n";
 531         }
 532         if (!$self->{seekable}) {
 533                 my $imp_before = $lei->{opt}->{'import-before'};
 534                 die "--import-before specified but $dst is not seekable\n"
 535                         if $imp_before && !ref($imp_before);
 536                 die "--augment specified but $dst is not seekable\n" if
 537                         $lei->{opt}->{augment};
 538         }
 539         if ($self->{zsfx} = PublicInbox::MboxReader::zsfx($dst)) {
 540                 pipe(my ($r, $w)) or die "pipe: $!";
 541                 $lei->{zpipe} = [ $r, $w ];
 542                 $lei->{ovv}->{lock_path} and
 543                         die 'BUG: unexpected {ovv}->{lock_path}';
 544                 $lei->{ovv}->ovv_out_lk_init;
 545         } elsif (!$self->{seekable} && !$lei->{ovv}->{lock_path}) {
 546                 $lei->{ovv}->ovv_out_lk_init;
 547         }
 548         $lei->{1} = $out;
 549         undef;
 550 }
 551
 552 sub _do_augment_mbox {
 553         my ($self, $lei) = @_;
 554         return unless $self->{seekable};
 555         my $opt = $lei->{opt};
 556         return if ($opt->{save} // 0) < 0;
 557         my $out = $lei->{1};
 558         my ($fmt, $dst) = @{$lei->{ovv}}{qw(fmt dst)};
 559         return unless -s $out;
 560         unless ($opt->{augment} || $opt->{'import-before'}) {
 561                 truncate($out, 0) or die "truncate($dst): $!";
 562                 return;
 563         }
 564         my $rd;
 565         if (my $zsfx = $self->{zsfx}) {
 566                 $rd = PublicInbox::MboxReader::zsfxcat($out, $zsfx, $lei);
 567         } else {
 568                 open($rd, '+>>&', $out) or die "dup: $!";
 569         }
 570         my $dedupe;
 571         if ($opt->{augment}) {
 572                 $dedupe = $lei->{dedupe};
 573                 $dedupe->prepare_dedupe if $dedupe;
 574         }
 575         if ($opt->{'import-before'}) { # the default
 576                 my $lse = $lei->{lse};
 577                 PublicInbox::MboxReader->$fmt($rd, \&_mbox_augment_kw_maybe,
 578                                                 $lei, $lse, $opt->{augment});
 579                 if (!$opt->{augment} and !truncate($out, 0)) {
 580                         die "truncate($dst): $!";
 581                 }
 582         } else { # --augment --no-import-before
 583                 PublicInbox::MboxReader->$fmt($rd, \&_augment, $lei);
 584         }
 585         # maybe some systems don't honor O_APPEND, Perl does this:
 586         seek($out, 0, SEEK_END) or die "seek $dst: $!";
 587         $dedupe->pause_dedupe if $dedupe;
 588 }
 589
 590 sub pre_augment { # fast (1 disk seek), runs in same process as post_augment
 591         my ($self, $lei) = @_;
 592         # _pre_augment_maildir, _pre_augment_mbox
 593         my $m = $self->can("_pre_augment_$self->{base_type}") or return;
 594         $m->($self, $lei);
 595 }
 596
 597 sub do_augment { # slow, runs in wq worker
 598         my ($self, $lei) = @_;
 599         # _do_augment_maildir, _do_augment_mbox, or _do_augment_imap
 600         my $m = $self->can("_do_augment_$self->{base_type}") or return;
 601         $m->($self, $lei);
 602 }
 603
 604 # fast (spawn compressor or mkdir), runs in same process as pre_augment
 605 sub post_augment {
 606         my ($self, $lei, @args) = @_;
 607         my $wait = $lei->{opt}->{'import-before'} ?
 608                         $lei->{sto}->ipc_do('checkpoint', 1) : 0;
 609         # _post_augment_mbox
 610         my $m = $self->can("_post_augment_$self->{base_type}") or return;
 611         $m->($self, $lei, @args);
 612 }
 613
 614 # called by every single l2m worker process
 615 sub do_post_auth {
 616         my ($self) = @_;
 617         my $lei = $self->{lei};
 618         # lei_xsearch can start as soon as all l2m workers get here
 619         pkt_do($lei->{pkt_op_p}, 'incr_start_query') or
 620                 die "incr_start_query: $!";
 621         my $aug;
 622         if (lock_free($self)) { # all workers do_augment
 623                 my $mod = $self->{-wq_nr_workers};
 624                 my $shard = $self->{-wq_worker_nr};
 625                 if (my $net = $lei->{net}) {
 626                         $net->{shard_info} = [ $mod, $shard ];
 627                 } else { # Maildir
 628                         $self->{shard_info} = [ $mod, $shard ];
 629                 }
 630                 $aug = '+'; # incr_post_augment
 631         } elsif ($self->{-wq_worker_nr} == 0) { # 1st worker do_augment
 632                 $aug = '.'; # do_post_augment
 633         }
 634         if ($aug) {
 635                 local $0 = 'do_augment';
 636                 eval { do_augment($self, $lei) };
 637                 $lei->fail($@) if $@;
 638                 pkt_do($lei->{pkt_op_p}, $aug) == 1 or
 639                                 die "do_post_augment trigger: $!";
 640         }
 641         # done augmenting, connect the compressor pipe for each worker
 642         if (my $zpipe = delete $lei->{zpipe}) {
 643                 $lei->{1} = $zpipe->[1];
 644                 close $zpipe->[0];
 645         }
 646         $self->{wcb} = $self->write_cb($lei);
 647 }
 648
 649 sub ipc_atfork_child {
 650         my ($self) = @_;
 651         my $lei = $self->{lei};
 652         $lei->_lei_atfork_child;
 653         if (my $lse = $lei->{lse}) {
 654                 $self->{-lms_ro} = $lse->{-lms_ro} //= $lse->lms;
 655         }
 656         $lei->{auth}->do_auth_atfork($self) if $lei->{auth};
 657         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 658         $self->SUPER::ipc_atfork_child;
 659 }
 660
 661 sub lock_free {
 662         $_[0]->{base_type} =~ /\A(?:maildir|imap|jmap)\z/ ? 1 : 0;
 663 }
 664
 665 # wakes up the MUA when complete so it can refresh messages list
 666 sub poke_dst {
 667         my ($self) = @_;
 668         if ($self->{base_type} eq 'maildir') {
 669                 my $t = time + 1;
 670                 utime($t, $t, $self->{poke_dh}) or warn "futimes: $!";
 671         }
 672 }
 673
 674 sub write_mail { # via ->wq_io_do
 675         my ($self, $smsg, $eml) = @_;
 676         return $self->{wcb}->(undef, $smsg, $eml) if $eml;
 677         $smsg->{-lms_ro} = $self->{-lms_ro};
 678         $self->{lei}->{ale}->git->cat_async($smsg->{blob}, \&git_to_mail,
 679                                 [$self->{wcb}, $smsg]);
 680 }
 681
 682 sub wq_atexit_child {
 683         my ($self) = @_;
 684         delete $self->{wcb};
 685         my $lei = $self->{lei};
 686         $lei->{ale}->git->async_wait_all;
 687         my $nr = delete($lei->{-nr_write}) or return;
 688         return if $lei->{early_mua} || !$lei->{-progress} || !$lei->{pkt_op_p};
 689         require PublicInbox::PktOp;
 690         PublicInbox::PktOp::pkt_do($lei->{pkt_op_p}, 'l2m_progress', $nr);
 691 }
 692
 693 # called in top-level lei-daemon when LeiAuth is done
 694 sub net_merge_all_done {
 695         my ($self) = @_;
 696         $self->wq_broadcast('do_post_auth');
 697         $self->wq_close(1);
 698 }
 699
 700 no warnings 'once'; # the following works even when LeiAuth is lazy-loaded
 701 *net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
 702 1;