lib/PublicInbox/LeiToMail.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Writes PublicInbox::Eml objects atomically to a mbox variant or Maildir
   5 package PublicInbox::LeiToMail;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Lock;
  11 use PublicInbox::ProcessPipe;
  12 use PublicInbox::Spawn qw(which spawn popen_rd);
  13 use PublicInbox::LeiDedupe;
  14 use PublicInbox::Git;
  15 use PublicInbox::GitAsyncCat;
  16 use PublicInbox::PktOp qw(pkt_do);
  17 use Symbol qw(gensym);
  18 use IO::Handle; # ->autoflush
  19 use Fcntl qw(SEEK_SET SEEK_END O_CREAT O_EXCL O_WRONLY);
  20 use Errno qw(EEXIST ESPIPE ENOENT EPIPE);
  21 use Digest::SHA qw(sha256_hex);
  22
  23 # struggles with short-lived repos, Gcf2Client makes little sense with lei;
  24 # but we may use in-process libgit2 in the future.
  25 $PublicInbox::GitAsyncCat::GCF2C = 0;
  26
  27 my %kw2char = ( # Maildir characters
  28         draft => 'D',
  29         flagged => 'F',
  30         answered => 'R',
  31         seen => 'S'
  32 );
  33
  34 my %kw2status = (
  35         flagged => [ 'X-Status' => 'F' ],
  36         answered => [ 'X-Status' => 'A' ],
  37         seen => [ 'Status' => 'R' ],
  38         draft => [ 'X-Status' => 'T' ],
  39 );
  40
  41 sub _mbox_hdr_buf ($$$) {
  42         my ($eml, $type, $smsg) = @_;
  43         $eml->header_set($_) for (qw(Lines Bytes Content-Length));
  44
  45         # Messages are always 'O' (non-\Recent in IMAP), it saves
  46         # MUAs the trouble of rewriting the mbox if no other
  47         # changes are made
  48         my %hdr = (Status => [ 'O' ]); # set Status, X-Status
  49         for my $k (@{$smsg->{kw} // []}) {
  50                 if (my $ent = $kw2status{$k}) {
  51                         push @{$hdr{$ent->[0]}}, $ent->[1];
  52                 } else { # X-Label?
  53                         warn "TODO: keyword `$k' not supported for mbox\n";
  54                 }
  55         }
  56         while (my ($name, $chars) = each %hdr) {
  57                 $eml->header_set($name, join('', sort @$chars));
  58         }
  59         my $buf = delete $eml->{hdr};
  60
  61         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
  62         $$buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  63         my $ident = $smsg->{blob} // 'lei';
  64         if (defined(my $pct = $smsg->{pct})) { $ident .= "=$pct" }
  65
  66         substr($$buf, 0, 0, # prepend From line
  67                 "From $ident\@$type Thu Jan  1 00:00:00 1970$eml->{crlf}");
  68         $buf;
  69 }
  70
  71 sub atomic_append { # for on-disk destinations (O_APPEND, or O_EXCL)
  72         my ($lei, $buf) = @_;
  73         if (defined(my $w = syswrite($lei->{1} // return, $$buf))) {
  74                 return if $w == length($$buf);
  75                 $buf = "short atomic write: $w != ".length($$buf);
  76         } elsif ($! == EPIPE) {
  77                 return $lei->note_sigpipe(1);
  78         } else {
  79                 $buf = "atomic write: $!";
  80         }
  81         $lei->fail($buf);
  82 }
  83
  84 sub eml2mboxrd ($;$) {
  85         my ($eml, $smsg) = @_;
  86         my $buf = _mbox_hdr_buf($eml, 'mboxrd', $smsg);
  87         if (my $bdy = delete $eml->{bdy}) {
  88                 $$bdy =~ s/^(>*From )/>$1/gm;
  89                 $$buf .= $eml->{crlf};
  90                 substr($$bdy, 0, 0, $$buf); # prepend header
  91                 $buf = $bdy;
  92         }
  93         $$buf .= $eml->{crlf};
  94         $buf;
  95 }
  96
  97 sub eml2mboxo {
  98         my ($eml, $smsg) = @_;
  99         my $buf = _mbox_hdr_buf($eml, 'mboxo', $smsg);
 100         if (my $bdy = delete $eml->{bdy}) {
 101                 $$bdy =~ s/^From />From /gm;
 102                 $$buf .= $eml->{crlf};
 103                 substr($$bdy, 0, 0, $$buf); # prepend header
 104                 $buf = $bdy;
 105         }
 106         $$buf .= $eml->{crlf};
 107         $buf;
 108 }
 109
 110 sub _mboxcl_common ($$$) {
 111         my ($buf, $bdy, $crlf) = @_;
 112         # add Lines: so mutt won't have to add it on MUA close
 113         my $lines = $$bdy =~ tr!\n!\n!;
 114         $$buf .= 'Content-Length: '.length($$bdy).$crlf.
 115                 'Lines: '.$lines.$crlf.$crlf;
 116         substr($$bdy, 0, 0, $$buf); # prepend header
 117         $_[0] = $bdy;
 118 }
 119
 120 # mboxcl still escapes "From " lines
 121 sub eml2mboxcl {
 122         my ($eml, $smsg) = @_;
 123         my $buf = _mbox_hdr_buf($eml, 'mboxcl', $smsg);
 124         my $crlf = $eml->{crlf};
 125         if (my $bdy = delete $eml->{bdy}) {
 126                 $$bdy =~ s/^From />From /gm;
 127                 _mboxcl_common($buf, $bdy, $crlf);
 128         }
 129         $$buf .= $crlf;
 130         $buf;
 131 }
 132
 133 # mboxcl2 has no "From " escaping
 134 sub eml2mboxcl2 {
 135         my ($eml, $smsg) = @_;
 136         my $buf = _mbox_hdr_buf($eml, 'mboxcl2', $smsg);
 137         my $crlf = $eml->{crlf};
 138         if (my $bdy = delete $eml->{bdy}) {
 139                 _mboxcl_common($buf, $bdy, $crlf);
 140         }
 141         $$buf .= $crlf;
 142         $buf;
 143 }
 144
 145 sub git_to_mail { # git->cat_async callback
 146         my ($bref, $oid, $type, $size, $arg) = @_;
 147         if ($type ne 'blob') {
 148                 if ($type eq 'missing') {
 149                         warn "missing $oid\n";
 150                 } else {
 151                         warn "unexpected type=$type for $oid\n";
 152                 }
 153         }
 154         my ($write_cb, $smsg) = @$arg;
 155         if ($smsg->{blob} ne $oid) {
 156                 die "BUG: expected=$smsg->{blob} got=$oid";
 157         }
 158         $write_cb->($bref, $smsg) if $size > 0;
 159 }
 160
 161 sub reap_compress { # dwaitpid callback
 162         my ($lei, $pid) = @_;
 163         my $cmd = delete $lei->{"pid.$pid"};
 164         return if $? == 0;
 165         $lei->fail("@$cmd failed", $? >> 8);
 166 }
 167
 168 # all of these support -c for stdout and -d for decompression,
 169 # mutt is commonly distributed with hooks for gz, bz2 and xz, at least
 170 # { foo => '' } means "--foo" is passed to the command-line,
 171 # otherwise { foo => '--bar' } passes "--bar"
 172 our %zsfx2cmd = (
 173         gz => [ qw(GZIP pigz gzip), { rsyncable => '', threads => '-p' } ],
 174         bz2 => [ 'bzip2', {} ],
 175         xz => [ 'xz', { threads => '-T' } ],
 176         # XXX does anybody care for these?  I prefer zstd on entire FSes,
 177         # so it's probably not necessary on a per-file basis
 178         # zst => [ 'zstd', { -default => [ qw(-q) ], # it's noisy by default
 179         #       rsyncable => '', threads => '-T' } ],
 180         # zz => [ 'pigz', { -default => [ '--zlib' ],
 181         #       rsyncable => '', threads => '-p' }],
 182         # lzo => [ 'lzop', {} ],
 183         # lzma => [ 'lzma', {} ],
 184 );
 185
 186 sub zsfx2cmd ($$$) {
 187         my ($zsfx, $decompress, $lei) = @_;
 188         my $x = $zsfx2cmd{$zsfx} // die "no support for suffix=.$zsfx";
 189         my @info = @$x;
 190         my $cmd_opt = pop @info;
 191         my @cmd = (undef, $decompress ? qw(-dc) : qw(-c));
 192         for my $exe (@info) {
 193                 # I think respecting client's ENV{GZIP} is OK, not sure
 194                 # about ENV overrides for other, less-common compressors
 195                 if ($exe eq uc($exe)) {
 196                         $exe = $lei->{env}->{$exe} or next;
 197                 }
 198                 $cmd[0] = which($exe) and last;
 199         }
 200         $cmd[0] // die join(' or ', @info)." missing for .$zsfx";
 201         # push @cmd, @{$cmd_opt->{-default}} if $cmd_opt->{-default};
 202         for my $bool (qw(rsyncable)) {
 203                 my $switch = $cmd_opt->{rsyncable} // next;
 204                 push @cmd, '--'.($switch || $bool);
 205         }
 206         for my $key (qw(threads)) { # support compression level?
 207                 my $switch = $cmd_opt->{$key} // next;
 208                 my $val = $lei->{opt}->{$key} // next;
 209                 push @cmd, $switch, $val;
 210         }
 211         \@cmd;
 212 }
 213
 214 sub _post_augment_mbox { # open a compressor process
 215         my ($self, $lei) = @_;
 216         my $zsfx = $self->{zsfx} or return;
 217         my $cmd = zsfx2cmd($zsfx, undef, $lei);
 218         my ($r, $w) = @{delete $lei->{zpipe}};
 219         my $rdr = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 220         my $pid = spawn($cmd, undef, $rdr);
 221         my $pp = gensym;
 222         my $dup = bless { "pid.$pid" => $cmd }, ref($lei);
 223         $dup->{$_} = $lei->{$_} for qw(2 sock);
 224         tie *$pp, 'PublicInbox::ProcessPipe', $pid, $w, \&reap_compress, $dup;
 225         $lei->{1} = $pp;
 226         die 'BUG: unexpected {ovv}->{lock_path}' if $lei->{ovv}->{lock_path};
 227         $lei->{ovv}->ovv_out_lk_init;
 228 }
 229
 230 sub decompress_src ($$$) {
 231         my ($in, $zsfx, $lei) = @_;
 232         my $cmd = zsfx2cmd($zsfx, 1, $lei);
 233         popen_rd($cmd, undef, { 0 => $in, 2 => $lei->{2} });
 234 }
 235
 236 sub dup_src ($) {
 237         my ($in) = @_;
 238         open my $dup, '+>>&', $in or die "dup: $!";
 239         $dup;
 240 }
 241
 242 # --augment existing output destination, with deduplication
 243 sub _augment { # MboxReader eml_cb
 244         my ($eml, $lei) = @_;
 245         # ignore return value, just populate the skv
 246         $lei->{dedupe}->is_dup($eml);
 247 }
 248
 249 sub _mbox_write_cb ($$) {
 250         my ($self, $lei) = @_;
 251         my $ovv = $lei->{ovv};
 252         my $m = 'eml2'.$ovv->{fmt};
 253         my $eml2mbox = $self->can($m) or die "$self->$m missing";
 254         $lei->{1} // die "no stdout ($m, $ovv->{dst})"; # redirected earlier
 255         $lei->{1}->autoflush(1);
 256         my $atomic_append = !defined($ovv->{lock_path});
 257         my $dedupe = $lei->{dedupe};
 258         $dedupe->prepare_dedupe;
 259         sub { # for git_to_mail
 260                 my ($buf, $smsg, $eml) = @_;
 261                 $eml //= PublicInbox::Eml->new($buf);
 262                 return if $dedupe->is_dup($eml, $smsg->{blob});
 263                 $buf = $eml2mbox->($eml, $smsg);
 264                 return atomic_append($lei, $buf) if $atomic_append;
 265                 my $lk = $ovv->lock_for_scope;
 266                 $lei->out($$buf);
 267         }
 268 }
 269
 270 sub update_kw_maybe ($$$$) {
 271         my ($lei, $lse, $eml, $kw) = @_;
 272         return unless $lse;
 273         my $x = $lse->kw_changed($eml, $kw);
 274         if ($x) {
 275                 $lei->{sto}->ipc_do('set_eml', $eml, @$kw);
 276         } elsif (!defined($x)) {
 277                 # TODO: xkw
 278         }
 279 }
 280
 281 sub _augment_or_unlink { # maildir_each_eml cb
 282         my ($f, $kw, $eml, $lei, $lse, $mod, $shard, $unlink) = @_;
 283         if ($mod) {
 284                 # can't get dirent.d_ino w/ pure Perl, so we extract the OID
 285                 # if it looks like one:
 286                 my $hex = $f =~ m!\b([a-f0-9]{40,})[^/]*\z! ?
 287                                 $1 : sha256_hex($f);
 288                 my $recno = hex(substr($hex, 0, 8));
 289                 return if ($recno % $mod) != $shard;
 290                 update_kw_maybe($lei, $lse, $eml, $kw);
 291         }
 292         $unlink ? unlink($f) : _augment($eml, $lei);
 293 }
 294
 295 # maildir_each_file callback, \&CORE::unlink doesn't work with it
 296 sub _unlink { unlink($_[0]) }
 297
 298 sub _rand () {
 299         state $seq = 0;
 300         sprintf('%x,%x,%x,%x', rand(0xffffffff), time, $$, ++$seq);
 301 }
 302
 303 sub _buf2maildir {
 304         my ($dst, $buf, $smsg) = @_;
 305         my $kw = $smsg->{kw} // [];
 306         my $sfx = join('', sort(map { $kw2char{$_} // () } @$kw));
 307         my $rand = ''; # chosen by die roll :P
 308         my ($tmp, $fh, $final, $ok);
 309         my $common = $smsg->{blob} // _rand;
 310         if (defined(my $pct = $smsg->{pct})) { $common .= "=$pct" }
 311         do {
 312                 $tmp = $dst.'tmp/'.$rand.$common;
 313         } while (!($ok = sysopen($fh, $tmp, O_CREAT|O_EXCL|O_WRONLY)) &&
 314                 $! == EEXIST && ($rand = _rand.','));
 315         if ($ok && print $fh $$buf and close($fh)) {
 316                 # ignore new/ and write only to cur/, otherwise MUAs
 317                 # with R/W access to the Maildir will end up doing
 318                 # a mass rename which can take a while with thousands
 319                 # of messages.
 320                 $dst .= 'cur/';
 321                 $rand = '';
 322                 do {
 323                         $final = $dst.$rand.$common.':2,'.$sfx;
 324                 } while (!($ok = link($tmp, $final)) && $! == EEXIST &&
 325                         ($rand = _rand.','));
 326                 die "link($tmp, $final): $!" unless $ok;
 327                 unlink($tmp) or warn "W: failed to unlink $tmp: $!\n";
 328         } else {
 329                 my $err = "Error writing $smsg->{blob} to $dst: $!\n";
 330                 $_[0] = undef; # clobber dst
 331                 unlink($tmp);
 332                 die $err;
 333         }
 334 }
 335
 336 sub _maildir_write_cb ($$) {
 337         my ($self, $lei) = @_;
 338         my $dedupe = $lei->{dedupe};
 339         $dedupe->prepare_dedupe if $dedupe;
 340         my $dst = $lei->{ovv}->{dst};
 341         sub { # for git_to_mail
 342                 my ($buf, $smsg, $eml) = @_;
 343                 $dst // return $lei->fail; # dst may be undef-ed in last run
 344                 $buf //= \($eml->as_string);
 345                 return _buf2maildir($dst, $buf, $smsg) if !$dedupe;
 346                 $eml //= PublicInbox::Eml->new($$buf); # copy buf
 347                 return if $dedupe->is_dup($eml, $smsg->{blob});
 348                 undef $eml;
 349                 _buf2maildir($dst, $buf, $smsg);
 350         }
 351 }
 352
 353 sub _imap_write_cb ($$) {
 354         my ($self, $lei) = @_;
 355         my $dedupe = $lei->{dedupe};
 356         $dedupe->prepare_dedupe if $dedupe;
 357         my $imap_append = $lei->{net}->can('imap_append');
 358         my $mic = $lei->{net}->mic_get($self->{uri});
 359         my $folder = $self->{uri}->mailbox;
 360         sub { # for git_to_mail
 361                 my ($bref, $smsg, $eml) = @_;
 362                 $mic // return $lei->fail; # dst may be undef-ed in last run
 363                 if ($dedupe) {
 364                         $eml //= PublicInbox::Eml->new($$bref); # copy bref
 365                         return if $dedupe->is_dup($eml, $smsg->{blob});
 366                 }
 367                 eval { $imap_append->($mic, $folder, $bref, $smsg, $eml) };
 368                 if (my $err = $@) {
 369                         undef $mic;
 370                         die $err;
 371                 }
 372         }
 373 }
 374
 375 sub write_cb { # returns a callback for git_to_mail
 376         my ($self, $lei) = @_;
 377         # _mbox_write_cb, _maildir_write_cb or _imap_write_cb
 378         my $m = "_$self->{base_type}_write_cb";
 379         $self->$m($lei);
 380 }
 381
 382 sub new {
 383         my ($cls, $lei) = @_;
 384         my $fmt = $lei->{ovv}->{fmt};
 385         my $dst = $lei->{ovv}->{dst};
 386         my $self = bless {}, $cls;
 387         if ($fmt eq 'maildir') {
 388                 require PublicInbox::MdirReader;
 389                 $self->{base_type} = 'maildir';
 390                 -e $dst && !-d _ and die
 391                                 "$dst exists and is not a directory\n";
 392                 $lei->{ovv}->{dst} = $dst .= '/' if substr($dst, -1) ne '/';
 393         } elsif (substr($fmt, 0, 4) eq 'mbox') {
 394                 require PublicInbox::MboxReader if $lei->{opt}->{augment};
 395                 (-d $dst || (-e _ && !-w _)) and die
 396                         "$dst exists and is not a writable file\n";
 397                 $self->can("eml2$fmt") or die "bad mbox format: $fmt\n";
 398                 $self->{base_type} = 'mbox';
 399         } elsif ($fmt =~ /\Aimaps?\z/) { # TODO .onion support
 400                 require PublicInbox::NetWriter;
 401                 my $net = PublicInbox::NetWriter->new;
 402                 $net->add_url($dst);
 403                 $net->{quiet} = $lei->{opt}->{quiet};
 404                 my $err = $net->errors($dst);
 405                 return $lei->fail($err) if $err;
 406                 require PublicInbox::URIimap; # TODO: URI cast early
 407                 $self->{uri} = PublicInbox::URIimap->new($dst);
 408                 $self->{uri}->mailbox or die "No mailbox: $dst";
 409                 $lei->{net} = $net;
 410                 $self->{base_type} = 'imap';
 411         } else {
 412                 die "bad mail --format=$fmt\n";
 413         }
 414         $self->{dst} = $dst;
 415         $lei->{dedupe} = PublicInbox::LeiDedupe->new($lei);
 416         $self;
 417 }
 418
 419 sub _pre_augment_maildir {
 420         my ($self, $lei) = @_;
 421         my $dst = $lei->{ovv}->{dst};
 422         for my $x (qw(tmp new cur)) {
 423                 my $d = $dst.$x;
 424                 next if -d $d;
 425                 require File::Path;
 426                 File::Path::mkpath($d);
 427                 -d $d or die "$d is not a directory";
 428         }
 429 }
 430
 431 sub _do_augment_maildir {
 432         my ($self, $lei) = @_;
 433         my $dst = $lei->{ovv}->{dst};
 434         my $lse = $lei->{sto}->search if $lei->{opt}->{'import-augment'};
 435         my ($mod, $shard) = @{$self->{shard_info} // []};
 436         if ($lei->{opt}->{augment}) {
 437                 my $dedupe = $lei->{dedupe};
 438                 if ($dedupe && $dedupe->prepare_dedupe) {
 439                         PublicInbox::MdirReader::maildir_each_eml($dst,
 440                                                 \&_augment_or_unlink,
 441                                                 $lei, $lse, $mod, $shard);
 442                         $dedupe->pause_dedupe;
 443                 }
 444         } elsif ($lse) {
 445                 PublicInbox::MdirReader::maildir_each_eml($dst,
 446                                         \&_augment_or_unlink,
 447                                         $lei, $lse, $mod, $shard, 1);
 448         } else {# clobber existing Maildir
 449                 PublicInbox::MdirReader::maildir_each_file($dst, \&_unlink);
 450         }
 451 }
 452
 453 sub _imap_augment_or_delete { # PublicInbox::NetReader::imap_each cb
 454         my ($url, $uid, $kw, $eml, $lei, $lse, $delete_mic) = @_;
 455         update_kw_maybe($lei, $lse, $eml, $kw);
 456         if ($delete_mic) {
 457                 $lei->{net}->imap_delete_1($url, $uid, $delete_mic);
 458         } else {
 459                 _augment($eml, $lei);
 460         }
 461 }
 462
 463 sub _do_augment_imap {
 464         my ($self, $lei) = @_;
 465         my $net = $lei->{net};
 466         my $lse = $lei->{sto}->search if $lei->{opt}->{'import-augment'};
 467         if ($lei->{opt}->{augment}) {
 468                 my $dedupe = $lei->{dedupe};
 469                 if ($dedupe && $dedupe->prepare_dedupe) {
 470                         $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 471                                         $lei, $lse);
 472                         $dedupe->pause_dedupe;
 473                 }
 474         } elsif ($lse) {
 475                 my $delete_mic;
 476                 $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 477                                         $lei, $lse, \$delete_mic);
 478                 $delete_mic->expunge if $delete_mic;
 479         } elsif (!$self->{-wq_worker_nr}) { # undef or 0
 480                 # clobber existing IMAP folder
 481                 $net->imap_delete_all($self->{uri});
 482         }
 483 }
 484
 485 sub _pre_augment_mbox {
 486         my ($self, $lei) = @_;
 487         my $dst = $lei->{ovv}->{dst};
 488         if ($dst ne '/dev/stdout') {
 489                 my $out;
 490                 if (-p $dst) {
 491                         open $out, '>', $dst or die "open($dst): $!";
 492                 } elsif (-f _ || !-e _) {
 493                         require PublicInbox::MboxLock;
 494                         my $m = $lei->{opt}->{'lock'} //
 495                                         PublicInbox::MboxLock->defaults;
 496                         $self->{mbl} = PublicInbox::MboxLock->acq($dst, 1, $m);
 497                         $out = $self->{mbl}->{fh};
 498                         if (!$lei->{opt}->{augment} and !truncate($out, 0)) {
 499                                 die "truncate($dst): $!";
 500                         }
 501                 }
 502                 $lei->{old_1} = $lei->{1}; # keep for spawning MUA
 503                 $lei->{1} = $out;
 504         }
 505         # Perl does SEEK_END even with O_APPEND :<
 506         $self->{seekable} = seek($lei->{1}, 0, SEEK_SET);
 507         if (!$self->{seekable} && $! != ESPIPE && $dst ne '/dev/stdout') {
 508                 die "seek($dst): $!\n";
 509         }
 510         state $zsfx_allow = join('|', keys %zsfx2cmd);
 511         ($self->{zsfx}) = ($dst =~ /\.($zsfx_allow)\z/) or return;
 512         pipe(my ($r, $w)) or die "pipe: $!";
 513         $lei->{zpipe} = [ $r, $w ];
 514 }
 515
 516 sub _do_augment_mbox {
 517         my ($self, $lei) = @_;
 518         return if !$lei->{opt}->{augment};
 519         my $dedupe = $lei->{dedupe};
 520         my $dst = $lei->{ovv}->{dst};
 521         die "cannot augment $dst, not seekable\n" if !$self->{seekable};
 522         my $out = $lei->{1};
 523         if (-s $out && $dedupe && $dedupe->prepare_dedupe) {
 524                 my $zsfx = $self->{zsfx};
 525                 my $rd = $zsfx ? decompress_src($out, $zsfx, $lei) :
 526                                 dup_src($out);
 527                 my $fmt = $lei->{ovv}->{fmt};
 528                 PublicInbox::MboxReader->$fmt($rd, \&_augment, $lei);
 529         }
 530         # maybe some systems don't honor O_APPEND, Perl does this:
 531         seek($out, 0, SEEK_END) or die "seek $dst: $!";
 532         $dedupe->pause_dedupe if $dedupe;
 533 }
 534
 535 sub pre_augment { # fast (1 disk seek), runs in same process as post_augment
 536         my ($self, $lei) = @_;
 537         # _pre_augment_maildir, _pre_augment_mbox
 538         my $m = $self->can("_pre_augment_$self->{base_type}") or return;
 539         $m->($self, $lei);
 540 }
 541
 542 sub do_augment { # slow, runs in wq worker
 543         my ($self, $lei) = @_;
 544         # _do_augment_maildir, _do_augment_mbox, or _do_augment_imap
 545         my $m = "_do_augment_$self->{base_type}";
 546         $self->$m($lei);
 547 }
 548
 549 # fast (spawn compressor or mkdir), runs in same process as pre_augment
 550 sub post_augment {
 551         my ($self, $lei, @args) = @_;
 552         my $wait = $lei->{opt}->{'import-augment'} ?
 553                         $lei->{sto}->ipc_do('checkpoint', 1) : 0;
 554         # _post_augment_mbox
 555         my $m = $self->can("_post_augment_$self->{base_type}") or return;
 556         $m->($self, $lei, @args);
 557 }
 558
 559 sub do_post_auth {
 560         my ($self) = @_;
 561         my $lei = $self->{lei};
 562         # lei_xsearch can start as soon as all l2m workers get here
 563         pkt_do($lei->{pkt_op_p}, 'incr_start_query') or
 564                 die "incr_start_query: $!";
 565         my $aug;
 566         if (lock_free($self)) {
 567                 my $mod = $self->{-wq_nr_workers};
 568                 my $shard = $self->{-wq_worker_nr};
 569                 if (my $net = $lei->{net}) {
 570                         $net->{shard_info} = [ $mod, $shard ];
 571                 } else { # Maildir (MH?)
 572                         $self->{shard_info} = [ $mod, $shard ];
 573                 }
 574                 $aug = '+'; # incr_post_augment
 575         } elsif ($self->{-wq_worker_nr} == 0) {
 576                 $aug = '.'; # do_post_augment
 577         }
 578         if ($aug) {
 579                 local $0 = 'do_augment';
 580                 eval { do_augment($self, $lei) };
 581                 $lei->fail($@) if $@;
 582                 pkt_do($lei->{pkt_op_p}, $aug) == 1 or
 583                                 die "do_post_augment trigger: $!";
 584         }
 585         if (my $zpipe = delete $lei->{zpipe}) {
 586                 $lei->{1} = $zpipe->[1];
 587                 close $zpipe->[0];
 588         }
 589         $self->{wcb} = $self->write_cb($lei);
 590 }
 591
 592 sub ipc_atfork_child {
 593         my ($self) = @_;
 594         my $lei = $self->{lei};
 595         $lei->lei_atfork_child;
 596         $lei->{auth}->do_auth_atfork($self) if $lei->{auth};
 597         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 598         $self->SUPER::ipc_atfork_child;
 599 }
 600
 601 sub lock_free {
 602         $_[0]->{base_type} =~ /\A(?:maildir|mh|imap|jmap)\z/ ? 1 : 0;
 603 }
 604
 605 sub poke_dst {
 606         my ($self) = @_;
 607         if ($self->{base_type} eq 'maildir') {
 608                 my $t = time + 1;
 609                 utime($t, $t, "$self->{dst}/cur");
 610         }
 611 }
 612
 613 sub write_mail { # via ->wq_io_do
 614         my ($self, $git_dir, $smsg) = @_;
 615         my $git = $self->{"$$\0$git_dir"} //= PublicInbox::Git->new($git_dir);
 616         git_async_cat($git, $smsg->{blob}, \&git_to_mail,
 617                                 [$self->{wcb}, $smsg]);
 618 }
 619
 620 sub wq_atexit_child {
 621         my ($self) = @_;
 622         delete $self->{wcb};
 623         for my $git (delete @$self{grep(/\A$$\0/, keys %$self)}) {
 624                 $git->async_wait_all;
 625         }
 626         $SIG{__WARN__} = 'DEFAULT';
 627 }
 628
 629 # called in top-level lei-daemon when LeiAuth is done
 630 sub net_merge_complete {
 631         my ($self) = @_;
 632         $self->wq_broadcast('do_post_auth');
 633         $self->wq_close(1);
 634 }
 635
 636 no warnings 'once'; # the following works even when LeiAuth is lazy-loaded
 637 *net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
 638 1;