lib/PublicInbox/LeiToMail.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Writes PublicInbox::Eml objects atomically to a mbox variant or Maildir
   5 package PublicInbox::LeiToMail;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Lock;
  11 use PublicInbox::ProcessPipe;
  12 use PublicInbox::Spawn qw(which spawn popen_rd);
  13 use PublicInbox::LeiDedupe;
  14 use PublicInbox::Git;
  15 use PublicInbox::GitAsyncCat;
  16 use PublicInbox::PktOp qw(pkt_do);
  17 use Symbol qw(gensym);
  18 use IO::Handle; # ->autoflush
  19 use Fcntl qw(SEEK_SET SEEK_END O_CREAT O_EXCL O_WRONLY);
  20 use Errno qw(EEXIST ESPIPE ENOENT EPIPE);
  21 use Digest::SHA qw(sha256_hex);
  22
  23 # struggles with short-lived repos, Gcf2Client makes little sense with lei;
  24 # but we may use in-process libgit2 in the future.
  25 $PublicInbox::GitAsyncCat::GCF2C = 0;
  26
  27 my %kw2char = ( # Maildir characters
  28         draft => 'D',
  29         flagged => 'F',
  30         answered => 'R',
  31         seen => 'S'
  32 );
  33
  34 my %kw2status = (
  35         flagged => [ 'X-Status' => 'F' ],
  36         answered => [ 'X-Status' => 'A' ],
  37         seen => [ 'Status' => 'R' ],
  38         draft => [ 'X-Status' => 'T' ],
  39 );
  40
  41 sub _mbox_hdr_buf ($$$) {
  42         my ($eml, $type, $smsg) = @_;
  43         $eml->header_set($_) for (qw(Lines Bytes Content-Length));
  44
  45         # Messages are always 'O' (non-\Recent in IMAP), it saves
  46         # MUAs the trouble of rewriting the mbox if no other
  47         # changes are made
  48         my %hdr = (Status => [ 'O' ]); # set Status, X-Status
  49         for my $k (@{$smsg->{kw} // []}) {
  50                 if (my $ent = $kw2status{$k}) {
  51                         push @{$hdr{$ent->[0]}}, $ent->[1];
  52                 } else { # X-Label?
  53                         warn "TODO: keyword `$k' not supported for mbox\n";
  54                 }
  55         }
  56         while (my ($name, $chars) = each %hdr) {
  57                 $eml->header_set($name, join('', sort @$chars));
  58         }
  59         my $buf = delete $eml->{hdr};
  60
  61         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
  62         $$buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  63         my $ident = $smsg->{blob} // 'lei';
  64         if (defined(my $pct = $smsg->{pct})) { $ident .= "=$pct" }
  65
  66         substr($$buf, 0, 0, # prepend From line
  67                 "From $ident\@$type Thu Jan  1 00:00:00 1970$eml->{crlf}");
  68         $buf;
  69 }
  70
  71 sub atomic_append { # for on-disk destinations (O_APPEND, or O_EXCL)
  72         my ($lei, $buf) = @_;
  73         if (defined(my $w = syswrite($lei->{1} // return, $$buf))) {
  74                 return if $w == length($$buf);
  75                 $buf = "short atomic write: $w != ".length($$buf);
  76         } elsif ($! == EPIPE) {
  77                 return $lei->note_sigpipe(1);
  78         } else {
  79                 $buf = "atomic write: $!";
  80         }
  81         $lei->fail($buf);
  82 }
  83
  84 sub eml2mboxrd ($;$) {
  85         my ($eml, $smsg) = @_;
  86         my $buf = _mbox_hdr_buf($eml, 'mboxrd', $smsg);
  87         if (my $bdy = delete $eml->{bdy}) {
  88                 $$bdy =~ s/^(>*From )/>$1/gm;
  89                 $$buf .= $eml->{crlf};
  90                 substr($$bdy, 0, 0, $$buf); # prepend header
  91                 $buf = $bdy;
  92         }
  93         $$buf .= $eml->{crlf};
  94         $buf;
  95 }
  96
  97 sub eml2mboxo {
  98         my ($eml, $smsg) = @_;
  99         my $buf = _mbox_hdr_buf($eml, 'mboxo', $smsg);
 100         if (my $bdy = delete $eml->{bdy}) {
 101                 $$bdy =~ s/^From />From /gm;
 102                 $$buf .= $eml->{crlf};
 103                 substr($$bdy, 0, 0, $$buf); # prepend header
 104                 $buf = $bdy;
 105         }
 106         $$buf .= $eml->{crlf};
 107         $buf;
 108 }
 109
 110 sub _mboxcl_common ($$$) {
 111         my ($buf, $bdy, $crlf) = @_;
 112         # add Lines: so mutt won't have to add it on MUA close
 113         my $lines = $$bdy =~ tr!\n!\n!;
 114         $$buf .= 'Content-Length: '.length($$bdy).$crlf.
 115                 'Lines: '.$lines.$crlf.$crlf;
 116         substr($$bdy, 0, 0, $$buf); # prepend header
 117         $_[0] = $bdy;
 118 }
 119
 120 # mboxcl still escapes "From " lines
 121 sub eml2mboxcl {
 122         my ($eml, $smsg) = @_;
 123         my $buf = _mbox_hdr_buf($eml, 'mboxcl', $smsg);
 124         my $crlf = $eml->{crlf};
 125         if (my $bdy = delete $eml->{bdy}) {
 126                 $$bdy =~ s/^From />From /gm;
 127                 _mboxcl_common($buf, $bdy, $crlf);
 128         }
 129         $$buf .= $crlf;
 130         $buf;
 131 }
 132
 133 # mboxcl2 has no "From " escaping
 134 sub eml2mboxcl2 {
 135         my ($eml, $smsg) = @_;
 136         my $buf = _mbox_hdr_buf($eml, 'mboxcl2', $smsg);
 137         my $crlf = $eml->{crlf};
 138         if (my $bdy = delete $eml->{bdy}) {
 139                 _mboxcl_common($buf, $bdy, $crlf);
 140         }
 141         $$buf .= $crlf;
 142         $buf;
 143 }
 144
 145 sub git_to_mail { # git->cat_async callback
 146         my ($bref, $oid, $type, $size, $arg) = @_;
 147         if ($type ne 'blob') {
 148                 if ($type eq 'missing') {
 149                         warn "missing $oid\n";
 150                 } else {
 151                         warn "unexpected type=$type for $oid\n";
 152                 }
 153         }
 154         my ($write_cb, $smsg) = @$arg;
 155         if ($smsg->{blob} ne $oid) {
 156                 die "BUG: expected=$smsg->{blob} got=$oid";
 157         }
 158         $write_cb->($bref, $smsg) if $size > 0;
 159 }
 160
 161 sub reap_compress { # dwaitpid callback
 162         my ($lei, $pid) = @_;
 163         my $cmd = delete $lei->{"pid.$pid"};
 164         return if $? == 0;
 165         $lei->fail("@$cmd failed", $? >> 8);
 166 }
 167
 168 # all of these support -c for stdout and -d for decompression,
 169 # mutt is commonly distributed with hooks for gz, bz2 and xz, at least
 170 # { foo => '' } means "--foo" is passed to the command-line,
 171 # otherwise { foo => '--bar' } passes "--bar"
 172 our %zsfx2cmd = (
 173         gz => [ qw(GZIP pigz gzip), { rsyncable => '', threads => '-p' } ],
 174         bz2 => [ 'bzip2', {} ],
 175         xz => [ 'xz', { threads => '-T' } ],
 176         # XXX does anybody care for these?  I prefer zstd on entire FSes,
 177         # so it's probably not necessary on a per-file basis
 178         # zst => [ 'zstd', { -default => [ qw(-q) ], # it's noisy by default
 179         #       rsyncable => '', threads => '-T' } ],
 180         # zz => [ 'pigz', { -default => [ '--zlib' ],
 181         #       rsyncable => '', threads => '-p' }],
 182         # lzo => [ 'lzop', {} ],
 183         # lzma => [ 'lzma', {} ],
 184 );
 185
 186 sub zsfx2cmd ($$$) {
 187         my ($zsfx, $decompress, $lei) = @_;
 188         my $x = $zsfx2cmd{$zsfx} // die "no support for suffix=.$zsfx";
 189         my @info = @$x;
 190         my $cmd_opt = pop @info;
 191         my @cmd = (undef, $decompress ? qw(-dc) : qw(-c));
 192         for my $exe (@info) {
 193                 # I think respecting client's ENV{GZIP} is OK, not sure
 194                 # about ENV overrides for other, less-common compressors
 195                 if ($exe eq uc($exe)) {
 196                         $exe = $lei->{env}->{$exe} or next;
 197                 }
 198                 $cmd[0] = which($exe) and last;
 199         }
 200         $cmd[0] // die join(' or ', @info)." missing for .$zsfx";
 201         # push @cmd, @{$cmd_opt->{-default}} if $cmd_opt->{-default};
 202         for my $bool (qw(rsyncable)) {
 203                 my $switch = $cmd_opt->{rsyncable} // next;
 204                 push @cmd, '--'.($switch || $bool);
 205         }
 206         for my $key (qw(threads)) { # support compression level?
 207                 my $switch = $cmd_opt->{$key} // next;
 208                 my $val = $lei->{opt}->{$key} // next;
 209                 push @cmd, $switch, $val;
 210         }
 211         \@cmd;
 212 }
 213
 214 sub _post_augment_mbox { # open a compressor process
 215         my ($self, $lei) = @_;
 216         my $zsfx = $self->{zsfx} or return;
 217         my $cmd = zsfx2cmd($zsfx, undef, $lei);
 218         my ($r, $w) = @{delete $lei->{zpipe}};
 219         my $rdr = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 220         my $pid = spawn($cmd, undef, $rdr);
 221         my $pp = gensym;
 222         my $dup = bless { "pid.$pid" => $cmd }, ref($lei);
 223         $dup->{$_} = $lei->{$_} for qw(2 sock);
 224         tie *$pp, 'PublicInbox::ProcessPipe', $pid, $w, \&reap_compress, $dup;
 225         $lei->{1} = $pp;
 226         die 'BUG: unexpected {ovv}->{lock_path}' if $lei->{ovv}->{lock_path};
 227         $lei->{ovv}->ovv_out_lk_init;
 228 }
 229
 230 sub decompress_src ($$$) {
 231         my ($in, $zsfx, $lei) = @_;
 232         my $cmd = zsfx2cmd($zsfx, 1, $lei);
 233         popen_rd($cmd, undef, { 0 => $in, 2 => $lei->{2} });
 234 }
 235
 236 sub dup_src ($) {
 237         my ($in) = @_;
 238         open my $dup, '+>>&', $in or die "dup: $!";
 239         $dup;
 240 }
 241
 242 # --augment existing output destination, with deduplication
 243 sub _augment { # MboxReader eml_cb
 244         my ($eml, $lei) = @_;
 245         # ignore return value, just populate the skv
 246         $lei->{dedupe}->is_dup($eml);
 247 }
 248
 249 sub _mbox_write_cb ($$) {
 250         my ($self, $lei) = @_;
 251         my $ovv = $lei->{ovv};
 252         my $m = 'eml2'.$ovv->{fmt};
 253         my $eml2mbox = $self->can($m) or die "$self->$m missing";
 254         $lei->{1} // die "no stdout ($m, $ovv->{dst})"; # redirected earlier
 255         $lei->{1}->autoflush(1);
 256         my $atomic_append = !defined($ovv->{lock_path});
 257         my $dedupe = $lei->{dedupe};
 258         $dedupe->prepare_dedupe;
 259         sub { # for git_to_mail
 260                 my ($buf, $smsg, $eml) = @_;
 261                 $eml //= PublicInbox::Eml->new($buf);
 262                 return if $dedupe->is_dup($eml, $smsg->{blob});
 263                 $buf = $eml2mbox->($eml, $smsg);
 264                 return atomic_append($lei, $buf) if $atomic_append;
 265                 my $lk = $ovv->lock_for_scope;
 266                 $lei->out($$buf);
 267         }
 268 }
 269
 270 sub _augment_file { # maildir_each_eml cb
 271         my ($f, undef, $eml, $lei, $mod, $shard) = @_;
 272         if ($mod) {
 273                 # can't get dirent.d_ino w/ pure Perl, so we extract the OID
 274                 # if it looks like one:
 275                 my $hex = $f =~ m!\b([a-f0-9]{40,})[^/]*\z! ?
 276                                 $1 : sha256_hex($f);
 277                 my $recno = hex(substr($hex, 0, 8));
 278                 return if ($recno % $mod) != $shard;
 279         }
 280         _augment($eml, $lei);
 281 }
 282
 283 # maildir_each_file callback, \&CORE::unlink doesn't work with it
 284 sub _unlink { unlink($_[0]) }
 285
 286 sub _rand () {
 287         state $seq = 0;
 288         sprintf('%x,%x,%x,%x', rand(0xffffffff), time, $$, ++$seq);
 289 }
 290
 291 sub _buf2maildir {
 292         my ($dst, $buf, $smsg) = @_;
 293         my $kw = $smsg->{kw} // [];
 294         my $sfx = join('', sort(map { $kw2char{$_} // () } @$kw));
 295         my $rand = ''; # chosen by die roll :P
 296         my ($tmp, $fh, $final, $ok);
 297         my $common = $smsg->{blob} // _rand;
 298         if (defined(my $pct = $smsg->{pct})) { $common .= "=$pct" }
 299         do {
 300                 $tmp = $dst.'tmp/'.$rand.$common;
 301         } while (!($ok = sysopen($fh, $tmp, O_CREAT|O_EXCL|O_WRONLY)) &&
 302                 $! == EEXIST && ($rand = _rand.','));
 303         if ($ok && print $fh $$buf and close($fh)) {
 304                 # ignore new/ and write only to cur/, otherwise MUAs
 305                 # with R/W access to the Maildir will end up doing
 306                 # a mass rename which can take a while with thousands
 307                 # of messages.
 308                 $dst .= 'cur/';
 309                 $rand = '';
 310                 do {
 311                         $final = $dst.$rand.$common.':2,'.$sfx;
 312                 } while (!($ok = link($tmp, $final)) && $! == EEXIST &&
 313                         ($rand = _rand.','));
 314                 die "link($tmp, $final): $!" unless $ok;
 315                 unlink($tmp) or warn "W: failed to unlink $tmp: $!\n";
 316         } else {
 317                 my $err = "Error writing $smsg->{blob} to $dst: $!\n";
 318                 $_[0] = undef; # clobber dst
 319                 unlink($tmp);
 320                 die $err;
 321         }
 322 }
 323
 324 sub _maildir_write_cb ($$) {
 325         my ($self, $lei) = @_;
 326         my $dedupe = $lei->{dedupe};
 327         $dedupe->prepare_dedupe if $dedupe;
 328         my $dst = $lei->{ovv}->{dst};
 329         sub { # for git_to_mail
 330                 my ($buf, $smsg, $eml) = @_;
 331                 $dst // return $lei->fail; # dst may be undef-ed in last run
 332                 $buf //= \($eml->as_string);
 333                 return _buf2maildir($dst, $buf, $smsg) if !$dedupe;
 334                 $eml //= PublicInbox::Eml->new($$buf); # copy buf
 335                 return if $dedupe->is_dup($eml, $smsg->{blob});
 336                 undef $eml;
 337                 _buf2maildir($dst, $buf, $smsg);
 338         }
 339 }
 340
 341 sub _imap_write_cb ($$) {
 342         my ($self, $lei) = @_;
 343         my $dedupe = $lei->{dedupe};
 344         $dedupe->prepare_dedupe if $dedupe;
 345         my $imap_append = $lei->{net}->can('imap_append');
 346         my $mic = $lei->{net}->mic_get($self->{uri});
 347         my $folder = $self->{uri}->mailbox;
 348         sub { # for git_to_mail
 349                 my ($bref, $smsg, $eml) = @_;
 350                 $mic // return $lei->fail; # dst may be undef-ed in last run
 351                 if ($dedupe) {
 352                         $eml //= PublicInbox::Eml->new($$bref); # copy bref
 353                         return if $dedupe->is_dup($eml, $smsg->{blob});
 354                 }
 355                 eval { $imap_append->($mic, $folder, $bref, $smsg, $eml) };
 356                 if (my $err = $@) {
 357                         undef $mic;
 358                         die $err;
 359                 }
 360         }
 361 }
 362
 363 sub write_cb { # returns a callback for git_to_mail
 364         my ($self, $lei) = @_;
 365         # _mbox_write_cb, _maildir_write_cb or _imap_write_cb
 366         my $m = "_$self->{base_type}_write_cb";
 367         $self->$m($lei);
 368 }
 369
 370 sub new {
 371         my ($cls, $lei) = @_;
 372         my $fmt = $lei->{ovv}->{fmt};
 373         my $dst = $lei->{ovv}->{dst};
 374         my $self = bless {}, $cls;
 375         if ($fmt eq 'maildir') {
 376                 require PublicInbox::MdirReader;
 377                 $self->{base_type} = 'maildir';
 378                 -e $dst && !-d _ and die
 379                                 "$dst exists and is not a directory\n";
 380                 $lei->{ovv}->{dst} = $dst .= '/' if substr($dst, -1) ne '/';
 381         } elsif (substr($fmt, 0, 4) eq 'mbox') {
 382                 require PublicInbox::MboxReader if $lei->{opt}->{augment};
 383                 (-d $dst || (-e _ && !-w _)) and die
 384                         "$dst exists and is not a writable file\n";
 385                 $self->can("eml2$fmt") or die "bad mbox format: $fmt\n";
 386                 $self->{base_type} = 'mbox';
 387         } elsif ($fmt =~ /\Aimaps?\z/) { # TODO .onion support
 388                 require PublicInbox::NetWriter;
 389                 my $net = PublicInbox::NetWriter->new;
 390                 $net->add_url($dst);
 391                 $net->{quiet} = $lei->{opt}->{quiet};
 392                 my $err = $net->errors($dst);
 393                 return $lei->fail($err) if $err;
 394                 require PublicInbox::URIimap; # TODO: URI cast early
 395                 $self->{uri} = PublicInbox::URIimap->new($dst);
 396                 $self->{uri}->mailbox or die "No mailbox: $dst";
 397                 $lei->{net} = $net;
 398                 $self->{base_type} = 'imap';
 399         } else {
 400                 die "bad mail --format=$fmt\n";
 401         }
 402         $self->{dst} = $dst;
 403         $lei->{dedupe} = PublicInbox::LeiDedupe->new($lei);
 404         $self;
 405 }
 406
 407 sub _pre_augment_maildir {
 408         my ($self, $lei) = @_;
 409         my $dst = $lei->{ovv}->{dst};
 410         for my $x (qw(tmp new cur)) {
 411                 my $d = $dst.$x;
 412                 next if -d $d;
 413                 require File::Path;
 414                 File::Path::mkpath($d);
 415                 -d $d or die "$d is not a directory";
 416         }
 417 }
 418
 419 sub _do_augment_maildir {
 420         my ($self, $lei) = @_;
 421         my $dst = $lei->{ovv}->{dst};
 422         if ($lei->{opt}->{augment}) {
 423                 my $dedupe = $lei->{dedupe};
 424                 if ($dedupe && $dedupe->prepare_dedupe) {
 425                         my ($mod, $shard) = @{$self->{shard_info} // []};
 426                         PublicInbox::MdirReader::maildir_each_eml($dst,
 427                                                 \&_augment_file,
 428                                                 $lei, $mod, $shard);
 429                         $dedupe->pause_dedupe;
 430                 }
 431         } else { # clobber existing Maildir
 432                 PublicInbox::MdirReader::maildir_each_file($dst, \&_unlink);
 433         }
 434 }
 435
 436 sub _augment_imap { # PublicInbox::NetReader::imap_each cb
 437         my ($url, $uid, $kw, $eml, $lei) = @_;
 438         _augment($eml, $lei);
 439 }
 440
 441 sub _do_augment_imap {
 442         my ($self, $lei) = @_;
 443         my $net = $lei->{net};
 444         if ($lei->{opt}->{augment}) {
 445                 my $dedupe = $lei->{dedupe};
 446                 if ($dedupe && $dedupe->prepare_dedupe) {
 447                         $net->imap_each($self->{uri}, \&_augment_imap, $lei);
 448                         $dedupe->pause_dedupe;
 449                 }
 450         } elsif (!$self->{-wq_worker_nr}) { # undef or 0
 451                 # clobber existing IMAP folder
 452                 $net->imap_delete_all($self->{uri});
 453         }
 454 }
 455
 456 sub _pre_augment_mbox {
 457         my ($self, $lei) = @_;
 458         my $dst = $lei->{ovv}->{dst};
 459         if ($dst ne '/dev/stdout') {
 460                 my $out;
 461                 if (-p $dst) {
 462                         open $out, '>', $dst or die "open($dst): $!";
 463                 } elsif (-f _ || !-e _) {
 464                         require PublicInbox::MboxLock;
 465                         my $m = $lei->{opt}->{'lock'} //
 466                                         PublicInbox::MboxLock->defaults;
 467                         $self->{mbl} = PublicInbox::MboxLock->acq($dst, 1, $m);
 468                         $out = $self->{mbl}->{fh};
 469                         if (!$lei->{opt}->{augment} and !truncate($out, 0)) {
 470                                 die "truncate($dst): $!";
 471                         }
 472                 }
 473                 $lei->{old_1} = $lei->{1}; # keep for spawning MUA
 474                 $lei->{1} = $out;
 475         }
 476         # Perl does SEEK_END even with O_APPEND :<
 477         $self->{seekable} = seek($lei->{1}, 0, SEEK_SET);
 478         if (!$self->{seekable} && $! != ESPIPE && $dst ne '/dev/stdout') {
 479                 die "seek($dst): $!\n";
 480         }
 481         state $zsfx_allow = join('|', keys %zsfx2cmd);
 482         ($self->{zsfx}) = ($dst =~ /\.($zsfx_allow)\z/) or return;
 483         pipe(my ($r, $w)) or die "pipe: $!";
 484         $lei->{zpipe} = [ $r, $w ];
 485 }
 486
 487 sub _do_augment_mbox {
 488         my ($self, $lei) = @_;
 489         return if !$lei->{opt}->{augment};
 490         my $dedupe = $lei->{dedupe};
 491         my $dst = $lei->{ovv}->{dst};
 492         die "cannot augment $dst, not seekable\n" if !$self->{seekable};
 493         my $out = $lei->{1};
 494         if (-s $out && $dedupe && $dedupe->prepare_dedupe) {
 495                 my $zsfx = $self->{zsfx};
 496                 my $rd = $zsfx ? decompress_src($out, $zsfx, $lei) :
 497                                 dup_src($out);
 498                 my $fmt = $lei->{ovv}->{fmt};
 499                 PublicInbox::MboxReader->$fmt($rd, \&_augment, $lei);
 500         }
 501         # maybe some systems don't honor O_APPEND, Perl does this:
 502         seek($out, 0, SEEK_END) or die "seek $dst: $!";
 503         $dedupe->pause_dedupe if $dedupe;
 504 }
 505
 506 sub pre_augment { # fast (1 disk seek), runs in same process as post_augment
 507         my ($self, $lei) = @_;
 508         # _pre_augment_maildir, _pre_augment_mbox
 509         my $m = $self->can("_pre_augment_$self->{base_type}") or return;
 510         $m->($self, $lei);
 511 }
 512
 513 sub do_augment { # slow, runs in wq worker
 514         my ($self, $lei) = @_;
 515         # _do_augment_maildir, _do_augment_mbox, or _do_augment_imap
 516         my $m = "_do_augment_$self->{base_type}";
 517         $self->$m($lei);
 518 }
 519
 520 # fast (spawn compressor or mkdir), runs in same process as pre_augment
 521 sub post_augment {
 522         my ($self, $lei, @args) = @_;
 523         # _post_augment_mbox
 524         my $m = $self->can("_post_augment_$self->{base_type}") or return;
 525         $m->($self, $lei, @args);
 526 }
 527
 528 sub do_post_auth {
 529         my ($self) = @_;
 530         my $lei = $self->{lei};
 531         # lei_xsearch can start as soon as all l2m workers get here
 532         pkt_do($lei->{pkt_op_p}, 'incr_start_query') or
 533                 die "incr_start_query: $!";
 534         my $aug;
 535         if (lock_free($self)) {
 536                 my $mod = $self->{-wq_nr_workers};
 537                 my $shard = $self->{-wq_worker_nr};
 538                 if (my $net = $lei->{net}) {
 539                         $net->{shard_info} = [ $mod, $shard ];
 540                 } else { # Maildir (MH?)
 541                         $self->{shard_info} = [ $mod, $shard ];
 542                 }
 543                 $aug = '+'; # incr_post_augment
 544         } elsif ($self->{-wq_worker_nr} == 0) {
 545                 $aug = '.'; # do_post_augment
 546         }
 547         if ($aug) {
 548                 local $0 = 'do_augment';
 549                 eval { do_augment($self, $lei) };
 550                 $lei->fail($@) if $@;
 551                 pkt_do($lei->{pkt_op_p}, $aug) == 1 or
 552                                 die "do_post_augment trigger: $!";
 553         }
 554         if (my $zpipe = delete $lei->{zpipe}) {
 555                 $lei->{1} = $zpipe->[1];
 556                 close $zpipe->[0];
 557         }
 558         $self->{wcb} = $self->write_cb($lei);
 559 }
 560
 561 sub ipc_atfork_child {
 562         my ($self) = @_;
 563         my $lei = $self->{lei};
 564         $lei->lei_atfork_child;
 565         $lei->{auth}->do_auth_atfork($self) if $lei->{auth};
 566         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 567         $self->SUPER::ipc_atfork_child;
 568 }
 569
 570 sub lock_free {
 571         $_[0]->{base_type} =~ /\A(?:maildir|mh|imap|jmap)\z/ ? 1 : 0;
 572 }
 573
 574 sub poke_dst {
 575         my ($self) = @_;
 576         if ($self->{base_type} eq 'maildir') {
 577                 my $t = time + 1;
 578                 utime($t, $t, "$self->{dst}/cur");
 579         }
 580 }
 581
 582 sub write_mail { # via ->wq_io_do
 583         my ($self, $git_dir, $smsg) = @_;
 584         my $git = $self->{"$$\0$git_dir"} //= PublicInbox::Git->new($git_dir);
 585         git_async_cat($git, $smsg->{blob}, \&git_to_mail,
 586                                 [$self->{wcb}, $smsg]);
 587 }
 588
 589 sub wq_atexit_child {
 590         my ($self) = @_;
 591         delete $self->{wcb};
 592         for my $git (delete @$self{grep(/\A$$\0/, keys %$self)}) {
 593                 $git->async_wait_all;
 594         }
 595         $SIG{__WARN__} = 'DEFAULT';
 596 }
 597
 598 # called in top-level lei-daemon when LeiAuth is done
 599 sub net_merge_complete {
 600         my ($self) = @_;
 601         $self->wq_broadcast('do_post_auth');
 602         $self->wq_close(1);
 603 }
 604
 605 no warnings 'once'; # the following works even when LeiAuth is lazy-loaded
 606 *net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
 607 1;