lib/PublicInbox/LeiToMail.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Writes PublicInbox::Eml objects atomically to a mbox variant or Maildir
   5 package PublicInbox::LeiToMail;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::ProcessPipe;
  11 use PublicInbox::Spawn qw(spawn);
  12 use Symbol qw(gensym);
  13 use IO::Handle; # ->autoflush
  14 use Fcntl qw(SEEK_SET SEEK_END O_CREAT O_EXCL O_WRONLY);
  15 use PublicInbox::Syscall qw(rename_noreplace);
  16
  17 my %kw2char = ( # Maildir characters
  18         draft => 'D',
  19         flagged => 'F',
  20         forwarded => 'P', # passed
  21         answered => 'R',
  22         seen => 'S',
  23 );
  24
  25 my %kw2status = (
  26         flagged => [ 'X-Status' => 'F' ],
  27         answered => [ 'X-Status' => 'A' ],
  28         seen => [ 'Status' => 'R' ],
  29         draft => [ 'X-Status' => 'T' ],
  30 );
  31
  32 sub _mbox_hdr_buf ($$$) {
  33         my ($eml, $type, $smsg) = @_;
  34         $eml->header_set($_) for (qw(Lines Bytes Content-Length));
  35
  36         my %hdr = (Status => []); # set Status, X-Status
  37         for my $k (@{$smsg->{kw} // []}) {
  38                 if (my $ent = $kw2status{$k}) {
  39                         push @{$hdr{$ent->[0]}}, $ent->[1];
  40                 } else { # X-Label?
  41                         warn "# keyword `$k' not supported for mbox\n";
  42                 }
  43         }
  44         # When writing to empty mboxes, messages are always 'O'
  45         # (not-\Recent in IMAP), it saves MUAs the trouble of
  46         # rewriting the mbox if no other changes are made.
  47         # We put 'O' at the end (e.g. "Status: RO") to match mutt(1) output.
  48         # We only set smsg->{-recent} if augmenting existing stores.
  49         my $status = join('', sort(@{$hdr{Status}}));
  50         $status .= 'O' unless $smsg->{-recent};
  51         $eml->header_set('Status', $status) if $status;
  52         if (my $chars = delete $hdr{'X-Status'}) {
  53                 $eml->header_set('X-Status', join('', sort(@$chars)));
  54         }
  55         my $buf = delete $eml->{hdr};
  56
  57         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
  58         $$buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  59         my $ident = $smsg->{blob} // 'lei';
  60         if (defined(my $pct = $smsg->{pct})) { $ident .= "=$pct" }
  61
  62         substr($$buf, 0, 0, # prepend From line
  63                 "From $ident\@$type Thu Jan  1 00:00:00 1970$eml->{crlf}");
  64         $buf;
  65 }
  66
  67 sub atomic_append { # for on-disk destinations (O_APPEND, or O_EXCL)
  68         my ($lei, $buf) = @_;
  69         if (defined(my $w = syswrite($lei->{1} // return, $$buf))) {
  70                 return if $w == length($$buf);
  71                 $buf = "short atomic write: $w != ".length($$buf);
  72         } elsif ($!{EPIPE}) {
  73                 return $lei->note_sigpipe(1);
  74         } else {
  75                 $buf = "atomic write: $!";
  76         }
  77         $lei->fail($buf);
  78 }
  79
  80 sub eml2mboxrd ($;$) {
  81         my ($eml, $smsg) = @_;
  82         my $buf = _mbox_hdr_buf($eml, 'mboxrd', $smsg);
  83         if (my $bdy = delete $eml->{bdy}) {
  84                 $$bdy =~ s/^(>*From )/>$1/gm;
  85                 $$buf .= $eml->{crlf};
  86                 substr($$bdy, 0, 0, $$buf); # prepend header
  87                 $buf = $bdy;
  88         }
  89         $$buf .= $eml->{crlf};
  90         $buf;
  91 }
  92
  93 sub eml2mboxo {
  94         my ($eml, $smsg) = @_;
  95         my $buf = _mbox_hdr_buf($eml, 'mboxo', $smsg);
  96         if (my $bdy = delete $eml->{bdy}) {
  97                 $$bdy =~ s/^From />From /gm;
  98                 $$buf .= $eml->{crlf};
  99                 substr($$bdy, 0, 0, $$buf); # prepend header
 100                 $buf = $bdy;
 101         }
 102         $$buf .= $eml->{crlf};
 103         $buf;
 104 }
 105
 106 sub _mboxcl_common ($$$) {
 107         my ($buf, $bdy, $crlf) = @_;
 108         # add Lines: so mutt won't have to add it on MUA close
 109         my $lines = $$bdy =~ tr!\n!\n!;
 110         $$buf .= 'Content-Length: '.length($$bdy).$crlf.
 111                 'Lines: '.$lines.$crlf.$crlf;
 112         substr($$bdy, 0, 0, $$buf); # prepend header
 113         $$bdy .= $crlf;
 114         $bdy;
 115 }
 116
 117 # mboxcl still escapes "From " lines
 118 sub eml2mboxcl {
 119         my ($eml, $smsg) = @_;
 120         my $buf = _mbox_hdr_buf($eml, 'mboxcl', $smsg);
 121         my $bdy = delete($eml->{bdy}) // \(my $empty = '');
 122         $$bdy =~ s/^From />From /gm;
 123         _mboxcl_common($buf, $bdy, $eml->{crlf});
 124 }
 125
 126 # mboxcl2 has no "From " escaping
 127 sub eml2mboxcl2 {
 128         my ($eml, $smsg) = @_;
 129         my $buf = _mbox_hdr_buf($eml, 'mboxcl2', $smsg);
 130         my $bdy = delete($eml->{bdy}) // \(my $empty = '');
 131         _mboxcl_common($buf, $bdy, $eml->{crlf});
 132 }
 133
 134 sub git_to_mail { # git->cat_async callback
 135         my ($bref, $oid, $type, $size, $arg) = @_;
 136         $type // return; # called by git->async_abort
 137         my ($write_cb, $smsg) = @$arg;
 138         if ($type eq 'missing' && $smsg->{-lms_rw}) {
 139                 if ($bref = $smsg->{-lms_rw}->local_blob($oid, 1)) {
 140                         $type = 'blob';
 141                         $size = length($$bref);
 142                 }
 143         }
 144         return warn("W: $oid is $type (!= blob)\n") if $type ne 'blob';
 145         return warn("E: $oid is empty\n") unless $size;
 146         die "BUG: expected=$smsg->{blob} got=$oid" if $smsg->{blob} ne $oid;
 147         $write_cb->($bref, $smsg);
 148 }
 149
 150 sub reap_compress { # dwaitpid callback
 151         my ($lei, $pid) = @_;
 152         my $cmd = delete $lei->{"pid.$pid"};
 153         return if $? == 0;
 154         $lei->fail("@$cmd failed", $? >> 8);
 155 }
 156
 157 sub _post_augment_mbox { # open a compressor process from top-level process
 158         my ($self, $lei) = @_;
 159         my $zsfx = $self->{zsfx} or return;
 160         my $cmd = PublicInbox::MboxReader::zsfx2cmd($zsfx, undef, $lei);
 161         my ($r, $w) = @{delete $lei->{zpipe}};
 162         my $rdr = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2}, pgid => 0 };
 163         my $pid = spawn($cmd, undef, $rdr);
 164         my $pp = gensym;
 165         my $dup = bless { "pid.$pid" => $cmd }, ref($lei);
 166         $dup->{$_} = $lei->{$_} for qw(2 sock);
 167         tie *$pp, 'PublicInbox::ProcessPipe', $pid, $w, \&reap_compress, $dup;
 168         $lei->{1} = $pp;
 169 }
 170
 171 # --augment existing output destination, with deduplication
 172 sub _augment { # MboxReader eml_cb
 173         my ($eml, $lei) = @_;
 174         # ignore return value, just populate the skv
 175         $lei->{dedupe}->is_dup($eml);
 176 }
 177
 178 sub _mbox_augment_kw_maybe {
 179         my ($eml, $lei, $lse, $augment) = @_;
 180         my $kw = PublicInbox::MboxReader::mbox_keywords($eml);
 181         update_kw_maybe($lei, $lse, $eml, $kw);
 182         _augment($eml, $lei) if $augment;
 183 }
 184
 185 sub _mbox_write_cb ($$) {
 186         my ($self, $lei) = @_;
 187         my $ovv = $lei->{ovv};
 188         my $m = 'eml2'.$ovv->{fmt};
 189         my $eml2mbox = $self->can($m) or die "$self->$m missing";
 190         $lei->{1} // die "no stdout ($m, $ovv->{dst})"; # redirected earlier
 191         $lei->{1}->autoflush(1);
 192         my $atomic_append = !defined($ovv->{lock_path});
 193         my $dedupe = $lei->{dedupe};
 194         $dedupe->prepare_dedupe;
 195         my $lse = $lei->{lse}; # may be undef
 196         my $set_recent = $dedupe->has_entries;
 197         sub { # for git_to_mail
 198                 my ($buf, $smsg, $eml) = @_;
 199                 $eml //= PublicInbox::Eml->new($buf);
 200                 return if $dedupe->is_dup($eml, $smsg);
 201                 $lse->xsmsg_vmd($smsg) if $lse;
 202                 $smsg->{-recent} = 1 if $set_recent;
 203                 $buf = $eml2mbox->($eml, $smsg);
 204                 if ($atomic_append) {
 205                         atomic_append($lei, $buf);
 206                 } else {
 207                         my $lk = $ovv->lock_for_scope;
 208                         $lei->out($$buf);
 209                 }
 210                 ++$lei->{-nr_write};
 211         }
 212 }
 213
 214 sub update_kw_maybe ($$$$) {
 215         my ($lei, $lse, $eml, $kw) = @_;
 216         return unless $lse;
 217         my $c = $lse->kw_changed($eml, $kw, my $docids = []);
 218         my $vmd = { kw => $kw };
 219         if (scalar @$docids) { # already in lei/store
 220                 $lei->{sto}->wq_do('set_eml_vmd', undef, $vmd, $docids) if $c;
 221         } elsif (my $xoids = $lei->{ale}->xoids_for($eml)) {
 222                 # it's in an external, only set kw, here
 223                 $lei->{sto}->wq_do('set_xvmd', $xoids, $eml, $vmd);
 224         } else { # never-before-seen, import the whole thing
 225                 # XXX this is critical in protecting against accidental
 226                 # data loss without --augment
 227                 $lei->{sto}->wq_do('set_eml', $eml, $vmd);
 228         }
 229 }
 230
 231 sub _md_update { # maildir_each_eml cb
 232         my ($f, $kw, $eml, $lei, $lse, $unlink) = @_;
 233         update_kw_maybe($lei, $lse, $eml, $kw);
 234         $unlink ? unlink($f) : _augment($eml, $lei);
 235 }
 236
 237 # maildir_each_file callback, \&CORE::unlink doesn't work with it
 238 sub _unlink { unlink($_[0]) }
 239
 240 sub _rand () {
 241         state $seq = 0;
 242         sprintf('%x,%x,%x,%x', rand(0xffffffff), time, $$, ++$seq);
 243 }
 244
 245 sub kw2suffix ($;@) {
 246         my $kw = shift;
 247         join('', sort(map { $kw2char{$_} // () } @$kw, @_));
 248 }
 249
 250 sub _buf2maildir ($$$$) {
 251         my ($dst, $buf, $smsg, $dir) = @_;
 252         my $kw = $smsg->{kw} // [];
 253         my $rand = ''; # chosen by die roll :P
 254         my ($tmp, $fh, $base, $ok);
 255         my $common = $smsg->{blob} // _rand;
 256         if (defined(my $pct = $smsg->{pct})) { $common .= "=$pct" }
 257         do {
 258                 $tmp = $dst.'tmp/'.$rand.$common;
 259         } while (!($ok = sysopen($fh, $tmp, O_CREAT|O_EXCL|O_WRONLY)) &&
 260                 $!{EEXIST} && ($rand = _rand.','));
 261         if ($ok && print $fh $$buf and close($fh)) {
 262                 $dst .= $dir; # 'new/' or 'cur/'
 263                 $rand = '';
 264                 do {
 265                         $base = $rand.$common.':2,'.kw2suffix($kw);
 266                 } while (!($ok = rename_noreplace($tmp, $dst.$base)) &&
 267                         $!{EEXIST} && ($rand = _rand.','));
 268                 \$base;
 269         } else {
 270                 my $err = "Error writing $smsg->{blob} to $dst: $!\n";
 271                 $_[0] = undef; # clobber dst
 272                 unlink($tmp);
 273                 die $err;
 274         }
 275 }
 276
 277 sub _maildir_write_cb ($$) {
 278         my ($self, $lei) = @_;
 279         my $dedupe = $lei->{dedupe};
 280         $dedupe->prepare_dedupe if $dedupe;
 281         my $dst = $lei->{ovv}->{dst};
 282         my $lse = $lei->{lse}; # may be undef
 283         my $lms = $self->{-lms_rw};
 284         my $out = $lms ? 'maildir:'.$lei->abs_path($dst) : undef;
 285         $lms->lms_write_prepare if $lms;
 286
 287         # Favor cur/ and only write to new/ when augmenting.  This
 288         # saves MUAs from having to do a mass rename when the initial
 289         # search result set is huge.
 290         my $dir = $dedupe && $dedupe->has_entries ? 'new/' : 'cur/';
 291         sub { # for git_to_mail
 292                 my ($bref, $smsg, $eml) = @_;
 293                 $dst // return $lei->fail; # dst may be undef-ed in last run
 294                 return if $dedupe && $dedupe->is_dup($eml //
 295                                                 PublicInbox::Eml->new($$bref),
 296                                                 $smsg);
 297                 $lse->xsmsg_vmd($smsg) if $lse;
 298                 my $n = _buf2maildir($dst, $bref // \($eml->as_string),
 299                                         $smsg, $dir);
 300                 $lms->set_src($smsg->oidbin, $out, $n) if $lms;
 301                 ++$lei->{-nr_write};
 302         }
 303 }
 304
 305 sub _imap_write_cb ($$) {
 306         my ($self, $lei) = @_;
 307         my $dedupe = $lei->{dedupe};
 308         $dedupe->prepare_dedupe if $dedupe;
 309         my $append = $lei->{net}->can('imap_append');
 310         my $uri = $self->{uri};
 311         my $mic = $lei->{net}->mic_get($uri);
 312         my $folder = $uri->mailbox;
 313         $uri->uidvalidity($mic->uidvalidity($folder));
 314         my $lse = $lei->{lse}; # may be undef
 315         my $lms = $self->{-lms_rw};
 316         $lms->lms_write_prepare if $lms;
 317         sub { # for git_to_mail
 318                 my ($bref, $smsg, $eml) = @_;
 319                 $mic // return $lei->fail; # mic may be undef-ed in last run
 320                 return if $dedupe && $dedupe->is_dup($eml //
 321                                                 PublicInbox::Eml->new($$bref),
 322                                                 $smsg);
 323                 $lse->xsmsg_vmd($smsg) if $lse;
 324                 my $uid = eval { $append->($mic, $folder, $bref, $smsg, $eml) };
 325                 if (my $err = $@) {
 326                         undef $mic;
 327                         die $err;
 328                 }
 329                 # imap_append returns UID if IMAP server has UIDPLUS extension
 330                 ($lms && $uid =~ /\A[0-9]+\z/) and
 331                         $lms->set_src($smsg->oidbin, $$uri, $uid + 0);
 332                 ++$lei->{-nr_write};
 333         }
 334 }
 335
 336 sub _text_write_cb ($$) {
 337         my ($self, $lei) = @_;
 338         my $dedupe = $lei->{dedupe};
 339         $dedupe->prepare_dedupe if $dedupe;
 340         my $lvt = $lei->{lvt};
 341         my $ovv = $lei->{ovv};
 342         $lei->{1} // die "no stdout ($ovv->{dst})"; # redirected earlier
 343         $lei->{1}->autoflush(1);
 344         binmode $lei->{1}, ':utf8';
 345         my $lse = $lei->{lse}; # may be undef
 346         sub { # for git_to_mail
 347                 my ($bref, $smsg, $eml) = @_;
 348                 $lse->xsmsg_vmd($smsg) if $lse;
 349                 $eml //= PublicInbox::Eml->new($bref);
 350                 return if $dedupe && $dedupe->is_dup($eml, $smsg);
 351                 my $lk = $ovv->lock_for_scope;
 352                 $lei->out(${$lvt->eml_to_text($smsg, $eml)}, "\n");
 353         }
 354 }
 355
 356 sub _v2_write_cb ($$) {
 357         my ($self, $lei) = @_;
 358         my $dedupe = $lei->{dedupe};
 359         $dedupe->prepare_dedupe if $dedupe;
 360         sub { # for git_to_mail
 361                 my ($bref, $smsg, $eml) = @_;
 362                 $eml //= PublicInbox::Eml->new($bref);
 363                 return if $dedupe && $dedupe->is_dup($eml, $smsg);
 364                 $lei->{v2w}->wq_do('add', $eml); # V2Writable->add
 365                 ++$lei->{-nr_write};
 366         }
 367 }
 368
 369 sub write_cb { # returns a callback for git_to_mail
 370         my ($self, $lei) = @_;
 371         # _mbox_write_cb, _maildir_write_cb, _imap_write_cb, _v2_write_cb
 372         my $m = "_$self->{base_type}_write_cb";
 373         $self->$m($lei);
 374 }
 375
 376 sub new {
 377         my ($cls, $lei) = @_;
 378         my $fmt = $lei->{ovv}->{fmt};
 379         my $dst = $lei->{ovv}->{dst};
 380         my $self = bless {}, $cls;
 381         my @conflict;
 382         if ($fmt eq 'maildir') {
 383                 require PublicInbox::MdirReader;
 384                 $self->{base_type} = 'maildir';
 385                 -e $dst && !-d _ and die
 386                                 "$dst exists and is not a directory\n";
 387                 $lei->{ovv}->{dst} = $dst .= '/' if substr($dst, -1) ne '/';
 388                 $lei->{opt}->{save} //= \1 if $lei->{cmd} eq 'q';
 389         } elsif (substr($fmt, 0, 4) eq 'mbox') {
 390                 require PublicInbox::MboxReader;
 391                 $self->can("eml2$fmt") or die "bad mbox format: $fmt\n";
 392                 $self->{base_type} = 'mbox';
 393                 if ($lei->{cmd} eq 'q' &&
 394                                 (($lei->path_to_fd($dst) // -1) < 0) &&
 395                                 (-f $dst || !-e _)) {
 396                         $lei->{opt}->{save} //= \1;
 397                 }
 398         } elsif ($fmt =~ /\Aimaps?\z/) {
 399                 require PublicInbox::NetWriter;
 400                 require PublicInbox::URIimap;
 401                 # {net} may exist from "lei up" for auth
 402                 my $net = $lei->{net} // PublicInbox::NetWriter->new;
 403                 $net->{quiet} = $lei->{opt}->{quiet};
 404                 my $uri = PublicInbox::URIimap->new($dst)->canonical;
 405                 $net->add_url($$uri);
 406                 my $err = $net->errors($lei);
 407                 return $lei->fail($err) if $err;
 408                 $uri->mailbox or return $lei->fail("No mailbox: $dst");
 409                 $self->{uri} = $uri;
 410                 $dst = $lei->{ovv}->{dst} = $$uri; # canonicalized
 411                 $lei->{net} = $net;
 412                 $self->{base_type} = 'imap';
 413                 $lei->{opt}->{save} //= \1 if $lei->{cmd} eq 'q';
 414         } elsif ($fmt eq 'text' || $fmt eq 'reply') {
 415                 require PublicInbox::LeiViewText;
 416                 $lei->{lvt} = PublicInbox::LeiViewText->new($lei, $fmt);
 417                 $self->{base_type} = 'text';
 418                 @conflict = qw(mua save);
 419         } elsif ($fmt eq 'v2') {
 420                 die "--dedupe=oid and v2 are incompatible\n" if
 421                         ($lei->{opt}->{dedupe}//'') eq 'oid';
 422                 $self->{base_type} = 'v2';
 423                 $lei->{opt}->{save} = \1;
 424                 $dst = $lei->{ovv}->{dst} = $lei->abs_path($dst);
 425                 @conflict = qw(mua sort);
 426         } else {
 427                 die "bad mail --format=$fmt\n";
 428         }
 429         if ($self->{base_type} =~ /\A(?:text|mbox)\z/) {
 430                 (-d $dst || (-e _ && !-w _)) and die
 431                         "$dst exists and is not a writable file\n";
 432         }
 433         my @err = map { defined($lei->{opt}->{$_}) ? "--$_" : () } @conflict;
 434         die "@err incompatible with $fmt\n" if @err;
 435         $self->{dst} = $dst;
 436         $lei->{dedupe} = $lei->{lss} // do {
 437                 my $dd_cls = 'PublicInbox::'.
 438                         ($lei->{opt}->{save} ? 'LeiSavedSearch' : 'LeiDedupe');
 439                 eval "require $dd_cls";
 440                 die "$dd_cls: $@" if $@;
 441                 my $dd = $dd_cls->new($lei);
 442                 $lei->{lss} //= $dd if $dd && $dd->can('cfg_set');
 443                 $dd;
 444         };
 445         $self;
 446 }
 447
 448 sub _pre_augment_maildir {
 449         my ($self, $lei) = @_;
 450         my $dst = $lei->{ovv}->{dst};
 451         for my $x (qw(tmp new cur)) {
 452                 my $d = $dst.$x;
 453                 next if -d $d;
 454                 require File::Path;
 455                 File::Path::mkpath($d);
 456                 -d $d or die "$d is not a directory";
 457         }
 458         # for utime, so no opendir
 459         open $self->{poke_dh}, '<', "${dst}cur" or die "open ${dst}cur: $!";
 460 }
 461
 462 sub clobber_dst_prepare ($;$) {
 463         my ($lei, $f) = @_;
 464         if (my $lms = defined($f) ? $lei->lms : undef) {
 465                 $lms->lms_write_prepare;
 466                 $lms->forget_folders($f);
 467         }
 468         my $dedupe = $lei->{dedupe} or return;
 469         $dedupe->reset_dedupe if $dedupe->can('reset_dedupe');
 470 }
 471
 472 sub _do_augment_maildir {
 473         my ($self, $lei) = @_;
 474         return if $lei->{cmd} eq 'up';
 475         my $dst = $lei->{ovv}->{dst};
 476         my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
 477         my $mdr = PublicInbox::MdirReader->new;
 478         if ($lei->{opt}->{augment}) {
 479                 my $dedupe = $lei->{dedupe};
 480                 if ($dedupe && $dedupe->prepare_dedupe) {
 481                         $mdr->{shard_info} = $self->{shard_info};
 482                         $mdr->maildir_each_eml($dst, \&_md_update, $lei, $lse);
 483                         $dedupe->pause_dedupe;
 484                 }
 485         } elsif ($lse) {
 486                 clobber_dst_prepare($lei, "maildir:$dst");
 487                 $mdr->{shard_info} = $self->{shard_info};
 488                 $mdr->maildir_each_eml($dst, \&_md_update, $lei, $lse, 1);
 489         } else {# clobber existing Maildir
 490                 clobber_dst_prepare($lei, "maildir:$dst");
 491                 $mdr->maildir_each_file($dst, \&_unlink);
 492         }
 493 }
 494
 495 sub _imap_augment_or_delete { # PublicInbox::NetReader::imap_each cb
 496         my ($uri, $uid, $kw, $eml, $lei, $lse, $delete_mic) = @_;
 497         update_kw_maybe($lei, $lse, $eml, $kw);
 498         if ($delete_mic) {
 499                 $lei->{net}->imap_delete_1($uri, $uid, $delete_mic);
 500         } else {
 501                 _augment($eml, $lei);
 502         }
 503 }
 504
 505 sub _do_augment_imap {
 506         my ($self, $lei) = @_;
 507         return if $lei->{cmd} eq 'up';
 508         my $net = $lei->{net};
 509         my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
 510         if ($lei->{opt}->{augment}) {
 511                 my $dedupe = $lei->{dedupe};
 512                 if ($dedupe && $dedupe->prepare_dedupe) {
 513                         $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 514                                         $lei, $lse);
 515                         $dedupe->pause_dedupe;
 516                 }
 517         } elsif ($lse) {
 518                 my $delete_mic;
 519                 clobber_dst_prepare($lei, "$self->{uri}");
 520                 $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 521                                         $lei, $lse, \$delete_mic);
 522                 $delete_mic->expunge if $delete_mic;
 523         } elsif (!$self->{-wq_worker_nr}) { # undef or 0
 524                 # clobber existing IMAP folder
 525                 clobber_dst_prepare($lei, "$self->{uri}");
 526                 $net->imap_delete_all($self->{uri});
 527         }
 528 }
 529
 530 sub _pre_augment_text {
 531         my ($self, $lei) = @_;
 532         my $dst = $lei->{ovv}->{dst};
 533         my $out;
 534         my $devfd = $lei->path_to_fd($dst) // die "bad $dst";
 535         if ($devfd >= 0) {
 536                 $out = $lei->{$devfd};
 537         } else { # normal-looking path
 538                 if (-p $dst) {
 539                         open $out, '>', $dst or die "open($dst): $!";
 540                 } elsif (-f _ || !-e _) {
 541                         # text allows augment, HTML/Atom won't
 542                         my $mode = $lei->{opt}->{augment} ? '>>' : '>';
 543                         open $out, $mode, $dst or die "open($mode, $dst): $!";
 544                 } else {
 545                         die "$dst is not a file or FIFO\n";
 546                 }
 547         }
 548         $lei->{ovv}->ovv_out_lk_init if !$lei->{ovv}->{lock_path};
 549         $lei->{1} = $out;
 550         undef;
 551 }
 552
 553 sub _pre_augment_mbox {
 554         my ($self, $lei) = @_;
 555         my $dst = $lei->{ovv}->{dst};
 556         my $out;
 557         my $devfd = $lei->path_to_fd($dst) // die "bad $dst";
 558         if ($devfd >= 0) {
 559                 $out = $lei->{$devfd};
 560         } else { # normal-looking path
 561                 if (-p $dst) {
 562                         open $out, '>', $dst or die "open($dst): $!";
 563                 } elsif (-f _ || !-e _) {
 564                         require PublicInbox::MboxLock;
 565                         my $m = $lei->{opt}->{'lock'} //
 566                                         PublicInbox::MboxLock->defaults;
 567                         $self->{mbl} = PublicInbox::MboxLock->acq($dst, 1, $m);
 568                         $out = $self->{mbl}->{fh};
 569                 } else {
 570                         die "$dst is not a file or FIFO\n";
 571                 }
 572                 $lei->{old_1} = $lei->{1}; # keep for spawning MUA
 573         }
 574         # Perl does SEEK_END even with O_APPEND :<
 575         $self->{seekable} = seek($out, 0, SEEK_SET);
 576         if (!$self->{seekable} && !$!{ESPIPE} && !defined($devfd)) {
 577                 die "seek($dst): $!\n";
 578         }
 579         if (!$self->{seekable}) {
 580                 my $imp_before = $lei->{opt}->{'import-before'};
 581                 die "--import-before specified but $dst is not seekable\n"
 582                         if $imp_before && !ref($imp_before);
 583                 die "--augment specified but $dst is not seekable\n" if
 584                         $lei->{opt}->{augment};
 585                 die "cannot --save with unseekable $dst\n" if
 586                         $lei->{dedupe} && $lei->{dedupe}->can('reset_dedupe');
 587         }
 588         if ($self->{zsfx} = PublicInbox::MboxReader::zsfx($dst)) {
 589                 pipe(my ($r, $w)) or die "pipe: $!";
 590                 $lei->{zpipe} = [ $r, $w ];
 591                 $lei->{ovv}->{lock_path} and
 592                         die 'BUG: unexpected {ovv}->{lock_path}';
 593                 $lei->{ovv}->ovv_out_lk_init;
 594         } elsif (!$self->{seekable} && !$lei->{ovv}->{lock_path}) {
 595                 $lei->{ovv}->ovv_out_lk_init;
 596         }
 597         $lei->{1} = $out;
 598         undef;
 599 }
 600
 601 sub _do_augment_mbox {
 602         my ($self, $lei) = @_;
 603         return unless $self->{seekable};
 604         my $opt = $lei->{opt};
 605         return if $lei->{cmd} eq 'up';
 606         my $out = $lei->{1};
 607         my ($fmt, $dst) = @{$lei->{ovv}}{qw(fmt dst)};
 608         return clobber_dst_prepare($lei) unless -s $out;
 609         unless ($opt->{augment} || $opt->{'import-before'}) {
 610                 truncate($out, 0) or die "truncate($dst): $!";
 611                 return;
 612         }
 613         my $rd;
 614         if (my $zsfx = $self->{zsfx}) {
 615                 $rd = PublicInbox::MboxReader::zsfxcat($out, $zsfx, $lei);
 616         } else {
 617                 open($rd, '+>>&', $out) or die "dup: $!";
 618         }
 619         my $dedupe;
 620         if ($opt->{augment}) {
 621                 $dedupe = $lei->{dedupe};
 622                 $dedupe->prepare_dedupe if $dedupe;
 623         } else {
 624                 clobber_dst_prepare($lei);
 625         }
 626         if ($opt->{'import-before'}) { # the default
 627                 my $lse = $lei->{lse};
 628                 PublicInbox::MboxReader->$fmt($rd, \&_mbox_augment_kw_maybe,
 629                                                 $lei, $lse, $opt->{augment});
 630                 if (!$opt->{augment} and !truncate($out, 0)) {
 631                         die "truncate($dst): $!";
 632                 }
 633         } else { # --augment --no-import-before
 634                 PublicInbox::MboxReader->$fmt($rd, \&_augment, $lei);
 635         }
 636         # maybe some systems don't honor O_APPEND, Perl does this:
 637         seek($out, 0, SEEK_END) or die "seek $dst: $!";
 638         $dedupe->pause_dedupe if $dedupe;
 639 }
 640
 641 sub v2w_done_wait { # dwaitpid callback
 642         my ($arg, $pid) = @_;
 643         my ($v2w, $lei) = @$arg;
 644         $lei->child_error($?, "error for $v2w->{ibx}->{inboxdir}") if $?;
 645 }
 646
 647 sub _pre_augment_v2 {
 648         my ($self, $lei) = @_;
 649         my $dir = $self->{dst};
 650         require PublicInbox::InboxWritable;
 651         my ($ibx, @creat);
 652         if (-d $dir) {
 653                 my $opt = { -min_inbox_version => 2 };
 654                 require PublicInbox::Admin;
 655                 my @ibx = PublicInbox::Admin::resolve_inboxes([ $dir ], $opt);
 656                 $ibx = $ibx[0] or die "$dir is not a v2 inbox\n";
 657         } else {
 658                 $creat[0] = {};
 659                 $ibx = PublicInbox::Inbox->new({
 660                         name => 'lei-result', # XXX configurable
 661                         inboxdir => $dir,
 662                         version => 2,
 663                         address => [ 'lei@example.com' ],
 664                 });
 665         }
 666         PublicInbox::InboxWritable->new($ibx, @creat);
 667         $ibx->init_inbox if @creat;
 668         my $v2w = $ibx->importer;
 669         $v2w->wq_workers_start("lei/v2w $dir", 1, $lei->oldset, {lei => $lei});
 670         $v2w->wq_wait_async(\&v2w_done_wait, $lei);
 671         $lei->{v2w} = $v2w;
 672         return if !$lei->{opt}->{shared};
 673         my $d = "$lei->{ale}->{git}->{git_dir}/objects";
 674         my $al = "$dir/git/0.git/objects/info/alternates";
 675         open my $fh, '+>>', $al or die "open($al): $!";
 676         seek($fh, 0, SEEK_SET) or die "seek($al): $!";
 677         grep(/\A\Q$d\E\n/, <$fh>) and return;
 678         print $fh "$d\n" or die "print($al): $!";
 679         close $fh or die "close($al): $!";
 680 }
 681
 682 sub pre_augment { # fast (1 disk seek), runs in same process as post_augment
 683         my ($self, $lei) = @_;
 684         # _pre_augment_maildir, _pre_augment_mbox, _pre_augment_v2
 685         my $m = $self->can("_pre_augment_$self->{base_type}") or return;
 686         $m->($self, $lei);
 687 }
 688
 689 sub do_augment { # slow, runs in wq worker
 690         my ($self, $lei) = @_;
 691         # _do_augment_maildir, _do_augment_mbox, or _do_augment_imap
 692         my $m = $self->can("_do_augment_$self->{base_type}") or return;
 693         $m->($self, $lei);
 694 }
 695
 696 # fast (spawn compressor or mkdir), runs in same process as pre_augment
 697 sub post_augment {
 698         my ($self, $lei, @args) = @_;
 699         $self->{-au_noted}++ and $lei->qerr("# writing to $self->{dst} ...");
 700
 701         my $wait = $lei->{opt}->{'import-before'} ?
 702                         $lei->{sto}->wq_do('checkpoint', 1) : 0;
 703         # _post_augment_mbox
 704         my $m = $self->can("_post_augment_$self->{base_type}") or return;
 705         $m->($self, $lei, @args);
 706 }
 707
 708 # called by every single l2m worker process
 709 sub do_post_auth {
 710         my ($self) = @_;
 711         my $lei = $self->{lei};
 712         # lei_xsearch can start as soon as all l2m workers get here
 713         $lei->{pkt_op_p}->pkt_do('incr_start_query') or
 714                 die "incr_start_query: $!";
 715         my $aug;
 716         if (lock_free($self)) { # all workers do_augment
 717                 my $mod = $self->{-wq_nr_workers};
 718                 my $shard = $self->{-wq_worker_nr};
 719                 if (my $net = $lei->{net}) {
 720                         $net->{shard_info} = [ $mod, $shard ];
 721                 } else { # Maildir
 722                         $self->{shard_info} = [ $mod, $shard ];
 723                 }
 724                 $aug = 'incr_post_augment';
 725         } elsif ($self->{-wq_worker_nr} == 0) { # 1st worker do_augment
 726                 $aug = 'do_post_augment';
 727         }
 728         if ($aug) {
 729                 local $0 = 'do_augment';
 730                 eval { do_augment($self, $lei) };
 731                 $lei->fail($@) if $@;
 732                 $lei->{pkt_op_p}->pkt_do($aug) or die "pkt_do($aug): $!";
 733         }
 734         # done augmenting, connect the compressor pipe for each worker
 735         if (my $zpipe = delete $lei->{zpipe}) {
 736                 $lei->{1} = $zpipe->[1];
 737                 close $zpipe->[0];
 738         }
 739         my $au_peers = delete $self->{au_peers};
 740         if ($au_peers) { # wait for peer l2m to finish augmenting:
 741                 $au_peers->[1] = undef;
 742                 sysread($au_peers->[0], my $barrier1, 1);
 743         }
 744         $self->{wcb} = $self->write_cb($lei);
 745         if ($au_peers) { # wait for peer l2m to set write_cb
 746                 $au_peers->[3] = undef;
 747                 sysread($au_peers->[2], my $barrier2, 1);
 748         }
 749 }
 750
 751 sub ipc_atfork_child {
 752         my ($self) = @_;
 753         my $lei = $self->{lei};
 754         $lei->_lei_atfork_child;
 755         $lei->{auth}->do_auth_atfork($self) if $lei->{auth};
 756         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 757         $self->SUPER::ipc_atfork_child;
 758 }
 759
 760 sub lock_free {
 761         $_[0]->{base_type} =~ /\A(?:maildir|imap|jmap)\z/ ? 1 : 0;
 762 }
 763
 764 # wakes up the MUA when complete so it can refresh messages list
 765 sub poke_dst {
 766         my ($self) = @_;
 767         if ($self->{base_type} eq 'maildir') {
 768                 my $t = time + 1;
 769                 utime($t, $t, $self->{poke_dh}) or warn "futimes: $!";
 770         }
 771 }
 772
 773 sub write_mail { # via ->wq_io_do
 774         my ($self, $smsg, $eml) = @_;
 775         return $self->{wcb}->(undef, $smsg, $eml) if $eml;
 776         $smsg->{-lms_rw} = $self->{-lms_rw};
 777         $self->{lei}->{ale}->git->cat_async($smsg->{blob}, \&git_to_mail,
 778                                 [$self->{wcb}, $smsg]);
 779 }
 780
 781 sub wq_atexit_child {
 782         my ($self) = @_;
 783         local $PublicInbox::DS::in_loop = 0; # waitpid synchronously
 784         my $lei = $self->{lei};
 785         delete $self->{wcb};
 786         $lei->{ale}->git->async_wait_all;
 787         my $nr = delete($lei->{-nr_write}) or return;
 788         return if $lei->{early_mua} || !$lei->{-progress} || !$lei->{pkt_op_p};
 789         $lei->{pkt_op_p}->pkt_do('l2m_progress', $nr);
 790 }
 791
 792 # runs on a 1s timer in lei-daemon
 793 sub augment_inprogress {
 794         my ($err, $opt, $dst, $au_noted) = @_;
 795         eval {
 796                 return if $$au_noted++ || !$err || !defined(fileno($err));
 797                 print $err '# '.($opt->{'import-before'} ?
 798                                 "importing non-external contents of $dst" : (
 799                                 ($opt->{dedupe} // 'content') ne 'none') ?
 800                                 "scanning old contents of $dst for dedupe" :
 801                                 "removing old contents of $dst")." ...\n";
 802         };
 803         warn "E: $@ ($dst)" if $@;
 804 }
 805
 806 # called in top-level lei-daemon when LeiAuth is done
 807 sub net_merge_all_done {
 808         my ($self, $lei) = @_;
 809         if ($PublicInbox::DS::in_loop &&
 810                         $self->can("_do_augment_$self->{base_type}") &&
 811                         !$lei->{opt}->{quiet}) {
 812                 $self->{-au_noted} = 0;
 813                 PublicInbox::DS::add_timer(1, \&augment_inprogress,
 814                                 $lei->{2}, $lei->{opt},
 815                                 $self->{dst}, \$self->{-au_noted});
 816         }
 817         $self->wq_broadcast('do_post_auth');
 818         $self->wq_close;
 819 }
 820
 821 1;