lib/PublicInbox/LeiToMail.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Writes PublicInbox::Eml objects atomically to a mbox variant or Maildir
   5 package PublicInbox::LeiToMail;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Lock;
  11 use PublicInbox::ProcessPipe;
  12 use PublicInbox::Spawn qw(spawn);
  13 use PublicInbox::LeiDedupe;
  14 use PublicInbox::Git;
  15 use PublicInbox::GitAsyncCat;
  16 use PublicInbox::PktOp qw(pkt_do);
  17 use Symbol qw(gensym);
  18 use IO::Handle; # ->autoflush
  19 use Fcntl qw(SEEK_SET SEEK_END O_CREAT O_EXCL O_WRONLY);
  20 use Errno qw(EEXIST ESPIPE ENOENT EPIPE);
  21 use Digest::SHA qw(sha256_hex);
  22
  23 # struggles with short-lived repos, Gcf2Client makes little sense with lei;
  24 # but we may use in-process libgit2 in the future.
  25 $PublicInbox::GitAsyncCat::GCF2C = 0;
  26
  27 my %kw2char = ( # Maildir characters
  28         draft => 'D',
  29         flagged => 'F',
  30         answered => 'R',
  31         seen => 'S'
  32 );
  33
  34 my %kw2status = (
  35         flagged => [ 'X-Status' => 'F' ],
  36         answered => [ 'X-Status' => 'A' ],
  37         seen => [ 'Status' => 'R' ],
  38         draft => [ 'X-Status' => 'T' ],
  39 );
  40
  41 sub _mbox_hdr_buf ($$$) {
  42         my ($eml, $type, $smsg) = @_;
  43         $eml->header_set($_) for (qw(Lines Bytes Content-Length));
  44
  45         my %hdr = (Status => []); # set Status, X-Status
  46         for my $k (@{$smsg->{kw} // []}) {
  47                 if (my $ent = $kw2status{$k}) {
  48                         push @{$hdr{$ent->[0]}}, $ent->[1];
  49                 } else { # X-Label?
  50                         warn "TODO: keyword `$k' not supported for mbox\n";
  51                 }
  52         }
  53         # Messages are always 'O' (non-\Recent in IMAP), it saves
  54         # MUAs the trouble of rewriting the mbox if no other
  55         # changes are made.  We put 'O' at the end (e.g. "Status: RO")
  56         # to match mutt(1) output.
  57         $eml->header_set('Status', join('', sort(@{$hdr{Status}})). 'O');
  58         if (my $chars = delete $hdr{'X-Status'}) {
  59                 $eml->header_set('X-Status', join('', sort(@$chars)));
  60         }
  61         my $buf = delete $eml->{hdr};
  62
  63         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
  64         $$buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  65         my $ident = $smsg->{blob} // 'lei';
  66         if (defined(my $pct = $smsg->{pct})) { $ident .= "=$pct" }
  67
  68         substr($$buf, 0, 0, # prepend From line
  69                 "From $ident\@$type Thu Jan  1 00:00:00 1970$eml->{crlf}");
  70         $buf;
  71 }
  72
  73 sub atomic_append { # for on-disk destinations (O_APPEND, or O_EXCL)
  74         my ($lei, $buf) = @_;
  75         if (defined(my $w = syswrite($lei->{1} // return, $$buf))) {
  76                 return if $w == length($$buf);
  77                 $buf = "short atomic write: $w != ".length($$buf);
  78         } elsif ($! == EPIPE) {
  79                 return $lei->note_sigpipe(1);
  80         } else {
  81                 $buf = "atomic write: $!";
  82         }
  83         $lei->fail($buf);
  84 }
  85
  86 sub eml2mboxrd ($;$) {
  87         my ($eml, $smsg) = @_;
  88         my $buf = _mbox_hdr_buf($eml, 'mboxrd', $smsg);
  89         if (my $bdy = delete $eml->{bdy}) {
  90                 $$bdy =~ s/^(>*From )/>$1/gm;
  91                 $$buf .= $eml->{crlf};
  92                 substr($$bdy, 0, 0, $$buf); # prepend header
  93                 $buf = $bdy;
  94         }
  95         $$buf .= $eml->{crlf};
  96         $buf;
  97 }
  98
  99 sub eml2mboxo {
 100         my ($eml, $smsg) = @_;
 101         my $buf = _mbox_hdr_buf($eml, 'mboxo', $smsg);
 102         if (my $bdy = delete $eml->{bdy}) {
 103                 $$bdy =~ s/^From />From /gm;
 104                 $$buf .= $eml->{crlf};
 105                 substr($$bdy, 0, 0, $$buf); # prepend header
 106                 $buf = $bdy;
 107         }
 108         $$buf .= $eml->{crlf};
 109         $buf;
 110 }
 111
 112 sub _mboxcl_common ($$$) {
 113         my ($buf, $bdy, $crlf) = @_;
 114         # add Lines: so mutt won't have to add it on MUA close
 115         my $lines = $$bdy =~ tr!\n!\n!;
 116         $$buf .= 'Content-Length: '.length($$bdy).$crlf.
 117                 'Lines: '.$lines.$crlf.$crlf;
 118         substr($$bdy, 0, 0, $$buf); # prepend header
 119         $_[0] = $bdy;
 120 }
 121
 122 # mboxcl still escapes "From " lines
 123 sub eml2mboxcl {
 124         my ($eml, $smsg) = @_;
 125         my $buf = _mbox_hdr_buf($eml, 'mboxcl', $smsg);
 126         my $crlf = $eml->{crlf};
 127         if (my $bdy = delete $eml->{bdy}) {
 128                 $$bdy =~ s/^From />From /gm;
 129                 _mboxcl_common($buf, $bdy, $crlf);
 130         }
 131         $$buf .= $crlf;
 132         $buf;
 133 }
 134
 135 # mboxcl2 has no "From " escaping
 136 sub eml2mboxcl2 {
 137         my ($eml, $smsg) = @_;
 138         my $buf = _mbox_hdr_buf($eml, 'mboxcl2', $smsg);
 139         my $crlf = $eml->{crlf};
 140         if (my $bdy = delete $eml->{bdy}) {
 141                 _mboxcl_common($buf, $bdy, $crlf);
 142         }
 143         $$buf .= $crlf;
 144         $buf;
 145 }
 146
 147 sub git_to_mail { # git->cat_async callback
 148         my ($bref, $oid, $type, $size, $arg) = @_;
 149         if ($type ne 'blob') {
 150                 if ($type eq 'missing') {
 151                         warn "missing $oid\n";
 152                 } else {
 153                         warn "unexpected type=$type for $oid\n";
 154                 }
 155         }
 156         my ($write_cb, $smsg) = @$arg;
 157         if ($smsg->{blob} ne $oid) {
 158                 die "BUG: expected=$smsg->{blob} got=$oid";
 159         }
 160         $write_cb->($bref, $smsg) if $size > 0;
 161 }
 162
 163 sub reap_compress { # dwaitpid callback
 164         my ($lei, $pid) = @_;
 165         my $cmd = delete $lei->{"pid.$pid"};
 166         return if $? == 0;
 167         $lei->fail("@$cmd failed", $? >> 8);
 168 }
 169
 170 sub _post_augment_mbox { # open a compressor process
 171         my ($self, $lei) = @_;
 172         my $zsfx = $self->{zsfx} or return;
 173         my $cmd = PublicInbox::MboxReader::zsfx2cmd($zsfx, undef, $lei);
 174         my ($r, $w) = @{delete $lei->{zpipe}};
 175         my $rdr = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 176         my $pid = spawn($cmd, undef, $rdr);
 177         my $pp = gensym;
 178         my $dup = bless { "pid.$pid" => $cmd }, ref($lei);
 179         $dup->{$_} = $lei->{$_} for qw(2 sock);
 180         tie *$pp, 'PublicInbox::ProcessPipe', $pid, $w, \&reap_compress, $dup;
 181         $lei->{1} = $pp;
 182 }
 183
 184 sub dup_src ($) {
 185         my ($in) = @_;
 186         open my $dup, '+>>&', $in or die "dup: $!";
 187         $dup;
 188 }
 189
 190 # --augment existing output destination, with deduplication
 191 sub _augment { # MboxReader eml_cb
 192         my ($eml, $lei) = @_;
 193         # ignore return value, just populate the skv
 194         $lei->{dedupe}->is_dup($eml);
 195 }
 196
 197 sub _mbox_augment_kw_maybe {
 198         my ($eml, $lei, $lse, $augment) = @_;
 199         my $kw = PublicInbox::MboxReader::mbox_keywords($eml);
 200         update_kw_maybe($lei, $lse, $eml, $kw);
 201         _augment($eml, $lei) if $augment;
 202 }
 203
 204 sub _mbox_write_cb ($$) {
 205         my ($self, $lei) = @_;
 206         my $ovv = $lei->{ovv};
 207         my $m = 'eml2'.$ovv->{fmt};
 208         my $eml2mbox = $self->can($m) or die "$self->$m missing";
 209         $lei->{1} // die "no stdout ($m, $ovv->{dst})"; # redirected earlier
 210         $lei->{1}->autoflush(1);
 211         my $atomic_append = !defined($ovv->{lock_path});
 212         my $dedupe = $lei->{dedupe};
 213         $dedupe->prepare_dedupe;
 214         my $lse = $lei->{lse}; # may be undef
 215         sub { # for git_to_mail
 216                 my ($buf, $smsg, $eml) = @_;
 217                 $eml //= PublicInbox::Eml->new($buf);
 218                 return if $dedupe->is_dup($eml, $smsg->{blob});
 219                 $lse->xsmsg_vmd($smsg) if $lse;
 220                 $buf = $eml2mbox->($eml, $smsg);
 221                 return atomic_append($lei, $buf) if $atomic_append;
 222                 my $lk = $ovv->lock_for_scope;
 223                 $lei->out($$buf);
 224         }
 225 }
 226
 227 sub update_kw_maybe ($$$$) {
 228         my ($lei, $lse, $eml, $kw) = @_;
 229         return unless $lse;
 230         my $x = $lse->kw_changed($eml, $kw);
 231         my $vmd = { kw => $kw };
 232         if ($x) {
 233                 $lei->{sto}->ipc_do('set_eml', $eml, $vmd);
 234         } elsif (!defined($x)) {
 235                 if (my $xoids = $lei->{ale}->xoids_for($eml)) {
 236                         $lei->{sto}->ipc_do('set_xvmd', $xoids, $eml, $vmd);
 237                 } else {
 238                         $lei->{sto}->ipc_do('set_eml', $eml, $vmd);
 239                 }
 240         }
 241 }
 242
 243 sub _augment_or_unlink { # maildir_each_eml cb
 244         my ($f, $kw, $eml, $lei, $lse, $mod, $shard, $unlink) = @_;
 245         if ($mod) {
 246                 # can't get dirent.d_ino w/ pure Perl, so we extract the OID
 247                 # if it looks like one:
 248                 my $hex = $f =~ m!\b([a-f0-9]{40,})[^/]*\z! ?
 249                                 $1 : sha256_hex($f);
 250                 my $recno = hex(substr($hex, 0, 8));
 251                 return if ($recno % $mod) != $shard;
 252                 update_kw_maybe($lei, $lse, $eml, $kw);
 253         }
 254         $unlink ? unlink($f) : _augment($eml, $lei);
 255 }
 256
 257 # maildir_each_file callback, \&CORE::unlink doesn't work with it
 258 sub _unlink { unlink($_[0]) }
 259
 260 sub _rand () {
 261         state $seq = 0;
 262         sprintf('%x,%x,%x,%x', rand(0xffffffff), time, $$, ++$seq);
 263 }
 264
 265 sub _buf2maildir {
 266         my ($dst, $buf, $smsg) = @_;
 267         my $kw = $smsg->{kw} // [];
 268         my $sfx = join('', sort(map { $kw2char{$_} // () } @$kw));
 269         my $rand = ''; # chosen by die roll :P
 270         my ($tmp, $fh, $final, $ok);
 271         my $common = $smsg->{blob} // _rand;
 272         if (defined(my $pct = $smsg->{pct})) { $common .= "=$pct" }
 273         do {
 274                 $tmp = $dst.'tmp/'.$rand.$common;
 275         } while (!($ok = sysopen($fh, $tmp, O_CREAT|O_EXCL|O_WRONLY)) &&
 276                 $! == EEXIST && ($rand = _rand.','));
 277         if ($ok && print $fh $$buf and close($fh)) {
 278                 # ignore new/ and write only to cur/, otherwise MUAs
 279                 # with R/W access to the Maildir will end up doing
 280                 # a mass rename which can take a while with thousands
 281                 # of messages.
 282                 $dst .= 'cur/';
 283                 $rand = '';
 284                 do {
 285                         $final = $dst.$rand.$common.':2,'.$sfx;
 286                 } while (!($ok = link($tmp, $final)) && $! == EEXIST &&
 287                         ($rand = _rand.','));
 288                 die "link($tmp, $final): $!" unless $ok;
 289                 unlink($tmp) or warn "W: failed to unlink $tmp: $!\n";
 290         } else {
 291                 my $err = "Error writing $smsg->{blob} to $dst: $!\n";
 292                 $_[0] = undef; # clobber dst
 293                 unlink($tmp);
 294                 die $err;
 295         }
 296 }
 297
 298 sub _maildir_write_cb ($$) {
 299         my ($self, $lei) = @_;
 300         my $dedupe = $lei->{dedupe};
 301         $dedupe->prepare_dedupe if $dedupe;
 302         my $dst = $lei->{ovv}->{dst};
 303         my $lse = $lei->{lse}; # may be undef
 304         sub { # for git_to_mail
 305                 my ($buf, $smsg, $eml) = @_;
 306                 $dst // return $lei->fail; # dst may be undef-ed in last run
 307                 $buf //= \($eml->as_string);
 308                 $lse->xsmsg_vmd($smsg) if $lse;
 309                 return _buf2maildir($dst, $buf, $smsg) if !$dedupe;
 310                 $eml //= PublicInbox::Eml->new($$buf); # copy buf
 311                 return if $dedupe->is_dup($eml, $smsg->{blob});
 312                 undef $eml;
 313                 _buf2maildir($dst, $buf, $smsg);
 314         }
 315 }
 316
 317 sub _imap_write_cb ($$) {
 318         my ($self, $lei) = @_;
 319         my $dedupe = $lei->{dedupe};
 320         $dedupe->prepare_dedupe if $dedupe;
 321         my $imap_append = $lei->{net}->can('imap_append');
 322         my $mic = $lei->{net}->mic_get($self->{uri});
 323         my $folder = $self->{uri}->mailbox;
 324         my $lse = $lei->{lse}; # may be undef
 325         sub { # for git_to_mail
 326                 my ($bref, $smsg, $eml) = @_;
 327                 $mic // return $lei->fail; # dst may be undef-ed in last run
 328                 if ($dedupe) {
 329                         $eml //= PublicInbox::Eml->new($$bref); # copy bref
 330                         return if $dedupe->is_dup($eml, $smsg->{blob});
 331                 }
 332                 $lse->xsmsg_vmd($smsg) if $lse;
 333                 eval { $imap_append->($mic, $folder, $bref, $smsg, $eml) };
 334                 if (my $err = $@) {
 335                         undef $mic;
 336                         die $err;
 337                 }
 338         }
 339 }
 340
 341 sub write_cb { # returns a callback for git_to_mail
 342         my ($self, $lei) = @_;
 343         # _mbox_write_cb, _maildir_write_cb or _imap_write_cb
 344         my $m = "_$self->{base_type}_write_cb";
 345         $self->$m($lei);
 346 }
 347
 348 sub new {
 349         my ($cls, $lei) = @_;
 350         my $fmt = $lei->{ovv}->{fmt};
 351         my $dst = $lei->{ovv}->{dst};
 352         my $self = bless {}, $cls;
 353         if ($fmt eq 'maildir') {
 354                 require PublicInbox::MdirReader;
 355                 $self->{base_type} = 'maildir';
 356                 -e $dst && !-d _ and die
 357                                 "$dst exists and is not a directory\n";
 358                 $lei->{ovv}->{dst} = $dst .= '/' if substr($dst, -1) ne '/';
 359         } elsif (substr($fmt, 0, 4) eq 'mbox') {
 360                 require PublicInbox::MboxReader;
 361                 (-d $dst || (-e _ && !-w _)) and die
 362                         "$dst exists and is not a writable file\n";
 363                 $self->can("eml2$fmt") or die "bad mbox format: $fmt\n";
 364                 $self->{base_type} = 'mbox';
 365         } elsif ($fmt =~ /\Aimaps?\z/) { # TODO .onion support
 366                 require PublicInbox::NetWriter;
 367                 my $net = PublicInbox::NetWriter->new;
 368                 $net->add_url($dst);
 369                 $net->{quiet} = $lei->{opt}->{quiet};
 370                 my $err = $net->errors($dst);
 371                 return $lei->fail($err) if $err;
 372                 require PublicInbox::URIimap; # TODO: URI cast early
 373                 $self->{uri} = PublicInbox::URIimap->new($dst);
 374                 $self->{uri}->mailbox or die "No mailbox: $dst";
 375                 $lei->{net} = $net;
 376                 $self->{base_type} = 'imap';
 377         } else {
 378                 die "bad mail --format=$fmt\n";
 379         }
 380         $self->{dst} = $dst;
 381         $lei->{dedupe} = PublicInbox::LeiDedupe->new($lei);
 382         $self;
 383 }
 384
 385 sub _pre_augment_maildir {
 386         my ($self, $lei) = @_;
 387         my $dst = $lei->{ovv}->{dst};
 388         for my $x (qw(tmp new cur)) {
 389                 my $d = $dst.$x;
 390                 next if -d $d;
 391                 require File::Path;
 392                 File::Path::mkpath($d);
 393                 -d $d or die "$d is not a directory";
 394         }
 395 }
 396
 397 sub _do_augment_maildir {
 398         my ($self, $lei) = @_;
 399         my $dst = $lei->{ovv}->{dst};
 400         my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
 401         my ($mod, $shard) = @{$self->{shard_info} // []};
 402         if ($lei->{opt}->{augment}) {
 403                 my $dedupe = $lei->{dedupe};
 404                 if ($dedupe && $dedupe->prepare_dedupe) {
 405                         PublicInbox::MdirReader::maildir_each_eml($dst,
 406                                                 \&_augment_or_unlink,
 407                                                 $lei, $lse, $mod, $shard);
 408                         $dedupe->pause_dedupe;
 409                 }
 410         } elsif ($lse) {
 411                 PublicInbox::MdirReader::maildir_each_eml($dst,
 412                                         \&_augment_or_unlink,
 413                                         $lei, $lse, $mod, $shard, 1);
 414         } else {# clobber existing Maildir
 415                 PublicInbox::MdirReader::maildir_each_file($dst, \&_unlink);
 416         }
 417 }
 418
 419 sub _imap_augment_or_delete { # PublicInbox::NetReader::imap_each cb
 420         my ($url, $uid, $kw, $eml, $lei, $lse, $delete_mic) = @_;
 421         update_kw_maybe($lei, $lse, $eml, $kw);
 422         if ($delete_mic) {
 423                 $lei->{net}->imap_delete_1($url, $uid, $delete_mic);
 424         } else {
 425                 _augment($eml, $lei);
 426         }
 427 }
 428
 429 sub _do_augment_imap {
 430         my ($self, $lei) = @_;
 431         my $net = $lei->{net};
 432         my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
 433         if ($lei->{opt}->{augment}) {
 434                 my $dedupe = $lei->{dedupe};
 435                 if ($dedupe && $dedupe->prepare_dedupe) {
 436                         $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 437                                         $lei, $lse);
 438                         $dedupe->pause_dedupe;
 439                 }
 440         } elsif ($lse) {
 441                 my $delete_mic;
 442                 $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 443                                         $lei, $lse, \$delete_mic);
 444                 $delete_mic->expunge if $delete_mic;
 445         } elsif (!$self->{-wq_worker_nr}) { # undef or 0
 446                 # clobber existing IMAP folder
 447                 $net->imap_delete_all($self->{uri});
 448         }
 449 }
 450
 451 sub _pre_augment_mbox {
 452         my ($self, $lei) = @_;
 453         my $dst = $lei->{ovv}->{dst};
 454         my $out;
 455         my $devfd = $lei->path_to_fd($dst) // die "bad $dst";
 456         if ($devfd >= 0) {
 457                 $out = $lei->{$devfd};
 458         } else { # normal-looking path
 459                 if (-p $dst) {
 460                         open $out, '>', $dst or die "open($dst): $!";
 461                 } elsif (-f _ || !-e _) {
 462                         require PublicInbox::MboxLock;
 463                         my $m = $lei->{opt}->{'lock'} //
 464                                         PublicInbox::MboxLock->defaults;
 465                         $self->{mbl} = PublicInbox::MboxLock->acq($dst, 1, $m);
 466                         $out = $self->{mbl}->{fh};
 467                 } else {
 468                         die "$dst is not a file or FIFO\n";
 469                 }
 470                 $lei->{old_1} = $lei->{1}; # keep for spawning MUA
 471         }
 472         # Perl does SEEK_END even with O_APPEND :<
 473         $self->{seekable} = seek($out, 0, SEEK_SET);
 474         if (!$self->{seekable} && $! != ESPIPE && !defined($devfd)) {
 475                 die "seek($dst): $!\n";
 476         }
 477         if (!$self->{seekable}) {
 478                 my $imp_before = $lei->{opt}->{'import-before'};
 479                 die "--import-before specified but $dst is not seekable\n"
 480                         if $imp_before && !ref($imp_before);
 481                 die "--augment specified but $dst is not seekable\n" if
 482                         $lei->{opt}->{augment};
 483         }
 484         if ($self->{zsfx} = PublicInbox::MboxReader::zsfx($dst)) {
 485                 pipe(my ($r, $w)) or die "pipe: $!";
 486                 $lei->{zpipe} = [ $r, $w ];
 487                 $lei->{ovv}->{lock_path} and
 488                         die 'BUG: unexpected {ovv}->{lock_path}';
 489                 $lei->{ovv}->ovv_out_lk_init;
 490         } elsif (!$self->{seekable} && !$lei->{ovv}->{lock_path}) {
 491                 $lei->{ovv}->ovv_out_lk_init;
 492         }
 493         $lei->{1} = $out;
 494         undef;
 495 }
 496
 497 sub _do_augment_mbox {
 498         my ($self, $lei) = @_;
 499         return unless $self->{seekable};
 500         my $opt = $lei->{opt};
 501         my $out = $lei->{1};
 502         my ($fmt, $dst) = @{$lei->{ovv}}{qw(fmt dst)};
 503         return unless -s $out;
 504         unless ($opt->{augment} || $opt->{'import-before'}) {
 505                 truncate($out, 0) or die "truncate($dst): $!";
 506                 return;
 507         }
 508         my $zsfx = $self->{zsfx};
 509         my $rd = $zsfx ? PublicInbox::MboxReader::zsfxcat($out, $zsfx, $lei)
 510                         : dup_src($out);
 511         my $dedupe;
 512         if ($opt->{augment}) {
 513                 $dedupe = $lei->{dedupe};
 514                 $dedupe->prepare_dedupe if $dedupe;
 515         }
 516         if ($opt->{'import-before'}) { # the default
 517                 my $lse = $lei->{lse};
 518                 PublicInbox::MboxReader->$fmt($rd, \&_mbox_augment_kw_maybe,
 519                                                 $lei, $lse, $opt->{augment});
 520                 if (!$opt->{augment} and !truncate($out, 0)) {
 521                         die "truncate($dst): $!";
 522                 }
 523         } else { # --augment --no-import-before
 524                 PublicInbox::MboxReader->$fmt($rd, \&_augment, $lei);
 525         }
 526         # maybe some systems don't honor O_APPEND, Perl does this:
 527         seek($out, 0, SEEK_END) or die "seek $dst: $!";
 528         $dedupe->pause_dedupe if $dedupe;
 529 }
 530
 531 sub pre_augment { # fast (1 disk seek), runs in same process as post_augment
 532         my ($self, $lei) = @_;
 533         # _pre_augment_maildir, _pre_augment_mbox
 534         my $m = $self->can("_pre_augment_$self->{base_type}") or return;
 535         $m->($self, $lei);
 536 }
 537
 538 sub do_augment { # slow, runs in wq worker
 539         my ($self, $lei) = @_;
 540         # _do_augment_maildir, _do_augment_mbox, or _do_augment_imap
 541         my $m = "_do_augment_$self->{base_type}";
 542         $self->$m($lei);
 543 }
 544
 545 # fast (spawn compressor or mkdir), runs in same process as pre_augment
 546 sub post_augment {
 547         my ($self, $lei, @args) = @_;
 548         my $wait = $lei->{opt}->{'import-before'} ?
 549                         $lei->{sto}->ipc_do('checkpoint', 1) : 0;
 550         # _post_augment_mbox
 551         my $m = $self->can("_post_augment_$self->{base_type}") or return;
 552         $m->($self, $lei, @args);
 553 }
 554
 555 sub do_post_auth {
 556         my ($self) = @_;
 557         my $lei = $self->{lei};
 558         # lei_xsearch can start as soon as all l2m workers get here
 559         pkt_do($lei->{pkt_op_p}, 'incr_start_query') or
 560                 die "incr_start_query: $!";
 561         my $aug;
 562         if (lock_free($self)) {
 563                 my $mod = $self->{-wq_nr_workers};
 564                 my $shard = $self->{-wq_worker_nr};
 565                 if (my $net = $lei->{net}) {
 566                         $net->{shard_info} = [ $mod, $shard ];
 567                 } else { # Maildir (MH?)
 568                         $self->{shard_info} = [ $mod, $shard ];
 569                 }
 570                 $aug = '+'; # incr_post_augment
 571         } elsif ($self->{-wq_worker_nr} == 0) {
 572                 $aug = '.'; # do_post_augment
 573         }
 574         if ($aug) {
 575                 local $0 = 'do_augment';
 576                 eval { do_augment($self, $lei) };
 577                 $lei->fail($@) if $@;
 578                 pkt_do($lei->{pkt_op_p}, $aug) == 1 or
 579                                 die "do_post_augment trigger: $!";
 580         }
 581         if (my $zpipe = delete $lei->{zpipe}) {
 582                 $lei->{1} = $zpipe->[1];
 583                 close $zpipe->[0];
 584         }
 585         $self->{wcb} = $self->write_cb($lei);
 586 }
 587
 588 sub ipc_atfork_child {
 589         my ($self) = @_;
 590         my $lei = $self->{lei};
 591         $lei->_lei_atfork_child;
 592         $lei->{auth}->do_auth_atfork($self) if $lei->{auth};
 593         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 594         $self->SUPER::ipc_atfork_child;
 595 }
 596
 597 sub lock_free {
 598         $_[0]->{base_type} =~ /\A(?:maildir|mh|imap|jmap)\z/ ? 1 : 0;
 599 }
 600
 601 sub poke_dst {
 602         my ($self) = @_;
 603         if ($self->{base_type} eq 'maildir') {
 604                 my $t = time + 1;
 605                 utime($t, $t, $self->{dst} . 'cur');
 606         }
 607 }
 608
 609 sub write_mail { # via ->wq_io_do
 610         my ($self, $smsg) = @_;
 611         git_async_cat($self->{lei}->{ale}->git, $smsg->{blob}, \&git_to_mail,
 612                                 [$self->{wcb}, $smsg]);
 613 }
 614
 615 sub wq_atexit_child {
 616         my ($self) = @_;
 617         delete $self->{wcb};
 618         $self->{lei}->{ale}->git->async_wait_all;
 619         $SIG{__WARN__} = 'DEFAULT';
 620 }
 621
 622 # called in top-level lei-daemon when LeiAuth is done
 623 sub net_merge_complete {
 624         my ($self) = @_;
 625         $self->wq_broadcast('do_post_auth');
 626         $self->wq_close(1);
 627 }
 628
 629 no warnings 'once'; # the following works even when LeiAuth is lazy-loaded
 630 *net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
 631 1;