lib/PublicInbox/LeiToMail.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Writes PublicInbox::Eml objects atomically to a mbox variant or Maildir
   5 package PublicInbox::LeiToMail;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Lock;
  11 use PublicInbox::ProcessPipe;
  12 use PublicInbox::Spawn qw(which spawn popen_rd);
  13 use PublicInbox::LeiDedupe;
  14 use PublicInbox::OnDestroy;
  15 use PublicInbox::Git;
  16 use PublicInbox::GitAsyncCat;
  17 use Symbol qw(gensym);
  18 use IO::Handle; # ->autoflush
  19 use Fcntl qw(SEEK_SET SEEK_END O_CREAT O_EXCL O_WRONLY);
  20 use Errno qw(EEXIST ESPIPE ENOENT EPIPE);
  21 my ($maildir_each_file);
  22
  23 # struggles with short-lived repos, Gcf2Client makes little sense with lei;
  24 # but we may use in-process libgit2 in the future.
  25 $PublicInbox::GitAsyncCat::GCF2C = 0;
  26
  27 my %kw2char = ( # Maildir characters
  28         draft => 'D',
  29         flagged => 'F',
  30         answered => 'R',
  31         seen => 'S'
  32 );
  33
  34 my %kw2status = (
  35         flagged => [ 'X-Status' => 'F' ],
  36         answered => [ 'X-Status' => 'A' ],
  37         seen => [ 'Status' => 'R' ],
  38         draft => [ 'X-Status' => 'T' ],
  39 );
  40
  41 sub _mbox_hdr_buf ($$$) {
  42         my ($eml, $type, $smsg) = @_;
  43         $eml->header_set($_) for (qw(Lines Bytes Content-Length));
  44
  45         # Messages are always 'O' (non-\Recent in IMAP), it saves
  46         # MUAs the trouble of rewriting the mbox if no other
  47         # changes are made
  48         my %hdr = (Status => [ 'O' ]); # set Status, X-Status
  49         for my $k (@{$smsg->{kw} // []}) {
  50                 if (my $ent = $kw2status{$k}) {
  51                         push @{$hdr{$ent->[0]}}, $ent->[1];
  52                 } else { # X-Label?
  53                         warn "TODO: keyword `$k' not supported for mbox\n";
  54                 }
  55         }
  56         while (my ($name, $chars) = each %hdr) {
  57                 $eml->header_set($name, join('', sort @$chars));
  58         }
  59         my $buf = delete $eml->{hdr};
  60
  61         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
  62         $$buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  63         my $ident = $smsg->{blob} // 'lei';
  64         if (defined(my $pct = $smsg->{pct})) { $ident .= "=$pct" }
  65
  66         substr($$buf, 0, 0, # prepend From line
  67                 "From $ident\@$type Thu Jan  1 00:00:00 1970$eml->{crlf}");
  68         $buf;
  69 }
  70
  71 sub atomic_append { # for on-disk destinations (O_APPEND, or O_EXCL)
  72         my ($lei, $buf) = @_;
  73         if (defined(my $w = syswrite($lei->{1} // return, $$buf))) {
  74                 return if $w == length($$buf);
  75                 $buf = "short atomic write: $w != ".length($$buf);
  76         } elsif ($! == EPIPE) {
  77                 return $lei->note_sigpipe(1);
  78         } else {
  79                 $buf = "atomic write: $!";
  80         }
  81         $lei->fail($buf);
  82 }
  83
  84 sub eml2mboxrd ($;$) {
  85         my ($eml, $smsg) = @_;
  86         my $buf = _mbox_hdr_buf($eml, 'mboxrd', $smsg);
  87         if (my $bdy = delete $eml->{bdy}) {
  88                 $$bdy =~ s/^(>*From )/>$1/gm;
  89                 $$buf .= $eml->{crlf};
  90                 substr($$bdy, 0, 0, $$buf); # prepend header
  91                 $buf = $bdy;
  92         }
  93         $$buf .= $eml->{crlf};
  94         $buf;
  95 }
  96
  97 sub eml2mboxo {
  98         my ($eml, $smsg) = @_;
  99         my $buf = _mbox_hdr_buf($eml, 'mboxo', $smsg);
 100         if (my $bdy = delete $eml->{bdy}) {
 101                 $$bdy =~ s/^From />From /gm;
 102                 $$buf .= $eml->{crlf};
 103                 substr($$bdy, 0, 0, $$buf); # prepend header
 104                 $buf = $bdy;
 105         }
 106         $$buf .= $eml->{crlf};
 107         $buf;
 108 }
 109
 110 sub _mboxcl_common ($$$) {
 111         my ($buf, $bdy, $crlf) = @_;
 112         # add Lines: so mutt won't have to add it on MUA close
 113         my $lines = $$bdy =~ tr!\n!\n!;
 114         $$buf .= 'Content-Length: '.length($$bdy).$crlf.
 115                 'Lines: '.$lines.$crlf.$crlf;
 116         substr($$bdy, 0, 0, $$buf); # prepend header
 117         $_[0] = $bdy;
 118 }
 119
 120 # mboxcl still escapes "From " lines
 121 sub eml2mboxcl {
 122         my ($eml, $smsg) = @_;
 123         my $buf = _mbox_hdr_buf($eml, 'mboxcl', $smsg);
 124         my $crlf = $eml->{crlf};
 125         if (my $bdy = delete $eml->{bdy}) {
 126                 $$bdy =~ s/^From />From /gm;
 127                 _mboxcl_common($buf, $bdy, $crlf);
 128         }
 129         $$buf .= $crlf;
 130         $buf;
 131 }
 132
 133 # mboxcl2 has no "From " escaping
 134 sub eml2mboxcl2 {
 135         my ($eml, $smsg) = @_;
 136         my $buf = _mbox_hdr_buf($eml, 'mboxcl2', $smsg);
 137         my $crlf = $eml->{crlf};
 138         if (my $bdy = delete $eml->{bdy}) {
 139                 _mboxcl_common($buf, $bdy, $crlf);
 140         }
 141         $$buf .= $crlf;
 142         $buf;
 143 }
 144
 145 sub git_to_mail { # git->cat_async callback
 146         my ($bref, $oid, $type, $size, $arg) = @_;
 147         if ($type ne 'blob') {
 148                 if ($type eq 'missing') {
 149                         warn "missing $oid\n";
 150                 } else {
 151                         warn "unexpected type=$type for $oid\n";
 152                 }
 153         }
 154         my ($write_cb, $smsg) = @$arg;
 155         if ($smsg->{blob} ne $oid) {
 156                 die "BUG: expected=$smsg->{blob} got=$oid";
 157         }
 158         $write_cb->($bref, $smsg) if $size > 0;
 159 }
 160
 161 sub reap_compress { # dwaitpid callback
 162         my ($lei, $pid) = @_;
 163         my $cmd = delete $lei->{"pid.$pid"};
 164         return if $? == 0;
 165         $lei->fail("@$cmd failed", $? >> 8);
 166 }
 167
 168 # all of these support -c for stdout and -d for decompression,
 169 # mutt is commonly distributed with hooks for gz, bz2 and xz, at least
 170 # { foo => '' } means "--foo" is passed to the command-line,
 171 # otherwise { foo => '--bar' } passes "--bar"
 172 our %zsfx2cmd = (
 173         gz => [ qw(GZIP pigz gzip), { rsyncable => '', threads => '-p' } ],
 174         bz2 => [ 'bzip2', {} ],
 175         xz => [ 'xz', { threads => '-T' } ],
 176         # XXX does anybody care for these?  I prefer zstd on entire FSes,
 177         # so it's probably not necessary on a per-file basis
 178         # zst => [ 'zstd', { -default => [ qw(-q) ], # it's noisy by default
 179         #       rsyncable => '', threads => '-T' } ],
 180         # zz => [ 'pigz', { -default => [ '--zlib' ],
 181         #       rsyncable => '', threads => '-p' }],
 182         # lzo => [ 'lzop', {} ],
 183         # lzma => [ 'lzma', {} ],
 184 );
 185
 186 sub zsfx2cmd ($$$) {
 187         my ($zsfx, $decompress, $lei) = @_;
 188         my $x = $zsfx2cmd{$zsfx} // die "no support for suffix=.$zsfx";
 189         my @info = @$x;
 190         my $cmd_opt = pop @info;
 191         my @cmd = (undef, $decompress ? qw(-dc) : qw(-c));
 192         for my $exe (@info) {
 193                 # I think respecting client's ENV{GZIP} is OK, not sure
 194                 # about ENV overrides for other, less-common compressors
 195                 if ($exe eq uc($exe)) {
 196                         $exe = $lei->{env}->{$exe} or next;
 197                 }
 198                 $cmd[0] = which($exe) and last;
 199         }
 200         $cmd[0] // die join(' or ', @info)." missing for .$zsfx";
 201         # push @cmd, @{$cmd_opt->{-default}} if $cmd_opt->{-default};
 202         for my $bool (qw(rsyncable)) {
 203                 my $switch = $cmd_opt->{rsyncable} // next;
 204                 push @cmd, '--'.($switch || $bool);
 205         }
 206         for my $key (qw(threads)) { # support compression level?
 207                 my $switch = $cmd_opt->{$key} // next;
 208                 my $val = $lei->{opt}->{$key} // next;
 209                 push @cmd, $switch, $val;
 210         }
 211         \@cmd;
 212 }
 213
 214 sub _post_augment_mbox { # open a compressor process
 215         my ($self, $lei) = @_;
 216         my $zsfx = $self->{zsfx} or return;
 217         my $cmd = zsfx2cmd($zsfx, undef, $lei);
 218         my ($r, $w) = @{delete $lei->{zpipe}};
 219         my $rdr = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 220         my $pid = spawn($cmd, $lei->{env}, $rdr);
 221         my $pp = gensym;
 222         my $dup = bless { "pid.$pid" => $cmd }, ref($lei);
 223         $dup->{$_} = $lei->{$_} for qw(2 sock);
 224         tie *$pp, 'PublicInbox::ProcessPipe', $pid, $w, \&reap_compress, $dup;
 225         $lei->{1} = $pp;
 226         die 'BUG: unexpected {ovv}->{lock_path}' if $lei->{ovv}->{lock_path};
 227         $lei->{ovv}->ovv_out_lk_init;
 228 }
 229
 230 sub decompress_src ($$$) {
 231         my ($in, $zsfx, $lei) = @_;
 232         my $cmd = zsfx2cmd($zsfx, 1, $lei);
 233         popen_rd($cmd, $lei->{env}, { 0 => $in, 2 => $lei->{2} });
 234 }
 235
 236 sub dup_src ($) {
 237         my ($in) = @_;
 238         open my $dup, '+>>&', $in or die "dup: $!";
 239         $dup;
 240 }
 241
 242 # --augment existing output destination, with deduplication
 243 sub _augment { # MboxReader eml_cb
 244         my ($eml, $lei) = @_;
 245         # ignore return value, just populate the skv
 246         $lei->{dedupe}->is_dup($eml);
 247 }
 248
 249 sub _mbox_write_cb ($$) {
 250         my ($self, $lei) = @_;
 251         my $ovv = $lei->{ovv};
 252         my $m = 'eml2'.$ovv->{fmt};
 253         my $eml2mbox = $self->can($m) or die "$self->$m missing";
 254         $lei->{1} // die "no stdout ($m, $ovv->{dst})"; # redirected earlier
 255         $lei->{1}->autoflush(1);
 256         my $atomic_append = !defined($ovv->{lock_path});
 257         my $dedupe = $lei->{dedupe};
 258         $dedupe->prepare_dedupe;
 259         sub { # for git_to_mail
 260                 my ($buf, $smsg, $eml) = @_;
 261                 $eml //= PublicInbox::Eml->new($buf);
 262                 return if $dedupe->is_dup($eml, $smsg->{blob});
 263                 $buf = $eml2mbox->($eml, $smsg);
 264                 return atomic_append($lei, $buf) if $atomic_append;
 265                 my $lk = $ovv->lock_for_scope;
 266                 $lei->out($$buf);
 267         }
 268 }
 269
 270 sub _augment_file { # maildir_each_file cb
 271         my ($f, $lei) = @_;
 272         my $eml = PublicInbox::InboxWritable::eml_from_path($f) or return;
 273         _augment($eml, $lei);
 274 }
 275
 276 # maildir_each_file callback, \&CORE::unlink doesn't work with it
 277 sub _unlink { unlink($_[0]) }
 278
 279 sub _rand () {
 280         state $seq = 0;
 281         sprintf('%x,%x,%x,%x', rand(0xffffffff), time, $$, ++$seq);
 282 }
 283
 284 sub _buf2maildir {
 285         my ($dst, $buf, $smsg) = @_;
 286         my $kw = $smsg->{kw} // [];
 287         my $sfx = join('', sort(map { $kw2char{$_} // () } @$kw));
 288         my $rand = ''; # chosen by die roll :P
 289         my ($tmp, $fh, $final, $ok);
 290         my $common = $smsg->{blob} // _rand;
 291         if (defined(my $pct = $smsg->{pct})) { $common .= "=$pct" }
 292         do {
 293                 $tmp = $dst.'tmp/'.$rand.$common;
 294         } while (!($ok = sysopen($fh, $tmp, O_CREAT|O_EXCL|O_WRONLY)) &&
 295                 $! == EEXIST && ($rand = _rand.','));
 296         if ($ok && print $fh $$buf and close($fh)) {
 297                 # ignore new/ and write only to cur/, otherwise MUAs
 298                 # with R/W access to the Maildir will end up doing
 299                 # a mass rename which can take a while with thousands
 300                 # of messages.
 301                 $dst .= 'cur/';
 302                 $rand = '';
 303                 do {
 304                         $final = $dst.$rand.$common.':2,'.$sfx;
 305                 } while (!link($tmp, $final) && $! == EEXIST &&
 306                         ($rand = _rand.','));
 307                 unlink($tmp) or warn "W: failed to unlink $tmp: $!\n";
 308         } else {
 309                 my $err = "Error writing $smsg->{blob} to $dst: $!\n";
 310                 $_[0] = undef; # clobber dst
 311                 unlink($tmp);
 312                 die $err;
 313         }
 314 }
 315
 316 sub _maildir_write_cb ($$) {
 317         my ($self, $lei) = @_;
 318         my $dedupe = $lei->{dedupe};
 319         $dedupe->prepare_dedupe if $dedupe;
 320         my $dst = $lei->{ovv}->{dst};
 321         sub { # for git_to_mail
 322                 my ($buf, $smsg, $eml) = @_;
 323                 $dst // return $lei->fail; # dst may be undef-ed in last run
 324                 $buf //= \($eml->as_string);
 325                 return _buf2maildir($dst, $buf, $smsg) if !$dedupe;
 326                 $eml //= PublicInbox::Eml->new($$buf); # copy buf
 327                 return if $dedupe->is_dup($eml, $smsg->{blob});
 328                 undef $eml;
 329                 _buf2maildir($dst, $buf, $smsg);
 330         }
 331 }
 332
 333 sub write_cb { # returns a callback for git_to_mail
 334         my ($self, $lei) = @_;
 335         # _mbox_write_cb or _maildir_write_cb
 336         my $m = "_$self->{base_type}_write_cb";
 337         $self->$m($lei);
 338 }
 339
 340 sub new {
 341         my ($cls, $lei) = @_;
 342         my $fmt = $lei->{ovv}->{fmt};
 343         my $dst = $lei->{ovv}->{dst};
 344         my $self = bless {}, $cls;
 345         if ($fmt eq 'maildir') {
 346                 $maildir_each_file //= do {
 347                         require PublicInbox::MdirReader;
 348                         PublicInbox::MdirReader->can('maildir_each_file');
 349                 };
 350                 $lei->{opt}->{augment} and
 351                         require PublicInbox::InboxWritable; # eml_from_path
 352                 $self->{base_type} = 'maildir';
 353                 -e $dst && !-d _ and die
 354                                 "$dst exists and is not a directory\n";
 355                 $lei->{ovv}->{dst} = $dst .= '/' if substr($dst, -1) ne '/';
 356         } elsif (substr($fmt, 0, 4) eq 'mbox') {
 357                 require PublicInbox::MboxReader if $lei->{opt}->{augment};
 358                 (-d $dst || (-e _ && !-w _)) and die
 359                         "$dst exists and is not a writable file\n";
 360                 $self->can("eml2$fmt") or die "bad mbox --format=$fmt\n";
 361                 $self->{base_type} = 'mbox';
 362         } else {
 363                 die "bad mail --format=$fmt\n";
 364         }
 365         $self->{dst} = $dst;
 366         $lei->{dedupe} = PublicInbox::LeiDedupe->new($lei);
 367         $self;
 368 }
 369
 370 sub _pre_augment_maildir {
 371         my ($self, $lei) = @_;
 372         my $dst = $lei->{ovv}->{dst};
 373         for my $x (qw(tmp new cur)) {
 374                 my $d = $dst.$x;
 375                 next if -d $d;
 376                 require File::Path;
 377                 File::Path::mkpath($d);
 378                 -d $d or die "$d is not a directory";
 379         }
 380 }
 381
 382 sub _do_augment_maildir {
 383         my ($self, $lei) = @_;
 384         my $dst = $lei->{ovv}->{dst};
 385         if ($lei->{opt}->{augment}) {
 386                 my $dedupe = $lei->{dedupe};
 387                 if ($dedupe && $dedupe->prepare_dedupe) {
 388                         $maildir_each_file->($dst, \&_augment_file, $lei);
 389                         $dedupe->pause_dedupe;
 390                 }
 391         } else { # clobber existing Maildir
 392                 $maildir_each_file->($dst, \&_unlink);
 393         }
 394 }
 395
 396 sub _post_augment_maildir {} # noop
 397
 398 sub _pre_augment_mbox {
 399         my ($self, $lei) = @_;
 400         my $dst = $lei->{ovv}->{dst};
 401         if ($dst ne '/dev/stdout') {
 402                 my $mode = -p $dst ? '>' : '+>>';
 403                 if (-f _ && !$lei->{opt}->{augment} and !unlink($dst)) {
 404                         $! == ENOENT or die "unlink($dst): $!";
 405                 }
 406                 open my $out, $mode, $dst or die "open($dst): $!";
 407                 $lei->{old_1} = $lei->{1}; # keep for spawning MUA
 408                 $lei->{1} = $out;
 409         }
 410         # Perl does SEEK_END even with O_APPEND :<
 411         $self->{seekable} = seek($lei->{1}, 0, SEEK_SET);
 412         if (!$self->{seekable} && $! != ESPIPE && $dst ne '/dev/stdout') {
 413                 die "seek($dst): $!\n";
 414         }
 415         state $zsfx_allow = join('|', keys %zsfx2cmd);
 416         ($self->{zsfx}) = ($dst =~ /\.($zsfx_allow)\z/) or return;
 417         pipe(my ($r, $w)) or die "pipe: $!";
 418         $lei->{zpipe} = [ $r, $w ];
 419 }
 420
 421 sub _do_augment_mbox {
 422         my ($self, $lei) = @_;
 423         return if !$lei->{opt}->{augment};
 424         my $dedupe = $lei->{dedupe};
 425         my $dst = $lei->{ovv}->{dst};
 426         die "cannot augment $dst, not seekable\n" if !$self->{seekable};
 427         my $out = $lei->{1};
 428         if (-s $out && $dedupe && $dedupe->prepare_dedupe) {
 429                 my $zsfx = $self->{zsfx};
 430                 my $rd = $zsfx ? decompress_src($out, $zsfx, $lei) :
 431                                 dup_src($out);
 432                 my $fmt = $lei->{ovv}->{fmt};
 433                 PublicInbox::MboxReader->$fmt($rd, \&_augment, $lei);
 434         }
 435         # maybe some systems don't honor O_APPEND, Perl does this:
 436         seek($out, 0, SEEK_END) or die "seek $dst: $!";
 437         $dedupe->pause_dedupe if $dedupe;
 438 }
 439
 440 sub pre_augment { # fast (1 disk seek), runs in same process as post_augment
 441         my ($self, $lei) = @_;
 442         # _pre_augment_maildir, _pre_augment_mbox
 443         my $m = "_pre_augment_$self->{base_type}";
 444         $self->$m($lei);
 445 }
 446
 447 sub do_augment { # slow, runs in wq worker
 448         my ($self, $lei) = @_;
 449         # _do_augment_maildir, _do_augment_mbox
 450         my $m = "_do_augment_$self->{base_type}";
 451         $self->$m($lei);
 452 }
 453
 454 # fast (spawn compressor or mkdir), runs in same process as pre_augment
 455 sub post_augment {
 456         my ($self, $lei, @args) = @_;
 457         # _post_augment_maildir, _post_augment_mbox
 458         my $m = "_post_augment_$self->{base_type}";
 459         $self->$m($lei, @args);
 460 }
 461
 462 sub ipc_atfork_child {
 463         my ($self) = @_;
 464         my $lei = delete $self->{lei};
 465         $lei->lei_atfork_child;
 466         if (my $zpipe = delete $lei->{zpipe}) {
 467                 $lei->{1} = $zpipe->[1];
 468                 close $zpipe->[0];
 469         }
 470         $self->{wcb} = $self->write_cb($lei);
 471         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 472         $self->SUPER::ipc_atfork_child;
 473 }
 474
 475 sub lock_free {
 476         $_[0]->{base_type} =~ /\A(?:maildir|mh|imap|jmap)\z/ ? 1 : 0;
 477 }
 478
 479 sub poke_dst {
 480         my ($self) = @_;
 481         if ($self->{base_type} eq 'maildir') {
 482                 my $t = time + 1;
 483                 utime($t, $t, "$self->{dst}/cur");
 484         }
 485 }
 486
 487 sub write_mail { # via ->wq_io_do
 488         my ($self, $git_dir, $smsg) = @_;
 489         my $git = $self->{"$$\0$git_dir"} //= PublicInbox::Git->new($git_dir);
 490         git_async_cat($git, $smsg->{blob}, \&git_to_mail,
 491                                 [$self->{wcb}, $smsg]);
 492 }
 493
 494 sub wq_atexit_child {
 495         my ($self) = @_;
 496         delete $self->{wcb};
 497         for my $git (delete @$self{grep(/\A$$\0/, keys %$self)}) {
 498                 $git->async_wait_all;
 499         }
 500         $SIG{__WARN__} = 'DEFAULT';
 501 }
 502
 503 1;