lib/PublicInbox/LeiToMail.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Writes PublicInbox::Eml objects atomically to a mbox variant or Maildir
   5 package PublicInbox::LeiToMail;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Lock;
  11 use PublicInbox::ProcessPipe;
  12 use PublicInbox::Spawn qw(which spawn popen_rd);
  13 use PublicInbox::LeiDedupe;
  14 use PublicInbox::Git;
  15 use PublicInbox::GitAsyncCat;
  16 use PublicInbox::PktOp qw(pkt_do);
  17 use Symbol qw(gensym);
  18 use IO::Handle; # ->autoflush
  19 use Fcntl qw(SEEK_SET SEEK_END O_CREAT O_EXCL O_WRONLY);
  20 use Errno qw(EEXIST ESPIPE ENOENT EPIPE);
  21 use Digest::SHA qw(sha256_hex);
  22
  23 # struggles with short-lived repos, Gcf2Client makes little sense with lei;
  24 # but we may use in-process libgit2 in the future.
  25 $PublicInbox::GitAsyncCat::GCF2C = 0;
  26
  27 my %kw2char = ( # Maildir characters
  28         draft => 'D',
  29         flagged => 'F',
  30         answered => 'R',
  31         seen => 'S'
  32 );
  33
  34 my %kw2status = (
  35         flagged => [ 'X-Status' => 'F' ],
  36         answered => [ 'X-Status' => 'A' ],
  37         seen => [ 'Status' => 'R' ],
  38         draft => [ 'X-Status' => 'T' ],
  39 );
  40
  41 sub _mbox_hdr_buf ($$$) {
  42         my ($eml, $type, $smsg) = @_;
  43         $eml->header_set($_) for (qw(Lines Bytes Content-Length));
  44
  45         # Messages are always 'O' (non-\Recent in IMAP), it saves
  46         # MUAs the trouble of rewriting the mbox if no other
  47         # changes are made
  48         my %hdr = (Status => [ 'O' ]); # set Status, X-Status
  49         for my $k (@{$smsg->{kw} // []}) {
  50                 if (my $ent = $kw2status{$k}) {
  51                         push @{$hdr{$ent->[0]}}, $ent->[1];
  52                 } else { # X-Label?
  53                         warn "TODO: keyword `$k' not supported for mbox\n";
  54                 }
  55         }
  56         while (my ($name, $chars) = each %hdr) {
  57                 $eml->header_set($name, join('', sort @$chars));
  58         }
  59         my $buf = delete $eml->{hdr};
  60
  61         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
  62         $$buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  63         my $ident = $smsg->{blob} // 'lei';
  64         if (defined(my $pct = $smsg->{pct})) { $ident .= "=$pct" }
  65
  66         substr($$buf, 0, 0, # prepend From line
  67                 "From $ident\@$type Thu Jan  1 00:00:00 1970$eml->{crlf}");
  68         $buf;
  69 }
  70
  71 sub atomic_append { # for on-disk destinations (O_APPEND, or O_EXCL)
  72         my ($lei, $buf) = @_;
  73         if (defined(my $w = syswrite($lei->{1} // return, $$buf))) {
  74                 return if $w == length($$buf);
  75                 $buf = "short atomic write: $w != ".length($$buf);
  76         } elsif ($! == EPIPE) {
  77                 return $lei->note_sigpipe(1);
  78         } else {
  79                 $buf = "atomic write: $!";
  80         }
  81         $lei->fail($buf);
  82 }
  83
  84 sub eml2mboxrd ($;$) {
  85         my ($eml, $smsg) = @_;
  86         my $buf = _mbox_hdr_buf($eml, 'mboxrd', $smsg);
  87         if (my $bdy = delete $eml->{bdy}) {
  88                 $$bdy =~ s/^(>*From )/>$1/gm;
  89                 $$buf .= $eml->{crlf};
  90                 substr($$bdy, 0, 0, $$buf); # prepend header
  91                 $buf = $bdy;
  92         }
  93         $$buf .= $eml->{crlf};
  94         $buf;
  95 }
  96
  97 sub eml2mboxo {
  98         my ($eml, $smsg) = @_;
  99         my $buf = _mbox_hdr_buf($eml, 'mboxo', $smsg);
 100         if (my $bdy = delete $eml->{bdy}) {
 101                 $$bdy =~ s/^From />From /gm;
 102                 $$buf .= $eml->{crlf};
 103                 substr($$bdy, 0, 0, $$buf); # prepend header
 104                 $buf = $bdy;
 105         }
 106         $$buf .= $eml->{crlf};
 107         $buf;
 108 }
 109
 110 sub _mboxcl_common ($$$) {
 111         my ($buf, $bdy, $crlf) = @_;
 112         # add Lines: so mutt won't have to add it on MUA close
 113         my $lines = $$bdy =~ tr!\n!\n!;
 114         $$buf .= 'Content-Length: '.length($$bdy).$crlf.
 115                 'Lines: '.$lines.$crlf.$crlf;
 116         substr($$bdy, 0, 0, $$buf); # prepend header
 117         $_[0] = $bdy;
 118 }
 119
 120 # mboxcl still escapes "From " lines
 121 sub eml2mboxcl {
 122         my ($eml, $smsg) = @_;
 123         my $buf = _mbox_hdr_buf($eml, 'mboxcl', $smsg);
 124         my $crlf = $eml->{crlf};
 125         if (my $bdy = delete $eml->{bdy}) {
 126                 $$bdy =~ s/^From />From /gm;
 127                 _mboxcl_common($buf, $bdy, $crlf);
 128         }
 129         $$buf .= $crlf;
 130         $buf;
 131 }
 132
 133 # mboxcl2 has no "From " escaping
 134 sub eml2mboxcl2 {
 135         my ($eml, $smsg) = @_;
 136         my $buf = _mbox_hdr_buf($eml, 'mboxcl2', $smsg);
 137         my $crlf = $eml->{crlf};
 138         if (my $bdy = delete $eml->{bdy}) {
 139                 _mboxcl_common($buf, $bdy, $crlf);
 140         }
 141         $$buf .= $crlf;
 142         $buf;
 143 }
 144
 145 sub git_to_mail { # git->cat_async callback
 146         my ($bref, $oid, $type, $size, $arg) = @_;
 147         if ($type ne 'blob') {
 148                 if ($type eq 'missing') {
 149                         warn "missing $oid\n";
 150                 } else {
 151                         warn "unexpected type=$type for $oid\n";
 152                 }
 153         }
 154         my ($write_cb, $smsg) = @$arg;
 155         if ($smsg->{blob} ne $oid) {
 156                 die "BUG: expected=$smsg->{blob} got=$oid";
 157         }
 158         $write_cb->($bref, $smsg) if $size > 0;
 159 }
 160
 161 sub reap_compress { # dwaitpid callback
 162         my ($lei, $pid) = @_;
 163         my $cmd = delete $lei->{"pid.$pid"};
 164         return if $? == 0;
 165         $lei->fail("@$cmd failed", $? >> 8);
 166 }
 167
 168 # all of these support -c for stdout and -d for decompression,
 169 # mutt is commonly distributed with hooks for gz, bz2 and xz, at least
 170 # { foo => '' } means "--foo" is passed to the command-line,
 171 # otherwise { foo => '--bar' } passes "--bar"
 172 our %zsfx2cmd = (
 173         gz => [ qw(GZIP pigz gzip), { rsyncable => '', threads => '-p' } ],
 174         bz2 => [ 'bzip2', {} ],
 175         xz => [ 'xz', { threads => '-T' } ],
 176         # XXX does anybody care for these?  I prefer zstd on entire FSes,
 177         # so it's probably not necessary on a per-file basis
 178         # zst => [ 'zstd', { -default => [ qw(-q) ], # it's noisy by default
 179         #       rsyncable => '', threads => '-T' } ],
 180         # zz => [ 'pigz', { -default => [ '--zlib' ],
 181         #       rsyncable => '', threads => '-p' }],
 182         # lzo => [ 'lzop', {} ],
 183         # lzma => [ 'lzma', {} ],
 184 );
 185
 186 sub zsfx2cmd ($$$) {
 187         my ($zsfx, $decompress, $lei) = @_;
 188         my $x = $zsfx2cmd{$zsfx} // die "no support for suffix=.$zsfx";
 189         my @info = @$x;
 190         my $cmd_opt = pop @info;
 191         my @cmd = (undef, $decompress ? qw(-dc) : qw(-c));
 192         for my $exe (@info) {
 193                 # I think respecting client's ENV{GZIP} is OK, not sure
 194                 # about ENV overrides for other, less-common compressors
 195                 if ($exe eq uc($exe)) {
 196                         $exe = $lei->{env}->{$exe} or next;
 197                 }
 198                 $cmd[0] = which($exe) and last;
 199         }
 200         $cmd[0] // die join(' or ', @info)." missing for .$zsfx";
 201         # push @cmd, @{$cmd_opt->{-default}} if $cmd_opt->{-default};
 202         for my $bool (qw(rsyncable)) {
 203                 my $switch = $cmd_opt->{rsyncable} // next;
 204                 push @cmd, '--'.($switch || $bool);
 205         }
 206         for my $key (qw(threads)) { # support compression level?
 207                 my $switch = $cmd_opt->{$key} // next;
 208                 my $val = $lei->{opt}->{$key} // next;
 209                 push @cmd, $switch, $val;
 210         }
 211         \@cmd;
 212 }
 213
 214 sub _post_augment_mbox { # open a compressor process
 215         my ($self, $lei) = @_;
 216         my $zsfx = $self->{zsfx} or return;
 217         my $cmd = zsfx2cmd($zsfx, undef, $lei);
 218         my ($r, $w) = @{delete $lei->{zpipe}};
 219         my $rdr = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 220         my $pid = spawn($cmd, undef, $rdr);
 221         my $pp = gensym;
 222         my $dup = bless { "pid.$pid" => $cmd }, ref($lei);
 223         $dup->{$_} = $lei->{$_} for qw(2 sock);
 224         tie *$pp, 'PublicInbox::ProcessPipe', $pid, $w, \&reap_compress, $dup;
 225         $lei->{1} = $pp;
 226         die 'BUG: unexpected {ovv}->{lock_path}' if $lei->{ovv}->{lock_path};
 227         $lei->{ovv}->ovv_out_lk_init;
 228 }
 229
 230 sub decompress_src ($$$) {
 231         my ($in, $zsfx, $lei) = @_;
 232         my $cmd = zsfx2cmd($zsfx, 1, $lei);
 233         popen_rd($cmd, undef, { 0 => $in, 2 => $lei->{2} });
 234 }
 235
 236 sub dup_src ($) {
 237         my ($in) = @_;
 238         open my $dup, '+>>&', $in or die "dup: $!";
 239         $dup;
 240 }
 241
 242 # --augment existing output destination, with deduplication
 243 sub _augment { # MboxReader eml_cb
 244         my ($eml, $lei) = @_;
 245         # ignore return value, just populate the skv
 246         $lei->{dedupe}->is_dup($eml);
 247 }
 248
 249 sub _mbox_write_cb ($$) {
 250         my ($self, $lei) = @_;
 251         my $ovv = $lei->{ovv};
 252         my $m = 'eml2'.$ovv->{fmt};
 253         my $eml2mbox = $self->can($m) or die "$self->$m missing";
 254         $lei->{1} // die "no stdout ($m, $ovv->{dst})"; # redirected earlier
 255         $lei->{1}->autoflush(1);
 256         my $atomic_append = !defined($ovv->{lock_path});
 257         my $dedupe = $lei->{dedupe};
 258         $dedupe->prepare_dedupe;
 259         sub { # for git_to_mail
 260                 my ($buf, $smsg, $eml) = @_;
 261                 $eml //= PublicInbox::Eml->new($buf);
 262                 return if $dedupe->is_dup($eml, $smsg->{blob});
 263                 $buf = $eml2mbox->($eml, $smsg);
 264                 return atomic_append($lei, $buf) if $atomic_append;
 265                 my $lk = $ovv->lock_for_scope;
 266                 $lei->out($$buf);
 267         }
 268 }
 269
 270 sub _augment_or_unlink { # maildir_each_eml cb
 271         my ($f, $kw, $eml, $lei, $lse, $mod, $shard, $unlink) = @_;
 272         if ($mod) {
 273                 # can't get dirent.d_ino w/ pure Perl, so we extract the OID
 274                 # if it looks like one:
 275                 my $hex = $f =~ m!\b([a-f0-9]{40,})[^/]*\z! ?
 276                                 $1 : sha256_hex($f);
 277                 my $recno = hex(substr($hex, 0, 8));
 278                 return if ($recno % $mod) != $shard;
 279                 if ($lse) {
 280                         my $x = $lse->kw_changed($eml, $kw);
 281                         if ($x) {
 282                                 $lei->{sto}->ipc_do('set_eml', $eml, @$kw);
 283                         } elsif (!defined($x)) {
 284                                 # TODO: xkw
 285                         }
 286                 }
 287         }
 288         $unlink ? unlink($f) : _augment($eml, $lei);
 289 }
 290
 291 # maildir_each_file callback, \&CORE::unlink doesn't work with it
 292 sub _unlink { unlink($_[0]) }
 293
 294 sub _rand () {
 295         state $seq = 0;
 296         sprintf('%x,%x,%x,%x', rand(0xffffffff), time, $$, ++$seq);
 297 }
 298
 299 sub _buf2maildir {
 300         my ($dst, $buf, $smsg) = @_;
 301         my $kw = $smsg->{kw} // [];
 302         my $sfx = join('', sort(map { $kw2char{$_} // () } @$kw));
 303         my $rand = ''; # chosen by die roll :P
 304         my ($tmp, $fh, $final, $ok);
 305         my $common = $smsg->{blob} // _rand;
 306         if (defined(my $pct = $smsg->{pct})) { $common .= "=$pct" }
 307         do {
 308                 $tmp = $dst.'tmp/'.$rand.$common;
 309         } while (!($ok = sysopen($fh, $tmp, O_CREAT|O_EXCL|O_WRONLY)) &&
 310                 $! == EEXIST && ($rand = _rand.','));
 311         if ($ok && print $fh $$buf and close($fh)) {
 312                 # ignore new/ and write only to cur/, otherwise MUAs
 313                 # with R/W access to the Maildir will end up doing
 314                 # a mass rename which can take a while with thousands
 315                 # of messages.
 316                 $dst .= 'cur/';
 317                 $rand = '';
 318                 do {
 319                         $final = $dst.$rand.$common.':2,'.$sfx;
 320                 } while (!($ok = link($tmp, $final)) && $! == EEXIST &&
 321                         ($rand = _rand.','));
 322                 die "link($tmp, $final): $!" unless $ok;
 323                 unlink($tmp) or warn "W: failed to unlink $tmp: $!\n";
 324         } else {
 325                 my $err = "Error writing $smsg->{blob} to $dst: $!\n";
 326                 $_[0] = undef; # clobber dst
 327                 unlink($tmp);
 328                 die $err;
 329         }
 330 }
 331
 332 sub _maildir_write_cb ($$) {
 333         my ($self, $lei) = @_;
 334         my $dedupe = $lei->{dedupe};
 335         $dedupe->prepare_dedupe if $dedupe;
 336         my $dst = $lei->{ovv}->{dst};
 337         sub { # for git_to_mail
 338                 my ($buf, $smsg, $eml) = @_;
 339                 $dst // return $lei->fail; # dst may be undef-ed in last run
 340                 $buf //= \($eml->as_string);
 341                 return _buf2maildir($dst, $buf, $smsg) if !$dedupe;
 342                 $eml //= PublicInbox::Eml->new($$buf); # copy buf
 343                 return if $dedupe->is_dup($eml, $smsg->{blob});
 344                 undef $eml;
 345                 _buf2maildir($dst, $buf, $smsg);
 346         }
 347 }
 348
 349 sub _imap_write_cb ($$) {
 350         my ($self, $lei) = @_;
 351         my $dedupe = $lei->{dedupe};
 352         $dedupe->prepare_dedupe if $dedupe;
 353         my $imap_append = $lei->{net}->can('imap_append');
 354         my $mic = $lei->{net}->mic_get($self->{uri});
 355         my $folder = $self->{uri}->mailbox;
 356         sub { # for git_to_mail
 357                 my ($bref, $smsg, $eml) = @_;
 358                 $mic // return $lei->fail; # dst may be undef-ed in last run
 359                 if ($dedupe) {
 360                         $eml //= PublicInbox::Eml->new($$bref); # copy bref
 361                         return if $dedupe->is_dup($eml, $smsg->{blob});
 362                 }
 363                 eval { $imap_append->($mic, $folder, $bref, $smsg, $eml) };
 364                 if (my $err = $@) {
 365                         undef $mic;
 366                         die $err;
 367                 }
 368         }
 369 }
 370
 371 sub write_cb { # returns a callback for git_to_mail
 372         my ($self, $lei) = @_;
 373         # _mbox_write_cb, _maildir_write_cb or _imap_write_cb
 374         my $m = "_$self->{base_type}_write_cb";
 375         $self->$m($lei);
 376 }
 377
 378 sub new {
 379         my ($cls, $lei) = @_;
 380         my $fmt = $lei->{ovv}->{fmt};
 381         my $dst = $lei->{ovv}->{dst};
 382         my $self = bless {}, $cls;
 383         if ($fmt eq 'maildir') {
 384                 require PublicInbox::MdirReader;
 385                 $self->{base_type} = 'maildir';
 386                 -e $dst && !-d _ and die
 387                                 "$dst exists and is not a directory\n";
 388                 $lei->{ovv}->{dst} = $dst .= '/' if substr($dst, -1) ne '/';
 389         } elsif (substr($fmt, 0, 4) eq 'mbox') {
 390                 require PublicInbox::MboxReader if $lei->{opt}->{augment};
 391                 (-d $dst || (-e _ && !-w _)) and die
 392                         "$dst exists and is not a writable file\n";
 393                 $self->can("eml2$fmt") or die "bad mbox format: $fmt\n";
 394                 $self->{base_type} = 'mbox';
 395         } elsif ($fmt =~ /\Aimaps?\z/) { # TODO .onion support
 396                 require PublicInbox::NetWriter;
 397                 my $net = PublicInbox::NetWriter->new;
 398                 $net->add_url($dst);
 399                 $net->{quiet} = $lei->{opt}->{quiet};
 400                 my $err = $net->errors($dst);
 401                 return $lei->fail($err) if $err;
 402                 require PublicInbox::URIimap; # TODO: URI cast early
 403                 $self->{uri} = PublicInbox::URIimap->new($dst);
 404                 $self->{uri}->mailbox or die "No mailbox: $dst";
 405                 $lei->{net} = $net;
 406                 $self->{base_type} = 'imap';
 407         } else {
 408                 die "bad mail --format=$fmt\n";
 409         }
 410         $self->{dst} = $dst;
 411         $lei->{dedupe} = PublicInbox::LeiDedupe->new($lei);
 412         $self;
 413 }
 414
 415 sub _pre_augment_maildir {
 416         my ($self, $lei) = @_;
 417         my $dst = $lei->{ovv}->{dst};
 418         for my $x (qw(tmp new cur)) {
 419                 my $d = $dst.$x;
 420                 next if -d $d;
 421                 require File::Path;
 422                 File::Path::mkpath($d);
 423                 -d $d or die "$d is not a directory";
 424         }
 425 }
 426
 427 sub _do_augment_maildir {
 428         my ($self, $lei) = @_;
 429         my $dst = $lei->{ovv}->{dst};
 430         my $lse = $lei->{sto}->search if $lei->{opt}->{'import-augment'};
 431         my ($mod, $shard) = @{$self->{shard_info} // []};
 432         if ($lei->{opt}->{augment}) {
 433                 my $dedupe = $lei->{dedupe};
 434                 if ($dedupe && $dedupe->prepare_dedupe) {
 435                         PublicInbox::MdirReader::maildir_each_eml($dst,
 436                                                 \&_augment_or_unlink,
 437                                                 $lei, $lse, $mod, $shard);
 438                         $dedupe->pause_dedupe;
 439                 }
 440         } elsif ($lse) {
 441                 PublicInbox::MdirReader::maildir_each_eml($dst,
 442                                         \&_augment_or_unlink,
 443                                         $lei, $lse, $mod, $shard, 1);
 444         } else {# clobber existing Maildir
 445                 PublicInbox::MdirReader::maildir_each_file($dst, \&_unlink);
 446         }
 447 }
 448
 449 sub _post_augment_maildir {
 450         my ($self, $lei) = @_;
 451         $lei->{opt}->{'import-augment'} or return;
 452         my $wait = $lei->{sto}->ipc_do('checkpoint', 1);
 453 }
 454
 455 sub _augment_imap { # PublicInbox::NetReader::imap_each cb
 456         my ($url, $uid, $kw, $eml, $lei) = @_;
 457         _augment($eml, $lei);
 458 }
 459
 460 sub _do_augment_imap {
 461         my ($self, $lei) = @_;
 462         my $net = $lei->{net};
 463         if ($lei->{opt}->{augment}) {
 464                 my $dedupe = $lei->{dedupe};
 465                 if ($dedupe && $dedupe->prepare_dedupe) {
 466                         $net->imap_each($self->{uri}, \&_augment_imap, $lei);
 467                         $dedupe->pause_dedupe;
 468                 }
 469         } elsif (!$self->{-wq_worker_nr}) { # undef or 0
 470                 # clobber existing IMAP folder
 471                 $net->imap_delete_all($self->{uri});
 472         }
 473 }
 474
 475 sub _pre_augment_mbox {
 476         my ($self, $lei) = @_;
 477         my $dst = $lei->{ovv}->{dst};
 478         if ($dst ne '/dev/stdout') {
 479                 my $out;
 480                 if (-p $dst) {
 481                         open $out, '>', $dst or die "open($dst): $!";
 482                 } elsif (-f _ || !-e _) {
 483                         require PublicInbox::MboxLock;
 484                         my $m = $lei->{opt}->{'lock'} //
 485                                         PublicInbox::MboxLock->defaults;
 486                         $self->{mbl} = PublicInbox::MboxLock->acq($dst, 1, $m);
 487                         $out = $self->{mbl}->{fh};
 488                         if (!$lei->{opt}->{augment} and !truncate($out, 0)) {
 489                                 die "truncate($dst): $!";
 490                         }
 491                 }
 492                 $lei->{old_1} = $lei->{1}; # keep for spawning MUA
 493                 $lei->{1} = $out;
 494         }
 495         # Perl does SEEK_END even with O_APPEND :<
 496         $self->{seekable} = seek($lei->{1}, 0, SEEK_SET);
 497         if (!$self->{seekable} && $! != ESPIPE && $dst ne '/dev/stdout') {
 498                 die "seek($dst): $!\n";
 499         }
 500         state $zsfx_allow = join('|', keys %zsfx2cmd);
 501         ($self->{zsfx}) = ($dst =~ /\.($zsfx_allow)\z/) or return;
 502         pipe(my ($r, $w)) or die "pipe: $!";
 503         $lei->{zpipe} = [ $r, $w ];
 504 }
 505
 506 sub _do_augment_mbox {
 507         my ($self, $lei) = @_;
 508         return if !$lei->{opt}->{augment};
 509         my $dedupe = $lei->{dedupe};
 510         my $dst = $lei->{ovv}->{dst};
 511         die "cannot augment $dst, not seekable\n" if !$self->{seekable};
 512         my $out = $lei->{1};
 513         if (-s $out && $dedupe && $dedupe->prepare_dedupe) {
 514                 my $zsfx = $self->{zsfx};
 515                 my $rd = $zsfx ? decompress_src($out, $zsfx, $lei) :
 516                                 dup_src($out);
 517                 my $fmt = $lei->{ovv}->{fmt};
 518                 PublicInbox::MboxReader->$fmt($rd, \&_augment, $lei);
 519         }
 520         # maybe some systems don't honor O_APPEND, Perl does this:
 521         seek($out, 0, SEEK_END) or die "seek $dst: $!";
 522         $dedupe->pause_dedupe if $dedupe;
 523 }
 524
 525 sub pre_augment { # fast (1 disk seek), runs in same process as post_augment
 526         my ($self, $lei) = @_;
 527         # _pre_augment_maildir, _pre_augment_mbox
 528         my $m = $self->can("_pre_augment_$self->{base_type}") or return;
 529         $m->($self, $lei);
 530 }
 531
 532 sub do_augment { # slow, runs in wq worker
 533         my ($self, $lei) = @_;
 534         # _do_augment_maildir, _do_augment_mbox, or _do_augment_imap
 535         my $m = "_do_augment_$self->{base_type}";
 536         $self->$m($lei);
 537 }
 538
 539 # fast (spawn compressor or mkdir), runs in same process as pre_augment
 540 sub post_augment {
 541         my ($self, $lei, @args) = @_;
 542         # _post_augment_mbox
 543         my $m = $self->can("_post_augment_$self->{base_type}") or return;
 544         $m->($self, $lei, @args);
 545 }
 546
 547 sub do_post_auth {
 548         my ($self) = @_;
 549         my $lei = $self->{lei};
 550         # lei_xsearch can start as soon as all l2m workers get here
 551         pkt_do($lei->{pkt_op_p}, 'incr_start_query') or
 552                 die "incr_start_query: $!";
 553         my $aug;
 554         if (lock_free($self)) {
 555                 my $mod = $self->{-wq_nr_workers};
 556                 my $shard = $self->{-wq_worker_nr};
 557                 if (my $net = $lei->{net}) {
 558                         $net->{shard_info} = [ $mod, $shard ];
 559                 } else { # Maildir (MH?)
 560                         $self->{shard_info} = [ $mod, $shard ];
 561                 }
 562                 $aug = '+'; # incr_post_augment
 563         } elsif ($self->{-wq_worker_nr} == 0) {
 564                 $aug = '.'; # do_post_augment
 565         }
 566         if ($aug) {
 567                 local $0 = 'do_augment';
 568                 eval { do_augment($self, $lei) };
 569                 $lei->fail($@) if $@;
 570                 pkt_do($lei->{pkt_op_p}, $aug) == 1 or
 571                                 die "do_post_augment trigger: $!";
 572         }
 573         if (my $zpipe = delete $lei->{zpipe}) {
 574                 $lei->{1} = $zpipe->[1];
 575                 close $zpipe->[0];
 576         }
 577         $self->{wcb} = $self->write_cb($lei);
 578 }
 579
 580 sub ipc_atfork_child {
 581         my ($self) = @_;
 582         my $lei = $self->{lei};
 583         $lei->lei_atfork_child;
 584         $lei->{auth}->do_auth_atfork($self) if $lei->{auth};
 585         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 586         $self->SUPER::ipc_atfork_child;
 587 }
 588
 589 sub lock_free {
 590         $_[0]->{base_type} =~ /\A(?:maildir|mh|imap|jmap)\z/ ? 1 : 0;
 591 }
 592
 593 sub poke_dst {
 594         my ($self) = @_;
 595         if ($self->{base_type} eq 'maildir') {
 596                 my $t = time + 1;
 597                 utime($t, $t, "$self->{dst}/cur");
 598         }
 599 }
 600
 601 sub write_mail { # via ->wq_io_do
 602         my ($self, $git_dir, $smsg) = @_;
 603         my $git = $self->{"$$\0$git_dir"} //= PublicInbox::Git->new($git_dir);
 604         git_async_cat($git, $smsg->{blob}, \&git_to_mail,
 605                                 [$self->{wcb}, $smsg]);
 606 }
 607
 608 sub wq_atexit_child {
 609         my ($self) = @_;
 610         delete $self->{wcb};
 611         for my $git (delete @$self{grep(/\A$$\0/, keys %$self)}) {
 612                 $git->async_wait_all;
 613         }
 614         $SIG{__WARN__} = 'DEFAULT';
 615 }
 616
 617 # called in top-level lei-daemon when LeiAuth is done
 618 sub net_merge_complete {
 619         my ($self) = @_;
 620         $self->wq_broadcast('do_post_auth');
 621         $self->wq_close(1);
 622 }
 623
 624 no warnings 'once'; # the following works even when LeiAuth is lazy-loaded
 625 *net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
 626 1;