lib/PublicInbox/LeiToMail.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Writes PublicInbox::Eml objects atomically to a mbox variant or Maildir
   5 package PublicInbox::LeiToMail;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::ProcessPipe;
  11 use PublicInbox::Spawn qw(spawn);
  12 use Symbol qw(gensym);
  13 use IO::Handle; # ->autoflush
  14 use Fcntl qw(SEEK_SET SEEK_END O_CREAT O_EXCL O_WRONLY);
  15
  16 my %kw2char = ( # Maildir characters
  17         draft => 'D',
  18         flagged => 'F',
  19         forwarded => 'P', # passed
  20         answered => 'R',
  21         seen => 'S',
  22 );
  23
  24 my %kw2status = (
  25         flagged => [ 'X-Status' => 'F' ],
  26         answered => [ 'X-Status' => 'A' ],
  27         seen => [ 'Status' => 'R' ],
  28         draft => [ 'X-Status' => 'T' ],
  29 );
  30
  31 sub _mbox_hdr_buf ($$$) {
  32         my ($eml, $type, $smsg) = @_;
  33         $eml->header_set($_) for (qw(Lines Bytes Content-Length));
  34
  35         my %hdr = (Status => []); # set Status, X-Status
  36         for my $k (@{$smsg->{kw} // []}) {
  37                 if (my $ent = $kw2status{$k}) {
  38                         push @{$hdr{$ent->[0]}}, $ent->[1];
  39                 } else { # X-Label?
  40                         warn "# keyword `$k' not supported for mbox\n";
  41                 }
  42         }
  43         # When writing to empty mboxes, messages are always 'O'
  44         # (not-\Recent in IMAP), it saves MUAs the trouble of
  45         # rewriting the mbox if no other changes are made.
  46         # We put 'O' at the end (e.g. "Status: RO") to match mutt(1) output.
  47         # We only set smsg->{-recent} if augmenting existing stores.
  48         my $status = join('', sort(@{$hdr{Status}}));
  49         $status .= 'O' unless $smsg->{-recent};
  50         $eml->header_set('Status', $status) if $status;
  51         if (my $chars = delete $hdr{'X-Status'}) {
  52                 $eml->header_set('X-Status', join('', sort(@$chars)));
  53         }
  54         my $buf = delete $eml->{hdr};
  55
  56         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
  57         $$buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  58         my $ident = $smsg->{blob} // 'lei';
  59         if (defined(my $pct = $smsg->{pct})) { $ident .= "=$pct" }
  60
  61         substr($$buf, 0, 0, # prepend From line
  62                 "From $ident\@$type Thu Jan  1 00:00:00 1970$eml->{crlf}");
  63         $buf;
  64 }
  65
  66 sub atomic_append { # for on-disk destinations (O_APPEND, or O_EXCL)
  67         my ($lei, $buf) = @_;
  68         if (defined(my $w = syswrite($lei->{1} // return, $$buf))) {
  69                 return if $w == length($$buf);
  70                 $buf = "short atomic write: $w != ".length($$buf);
  71         } elsif ($!{EPIPE}) {
  72                 return $lei->note_sigpipe(1);
  73         } else {
  74                 $buf = "atomic write: $!";
  75         }
  76         $lei->fail($buf);
  77 }
  78
  79 sub eml2mboxrd ($;$) {
  80         my ($eml, $smsg) = @_;
  81         my $buf = _mbox_hdr_buf($eml, 'mboxrd', $smsg);
  82         if (my $bdy = delete $eml->{bdy}) {
  83                 $$bdy =~ s/^(>*From )/>$1/gm;
  84                 $$buf .= $eml->{crlf};
  85                 substr($$bdy, 0, 0, $$buf); # prepend header
  86                 $buf = $bdy;
  87         }
  88         $$buf .= $eml->{crlf};
  89         $buf;
  90 }
  91
  92 sub eml2mboxo {
  93         my ($eml, $smsg) = @_;
  94         my $buf = _mbox_hdr_buf($eml, 'mboxo', $smsg);
  95         if (my $bdy = delete $eml->{bdy}) {
  96                 $$bdy =~ s/^From />From /gm;
  97                 $$buf .= $eml->{crlf};
  98                 substr($$bdy, 0, 0, $$buf); # prepend header
  99                 $buf = $bdy;
 100         }
 101         $$buf .= $eml->{crlf};
 102         $buf;
 103 }
 104
 105 sub _mboxcl_common ($$$) {
 106         my ($buf, $bdy, $crlf) = @_;
 107         # add Lines: so mutt won't have to add it on MUA close
 108         my $lines = $$bdy =~ tr!\n!\n!;
 109         $$buf .= 'Content-Length: '.length($$bdy).$crlf.
 110                 'Lines: '.$lines.$crlf.$crlf;
 111         substr($$bdy, 0, 0, $$buf); # prepend header
 112         $$bdy .= $crlf;
 113         $bdy;
 114 }
 115
 116 # mboxcl still escapes "From " lines
 117 sub eml2mboxcl {
 118         my ($eml, $smsg) = @_;
 119         my $buf = _mbox_hdr_buf($eml, 'mboxcl', $smsg);
 120         my $bdy = delete($eml->{bdy}) // \(my $empty = '');
 121         $$bdy =~ s/^From />From /gm;
 122         _mboxcl_common($buf, $bdy, $eml->{crlf});
 123 }
 124
 125 # mboxcl2 has no "From " escaping
 126 sub eml2mboxcl2 {
 127         my ($eml, $smsg) = @_;
 128         my $buf = _mbox_hdr_buf($eml, 'mboxcl2', $smsg);
 129         my $bdy = delete($eml->{bdy}) // \(my $empty = '');
 130         _mboxcl_common($buf, $bdy, $eml->{crlf});
 131 }
 132
 133 sub git_to_mail { # git->cat_async callback
 134         my ($bref, $oid, $type, $size, $arg) = @_;
 135         my ($write_cb, $smsg) = @$arg;
 136         if ($type eq 'missing' && $smsg->{-lms_ro}) {
 137                 if ($bref = $smsg->{-lms_ro}->local_blob($oid, 1)) {
 138                         $type = 'blob';
 139                         $size = length($$bref);
 140                 }
 141         }
 142         return warn("W: $oid is $type (!= blob)\n") if $type ne 'blob';
 143         return warn("E: $oid is empty\n") unless $size;
 144         die "BUG: expected=$smsg->{blob} got=$oid" if $smsg->{blob} ne $oid;
 145         $write_cb->($bref, $smsg);
 146 }
 147
 148 sub reap_compress { # dwaitpid callback
 149         my ($lei, $pid) = @_;
 150         my $cmd = delete $lei->{"pid.$pid"};
 151         return if $? == 0;
 152         $lei->fail("@$cmd failed", $? >> 8);
 153 }
 154
 155 sub _post_augment_mbox { # open a compressor process from top-level process
 156         my ($self, $lei) = @_;
 157         my $zsfx = $self->{zsfx} or return;
 158         my $cmd = PublicInbox::MboxReader::zsfx2cmd($zsfx, undef, $lei);
 159         my ($r, $w) = @{delete $lei->{zpipe}};
 160         my $rdr = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 161         my $pid = spawn($cmd, undef, $rdr);
 162         my $pp = gensym;
 163         my $dup = bless { "pid.$pid" => $cmd }, ref($lei);
 164         $dup->{$_} = $lei->{$_} for qw(2 sock);
 165         tie *$pp, 'PublicInbox::ProcessPipe', $pid, $w, \&reap_compress, $dup;
 166         $lei->{1} = $pp;
 167 }
 168
 169 # --augment existing output destination, with deduplication
 170 sub _augment { # MboxReader eml_cb
 171         my ($eml, $lei) = @_;
 172         # ignore return value, just populate the skv
 173         $lei->{dedupe}->is_dup($eml);
 174 }
 175
 176 sub _mbox_augment_kw_maybe {
 177         my ($eml, $lei, $lse, $augment) = @_;
 178         my $kw = PublicInbox::MboxReader::mbox_keywords($eml);
 179         update_kw_maybe($lei, $lse, $eml, $kw);
 180         _augment($eml, $lei) if $augment;
 181 }
 182
 183 sub _mbox_write_cb ($$) {
 184         my ($self, $lei) = @_;
 185         my $ovv = $lei->{ovv};
 186         my $m = 'eml2'.$ovv->{fmt};
 187         my $eml2mbox = $self->can($m) or die "$self->$m missing";
 188         $lei->{1} // die "no stdout ($m, $ovv->{dst})"; # redirected earlier
 189         $lei->{1}->autoflush(1);
 190         my $atomic_append = !defined($ovv->{lock_path});
 191         my $dedupe = $lei->{dedupe};
 192         $dedupe->prepare_dedupe;
 193         my $lse = $lei->{lse}; # may be undef
 194         my $set_recent = $dedupe->has_entries;
 195         sub { # for git_to_mail
 196                 my ($buf, $smsg, $eml) = @_;
 197                 $eml //= PublicInbox::Eml->new($buf);
 198                 return if $dedupe->is_dup($eml, $smsg);
 199                 $lse->xsmsg_vmd($smsg) if $lse;
 200                 $smsg->{-recent} = 1 if $set_recent;
 201                 $buf = $eml2mbox->($eml, $smsg);
 202                 if ($atomic_append) {
 203                         atomic_append($lei, $buf);
 204                 } else {
 205                         my $lk = $ovv->lock_for_scope;
 206                         $lei->out($$buf);
 207                 }
 208                 ++$lei->{-nr_write};
 209         }
 210 }
 211
 212 sub update_kw_maybe ($$$$) {
 213         my ($lei, $lse, $eml, $kw) = @_;
 214         return unless $lse;
 215         my $c = $lse->kw_changed($eml, $kw, my $docids = []);
 216         my $vmd = { kw => $kw };
 217         if (scalar @$docids) { # already in lei/store
 218                 $lei->{sto}->ipc_do('set_eml_vmd', undef, $vmd, $docids) if $c;
 219         } elsif (my $xoids = $lei->{ale}->xoids_for($eml)) {
 220                 # it's in an external, only set kw, here
 221                 $lei->{sto}->ipc_do('set_xvmd', $xoids, $eml, $vmd);
 222         } else { # never-before-seen, import the whole thing
 223                 # XXX this is critical in protecting against accidental
 224                 # data loss without --augment
 225                 $lei->{sto}->ipc_do('set_eml', $eml, $vmd);
 226         }
 227 }
 228
 229 sub _md_update { # maildir_each_eml cb
 230         my ($f, $kw, $eml, $lei, $lse, $unlink) = @_;
 231         update_kw_maybe($lei, $lse, $eml, $kw);
 232         $unlink ? unlink($f) : _augment($eml, $lei);
 233 }
 234
 235 # maildir_each_file callback, \&CORE::unlink doesn't work with it
 236 sub _unlink { unlink($_[0]) }
 237
 238 sub _rand () {
 239         state $seq = 0;
 240         sprintf('%x,%x,%x,%x', rand(0xffffffff), time, $$, ++$seq);
 241 }
 242
 243 sub kw2suffix ($;@) {
 244         my $kw = shift;
 245         join('', sort(map { $kw2char{$_} // () } @$kw, @_));
 246 }
 247
 248 sub _buf2maildir ($$$$) {
 249         my ($dst, $buf, $smsg, $dir) = @_;
 250         my $kw = $smsg->{kw} // [];
 251         my $rand = ''; # chosen by die roll :P
 252         my ($tmp, $fh, $base, $ok);
 253         my $common = $smsg->{blob} // _rand;
 254         if (defined(my $pct = $smsg->{pct})) { $common .= "=$pct" }
 255         do {
 256                 $tmp = $dst.'tmp/'.$rand.$common;
 257         } while (!($ok = sysopen($fh, $tmp, O_CREAT|O_EXCL|O_WRONLY)) &&
 258                 $!{EEXIST} && ($rand = _rand.','));
 259         if ($ok && print $fh $$buf and close($fh)) {
 260                 $dst .= $dir; # 'new/' or 'cur/'
 261                 $rand = '';
 262                 do {
 263                         $base = $rand.$common.':2,'.kw2suffix($kw);
 264                 } while (!($ok = link($tmp, $dst.$base)) && $!{EEXIST} &&
 265                         ($rand = _rand.','));
 266                 die "link($tmp, $dst$base): $!" unless $ok;
 267                 unlink($tmp) or warn "W: failed to unlink $tmp: $!\n";
 268                 \$base;
 269         } else {
 270                 my $err = "Error writing $smsg->{blob} to $dst: $!\n";
 271                 $_[0] = undef; # clobber dst
 272                 unlink($tmp);
 273                 die $err;
 274         }
 275 }
 276
 277 sub _maildir_write_cb ($$) {
 278         my ($self, $lei) = @_;
 279         my $dedupe = $lei->{dedupe};
 280         $dedupe->prepare_dedupe if $dedupe;
 281         my $dst = $lei->{ovv}->{dst};
 282         my $lse = $lei->{lse}; # may be undef
 283         my $sto = $lei->{opt}->{'mail-sync'} ? $lei->{sto} : undef;
 284         my $out = $sto ? 'maildir:'.$lei->abs_path($dst) : undef;
 285
 286         # Favor cur/ and only write to new/ when augmenting.  This
 287         # saves MUAs from having to do a mass rename when the initial
 288         # search result set is huge.
 289         my $dir = $dedupe && $dedupe->has_entries ? 'new/' : 'cur/';
 290         sub { # for git_to_mail
 291                 my ($bref, $smsg, $eml) = @_;
 292                 $dst // return $lei->fail; # dst may be undef-ed in last run
 293                 return if $dedupe && $dedupe->is_dup($eml //
 294                                                 PublicInbox::Eml->new($$bref),
 295                                                 $smsg);
 296                 $lse->xsmsg_vmd($smsg) if $lse;
 297                 my $n = _buf2maildir($dst, $bref // \($eml->as_string),
 298                                         $smsg, $dir);
 299                 $sto->ipc_do('set_sync_info', $smsg->{blob}, $out, $n) if $sto;
 300                 ++$lei->{-nr_write};
 301         }
 302 }
 303
 304 sub _imap_write_cb ($$) {
 305         my ($self, $lei) = @_;
 306         my $dedupe = $lei->{dedupe};
 307         $dedupe->prepare_dedupe if $dedupe;
 308         my $append = $lei->{net}->can('imap_append');
 309         my $uri = $self->{uri};
 310         my $mic = $lei->{net}->mic_get($uri);
 311         my $folder = $uri->mailbox;
 312         $uri->uidvalidity($mic->uidvalidity($folder));
 313         my $lse = $lei->{lse}; # may be undef
 314         my $sto = $lei->{opt}->{'mail-sync'} ? $lei->{sto} : undef;
 315         sub { # for git_to_mail
 316                 my ($bref, $smsg, $eml) = @_;
 317                 $mic // return $lei->fail; # mic may be undef-ed in last run
 318                 return if $dedupe && $dedupe->is_dup($eml //
 319                                                 PublicInbox::Eml->new($$bref),
 320                                                 $smsg);
 321                 $lse->xsmsg_vmd($smsg) if $lse;
 322                 my $uid = eval { $append->($mic, $folder, $bref, $smsg, $eml) };
 323                 if (my $err = $@) {
 324                         undef $mic;
 325                         die $err;
 326                 }
 327                 # imap_append returns UID if IMAP server has UIDPLUS extension
 328                 ($sto && $uid =~ /\A[0-9]+\z/) and
 329                         $sto->ipc_do('set_sync_info',
 330                                         $smsg->{blob}, $$uri, $uid + 0);
 331                 ++$lei->{-nr_write};
 332         }
 333 }
 334
 335 sub _text_write_cb ($$) {
 336         my ($self, $lei) = @_;
 337         my $dedupe = $lei->{dedupe};
 338         $dedupe->prepare_dedupe if $dedupe;
 339         my $lvt = $lei->{lvt};
 340         my $ovv = $lei->{ovv};
 341         $lei->{1} // die "no stdout ($ovv->{dst})"; # redirected earlier
 342         $lei->{1}->autoflush(1);
 343         binmode $lei->{1}, ':utf8';
 344         my $lse = $lei->{lse}; # may be undef
 345         sub { # for git_to_mail
 346                 my ($bref, $smsg, $eml) = @_;
 347                 $lse->xsmsg_vmd($smsg) if $lse;
 348                 $eml //= PublicInbox::Eml->new($bref);
 349                 return if $dedupe && $dedupe->is_dup($eml, $smsg);
 350                 my $lk = $ovv->lock_for_scope;
 351                 $lei->out(${$lvt->eml_to_text($smsg, $eml)}, "\n");
 352         }
 353 }
 354
 355 sub _v2_write_cb ($$) {
 356         my ($self, $lei) = @_;
 357         my $dedupe = $lei->{dedupe};
 358         $dedupe->prepare_dedupe if $dedupe;
 359         sub { # for git_to_mail
 360                 my ($bref, $smsg, $eml) = @_;
 361                 $eml //= PublicInbox::Eml->new($bref);
 362                 return if $dedupe && $dedupe->is_dup($eml, $smsg);
 363                 $lei->{v2w}->ipc_do('add', $eml); # V2Writable->add
 364         }
 365 }
 366
 367 sub write_cb { # returns a callback for git_to_mail
 368         my ($self, $lei) = @_;
 369         # _mbox_write_cb, _maildir_write_cb, _imap_write_cb, _v2_write_cb
 370         my $m = "_$self->{base_type}_write_cb";
 371         $self->$m($lei);
 372 }
 373
 374 sub new {
 375         my ($cls, $lei) = @_;
 376         my $fmt = $lei->{ovv}->{fmt};
 377         my $dst = $lei->{ovv}->{dst};
 378         my $self = bless {}, $cls;
 379         my @conflict;
 380         if ($fmt eq 'maildir') {
 381                 require PublicInbox::MdirReader;
 382                 $self->{base_type} = 'maildir';
 383                 -e $dst && !-d _ and die
 384                                 "$dst exists and is not a directory\n";
 385                 $lei->{ovv}->{dst} = $dst .= '/' if substr($dst, -1) ne '/';
 386                 $lei->{opt}->{save} //= \1 if $lei->{cmd} eq 'q';
 387         } elsif (substr($fmt, 0, 4) eq 'mbox') {
 388                 require PublicInbox::MboxReader;
 389                 $self->can("eml2$fmt") or die "bad mbox format: $fmt\n";
 390                 $self->{base_type} = 'mbox';
 391                 if ($lei->{cmd} eq 'q' &&
 392                                 (($lei->path_to_fd($dst) // -1) < 0) &&
 393                                 (-f $dst || !-e _)) {
 394                         $lei->{opt}->{save} //= \1;
 395                 }
 396         } elsif ($fmt =~ /\Aimaps?\z/) {
 397                 require PublicInbox::NetWriter;
 398                 require PublicInbox::URIimap;
 399                 my $net = PublicInbox::NetWriter->new;
 400                 $net->{quiet} = $lei->{opt}->{quiet};
 401                 my $uri = PublicInbox::URIimap->new($dst)->canonical;
 402                 $net->add_url($$uri);
 403                 my $err = $net->errors($lei);
 404                 return $lei->fail($err) if $err;
 405                 $uri->mailbox or return $lei->fail("No mailbox: $dst");
 406                 $self->{uri} = $uri;
 407                 $dst = $lei->{ovv}->{dst} = $$uri; # canonicalized
 408                 $lei->{net} = $net;
 409                 $self->{base_type} = 'imap';
 410                 $lei->{opt}->{save} //= \1 if $lei->{cmd} eq 'q';
 411         } elsif ($fmt eq 'text') {
 412                 require PublicInbox::LeiViewText;
 413                 $lei->{lvt} = PublicInbox::LeiViewText->new($lei);
 414                 $self->{base_type} = 'text';
 415                 @conflict = qw(mua save);
 416         } elsif ($fmt eq 'v2') {
 417                 die "--dedupe=oid and v2 are incompatible\n" if
 418                         ($lei->{opt}->{dedupe}//'') eq 'oid';
 419                 $self->{base_type} = 'v2';
 420                 $lei->{opt}->{save} = \1;
 421                 $dst = $lei->{ovv}->{dst} = $lei->abs_path($dst);
 422                 @conflict = qw(mua sort);
 423         } else {
 424                 die "bad mail --format=$fmt\n";
 425         }
 426         if ($self->{base_type} =~ /\A(?:text|mbox)\z/) {
 427                 (-d $dst || (-e _ && !-w _)) and die
 428                         "$dst exists and is not a writable file\n";
 429         }
 430         my @err = map { defined($lei->{opt}->{$_}) ? "--$_" : () } @conflict;
 431         die "@err incompatible with $fmt\n" if @err;
 432         $self->{dst} = $dst;
 433         $lei->{dedupe} = $lei->{lss} // do {
 434                 my $dd_cls = 'PublicInbox::'.
 435                         ($lei->{opt}->{save} ? 'LeiSavedSearch' : 'LeiDedupe');
 436                 eval "require $dd_cls";
 437                 die "$dd_cls: $@" if $@;
 438                 $dd_cls->new($lei);
 439         };
 440         $self;
 441 }
 442
 443 sub _pre_augment_maildir {
 444         my ($self, $lei) = @_;
 445         my $dst = $lei->{ovv}->{dst};
 446         for my $x (qw(tmp new cur)) {
 447                 my $d = $dst.$x;
 448                 next if -d $d;
 449                 require File::Path;
 450                 File::Path::mkpath($d);
 451                 -d $d or die "$d is not a directory";
 452         }
 453         # for utime, so no opendir
 454         open $self->{poke_dh}, '<', "${dst}cur" or die "open ${dst}cur: $!";
 455 }
 456
 457 sub clobber_dst_prepare ($;$) {
 458         my ($lei, $f) = @_;
 459         my $wait = (defined($f) && $lei->{sto}) ?
 460                         $lei->{sto}->ipc_do('lms_forget_folders', $f) : undef;
 461         my $dedupe = $lei->{dedupe} or return;
 462         $dedupe->reset_dedupe if $dedupe->can('reset_dedupe');
 463 }
 464
 465 sub _do_augment_maildir {
 466         my ($self, $lei) = @_;
 467         return if $lei->{cmd} eq 'up';
 468         my $dst = $lei->{ovv}->{dst};
 469         my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
 470         my $mdr = PublicInbox::MdirReader->new;
 471         if ($lei->{opt}->{augment}) {
 472                 my $dedupe = $lei->{dedupe};
 473                 if ($dedupe && $dedupe->prepare_dedupe) {
 474                         $mdr->{shard_info} = $self->{shard_info};
 475                         $mdr->maildir_each_eml($dst, \&_md_update, $lei, $lse);
 476                         $dedupe->pause_dedupe;
 477                 }
 478         } elsif ($lse) {
 479                 clobber_dst_prepare($lei, "maildir:$dst");
 480                 $mdr->{shard_info} = $self->{shard_info};
 481                 $mdr->maildir_each_eml($dst, \&_md_update, $lei, $lse, 1);
 482         } else {# clobber existing Maildir
 483                 clobber_dst_prepare($lei, "maildir:$dst");
 484                 $mdr->maildir_each_file($dst, \&_unlink);
 485         }
 486 }
 487
 488 sub _imap_augment_or_delete { # PublicInbox::NetReader::imap_each cb
 489         my ($uri, $uid, $kw, $eml, $lei, $lse, $delete_mic) = @_;
 490         update_kw_maybe($lei, $lse, $eml, $kw);
 491         if ($delete_mic) {
 492                 $lei->{net}->imap_delete_1($uri, $uid, $delete_mic);
 493         } else {
 494                 _augment($eml, $lei);
 495         }
 496 }
 497
 498 sub _do_augment_imap {
 499         my ($self, $lei) = @_;
 500         return if $lei->{cmd} eq 'up';
 501         my $net = $lei->{net};
 502         my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
 503         if ($lei->{opt}->{augment}) {
 504                 my $dedupe = $lei->{dedupe};
 505                 if ($dedupe && $dedupe->prepare_dedupe) {
 506                         $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 507                                         $lei, $lse);
 508                         $dedupe->pause_dedupe;
 509                 }
 510         } elsif ($lse) {
 511                 my $delete_mic;
 512                 clobber_dst_prepare($lei, "$self->{uri}");
 513                 $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 514                                         $lei, $lse, \$delete_mic);
 515                 $delete_mic->expunge if $delete_mic;
 516         } elsif (!$self->{-wq_worker_nr}) { # undef or 0
 517                 # clobber existing IMAP folder
 518                 clobber_dst_prepare($lei, "$self->{uri}");
 519                 $net->imap_delete_all($self->{uri});
 520         }
 521 }
 522
 523 sub _pre_augment_text {
 524         my ($self, $lei) = @_;
 525         my $dst = $lei->{ovv}->{dst};
 526         my $out;
 527         my $devfd = $lei->path_to_fd($dst) // die "bad $dst";
 528         if ($devfd >= 0) {
 529                 $out = $lei->{$devfd};
 530         } else { # normal-looking path
 531                 if (-p $dst) {
 532                         open $out, '>', $dst or die "open($dst): $!";
 533                 } elsif (-f _ || !-e _) {
 534                         # text allows augment, HTML/Atom won't
 535                         my $mode = $lei->{opt}->{augment} ? '>>' : '>';
 536                         open $out, $mode, $dst or die "open($mode, $dst): $!";
 537                 } else {
 538                         die "$dst is not a file or FIFO\n";
 539                 }
 540         }
 541         $lei->{ovv}->ovv_out_lk_init if !$lei->{ovv}->{lock_path};
 542         $lei->{1} = $out;
 543         undef;
 544 }
 545
 546 sub _pre_augment_mbox {
 547         my ($self, $lei) = @_;
 548         my $dst = $lei->{ovv}->{dst};
 549         my $out;
 550         my $devfd = $lei->path_to_fd($dst) // die "bad $dst";
 551         if ($devfd >= 0) {
 552                 $out = $lei->{$devfd};
 553         } else { # normal-looking path
 554                 if (-p $dst) {
 555                         open $out, '>', $dst or die "open($dst): $!";
 556                 } elsif (-f _ || !-e _) {
 557                         require PublicInbox::MboxLock;
 558                         my $m = $lei->{opt}->{'lock'} //
 559                                         PublicInbox::MboxLock->defaults;
 560                         $self->{mbl} = PublicInbox::MboxLock->acq($dst, 1, $m);
 561                         $out = $self->{mbl}->{fh};
 562                 } else {
 563                         die "$dst is not a file or FIFO\n";
 564                 }
 565                 $lei->{old_1} = $lei->{1}; # keep for spawning MUA
 566         }
 567         # Perl does SEEK_END even with O_APPEND :<
 568         $self->{seekable} = seek($out, 0, SEEK_SET);
 569         if (!$self->{seekable} && !$!{ESPIPE} && !defined($devfd)) {
 570                 die "seek($dst): $!\n";
 571         }
 572         if (!$self->{seekable}) {
 573                 my $imp_before = $lei->{opt}->{'import-before'};
 574                 die "--import-before specified but $dst is not seekable\n"
 575                         if $imp_before && !ref($imp_before);
 576                 die "--augment specified but $dst is not seekable\n" if
 577                         $lei->{opt}->{augment};
 578                 die "cannot --save with unseekable $dst\n" if
 579                         $lei->{dedupe} && $lei->{dedupe}->can('reset_dedupe');
 580         }
 581         if ($self->{zsfx} = PublicInbox::MboxReader::zsfx($dst)) {
 582                 pipe(my ($r, $w)) or die "pipe: $!";
 583                 $lei->{zpipe} = [ $r, $w ];
 584                 $lei->{ovv}->{lock_path} and
 585                         die 'BUG: unexpected {ovv}->{lock_path}';
 586                 $lei->{ovv}->ovv_out_lk_init;
 587         } elsif (!$self->{seekable} && !$lei->{ovv}->{lock_path}) {
 588                 $lei->{ovv}->ovv_out_lk_init;
 589         }
 590         $lei->{1} = $out;
 591         undef;
 592 }
 593
 594 sub _do_augment_mbox {
 595         my ($self, $lei) = @_;
 596         return unless $self->{seekable};
 597         my $opt = $lei->{opt};
 598         return if $lei->{cmd} eq 'up';
 599         my $out = $lei->{1};
 600         my ($fmt, $dst) = @{$lei->{ovv}}{qw(fmt dst)};
 601         return clobber_dst_prepare($lei) unless -s $out;
 602         unless ($opt->{augment} || $opt->{'import-before'}) {
 603                 truncate($out, 0) or die "truncate($dst): $!";
 604                 return;
 605         }
 606         my $rd;
 607         if (my $zsfx = $self->{zsfx}) {
 608                 $rd = PublicInbox::MboxReader::zsfxcat($out, $zsfx, $lei);
 609         } else {
 610                 open($rd, '+>>&', $out) or die "dup: $!";
 611         }
 612         my $dedupe;
 613         if ($opt->{augment}) {
 614                 $dedupe = $lei->{dedupe};
 615                 $dedupe->prepare_dedupe if $dedupe;
 616         } else {
 617                 clobber_dst_prepare($lei);
 618         }
 619         if ($opt->{'import-before'}) { # the default
 620                 my $lse = $lei->{lse};
 621                 PublicInbox::MboxReader->$fmt($rd, \&_mbox_augment_kw_maybe,
 622                                                 $lei, $lse, $opt->{augment});
 623                 if (!$opt->{augment} and !truncate($out, 0)) {
 624                         die "truncate($dst): $!";
 625                 }
 626         } else { # --augment --no-import-before
 627                 PublicInbox::MboxReader->$fmt($rd, \&_augment, $lei);
 628         }
 629         # maybe some systems don't honor O_APPEND, Perl does this:
 630         seek($out, 0, SEEK_END) or die "seek $dst: $!";
 631         $dedupe->pause_dedupe if $dedupe;
 632 }
 633
 634 sub _pre_augment_v2 {
 635         my ($self, $lei) = @_;
 636         my $dir = $self->{dst};
 637         require PublicInbox::InboxWritable;
 638         my ($ibx, @creat);
 639         if (-d $dir) {
 640                 my $opt = { -min_inbox_version => 2 };
 641                 require PublicInbox::Admin;
 642                 my @ibx = PublicInbox::Admin::resolve_inboxes([ $dir ], $opt);
 643                 $ibx = $ibx[0] or die "$dir is not a v2 inbox\n";
 644         } else {
 645                 $creat[0] = {};
 646                 $ibx = PublicInbox::Inbox->new({
 647                         name => 'lei-result', # XXX configurable
 648                         inboxdir => $dir,
 649                         version => 2,
 650                         address => [ 'lei@example.com' ],
 651                 });
 652         }
 653         PublicInbox::InboxWritable->new($ibx, @creat);
 654         $ibx->init_inbox if @creat;
 655         my $v2w = $lei->{v2w} = $ibx->importer;
 656         $v2w->ipc_lock_init("$dir/ipc.lock");
 657         $v2w->ipc_worker_spawn("lei/v2w $dir", $lei->oldset, { lei => $lei });
 658         return if !$lei->{opt}->{shared};
 659         my $d = "$lei->{ale}->{git}->{git_dir}/objects";
 660         my $al = "$dir/git/0.git/objects/info/alternates";
 661         open my $fh, '+>>', $al or die "open($al): $!";
 662         seek($fh, 0, SEEK_SET) or die "seek($al): $!";
 663         grep(/\A\Q$d\E\n/, <$fh>) and return;
 664         print $fh "$d\n" or die "print($al): $!";
 665         close $fh or die "close($al): $!";
 666 }
 667
 668 sub pre_augment { # fast (1 disk seek), runs in same process as post_augment
 669         my ($self, $lei) = @_;
 670         # _pre_augment_maildir, _pre_augment_mbox, _pre_augment_v2
 671         my $m = $self->can("_pre_augment_$self->{base_type}") or return;
 672         $m->($self, $lei);
 673 }
 674
 675 sub do_augment { # slow, runs in wq worker
 676         my ($self, $lei) = @_;
 677         # _do_augment_maildir, _do_augment_mbox, or _do_augment_imap
 678         my $m = $self->can("_do_augment_$self->{base_type}") or return;
 679         $m->($self, $lei);
 680 }
 681
 682 # fast (spawn compressor or mkdir), runs in same process as pre_augment
 683 sub post_augment {
 684         my ($self, $lei, @args) = @_;
 685         my $wait = $lei->{opt}->{'import-before'} ?
 686                         $lei->{sto}->ipc_do('checkpoint', 1) : 0;
 687         # _post_augment_mbox
 688         my $m = $self->can("_post_augment_$self->{base_type}") or return;
 689         $m->($self, $lei, @args);
 690 }
 691
 692 # called by every single l2m worker process
 693 sub do_post_auth {
 694         my ($self) = @_;
 695         my $lei = $self->{lei};
 696         # lei_xsearch can start as soon as all l2m workers get here
 697         $lei->{pkt_op_p}->pkt_do('incr_start_query') or
 698                 die "incr_start_query: $!";
 699         my $aug;
 700         if (lock_free($self)) { # all workers do_augment
 701                 my $mod = $self->{-wq_nr_workers};
 702                 my $shard = $self->{-wq_worker_nr};
 703                 if (my $net = $lei->{net}) {
 704                         $net->{shard_info} = [ $mod, $shard ];
 705                 } else { # Maildir
 706                         $self->{shard_info} = [ $mod, $shard ];
 707                 }
 708                 $aug = '+'; # incr_post_augment
 709         } elsif ($self->{-wq_worker_nr} == 0) { # 1st worker do_augment
 710                 $aug = '.'; # do_post_augment
 711         }
 712         if ($aug) {
 713                 local $0 = 'do_augment';
 714                 eval { do_augment($self, $lei) };
 715                 $lei->fail($@) if $@;
 716                 $lei->{pkt_op_p}->pkt_do($aug) == 1 or
 717                                 die "do_post_augment trigger: $!";
 718         }
 719         # done augmenting, connect the compressor pipe for each worker
 720         if (my $zpipe = delete $lei->{zpipe}) {
 721                 $lei->{1} = $zpipe->[1];
 722                 close $zpipe->[0];
 723         }
 724         my $au_peers = delete $self->{au_peers};
 725         if ($au_peers) { # wait for peer l2m to finish augmenting:
 726                 $au_peers->[1] = undef;
 727                 sysread($au_peers->[0], my $barrier1, 1);
 728         }
 729         $self->{wcb} = $self->write_cb($lei);
 730         if ($au_peers) { # wait for peer l2m to set write_cb
 731                 $au_peers->[3] = undef;
 732                 sysread($au_peers->[2], my $barrier2, 1);
 733         }
 734 }
 735
 736 sub ipc_atfork_child {
 737         my ($self) = @_;
 738         my $lei = $self->{lei};
 739         $lei->_lei_atfork_child;
 740         if (my $lse = $lei->{lse}) {
 741                 $self->{-lms_ro} = $lse->{-lms_ro} //= $lse->lms;
 742         }
 743         $lei->{auth}->do_auth_atfork($self) if $lei->{auth};
 744         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 745         $self->SUPER::ipc_atfork_child;
 746 }
 747
 748 sub lock_free {
 749         $_[0]->{base_type} =~ /\A(?:maildir|imap|jmap)\z/ ? 1 : 0;
 750 }
 751
 752 # wakes up the MUA when complete so it can refresh messages list
 753 sub poke_dst {
 754         my ($self) = @_;
 755         if ($self->{base_type} eq 'maildir') {
 756                 my $t = time + 1;
 757                 utime($t, $t, $self->{poke_dh}) or warn "futimes: $!";
 758         }
 759 }
 760
 761 sub write_mail { # via ->wq_io_do
 762         my ($self, $smsg, $eml) = @_;
 763         return $self->{wcb}->(undef, $smsg, $eml) if $eml;
 764         $smsg->{-lms_ro} = $self->{-lms_ro};
 765         $self->{lei}->{ale}->git->cat_async($smsg->{blob}, \&git_to_mail,
 766                                 [$self->{wcb}, $smsg]);
 767 }
 768
 769 sub wq_atexit_child {
 770         my ($self) = @_;
 771         my $lei = $self->{lei};
 772         delete $self->{wcb};
 773         $lei->{ale}->git->async_wait_all;
 774         my $nr = delete($lei->{-nr_write}) or return;
 775         return if $lei->{early_mua} || !$lei->{-progress} || !$lei->{pkt_op_p};
 776         $lei->{pkt_op_p}->pkt_do('l2m_progress', $nr);
 777 }
 778
 779 # called in top-level lei-daemon when LeiAuth is done
 780 sub net_merge_all_done {
 781         my ($self) = @_;
 782         $self->wq_broadcast('do_post_auth');
 783         $self->wq_close(1);
 784 }
 785
 786 1;