lib/PublicInbox/LeiToMail.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Writes PublicInbox::Eml objects atomically to a mbox variant or Maildir
   5 package PublicInbox::LeiToMail;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::ProcessPipe;
  11 use PublicInbox::Spawn qw(spawn);
  12 use PublicInbox::PktOp qw(pkt_do);
  13 use Symbol qw(gensym);
  14 use IO::Handle; # ->autoflush
  15 use Fcntl qw(SEEK_SET SEEK_END O_CREAT O_EXCL O_WRONLY);
  16
  17 my %kw2char = ( # Maildir characters
  18         draft => 'D',
  19         flagged => 'F',
  20         forwarded => 'P', # passed
  21         answered => 'R',
  22         seen => 'S',
  23 );
  24
  25 my %kw2status = (
  26         flagged => [ 'X-Status' => 'F' ],
  27         answered => [ 'X-Status' => 'A' ],
  28         seen => [ 'Status' => 'R' ],
  29         draft => [ 'X-Status' => 'T' ],
  30 );
  31
  32 sub _mbox_hdr_buf ($$$) {
  33         my ($eml, $type, $smsg) = @_;
  34         $eml->header_set($_) for (qw(Lines Bytes Content-Length));
  35
  36         my %hdr = (Status => []); # set Status, X-Status
  37         for my $k (@{$smsg->{kw} // []}) {
  38                 if (my $ent = $kw2status{$k}) {
  39                         push @{$hdr{$ent->[0]}}, $ent->[1];
  40                 } else { # X-Label?
  41                         warn "# keyword `$k' not supported for mbox\n";
  42                 }
  43         }
  44         # Messages are always 'O' (non-\Recent in IMAP), it saves
  45         # MUAs the trouble of rewriting the mbox if no other
  46         # changes are made.  We put 'O' at the end (e.g. "Status: RO")
  47         # to match mutt(1) output.
  48         $eml->header_set('Status', join('', sort(@{$hdr{Status}})). 'O');
  49         if (my $chars = delete $hdr{'X-Status'}) {
  50                 $eml->header_set('X-Status', join('', sort(@$chars)));
  51         }
  52         my $buf = delete $eml->{hdr};
  53
  54         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
  55         $$buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  56         my $ident = $smsg->{blob} // 'lei';
  57         if (defined(my $pct = $smsg->{pct})) { $ident .= "=$pct" }
  58
  59         substr($$buf, 0, 0, # prepend From line
  60                 "From $ident\@$type Thu Jan  1 00:00:00 1970$eml->{crlf}");
  61         $buf;
  62 }
  63
  64 sub atomic_append { # for on-disk destinations (O_APPEND, or O_EXCL)
  65         my ($lei, $buf) = @_;
  66         if (defined(my $w = syswrite($lei->{1} // return, $$buf))) {
  67                 return if $w == length($$buf);
  68                 $buf = "short atomic write: $w != ".length($$buf);
  69         } elsif ($!{EPIPE}) {
  70                 return $lei->note_sigpipe(1);
  71         } else {
  72                 $buf = "atomic write: $!";
  73         }
  74         $lei->fail($buf);
  75 }
  76
  77 sub eml2mboxrd ($;$) {
  78         my ($eml, $smsg) = @_;
  79         my $buf = _mbox_hdr_buf($eml, 'mboxrd', $smsg);
  80         if (my $bdy = delete $eml->{bdy}) {
  81                 $$bdy =~ s/^(>*From )/>$1/gm;
  82                 $$buf .= $eml->{crlf};
  83                 substr($$bdy, 0, 0, $$buf); # prepend header
  84                 $buf = $bdy;
  85         }
  86         $$buf .= $eml->{crlf};
  87         $buf;
  88 }
  89
  90 sub eml2mboxo {
  91         my ($eml, $smsg) = @_;
  92         my $buf = _mbox_hdr_buf($eml, 'mboxo', $smsg);
  93         if (my $bdy = delete $eml->{bdy}) {
  94                 $$bdy =~ s/^From />From /gm;
  95                 $$buf .= $eml->{crlf};
  96                 substr($$bdy, 0, 0, $$buf); # prepend header
  97                 $buf = $bdy;
  98         }
  99         $$buf .= $eml->{crlf};
 100         $buf;
 101 }
 102
 103 sub _mboxcl_common ($$$) {
 104         my ($buf, $bdy, $crlf) = @_;
 105         # add Lines: so mutt won't have to add it on MUA close
 106         my $lines = $$bdy =~ tr!\n!\n!;
 107         $$buf .= 'Content-Length: '.length($$bdy).$crlf.
 108                 'Lines: '.$lines.$crlf.$crlf;
 109         substr($$bdy, 0, 0, $$buf); # prepend header
 110         $_[0] = $bdy;
 111 }
 112
 113 # mboxcl still escapes "From " lines
 114 sub eml2mboxcl {
 115         my ($eml, $smsg) = @_;
 116         my $buf = _mbox_hdr_buf($eml, 'mboxcl', $smsg);
 117         my $crlf = $eml->{crlf};
 118         if (my $bdy = delete $eml->{bdy}) {
 119                 $$bdy =~ s/^From />From /gm;
 120                 _mboxcl_common($buf, $bdy, $crlf);
 121         }
 122         $$buf .= $crlf;
 123         $buf;
 124 }
 125
 126 # mboxcl2 has no "From " escaping
 127 sub eml2mboxcl2 {
 128         my ($eml, $smsg) = @_;
 129         my $buf = _mbox_hdr_buf($eml, 'mboxcl2', $smsg);
 130         my $crlf = $eml->{crlf};
 131         if (my $bdy = delete $eml->{bdy}) {
 132                 _mboxcl_common($buf, $bdy, $crlf);
 133         }
 134         $$buf .= $crlf;
 135         $buf;
 136 }
 137
 138 sub git_to_mail { # git->cat_async callback
 139         my ($bref, $oid, $type, $size, $arg) = @_;
 140         return warn("W: $oid is $type (!= blob)\n") if $type ne 'blob';
 141         return warn("E: $oid is empty\n") unless $size;
 142         my ($write_cb, $smsg) = @$arg;
 143         die "BUG: expected=$smsg->{blob} got=$oid" if $smsg->{blob} ne $oid;
 144         $write_cb->($bref, $smsg);
 145 }
 146
 147 sub reap_compress { # dwaitpid callback
 148         my ($lei, $pid) = @_;
 149         my $cmd = delete $lei->{"pid.$pid"};
 150         return if $? == 0;
 151         $lei->fail("@$cmd failed", $? >> 8);
 152 }
 153
 154 sub _post_augment_mbox { # open a compressor process from top-level process
 155         my ($self, $lei) = @_;
 156         my $zsfx = $self->{zsfx} or return;
 157         my $cmd = PublicInbox::MboxReader::zsfx2cmd($zsfx, undef, $lei);
 158         my ($r, $w) = @{delete $lei->{zpipe}};
 159         my $rdr = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 160         my $pid = spawn($cmd, undef, $rdr);
 161         my $pp = gensym;
 162         my $dup = bless { "pid.$pid" => $cmd }, ref($lei);
 163         $dup->{$_} = $lei->{$_} for qw(2 sock);
 164         tie *$pp, 'PublicInbox::ProcessPipe', $pid, $w, \&reap_compress, $dup;
 165         $lei->{1} = $pp;
 166 }
 167
 168 # --augment existing output destination, with deduplication
 169 sub _augment { # MboxReader eml_cb
 170         my ($eml, $lei) = @_;
 171         # ignore return value, just populate the skv
 172         $lei->{dedupe}->is_dup($eml);
 173 }
 174
 175 sub _mbox_augment_kw_maybe {
 176         my ($eml, $lei, $lse, $augment) = @_;
 177         my $kw = PublicInbox::MboxReader::mbox_keywords($eml);
 178         update_kw_maybe($lei, $lse, $eml, $kw);
 179         _augment($eml, $lei) if $augment;
 180 }
 181
 182 sub _mbox_write_cb ($$) {
 183         my ($self, $lei) = @_;
 184         my $ovv = $lei->{ovv};
 185         my $m = 'eml2'.$ovv->{fmt};
 186         my $eml2mbox = $self->can($m) or die "$self->$m missing";
 187         $lei->{1} // die "no stdout ($m, $ovv->{dst})"; # redirected earlier
 188         $lei->{1}->autoflush(1);
 189         my $atomic_append = !defined($ovv->{lock_path});
 190         my $dedupe = $lei->{dedupe};
 191         $dedupe->prepare_dedupe;
 192         my $lse = $lei->{lse}; # may be undef
 193         sub { # for git_to_mail
 194                 my ($buf, $smsg, $eml) = @_;
 195                 $eml //= PublicInbox::Eml->new($buf);
 196                 return if $dedupe->is_dup($eml, $smsg);
 197                 $lse->xsmsg_vmd($smsg) if $lse;
 198                 $buf = $eml2mbox->($eml, $smsg);
 199                 if ($atomic_append) {
 200                         atomic_append($lei, $buf);
 201                 } else {
 202                         my $lk = $ovv->lock_for_scope;
 203                         $lei->out($$buf);
 204                 }
 205                 ++$lei->{-nr_write};
 206         }
 207 }
 208
 209 sub update_kw_maybe ($$$$) {
 210         my ($lei, $lse, $eml, $kw) = @_;
 211         return unless $lse;
 212         my $c = $lse->kw_changed($eml, $kw, my $docids = []);
 213         my $vmd = { kw => $kw };
 214         if (scalar @$docids) { # already in lei/store
 215                 $lei->{sto}->ipc_do('set_eml_vmd', undef, $vmd, $docids) if $c;
 216         } elsif (my $xoids = $lei->{ale}->xoids_for($eml)) {
 217                 # it's in an external, only set kw, here
 218                 $lei->{sto}->ipc_do('set_xvmd', $xoids, $eml, $vmd);
 219         } else { # never-before-seen, import the whole thing
 220                 # XXX this is critical in protecting against accidental
 221                 # data loss without --augment
 222                 $lei->{sto}->ipc_do('set_eml', $eml, $vmd);
 223         }
 224 }
 225
 226 sub _md_update { # maildir_each_eml cb
 227         my ($f, $kw, $eml, $lei, $lse, $unlink) = @_;
 228         update_kw_maybe($lei, $lse, $eml, $kw);
 229         $unlink ? unlink($f) : _augment($eml, $lei);
 230 }
 231
 232 # maildir_each_file callback, \&CORE::unlink doesn't work with it
 233 sub _unlink { unlink($_[0]) }
 234
 235 sub _rand () {
 236         state $seq = 0;
 237         sprintf('%x,%x,%x,%x', rand(0xffffffff), time, $$, ++$seq);
 238 }
 239
 240 sub _buf2maildir {
 241         my ($dst, $buf, $smsg) = @_;
 242         my $kw = $smsg->{kw} // [];
 243         my $sfx = join('', sort(map { $kw2char{$_} // () } @$kw));
 244         my $rand = ''; # chosen by die roll :P
 245         my ($tmp, $fh, $final, $ok);
 246         my $common = $smsg->{blob} // _rand;
 247         if (defined(my $pct = $smsg->{pct})) { $common .= "=$pct" }
 248         do {
 249                 $tmp = $dst.'tmp/'.$rand.$common;
 250         } while (!($ok = sysopen($fh, $tmp, O_CREAT|O_EXCL|O_WRONLY)) &&
 251                 $!{EEXIST} && ($rand = _rand.','));
 252         if ($ok && print $fh $$buf and close($fh)) {
 253                 # ignore new/ and write only to cur/, otherwise MUAs
 254                 # with R/W access to the Maildir will end up doing
 255                 # a mass rename which can take a while with thousands
 256                 # of messages.
 257                 $dst .= 'cur/';
 258                 $rand = '';
 259                 do {
 260                         $final = $dst.$rand.$common.':2,'.$sfx;
 261                 } while (!($ok = link($tmp, $final)) && $!{EEXIST} &&
 262                         ($rand = _rand.','));
 263                 die "link($tmp, $final): $!" unless $ok;
 264                 unlink($tmp) or warn "W: failed to unlink $tmp: $!\n";
 265         } else {
 266                 my $err = "Error writing $smsg->{blob} to $dst: $!\n";
 267                 $_[0] = undef; # clobber dst
 268                 unlink($tmp);
 269                 die $err;
 270         }
 271 }
 272
 273 sub _maildir_write_cb ($$) {
 274         my ($self, $lei) = @_;
 275         my $dedupe = $lei->{dedupe};
 276         $dedupe->prepare_dedupe if $dedupe;
 277         my $dst = $lei->{ovv}->{dst};
 278         my $lse = $lei->{lse}; # may be undef
 279         sub { # for git_to_mail
 280                 my ($bref, $smsg, $eml) = @_;
 281                 $dst // return $lei->fail; # dst may be undef-ed in last run
 282                 return if $dedupe && $dedupe->is_dup($eml //
 283                                                 PublicInbox::Eml->new($$bref));
 284                 $lse->xsmsg_vmd($smsg) if $lse;
 285                 _buf2maildir($dst, $bref // \($eml->as_string), $smsg);
 286                 ++$lei->{-nr_write};
 287         }
 288 }
 289
 290 sub _imap_write_cb ($$) {
 291         my ($self, $lei) = @_;
 292         my $dedupe = $lei->{dedupe};
 293         $dedupe->prepare_dedupe if $dedupe;
 294         my $imap_append = $lei->{net}->can('imap_append');
 295         my $mic = $lei->{net}->mic_get($self->{uri});
 296         my $folder = $self->{uri}->mailbox;
 297         my $lse = $lei->{lse}; # may be undef
 298         sub { # for git_to_mail
 299                 my ($bref, $smsg, $eml) = @_;
 300                 $mic // return $lei->fail; # mic may be undef-ed in last run
 301                 return if $dedupe && $dedupe->is_dup($eml //
 302                                                 PublicInbox::Eml->new($$bref));
 303                 $lse->xsmsg_vmd($smsg) if $lse;
 304                 eval { $imap_append->($mic, $folder, $bref, $smsg, $eml) };
 305                 if (my $err = $@) {
 306                         undef $mic;
 307                         die $err;
 308                 }
 309                 ++$lei->{-nr_write};
 310         }
 311 }
 312
 313 sub _text_write_cb ($$) {
 314         my ($self, $lei) = @_;
 315         my $dedupe = $lei->{dedupe};
 316         $dedupe->prepare_dedupe if $dedupe;
 317         my $lvt = $lei->{lvt};
 318         my $ovv = $lei->{ovv};
 319         $lei->{1} // die "no stdout ($ovv->{dst})"; # redirected earlier
 320         $lei->{1}->autoflush(1);
 321         binmode $lei->{1}, ':utf8';
 322         my $lse = $lei->{lse}; # may be undef
 323         sub { # for git_to_mail
 324                 my ($bref, $smsg, $eml) = @_;
 325                 $lse->xsmsg_vmd($smsg) if $lse;
 326                 $eml //= PublicInbox::Eml->new($bref); # copy bref
 327                 return if $dedupe && $dedupe->is_dup($eml, $smsg);
 328                 my $lk = $ovv->lock_for_scope;
 329                 $lei->out(${$lvt->eml_to_text($smsg, $eml)}, "\n");
 330         }
 331 }
 332
 333 sub write_cb { # returns a callback for git_to_mail
 334         my ($self, $lei) = @_;
 335         # _mbox_write_cb, _maildir_write_cb or _imap_write_cb
 336         my $m = "_$self->{base_type}_write_cb";
 337         $self->$m($lei);
 338 }
 339
 340 sub new {
 341         my ($cls, $lei) = @_;
 342         my $fmt = $lei->{ovv}->{fmt};
 343         my $dst = $lei->{ovv}->{dst};
 344         my $self = bless {}, $cls;
 345         if ($fmt eq 'maildir') {
 346                 require PublicInbox::MdirReader;
 347                 $self->{base_type} = 'maildir';
 348                 -e $dst && !-d _ and die
 349                                 "$dst exists and is not a directory\n";
 350                 $lei->{ovv}->{dst} = $dst .= '/' if substr($dst, -1) ne '/';
 351         } elsif (substr($fmt, 0, 4) eq 'mbox') {
 352                 require PublicInbox::MboxReader;
 353                 $self->can("eml2$fmt") or die "bad mbox format: $fmt\n";
 354                 $self->{base_type} = 'mbox';
 355         } elsif ($fmt =~ /\Aimaps?\z/) {
 356                 require PublicInbox::NetWriter;
 357                 require PublicInbox::URIimap;
 358                 my $net = PublicInbox::NetWriter->new;
 359                 $net->{quiet} = $lei->{opt}->{quiet};
 360                 my $uri = PublicInbox::URIimap->new($dst)->canonical;
 361                 $net->add_url($uri);
 362                 my $err = $net->errors($lei);
 363                 return $lei->fail($err) if $err;
 364                 $uri->mailbox or return $lei->fail("No mailbox: $dst");
 365                 $self->{uri} = $uri;
 366                 $dst = $lei->{ovv}->{dst} = $$uri; # canonicalized
 367                 $lei->{net} = $net;
 368                 $self->{base_type} = 'imap';
 369         } elsif ($fmt eq 'text') {
 370                 require PublicInbox::LeiViewText;
 371                 $lei->{lvt} = PublicInbox::LeiViewText->new($lei);
 372                 $self->{base_type} = 'text';
 373         } else {
 374                 die "bad mail --format=$fmt\n";
 375         }
 376         if ($self->{base_type} =~ /\A(?:text|mbox)\z/) {
 377                 (-d $dst || (-e _ && !-w _)) and die
 378                         "$dst exists and is not a writable file\n";
 379         }
 380         if ($self->{base_type} eq 'text') {
 381                 my @err = map {
 382                         defined($lei->{opt}->{$_}) ? "--$_" : ();
 383                 } (qw(mua save));
 384                 die "@err incompatible with $fmt\n" if @err;
 385         }
 386         $self->{dst} = $dst;
 387         $lei->{dedupe} = $lei->{lss} // do {
 388                 my $dd_cls = 'PublicInbox::'.
 389                         ($lei->{opt}->{save} ? 'LeiSavedSearch' : 'LeiDedupe');
 390                 eval "require $dd_cls";
 391                 die "$dd_cls: $@" if $@;
 392                 $dd_cls->new($lei);
 393         };
 394         $self;
 395 }
 396
 397 sub _pre_augment_maildir {
 398         my ($self, $lei) = @_;
 399         my $dst = $lei->{ovv}->{dst};
 400         for my $x (qw(tmp new cur)) {
 401                 my $d = $dst.$x;
 402                 next if -d $d;
 403                 require File::Path;
 404                 File::Path::mkpath($d);
 405                 -d $d or die "$d is not a directory";
 406         }
 407         # for utime, so no opendir
 408         open $self->{poke_dh}, '<', "${dst}cur" or die "open ${dst}cur: $!";
 409 }
 410
 411 sub _do_augment_maildir {
 412         my ($self, $lei) = @_;
 413         return if ($lei->{opt}->{save} // 0) < 0;
 414         my $dst = $lei->{ovv}->{dst};
 415         my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
 416         my $mdr = PublicInbox::MdirReader->new;
 417         if ($lei->{opt}->{augment}) {
 418                 my $dedupe = $lei->{dedupe};
 419                 if ($dedupe && $dedupe->prepare_dedupe) {
 420                         $mdr->{shard_info} = $self->{shard_info};
 421                         $mdr->maildir_each_eml($dst, \&_md_update, $lei, $lse);
 422                         $dedupe->pause_dedupe;
 423                 }
 424         } elsif ($lse) {
 425                 $mdr->{shard_info} = $self->{shard_info};
 426                 $mdr->maildir_each_eml($dst, \&_md_update, $lei, $lse, 1);
 427         } else {# clobber existing Maildir
 428                 $mdr->maildir_each_file($dst, \&_unlink);
 429         }
 430 }
 431
 432 sub _imap_augment_or_delete { # PublicInbox::NetReader::imap_each cb
 433         my ($url, $uid, $kw, $eml, $lei, $lse, $delete_mic) = @_;
 434         update_kw_maybe($lei, $lse, $eml, $kw);
 435         if ($delete_mic) {
 436                 $lei->{net}->imap_delete_1($url, $uid, $delete_mic);
 437         } else {
 438                 _augment($eml, $lei);
 439         }
 440 }
 441
 442 sub _do_augment_imap {
 443         my ($self, $lei) = @_;
 444         return if ($lei->{opt}->{save} // 0) < 0;
 445         my $net = $lei->{net};
 446         my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
 447         if ($lei->{opt}->{augment}) {
 448                 my $dedupe = $lei->{dedupe};
 449                 if ($dedupe && $dedupe->prepare_dedupe) {
 450                         $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 451                                         $lei, $lse);
 452                         $dedupe->pause_dedupe;
 453                 }
 454         } elsif ($lse) {
 455                 my $delete_mic;
 456                 $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 457                                         $lei, $lse, \$delete_mic);
 458                 $delete_mic->expunge if $delete_mic;
 459         } elsif (!$self->{-wq_worker_nr}) { # undef or 0
 460                 # clobber existing IMAP folder
 461                 $net->imap_delete_all($self->{uri});
 462         }
 463 }
 464
 465 sub _pre_augment_text {
 466         my ($self, $lei) = @_;
 467         my $dst = $lei->{ovv}->{dst};
 468         my $out;
 469         my $devfd = $lei->path_to_fd($dst) // die "bad $dst";
 470         if ($devfd >= 0) {
 471                 $out = $lei->{$devfd};
 472         } else { # normal-looking path
 473                 if (-p $dst) {
 474                         open $out, '>', $dst or die "open($dst): $!";
 475                 } elsif (-f _ || !-e _) {
 476                         # text allows augment, HTML/Atom won't
 477                         my $mode = $lei->{opt}->{augment} ? '>>' : '>';
 478                         open $out, $mode, $dst or die "open($mode, $dst): $!";
 479                 } else {
 480                         die "$dst is not a file or FIFO\n";
 481                 }
 482         }
 483         $lei->{ovv}->ovv_out_lk_init if !$lei->{ovv}->{lock_path};
 484         $lei->{1} = $out;
 485         undef;
 486 }
 487
 488 sub _pre_augment_mbox {
 489         my ($self, $lei) = @_;
 490         my $dst = $lei->{ovv}->{dst};
 491         my $out;
 492         my $devfd = $lei->path_to_fd($dst) // die "bad $dst";
 493         if ($devfd >= 0) {
 494                 $out = $lei->{$devfd};
 495         } else { # normal-looking path
 496                 if (-p $dst) {
 497                         open $out, '>', $dst or die "open($dst): $!";
 498                 } elsif (-f _ || !-e _) {
 499                         require PublicInbox::MboxLock;
 500                         my $m = $lei->{opt}->{'lock'} //
 501                                         PublicInbox::MboxLock->defaults;
 502                         $self->{mbl} = PublicInbox::MboxLock->acq($dst, 1, $m);
 503                         $out = $self->{mbl}->{fh};
 504                 } else {
 505                         die "$dst is not a file or FIFO\n";
 506                 }
 507                 $lei->{old_1} = $lei->{1}; # keep for spawning MUA
 508         }
 509         # Perl does SEEK_END even with O_APPEND :<
 510         $self->{seekable} = seek($out, 0, SEEK_SET);
 511         if (!$self->{seekable} && !$!{ESPIPE} && !defined($devfd)) {
 512                 die "seek($dst): $!\n";
 513         }
 514         if (!$self->{seekable}) {
 515                 my $imp_before = $lei->{opt}->{'import-before'};
 516                 die "--import-before specified but $dst is not seekable\n"
 517                         if $imp_before && !ref($imp_before);
 518                 die "--augment specified but $dst is not seekable\n" if
 519                         $lei->{opt}->{augment};
 520         }
 521         if ($self->{zsfx} = PublicInbox::MboxReader::zsfx($dst)) {
 522                 pipe(my ($r, $w)) or die "pipe: $!";
 523                 $lei->{zpipe} = [ $r, $w ];
 524                 $lei->{ovv}->{lock_path} and
 525                         die 'BUG: unexpected {ovv}->{lock_path}';
 526                 $lei->{ovv}->ovv_out_lk_init;
 527         } elsif (!$self->{seekable} && !$lei->{ovv}->{lock_path}) {
 528                 $lei->{ovv}->ovv_out_lk_init;
 529         }
 530         $lei->{1} = $out;
 531         undef;
 532 }
 533
 534 sub _do_augment_mbox {
 535         my ($self, $lei) = @_;
 536         return unless $self->{seekable};
 537         my $opt = $lei->{opt};
 538         return if ($opt->{save} // 0) < 0;
 539         my $out = $lei->{1};
 540         my ($fmt, $dst) = @{$lei->{ovv}}{qw(fmt dst)};
 541         return unless -s $out;
 542         unless ($opt->{augment} || $opt->{'import-before'}) {
 543                 truncate($out, 0) or die "truncate($dst): $!";
 544                 return;
 545         }
 546         my $rd;
 547         if (my $zsfx = $self->{zsfx}) {
 548                 $rd = PublicInbox::MboxReader::zsfxcat($out, $zsfx, $lei);
 549         } else {
 550                 open($rd, '+>>&', $out) or die "dup: $!";
 551         }
 552         my $dedupe;
 553         if ($opt->{augment}) {
 554                 $dedupe = $lei->{dedupe};
 555                 $dedupe->prepare_dedupe if $dedupe;
 556         }
 557         if ($opt->{'import-before'}) { # the default
 558                 my $lse = $lei->{lse};
 559                 PublicInbox::MboxReader->$fmt($rd, \&_mbox_augment_kw_maybe,
 560                                                 $lei, $lse, $opt->{augment});
 561                 if (!$opt->{augment} and !truncate($out, 0)) {
 562                         die "truncate($dst): $!";
 563                 }
 564         } else { # --augment --no-import-before
 565                 PublicInbox::MboxReader->$fmt($rd, \&_augment, $lei);
 566         }
 567         # maybe some systems don't honor O_APPEND, Perl does this:
 568         seek($out, 0, SEEK_END) or die "seek $dst: $!";
 569         $dedupe->pause_dedupe if $dedupe;
 570 }
 571
 572 sub pre_augment { # fast (1 disk seek), runs in same process as post_augment
 573         my ($self, $lei) = @_;
 574         # _pre_augment_maildir, _pre_augment_mbox
 575         my $m = $self->can("_pre_augment_$self->{base_type}") or return;
 576         $m->($self, $lei);
 577 }
 578
 579 sub do_augment { # slow, runs in wq worker
 580         my ($self, $lei) = @_;
 581         # _do_augment_maildir, _do_augment_mbox, or _do_augment_imap
 582         my $m = $self->can("_do_augment_$self->{base_type}") or return;
 583         $m->($self, $lei);
 584 }
 585
 586 # fast (spawn compressor or mkdir), runs in same process as pre_augment
 587 sub post_augment {
 588         my ($self, $lei, @args) = @_;
 589         my $wait = $lei->{opt}->{'import-before'} ?
 590                         $lei->{sto}->ipc_do('checkpoint', 1) : 0;
 591         # _post_augment_mbox
 592         my $m = $self->can("_post_augment_$self->{base_type}") or return;
 593         $m->($self, $lei, @args);
 594 }
 595
 596 # called by every single l2m worker process
 597 sub do_post_auth {
 598         my ($self) = @_;
 599         my $lei = $self->{lei};
 600         # lei_xsearch can start as soon as all l2m workers get here
 601         pkt_do($lei->{pkt_op_p}, 'incr_start_query') or
 602                 die "incr_start_query: $!";
 603         my $aug;
 604         if (lock_free($self)) { # all workers do_augment
 605                 my $mod = $self->{-wq_nr_workers};
 606                 my $shard = $self->{-wq_worker_nr};
 607                 if (my $net = $lei->{net}) {
 608                         $net->{shard_info} = [ $mod, $shard ];
 609                 } else { # Maildir
 610                         $self->{shard_info} = [ $mod, $shard ];
 611                 }
 612                 $aug = '+'; # incr_post_augment
 613         } elsif ($self->{-wq_worker_nr} == 0) { # 1st worker do_augment
 614                 $aug = '.'; # do_post_augment
 615         }
 616         if ($aug) {
 617                 local $0 = 'do_augment';
 618                 eval { do_augment($self, $lei) };
 619                 $lei->fail($@) if $@;
 620                 pkt_do($lei->{pkt_op_p}, $aug) == 1 or
 621                                 die "do_post_augment trigger: $!";
 622         }
 623         # done augmenting, connect the compressor pipe for each worker
 624         if (my $zpipe = delete $lei->{zpipe}) {
 625                 $lei->{1} = $zpipe->[1];
 626                 close $zpipe->[0];
 627         }
 628         $self->{wcb} = $self->write_cb($lei);
 629 }
 630
 631 sub ipc_atfork_child {
 632         my ($self) = @_;
 633         my $lei = $self->{lei};
 634         $lei->_lei_atfork_child;
 635         $lei->{auth}->do_auth_atfork($self) if $lei->{auth};
 636         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 637         $self->SUPER::ipc_atfork_child;
 638 }
 639
 640 sub lock_free {
 641         $_[0]->{base_type} =~ /\A(?:maildir|imap|jmap)\z/ ? 1 : 0;
 642 }
 643
 644 # wakes up the MUA when complete so it can refresh messages list
 645 sub poke_dst {
 646         my ($self) = @_;
 647         if ($self->{base_type} eq 'maildir') {
 648                 my $t = time + 1;
 649                 utime($t, $t, $self->{poke_dh}) or warn "futimes: $!";
 650         }
 651 }
 652
 653 sub write_mail { # via ->wq_io_do
 654         my ($self, $smsg, $eml) = @_;
 655         return $self->{wcb}->(undef, $smsg, $eml) if $eml;
 656         $self->{lei}->{ale}->git->cat_async($smsg->{blob}, \&git_to_mail,
 657                                 [$self->{wcb}, $smsg]);
 658 }
 659
 660 sub wq_atexit_child {
 661         my ($self) = @_;
 662         delete $self->{wcb};
 663         my $lei = $self->{lei};
 664         $lei->{ale}->git->async_wait_all;
 665         my $nr = delete($lei->{-nr_write}) or return;
 666         return if $lei->{early_mua} || !$lei->{-progress} || !$lei->{pkt_op_p};
 667         require PublicInbox::PktOp;
 668         PublicInbox::PktOp::pkt_do($lei->{pkt_op_p}, 'l2m_progress', $nr);
 669 }
 670
 671 # called in top-level lei-daemon when LeiAuth is done
 672 sub net_merge_complete {
 673         my ($self) = @_;
 674         $self->wq_broadcast('do_post_auth');
 675         $self->wq_close(1);
 676 }
 677
 678 no warnings 'once'; # the following works even when LeiAuth is lazy-loaded
 679 *net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
 680 1;