lib/PublicInbox/LeiToMail.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Writes PublicInbox::Eml objects atomically to a mbox variant or Maildir
   5 package PublicInbox::LeiToMail;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::ProcessPipe;
  11 use PublicInbox::Spawn qw(spawn);
  12 use PublicInbox::PktOp qw(pkt_do);
  13 use Symbol qw(gensym);
  14 use IO::Handle; # ->autoflush
  15 use Fcntl qw(SEEK_SET SEEK_END O_CREAT O_EXCL O_WRONLY);
  16
  17 my %kw2char = ( # Maildir characters
  18         draft => 'D',
  19         flagged => 'F',
  20         forwarded => 'P', # passed
  21         answered => 'R',
  22         seen => 'S',
  23 );
  24
  25 my %kw2status = (
  26         flagged => [ 'X-Status' => 'F' ],
  27         answered => [ 'X-Status' => 'A' ],
  28         seen => [ 'Status' => 'R' ],
  29         draft => [ 'X-Status' => 'T' ],
  30 );
  31
  32 sub _mbox_hdr_buf ($$$) {
  33         my ($eml, $type, $smsg) = @_;
  34         $eml->header_set($_) for (qw(Lines Bytes Content-Length));
  35
  36         my %hdr = (Status => []); # set Status, X-Status
  37         for my $k (@{$smsg->{kw} // []}) {
  38                 if (my $ent = $kw2status{$k}) {
  39                         push @{$hdr{$ent->[0]}}, $ent->[1];
  40                 } else { # X-Label?
  41                         warn "TODO: keyword `$k' not supported for mbox\n";
  42                 }
  43         }
  44         # Messages are always 'O' (non-\Recent in IMAP), it saves
  45         # MUAs the trouble of rewriting the mbox if no other
  46         # changes are made.  We put 'O' at the end (e.g. "Status: RO")
  47         # to match mutt(1) output.
  48         $eml->header_set('Status', join('', sort(@{$hdr{Status}})). 'O');
  49         if (my $chars = delete $hdr{'X-Status'}) {
  50                 $eml->header_set('X-Status', join('', sort(@$chars)));
  51         }
  52         my $buf = delete $eml->{hdr};
  53
  54         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
  55         $$buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  56         my $ident = $smsg->{blob} // 'lei';
  57         if (defined(my $pct = $smsg->{pct})) { $ident .= "=$pct" }
  58
  59         substr($$buf, 0, 0, # prepend From line
  60                 "From $ident\@$type Thu Jan  1 00:00:00 1970$eml->{crlf}");
  61         $buf;
  62 }
  63
  64 sub atomic_append { # for on-disk destinations (O_APPEND, or O_EXCL)
  65         my ($lei, $buf) = @_;
  66         if (defined(my $w = syswrite($lei->{1} // return, $$buf))) {
  67                 return if $w == length($$buf);
  68                 $buf = "short atomic write: $w != ".length($$buf);
  69         } elsif ($!{EPIPE}) {
  70                 return $lei->note_sigpipe(1);
  71         } else {
  72                 $buf = "atomic write: $!";
  73         }
  74         $lei->fail($buf);
  75 }
  76
  77 sub eml2mboxrd ($;$) {
  78         my ($eml, $smsg) = @_;
  79         my $buf = _mbox_hdr_buf($eml, 'mboxrd', $smsg);
  80         if (my $bdy = delete $eml->{bdy}) {
  81                 $$bdy =~ s/^(>*From )/>$1/gm;
  82                 $$buf .= $eml->{crlf};
  83                 substr($$bdy, 0, 0, $$buf); # prepend header
  84                 $buf = $bdy;
  85         }
  86         $$buf .= $eml->{crlf};
  87         $buf;
  88 }
  89
  90 sub eml2mboxo {
  91         my ($eml, $smsg) = @_;
  92         my $buf = _mbox_hdr_buf($eml, 'mboxo', $smsg);
  93         if (my $bdy = delete $eml->{bdy}) {
  94                 $$bdy =~ s/^From />From /gm;
  95                 $$buf .= $eml->{crlf};
  96                 substr($$bdy, 0, 0, $$buf); # prepend header
  97                 $buf = $bdy;
  98         }
  99         $$buf .= $eml->{crlf};
 100         $buf;
 101 }
 102
 103 sub _mboxcl_common ($$$) {
 104         my ($buf, $bdy, $crlf) = @_;
 105         # add Lines: so mutt won't have to add it on MUA close
 106         my $lines = $$bdy =~ tr!\n!\n!;
 107         $$buf .= 'Content-Length: '.length($$bdy).$crlf.
 108                 'Lines: '.$lines.$crlf.$crlf;
 109         substr($$bdy, 0, 0, $$buf); # prepend header
 110         $_[0] = $bdy;
 111 }
 112
 113 # mboxcl still escapes "From " lines
 114 sub eml2mboxcl {
 115         my ($eml, $smsg) = @_;
 116         my $buf = _mbox_hdr_buf($eml, 'mboxcl', $smsg);
 117         my $crlf = $eml->{crlf};
 118         if (my $bdy = delete $eml->{bdy}) {
 119                 $$bdy =~ s/^From />From /gm;
 120                 _mboxcl_common($buf, $bdy, $crlf);
 121         }
 122         $$buf .= $crlf;
 123         $buf;
 124 }
 125
 126 # mboxcl2 has no "From " escaping
 127 sub eml2mboxcl2 {
 128         my ($eml, $smsg) = @_;
 129         my $buf = _mbox_hdr_buf($eml, 'mboxcl2', $smsg);
 130         my $crlf = $eml->{crlf};
 131         if (my $bdy = delete $eml->{bdy}) {
 132                 _mboxcl_common($buf, $bdy, $crlf);
 133         }
 134         $$buf .= $crlf;
 135         $buf;
 136 }
 137
 138 sub git_to_mail { # git->cat_async callback
 139         my ($bref, $oid, $type, $size, $arg) = @_;
 140         return warn("W: $oid is $type (!= blob)\n") if $type ne 'blob';
 141         return warn("E: $oid is empty\n") unless $size;
 142         my ($write_cb, $smsg) = @$arg;
 143         die "BUG: expected=$smsg->{blob} got=$oid" if $smsg->{blob} ne $oid;
 144         $write_cb->($bref, $smsg);
 145 }
 146
 147 sub reap_compress { # dwaitpid callback
 148         my ($lei, $pid) = @_;
 149         my $cmd = delete $lei->{"pid.$pid"};
 150         return if $? == 0;
 151         $lei->fail("@$cmd failed", $? >> 8);
 152 }
 153
 154 sub _post_augment_mbox { # open a compressor process from top-level process
 155         my ($self, $lei) = @_;
 156         my $zsfx = $self->{zsfx} or return;
 157         my $cmd = PublicInbox::MboxReader::zsfx2cmd($zsfx, undef, $lei);
 158         my ($r, $w) = @{delete $lei->{zpipe}};
 159         my $rdr = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 160         my $pid = spawn($cmd, undef, $rdr);
 161         my $pp = gensym;
 162         my $dup = bless { "pid.$pid" => $cmd }, ref($lei);
 163         $dup->{$_} = $lei->{$_} for qw(2 sock);
 164         tie *$pp, 'PublicInbox::ProcessPipe', $pid, $w, \&reap_compress, $dup;
 165         $lei->{1} = $pp;
 166 }
 167
 168 # --augment existing output destination, with deduplication
 169 sub _augment { # MboxReader eml_cb
 170         my ($eml, $lei) = @_;
 171         # ignore return value, just populate the skv
 172         $lei->{dedupe}->is_dup($eml);
 173 }
 174
 175 sub _mbox_augment_kw_maybe {
 176         my ($eml, $lei, $lse, $augment) = @_;
 177         my $kw = PublicInbox::MboxReader::mbox_keywords($eml);
 178         update_kw_maybe($lei, $lse, $eml, $kw);
 179         _augment($eml, $lei) if $augment;
 180 }
 181
 182 sub _mbox_write_cb ($$) {
 183         my ($self, $lei) = @_;
 184         my $ovv = $lei->{ovv};
 185         my $m = 'eml2'.$ovv->{fmt};
 186         my $eml2mbox = $self->can($m) or die "$self->$m missing";
 187         $lei->{1} // die "no stdout ($m, $ovv->{dst})"; # redirected earlier
 188         $lei->{1}->autoflush(1);
 189         my $atomic_append = !defined($ovv->{lock_path});
 190         my $dedupe = $lei->{dedupe};
 191         $dedupe->prepare_dedupe;
 192         my $lse = $lei->{lse}; # may be undef
 193         sub { # for git_to_mail
 194                 my ($buf, $smsg, $eml) = @_;
 195                 $eml //= PublicInbox::Eml->new($buf);
 196                 return if $dedupe->is_dup($eml, $smsg);
 197                 $lse->xsmsg_vmd($smsg) if $lse;
 198                 $buf = $eml2mbox->($eml, $smsg);
 199                 return atomic_append($lei, $buf) if $atomic_append;
 200                 my $lk = $ovv->lock_for_scope;
 201                 $lei->out($$buf);
 202         }
 203 }
 204
 205 sub update_kw_maybe ($$$$) {
 206         my ($lei, $lse, $eml, $kw) = @_;
 207         return unless $lse;
 208         my $c = $lse->kw_changed($eml, $kw, my $docids = []);
 209         my $vmd = { kw => $kw };
 210         if (scalar @$docids) { # already in lei/store
 211                 $lei->{sto}->ipc_do('set_eml_vmd', undef, $vmd, $docids) if $c;
 212         } elsif (my $xoids = $lei->{ale}->xoids_for($eml)) {
 213                 # it's in an external, only set kw, here
 214                 $lei->{sto}->ipc_do('set_xvmd', $xoids, $eml, $vmd);
 215         } else { # never-before-seen, import the whole thing
 216                 # XXX this is critical in protecting against accidental
 217                 # data loss without --augment
 218                 $lei->{sto}->ipc_do('set_eml', $eml, $vmd);
 219         }
 220 }
 221
 222 sub _md_update { # maildir_each_eml cb
 223         my ($f, $kw, $eml, $lei, $lse, $unlink) = @_;
 224         update_kw_maybe($lei, $lse, $eml, $kw);
 225         $unlink ? unlink($f) : _augment($eml, $lei);
 226 }
 227
 228 # maildir_each_file callback, \&CORE::unlink doesn't work with it
 229 sub _unlink { unlink($_[0]) }
 230
 231 sub _rand () {
 232         state $seq = 0;
 233         sprintf('%x,%x,%x,%x', rand(0xffffffff), time, $$, ++$seq);
 234 }
 235
 236 sub _buf2maildir {
 237         my ($dst, $buf, $smsg) = @_;
 238         my $kw = $smsg->{kw} // [];
 239         my $sfx = join('', sort(map { $kw2char{$_} // () } @$kw));
 240         my $rand = ''; # chosen by die roll :P
 241         my ($tmp, $fh, $final, $ok);
 242         my $common = $smsg->{blob} // _rand;
 243         if (defined(my $pct = $smsg->{pct})) { $common .= "=$pct" }
 244         do {
 245                 $tmp = $dst.'tmp/'.$rand.$common;
 246         } while (!($ok = sysopen($fh, $tmp, O_CREAT|O_EXCL|O_WRONLY)) &&
 247                 $!{EEXIST} && ($rand = _rand.','));
 248         if ($ok && print $fh $$buf and close($fh)) {
 249                 # ignore new/ and write only to cur/, otherwise MUAs
 250                 # with R/W access to the Maildir will end up doing
 251                 # a mass rename which can take a while with thousands
 252                 # of messages.
 253                 $dst .= 'cur/';
 254                 $rand = '';
 255                 do {
 256                         $final = $dst.$rand.$common.':2,'.$sfx;
 257                 } while (!($ok = link($tmp, $final)) && $!{EEXIST} &&
 258                         ($rand = _rand.','));
 259                 die "link($tmp, $final): $!" unless $ok;
 260                 unlink($tmp) or warn "W: failed to unlink $tmp: $!\n";
 261         } else {
 262                 my $err = "Error writing $smsg->{blob} to $dst: $!\n";
 263                 $_[0] = undef; # clobber dst
 264                 unlink($tmp);
 265                 die $err;
 266         }
 267 }
 268
 269 sub _maildir_write_cb ($$) {
 270         my ($self, $lei) = @_;
 271         my $dedupe = $lei->{dedupe};
 272         $dedupe->prepare_dedupe if $dedupe;
 273         my $dst = $lei->{ovv}->{dst};
 274         my $lse = $lei->{lse}; # may be undef
 275         sub { # for git_to_mail
 276                 my ($buf, $smsg, $eml) = @_;
 277                 $dst // return $lei->fail; # dst may be undef-ed in last run
 278                 $buf //= \($eml->as_string);
 279                 $lse->xsmsg_vmd($smsg) if $lse;
 280                 return _buf2maildir($dst, $buf, $smsg) if !$dedupe;
 281                 $eml //= PublicInbox::Eml->new($$buf); # copy buf
 282                 return if $dedupe->is_dup($eml, $smsg);
 283                 undef $eml;
 284                 _buf2maildir($dst, $buf, $smsg);
 285         }
 286 }
 287
 288 sub _imap_write_cb ($$) {
 289         my ($self, $lei) = @_;
 290         my $dedupe = $lei->{dedupe};
 291         $dedupe->prepare_dedupe if $dedupe;
 292         my $imap_append = $lei->{net}->can('imap_append');
 293         my $mic = $lei->{net}->mic_get($self->{uri});
 294         my $folder = $self->{uri}->mailbox;
 295         my $lse = $lei->{lse}; # may be undef
 296         sub { # for git_to_mail
 297                 my ($bref, $smsg, $eml) = @_;
 298                 $mic // return $lei->fail; # mic may be undef-ed in last run
 299                 if ($dedupe) {
 300                         $eml //= PublicInbox::Eml->new($$bref); # copy bref
 301                         return if $dedupe->is_dup($eml, $smsg);
 302                 }
 303                 $lse->xsmsg_vmd($smsg) if $lse;
 304                 eval { $imap_append->($mic, $folder, $bref, $smsg, $eml) };
 305                 if (my $err = $@) {
 306                         undef $mic;
 307                         die $err;
 308                 }
 309         }
 310 }
 311
 312 sub write_cb { # returns a callback for git_to_mail
 313         my ($self, $lei) = @_;
 314         # _mbox_write_cb, _maildir_write_cb or _imap_write_cb
 315         my $m = "_$self->{base_type}_write_cb";
 316         $self->$m($lei);
 317 }
 318
 319 sub new {
 320         my ($cls, $lei) = @_;
 321         my $fmt = $lei->{ovv}->{fmt};
 322         my $dst = $lei->{ovv}->{dst};
 323         my $self = bless {}, $cls;
 324         if ($fmt eq 'maildir') {
 325                 require PublicInbox::MdirReader;
 326                 $self->{base_type} = 'maildir';
 327                 -e $dst && !-d _ and die
 328                                 "$dst exists and is not a directory\n";
 329                 $lei->{ovv}->{dst} = $dst .= '/' if substr($dst, -1) ne '/';
 330         } elsif (substr($fmt, 0, 4) eq 'mbox') {
 331                 require PublicInbox::MboxReader;
 332                 (-d $dst || (-e _ && !-w _)) and die
 333                         "$dst exists and is not a writable file\n";
 334                 $self->can("eml2$fmt") or die "bad mbox format: $fmt\n";
 335                 $self->{base_type} = 'mbox';
 336         } elsif ($fmt =~ /\Aimaps?\z/) { # TODO .onion support
 337                 require PublicInbox::NetWriter;
 338                 my $net = PublicInbox::NetWriter->new;
 339                 $net->add_url($dst);
 340                 $net->{quiet} = $lei->{opt}->{quiet};
 341                 my $err = $net->errors($dst);
 342                 return $lei->fail($err) if $err;
 343                 require PublicInbox::URIimap; # TODO: URI cast early
 344                 $self->{uri} = PublicInbox::URIimap->new($dst);
 345                 $self->{uri}->mailbox or die "No mailbox: $dst";
 346                 $lei->{net} = $net;
 347                 $self->{base_type} = 'imap';
 348         } else {
 349                 die "bad mail --format=$fmt\n";
 350         }
 351         $self->{dst} = $dst;
 352         my $dd_cls = 'PublicInbox::'.
 353                 ($lei->{opt}->{save} ? 'LeiSavedSearch' : 'LeiDedupe');
 354         eval "require $dd_cls";
 355         die "$dd_cls: $@" if $@;
 356         $lei->{dedupe} = $dd_cls->new($lei);
 357         $self;
 358 }
 359
 360 sub _pre_augment_maildir {
 361         my ($self, $lei) = @_;
 362         my $dst = $lei->{ovv}->{dst};
 363         for my $x (qw(tmp new cur)) {
 364                 my $d = $dst.$x;
 365                 next if -d $d;
 366                 require File::Path;
 367                 File::Path::mkpath($d);
 368                 -d $d or die "$d is not a directory";
 369         }
 370 }
 371
 372 sub _do_augment_maildir {
 373         my ($self, $lei) = @_;
 374         return if defined($lei->{opt}->{save});
 375         my $dst = $lei->{ovv}->{dst};
 376         my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
 377         my $mdr = PublicInbox::MdirReader->new;
 378         if ($lei->{opt}->{augment}) {
 379                 my $dedupe = $lei->{dedupe};
 380                 if ($dedupe && $dedupe->prepare_dedupe) {
 381                         $mdr->{shard_info} = $self->{shard_info};
 382                         $mdr->maildir_each_eml($dst, \&_md_update, $lei, $lse);
 383                         $dedupe->pause_dedupe;
 384                 }
 385         } elsif ($lse) {
 386                 $mdr->{shard_info} = $self->{shard_info};
 387                 $mdr->maildir_each_eml($dst, \&_md_update, $lei, $lse, 1);
 388         } else {# clobber existing Maildir
 389                 $mdr->maildir_each_file($dst, \&_unlink);
 390         }
 391 }
 392
 393 sub _imap_augment_or_delete { # PublicInbox::NetReader::imap_each cb
 394         my ($url, $uid, $kw, $eml, $lei, $lse, $delete_mic) = @_;
 395         update_kw_maybe($lei, $lse, $eml, $kw);
 396         if ($delete_mic) {
 397                 $lei->{net}->imap_delete_1($url, $uid, $delete_mic);
 398         } else {
 399                 _augment($eml, $lei);
 400         }
 401 }
 402
 403 sub _do_augment_imap {
 404         my ($self, $lei) = @_;
 405         return if defined($lei->{opt}->{save});
 406         my $net = $lei->{net};
 407         my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
 408         if ($lei->{opt}->{augment}) {
 409                 my $dedupe = $lei->{dedupe};
 410                 if ($dedupe && $dedupe->prepare_dedupe) {
 411                         $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 412                                         $lei, $lse);
 413                         $dedupe->pause_dedupe;
 414                 }
 415         } elsif ($lse) {
 416                 my $delete_mic;
 417                 $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 418                                         $lei, $lse, \$delete_mic);
 419                 $delete_mic->expunge if $delete_mic;
 420         } elsif (!$self->{-wq_worker_nr}) { # undef or 0
 421                 # clobber existing IMAP folder
 422                 $net->imap_delete_all($self->{uri});
 423         }
 424 }
 425
 426 sub _pre_augment_mbox {
 427         my ($self, $lei) = @_;
 428         my $dst = $lei->{ovv}->{dst};
 429         my $out;
 430         my $devfd = $lei->path_to_fd($dst) // die "bad $dst";
 431         if ($devfd >= 0) {
 432                 $out = $lei->{$devfd};
 433         } else { # normal-looking path
 434                 if (-p $dst) {
 435                         open $out, '>', $dst or die "open($dst): $!";
 436                 } elsif (-f _ || !-e _) {
 437                         require PublicInbox::MboxLock;
 438                         my $m = $lei->{opt}->{'lock'} //
 439                                         PublicInbox::MboxLock->defaults;
 440                         $self->{mbl} = PublicInbox::MboxLock->acq($dst, 1, $m);
 441                         $out = $self->{mbl}->{fh};
 442                 } else {
 443                         die "$dst is not a file or FIFO\n";
 444                 }
 445                 $lei->{old_1} = $lei->{1}; # keep for spawning MUA
 446         }
 447         # Perl does SEEK_END even with O_APPEND :<
 448         $self->{seekable} = seek($out, 0, SEEK_SET);
 449         if (!$self->{seekable} && !$!{ESPIPE} && !defined($devfd)) {
 450                 die "seek($dst): $!\n";
 451         }
 452         if (!$self->{seekable}) {
 453                 my $imp_before = $lei->{opt}->{'import-before'};
 454                 die "--import-before specified but $dst is not seekable\n"
 455                         if $imp_before && !ref($imp_before);
 456                 die "--augment specified but $dst is not seekable\n" if
 457                         $lei->{opt}->{augment};
 458         }
 459         if ($self->{zsfx} = PublicInbox::MboxReader::zsfx($dst)) {
 460                 pipe(my ($r, $w)) or die "pipe: $!";
 461                 $lei->{zpipe} = [ $r, $w ];
 462                 $lei->{ovv}->{lock_path} and
 463                         die 'BUG: unexpected {ovv}->{lock_path}';
 464                 $lei->{ovv}->ovv_out_lk_init;
 465         } elsif (!$self->{seekable} && !$lei->{ovv}->{lock_path}) {
 466                 $lei->{ovv}->ovv_out_lk_init;
 467         }
 468         $lei->{1} = $out;
 469         undef;
 470 }
 471
 472 sub _do_augment_mbox {
 473         my ($self, $lei) = @_;
 474         return unless $self->{seekable};
 475         my $opt = $lei->{opt};
 476         return if defined($opt->{save});
 477         my $out = $lei->{1};
 478         my ($fmt, $dst) = @{$lei->{ovv}}{qw(fmt dst)};
 479         return unless -s $out;
 480         unless ($opt->{augment} || $opt->{'import-before'}) {
 481                 truncate($out, 0) or die "truncate($dst): $!";
 482                 return;
 483         }
 484         my $rd;
 485         if (my $zsfx = $self->{zsfx}) {
 486                 $rd = PublicInbox::MboxReader::zsfxcat($out, $zsfx, $lei);
 487         } else {
 488                 open($rd, '+>>&', $out) or die "dup: $!";
 489         }
 490         my $dedupe;
 491         if ($opt->{augment}) {
 492                 $dedupe = $lei->{dedupe};
 493                 $dedupe->prepare_dedupe if $dedupe;
 494         }
 495         if ($opt->{'import-before'}) { # the default
 496                 my $lse = $lei->{lse};
 497                 PublicInbox::MboxReader->$fmt($rd, \&_mbox_augment_kw_maybe,
 498                                                 $lei, $lse, $opt->{augment});
 499                 if (!$opt->{augment} and !truncate($out, 0)) {
 500                         die "truncate($dst): $!";
 501                 }
 502         } else { # --augment --no-import-before
 503                 PublicInbox::MboxReader->$fmt($rd, \&_augment, $lei);
 504         }
 505         # maybe some systems don't honor O_APPEND, Perl does this:
 506         seek($out, 0, SEEK_END) or die "seek $dst: $!";
 507         $dedupe->pause_dedupe if $dedupe;
 508 }
 509
 510 sub pre_augment { # fast (1 disk seek), runs in same process as post_augment
 511         my ($self, $lei) = @_;
 512         # _pre_augment_maildir, _pre_augment_mbox
 513         my $m = $self->can("_pre_augment_$self->{base_type}") or return;
 514         $m->($self, $lei);
 515 }
 516
 517 sub do_augment { # slow, runs in wq worker
 518         my ($self, $lei) = @_;
 519         # _do_augment_maildir, _do_augment_mbox, or _do_augment_imap
 520         my $m = "_do_augment_$self->{base_type}";
 521         $self->$m($lei);
 522 }
 523
 524 # fast (spawn compressor or mkdir), runs in same process as pre_augment
 525 sub post_augment {
 526         my ($self, $lei, @args) = @_;
 527         my $wait = $lei->{opt}->{'import-before'} ?
 528                         $lei->{sto}->ipc_do('checkpoint', 1) : 0;
 529         # _post_augment_mbox
 530         my $m = $self->can("_post_augment_$self->{base_type}") or return;
 531         $m->($self, $lei, @args);
 532 }
 533
 534 # called by every single l2m worker process
 535 sub do_post_auth {
 536         my ($self) = @_;
 537         my $lei = $self->{lei};
 538         # lei_xsearch can start as soon as all l2m workers get here
 539         pkt_do($lei->{pkt_op_p}, 'incr_start_query') or
 540                 die "incr_start_query: $!";
 541         my $aug;
 542         if (lock_free($self)) { # all workers do_augment
 543                 my $mod = $self->{-wq_nr_workers};
 544                 my $shard = $self->{-wq_worker_nr};
 545                 if (my $net = $lei->{net}) {
 546                         $net->{shard_info} = [ $mod, $shard ];
 547                 } else { # Maildir
 548                         $self->{shard_info} = [ $mod, $shard ];
 549                 }
 550                 $aug = '+'; # incr_post_augment
 551         } elsif ($self->{-wq_worker_nr} == 0) { # 1st worker do_augment
 552                 $aug = '.'; # do_post_augment
 553         }
 554         if ($aug) {
 555                 local $0 = 'do_augment';
 556                 eval { do_augment($self, $lei) };
 557                 $lei->fail($@) if $@;
 558                 pkt_do($lei->{pkt_op_p}, $aug) == 1 or
 559                                 die "do_post_augment trigger: $!";
 560         }
 561         # done augmenting, connect the compressor pipe for each worker
 562         if (my $zpipe = delete $lei->{zpipe}) {
 563                 $lei->{1} = $zpipe->[1];
 564                 close $zpipe->[0];
 565         }
 566         $self->{wcb} = $self->write_cb($lei);
 567 }
 568
 569 sub ipc_atfork_child {
 570         my ($self) = @_;
 571         my $lei = $self->{lei};
 572         $lei->_lei_atfork_child;
 573         $lei->{auth}->do_auth_atfork($self) if $lei->{auth};
 574         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 575         $self->SUPER::ipc_atfork_child;
 576 }
 577
 578 sub lock_free {
 579         $_[0]->{base_type} =~ /\A(?:maildir|imap|jmap)\z/ ? 1 : 0;
 580 }
 581
 582 # wakes up the MUA when complete so it can refresh messages list
 583 sub poke_dst {
 584         my ($self) = @_;
 585         if ($self->{base_type} eq 'maildir') {
 586                 my $t = time + 1;
 587                 utime($t, $t, $self->{dst} . 'cur');
 588         }
 589 }
 590
 591 sub write_mail { # via ->wq_io_do
 592         my ($self, $smsg, $eml) = @_;
 593         return $self->{wcb}->(undef, $smsg, $eml) if $eml;
 594         $self->{lei}->{ale}->git->cat_async($smsg->{blob}, \&git_to_mail,
 595                                 [$self->{wcb}, $smsg]);
 596 }
 597
 598 sub wq_atexit_child {
 599         my ($self) = @_;
 600         delete $self->{wcb};
 601         $self->{lei}->{ale}->git->async_wait_all;
 602 }
 603
 604 # called in top-level lei-daemon when LeiAuth is done
 605 sub net_merge_complete {
 606         my ($self) = @_;
 607         $self->wq_broadcast('do_post_auth');
 608         $self->wq_close(1);
 609 }
 610
 611 no warnings 'once'; # the following works even when LeiAuth is lazy-loaded
 612 *net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
 613 1;