lib/PublicInbox/LeiToMail.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Writes PublicInbox::Eml objects atomically to a mbox variant or Maildir
   5 package PublicInbox::LeiToMail;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::ProcessPipe;
  11 use PublicInbox::Spawn qw(spawn);
  12 use PublicInbox::PktOp qw(pkt_do);
  13 use Symbol qw(gensym);
  14 use IO::Handle; # ->autoflush
  15 use Fcntl qw(SEEK_SET SEEK_END O_CREAT O_EXCL O_WRONLY);
  16
  17 my %kw2char = ( # Maildir characters
  18         draft => 'D',
  19         flagged => 'F',
  20         forwarded => 'P', # passed
  21         answered => 'R',
  22         seen => 'S',
  23 );
  24
  25 my %kw2status = (
  26         flagged => [ 'X-Status' => 'F' ],
  27         answered => [ 'X-Status' => 'A' ],
  28         seen => [ 'Status' => 'R' ],
  29         draft => [ 'X-Status' => 'T' ],
  30 );
  31
  32 sub _mbox_hdr_buf ($$$) {
  33         my ($eml, $type, $smsg) = @_;
  34         $eml->header_set($_) for (qw(Lines Bytes Content-Length));
  35
  36         my %hdr = (Status => []); # set Status, X-Status
  37         for my $k (@{$smsg->{kw} // []}) {
  38                 if (my $ent = $kw2status{$k}) {
  39                         push @{$hdr{$ent->[0]}}, $ent->[1];
  40                 } else { # X-Label?
  41                         warn "# keyword `$k' not supported for mbox\n";
  42                 }
  43         }
  44         # Messages are always 'O' (non-\Recent in IMAP), it saves
  45         # MUAs the trouble of rewriting the mbox if no other
  46         # changes are made.  We put 'O' at the end (e.g. "Status: RO")
  47         # to match mutt(1) output.
  48         $eml->header_set('Status', join('', sort(@{$hdr{Status}})). 'O');
  49         if (my $chars = delete $hdr{'X-Status'}) {
  50                 $eml->header_set('X-Status', join('', sort(@$chars)));
  51         }
  52         my $buf = delete $eml->{hdr};
  53
  54         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
  55         $$buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  56         my $ident = $smsg->{blob} // 'lei';
  57         if (defined(my $pct = $smsg->{pct})) { $ident .= "=$pct" }
  58
  59         substr($$buf, 0, 0, # prepend From line
  60                 "From $ident\@$type Thu Jan  1 00:00:00 1970$eml->{crlf}");
  61         $buf;
  62 }
  63
  64 sub atomic_append { # for on-disk destinations (O_APPEND, or O_EXCL)
  65         my ($lei, $buf) = @_;
  66         if (defined(my $w = syswrite($lei->{1} // return, $$buf))) {
  67                 return if $w == length($$buf);
  68                 $buf = "short atomic write: $w != ".length($$buf);
  69         } elsif ($!{EPIPE}) {
  70                 return $lei->note_sigpipe(1);
  71         } else {
  72                 $buf = "atomic write: $!";
  73         }
  74         $lei->fail($buf);
  75 }
  76
  77 sub eml2mboxrd ($;$) {
  78         my ($eml, $smsg) = @_;
  79         my $buf = _mbox_hdr_buf($eml, 'mboxrd', $smsg);
  80         if (my $bdy = delete $eml->{bdy}) {
  81                 $$bdy =~ s/^(>*From )/>$1/gm;
  82                 $$buf .= $eml->{crlf};
  83                 substr($$bdy, 0, 0, $$buf); # prepend header
  84                 $buf = $bdy;
  85         }
  86         $$buf .= $eml->{crlf};
  87         $buf;
  88 }
  89
  90 sub eml2mboxo {
  91         my ($eml, $smsg) = @_;
  92         my $buf = _mbox_hdr_buf($eml, 'mboxo', $smsg);
  93         if (my $bdy = delete $eml->{bdy}) {
  94                 $$bdy =~ s/^From />From /gm;
  95                 $$buf .= $eml->{crlf};
  96                 substr($$bdy, 0, 0, $$buf); # prepend header
  97                 $buf = $bdy;
  98         }
  99         $$buf .= $eml->{crlf};
 100         $buf;
 101 }
 102
 103 sub _mboxcl_common ($$$) {
 104         my ($buf, $bdy, $crlf) = @_;
 105         # add Lines: so mutt won't have to add it on MUA close
 106         my $lines = $$bdy =~ tr!\n!\n!;
 107         $$buf .= 'Content-Length: '.length($$bdy).$crlf.
 108                 'Lines: '.$lines.$crlf.$crlf;
 109         substr($$bdy, 0, 0, $$buf); # prepend header
 110         $_[0] = $bdy;
 111 }
 112
 113 # mboxcl still escapes "From " lines
 114 sub eml2mboxcl {
 115         my ($eml, $smsg) = @_;
 116         my $buf = _mbox_hdr_buf($eml, 'mboxcl', $smsg);
 117         my $crlf = $eml->{crlf};
 118         if (my $bdy = delete $eml->{bdy}) {
 119                 $$bdy =~ s/^From />From /gm;
 120                 _mboxcl_common($buf, $bdy, $crlf);
 121         }
 122         $$buf .= $crlf;
 123         $buf;
 124 }
 125
 126 # mboxcl2 has no "From " escaping
 127 sub eml2mboxcl2 {
 128         my ($eml, $smsg) = @_;
 129         my $buf = _mbox_hdr_buf($eml, 'mboxcl2', $smsg);
 130         my $crlf = $eml->{crlf};
 131         if (my $bdy = delete $eml->{bdy}) {
 132                 _mboxcl_common($buf, $bdy, $crlf);
 133         }
 134         $$buf .= $crlf;
 135         $buf;
 136 }
 137
 138 sub git_to_mail { # git->cat_async callback
 139         my ($bref, $oid, $type, $size, $arg) = @_;
 140         return warn("W: $oid is $type (!= blob)\n") if $type ne 'blob';
 141         return warn("E: $oid is empty\n") unless $size;
 142         my ($write_cb, $smsg) = @$arg;
 143         die "BUG: expected=$smsg->{blob} got=$oid" if $smsg->{blob} ne $oid;
 144         $write_cb->($bref, $smsg);
 145 }
 146
 147 sub reap_compress { # dwaitpid callback
 148         my ($lei, $pid) = @_;
 149         my $cmd = delete $lei->{"pid.$pid"};
 150         return if $? == 0;
 151         $lei->fail("@$cmd failed", $? >> 8);
 152 }
 153
 154 sub _post_augment_mbox { # open a compressor process from top-level process
 155         my ($self, $lei) = @_;
 156         my $zsfx = $self->{zsfx} or return;
 157         my $cmd = PublicInbox::MboxReader::zsfx2cmd($zsfx, undef, $lei);
 158         my ($r, $w) = @{delete $lei->{zpipe}};
 159         my $rdr = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 160         my $pid = spawn($cmd, undef, $rdr);
 161         my $pp = gensym;
 162         my $dup = bless { "pid.$pid" => $cmd }, ref($lei);
 163         $dup->{$_} = $lei->{$_} for qw(2 sock);
 164         tie *$pp, 'PublicInbox::ProcessPipe', $pid, $w, \&reap_compress, $dup;
 165         $lei->{1} = $pp;
 166 }
 167
 168 # --augment existing output destination, with deduplication
 169 sub _augment { # MboxReader eml_cb
 170         my ($eml, $lei) = @_;
 171         # ignore return value, just populate the skv
 172         $lei->{dedupe}->is_dup($eml);
 173 }
 174
 175 sub _mbox_augment_kw_maybe {
 176         my ($eml, $lei, $lse, $augment) = @_;
 177         my $kw = PublicInbox::MboxReader::mbox_keywords($eml);
 178         update_kw_maybe($lei, $lse, $eml, $kw);
 179         _augment($eml, $lei) if $augment;
 180 }
 181
 182 sub _mbox_write_cb ($$) {
 183         my ($self, $lei) = @_;
 184         my $ovv = $lei->{ovv};
 185         my $m = 'eml2'.$ovv->{fmt};
 186         my $eml2mbox = $self->can($m) or die "$self->$m missing";
 187         $lei->{1} // die "no stdout ($m, $ovv->{dst})"; # redirected earlier
 188         $lei->{1}->autoflush(1);
 189         my $atomic_append = !defined($ovv->{lock_path});
 190         my $dedupe = $lei->{dedupe};
 191         $dedupe->prepare_dedupe;
 192         my $lse = $lei->{lse}; # may be undef
 193         sub { # for git_to_mail
 194                 my ($buf, $smsg, $eml) = @_;
 195                 $eml //= PublicInbox::Eml->new($buf);
 196                 return if $dedupe->is_dup($eml, $smsg);
 197                 $lse->xsmsg_vmd($smsg) if $lse;
 198                 $buf = $eml2mbox->($eml, $smsg);
 199                 if ($atomic_append) {
 200                         atomic_append($lei, $buf);
 201                 } else {
 202                         my $lk = $ovv->lock_for_scope;
 203                         $lei->out($$buf);
 204                 }
 205                 ++$lei->{-nr_write};
 206         }
 207 }
 208
 209 sub update_kw_maybe ($$$$) {
 210         my ($lei, $lse, $eml, $kw) = @_;
 211         return unless $lse;
 212         my $c = $lse->kw_changed($eml, $kw, my $docids = []);
 213         my $vmd = { kw => $kw };
 214         if (scalar @$docids) { # already in lei/store
 215                 $lei->{sto}->ipc_do('set_eml_vmd', undef, $vmd, $docids) if $c;
 216         } elsif (my $xoids = $lei->{ale}->xoids_for($eml)) {
 217                 # it's in an external, only set kw, here
 218                 $lei->{sto}->ipc_do('set_xvmd', $xoids, $eml, $vmd);
 219         } else { # never-before-seen, import the whole thing
 220                 # XXX this is critical in protecting against accidental
 221                 # data loss without --augment
 222                 $lei->{sto}->ipc_do('set_eml', $eml, $vmd);
 223         }
 224 }
 225
 226 sub _md_update { # maildir_each_eml cb
 227         my ($f, $kw, $eml, $lei, $lse, $unlink) = @_;
 228         update_kw_maybe($lei, $lse, $eml, $kw);
 229         $unlink ? unlink($f) : _augment($eml, $lei);
 230 }
 231
 232 # maildir_each_file callback, \&CORE::unlink doesn't work with it
 233 sub _unlink { unlink($_[0]) }
 234
 235 sub _rand () {
 236         state $seq = 0;
 237         sprintf('%x,%x,%x,%x', rand(0xffffffff), time, $$, ++$seq);
 238 }
 239
 240 sub _buf2maildir {
 241         my ($dst, $buf, $smsg) = @_;
 242         my $kw = $smsg->{kw} // [];
 243         my $sfx = join('', sort(map { $kw2char{$_} // () } @$kw));
 244         my $rand = ''; # chosen by die roll :P
 245         my ($tmp, $fh, $base, $ok);
 246         my $common = $smsg->{blob} // _rand;
 247         if (defined(my $pct = $smsg->{pct})) { $common .= "=$pct" }
 248         do {
 249                 $tmp = $dst.'tmp/'.$rand.$common;
 250         } while (!($ok = sysopen($fh, $tmp, O_CREAT|O_EXCL|O_WRONLY)) &&
 251                 $!{EEXIST} && ($rand = _rand.','));
 252         if ($ok && print $fh $$buf and close($fh)) {
 253                 # ignore new/ and write only to cur/, otherwise MUAs
 254                 # with R/W access to the Maildir will end up doing
 255                 # a mass rename which can take a while with thousands
 256                 # of messages.
 257                 $dst .= 'cur/';
 258                 $rand = '';
 259                 do {
 260                         $base = $rand.$common.':2,'.$sfx
 261                 } while (!($ok = link($tmp, $dst.$base)) && $!{EEXIST} &&
 262                         ($rand = _rand.','));
 263                 die "link($tmp, $dst$base): $!" unless $ok;
 264                 unlink($tmp) or warn "W: failed to unlink $tmp: $!\n";
 265                 \$base;
 266         } else {
 267                 my $err = "Error writing $smsg->{blob} to $dst: $!\n";
 268                 $_[0] = undef; # clobber dst
 269                 unlink($tmp);
 270                 die $err;
 271         }
 272 }
 273
 274 sub _maildir_write_cb ($$) {
 275         my ($self, $lei) = @_;
 276         my $dedupe = $lei->{dedupe};
 277         $dedupe->prepare_dedupe if $dedupe;
 278         my $dst = $lei->{ovv}->{dst};
 279         my $lse = $lei->{lse}; # may be undef
 280         my $sto = $lei->{opt}->{'mail-sync'} ? $lei->{sto} : undef;
 281         my $out = $sto ? 'maildir:'.$lei->rel2abs($dst) : undef;
 282         sub { # for git_to_mail
 283                 my ($bref, $smsg, $eml) = @_;
 284                 $dst // return $lei->fail; # dst may be undef-ed in last run
 285                 return if $dedupe && $dedupe->is_dup($eml //
 286                                                 PublicInbox::Eml->new($$bref));
 287                 $lse->xsmsg_vmd($smsg) if $lse;
 288                 my $n = _buf2maildir($dst, $bref // \($eml->as_string), $smsg);
 289                 $sto->ipc_do('set_sync_info', $smsg->{blob}, $out, $n) if $sto;
 290                 ++$lei->{-nr_write};
 291         }
 292 }
 293
 294 sub _imap_write_cb ($$) {
 295         my ($self, $lei) = @_;
 296         my $dedupe = $lei->{dedupe};
 297         $dedupe->prepare_dedupe if $dedupe;
 298         my $append = $lei->{net}->can('imap_append');
 299         my $mic = $lei->{net}->mic_get($self->{uri});
 300         my $folder = $self->{uri}->mailbox;
 301         my $lse = $lei->{lse}; # may be undef
 302         my $sto = $lei->{opt}->{'mail-sync'} ? $lei->{sto} : undef;
 303         my $out = $lei->{ovv}->{dst};
 304         sub { # for git_to_mail
 305                 my ($bref, $smsg, $eml) = @_;
 306                 $mic // return $lei->fail; # mic may be undef-ed in last run
 307                 return if $dedupe && $dedupe->is_dup($eml //
 308                                                 PublicInbox::Eml->new($$bref));
 309                 $lse->xsmsg_vmd($smsg) if $lse;
 310                 my $uid = eval { $append->($mic, $folder, $bref, $smsg, $eml) };
 311                 if (my $err = $@) {
 312                         undef $mic;
 313                         die $err;
 314                 }
 315                 # imap_append returns UID if IMAP server has UIDPLUS extension
 316                 ($sto && $uid =~ /\A[0-9]+\z/) and
 317                         $sto->ipc_do('set_sync_info',
 318                                         $smsg->{blob}, $out, $uid + 0);
 319                 ++$lei->{-nr_write};
 320         }
 321 }
 322
 323 sub _text_write_cb ($$) {
 324         my ($self, $lei) = @_;
 325         my $dedupe = $lei->{dedupe};
 326         $dedupe->prepare_dedupe if $dedupe;
 327         my $lvt = $lei->{lvt};
 328         my $ovv = $lei->{ovv};
 329         $lei->{1} // die "no stdout ($ovv->{dst})"; # redirected earlier
 330         $lei->{1}->autoflush(1);
 331         binmode $lei->{1}, ':utf8';
 332         my $lse = $lei->{lse}; # may be undef
 333         sub { # for git_to_mail
 334                 my ($bref, $smsg, $eml) = @_;
 335                 $lse->xsmsg_vmd($smsg) if $lse;
 336                 $eml //= PublicInbox::Eml->new($bref); # copy bref
 337                 return if $dedupe && $dedupe->is_dup($eml, $smsg);
 338                 my $lk = $ovv->lock_for_scope;
 339                 $lei->out(${$lvt->eml_to_text($smsg, $eml)}, "\n");
 340         }
 341 }
 342
 343 sub write_cb { # returns a callback for git_to_mail
 344         my ($self, $lei) = @_;
 345         # _mbox_write_cb, _maildir_write_cb or _imap_write_cb
 346         my $m = "_$self->{base_type}_write_cb";
 347         $self->$m($lei);
 348 }
 349
 350 sub new {
 351         my ($cls, $lei) = @_;
 352         my $fmt = $lei->{ovv}->{fmt};
 353         my $dst = $lei->{ovv}->{dst};
 354         my $self = bless {}, $cls;
 355         if ($fmt eq 'maildir') {
 356                 require PublicInbox::MdirReader;
 357                 $self->{base_type} = 'maildir';
 358                 -e $dst && !-d _ and die
 359                                 "$dst exists and is not a directory\n";
 360                 $lei->{ovv}->{dst} = $dst .= '/' if substr($dst, -1) ne '/';
 361         } elsif (substr($fmt, 0, 4) eq 'mbox') {
 362                 require PublicInbox::MboxReader;
 363                 $self->can("eml2$fmt") or die "bad mbox format: $fmt\n";
 364                 $self->{base_type} = 'mbox';
 365         } elsif ($fmt =~ /\Aimaps?\z/) {
 366                 require PublicInbox::NetWriter;
 367                 require PublicInbox::URIimap;
 368                 my $net = PublicInbox::NetWriter->new;
 369                 $net->{quiet} = $lei->{opt}->{quiet};
 370                 my $uri = PublicInbox::URIimap->new($dst)->canonical;
 371                 $net->add_url($uri);
 372                 my $err = $net->errors($lei);
 373                 return $lei->fail($err) if $err;
 374                 $uri->mailbox or return $lei->fail("No mailbox: $dst");
 375                 $self->{uri} = $uri;
 376                 $dst = $lei->{ovv}->{dst} = $$uri; # canonicalized
 377                 $lei->{net} = $net;
 378                 $self->{base_type} = 'imap';
 379         } elsif ($fmt eq 'text') {
 380                 require PublicInbox::LeiViewText;
 381                 $lei->{lvt} = PublicInbox::LeiViewText->new($lei);
 382                 $self->{base_type} = 'text';
 383         } else {
 384                 die "bad mail --format=$fmt\n";
 385         }
 386         if ($self->{base_type} =~ /\A(?:text|mbox)\z/) {
 387                 (-d $dst || (-e _ && !-w _)) and die
 388                         "$dst exists and is not a writable file\n";
 389         }
 390         if ($self->{base_type} eq 'text') {
 391                 my @err = map {
 392                         defined($lei->{opt}->{$_}) ? "--$_" : ();
 393                 } (qw(mua save));
 394                 die "@err incompatible with $fmt\n" if @err;
 395         }
 396         $self->{dst} = $dst;
 397         $lei->{dedupe} = $lei->{lss} // do {
 398                 my $dd_cls = 'PublicInbox::'.
 399                         ($lei->{opt}->{save} ? 'LeiSavedSearch' : 'LeiDedupe');
 400                 eval "require $dd_cls";
 401                 die "$dd_cls: $@" if $@;
 402                 $dd_cls->new($lei);
 403         };
 404         $self;
 405 }
 406
 407 sub _pre_augment_maildir {
 408         my ($self, $lei) = @_;
 409         my $dst = $lei->{ovv}->{dst};
 410         for my $x (qw(tmp new cur)) {
 411                 my $d = $dst.$x;
 412                 next if -d $d;
 413                 require File::Path;
 414                 File::Path::mkpath($d);
 415                 -d $d or die "$d is not a directory";
 416         }
 417         # for utime, so no opendir
 418         open $self->{poke_dh}, '<', "${dst}cur" or die "open ${dst}cur: $!";
 419 }
 420
 421 sub _do_augment_maildir {
 422         my ($self, $lei) = @_;
 423         return if ($lei->{opt}->{save} // 0) < 0;
 424         my $dst = $lei->{ovv}->{dst};
 425         my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
 426         my $mdr = PublicInbox::MdirReader->new;
 427         if ($lei->{opt}->{augment}) {
 428                 my $dedupe = $lei->{dedupe};
 429                 if ($dedupe && $dedupe->prepare_dedupe) {
 430                         $mdr->{shard_info} = $self->{shard_info};
 431                         $mdr->maildir_each_eml($dst, \&_md_update, $lei, $lse);
 432                         $dedupe->pause_dedupe;
 433                 }
 434         } elsif ($lse) {
 435                 $mdr->{shard_info} = $self->{shard_info};
 436                 $mdr->maildir_each_eml($dst, \&_md_update, $lei, $lse, 1);
 437         } else {# clobber existing Maildir
 438                 $mdr->maildir_each_file($dst, \&_unlink);
 439         }
 440 }
 441
 442 sub _imap_augment_or_delete { # PublicInbox::NetReader::imap_each cb
 443         my ($url, $uid, $kw, $eml, $lei, $lse, $delete_mic) = @_;
 444         update_kw_maybe($lei, $lse, $eml, $kw);
 445         if ($delete_mic) {
 446                 $lei->{net}->imap_delete_1($url, $uid, $delete_mic);
 447         } else {
 448                 _augment($eml, $lei);
 449         }
 450 }
 451
 452 sub _do_augment_imap {
 453         my ($self, $lei) = @_;
 454         return if ($lei->{opt}->{save} // 0) < 0;
 455         my $net = $lei->{net};
 456         my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
 457         if ($lei->{opt}->{augment}) {
 458                 my $dedupe = $lei->{dedupe};
 459                 if ($dedupe && $dedupe->prepare_dedupe) {
 460                         $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 461                                         $lei, $lse);
 462                         $dedupe->pause_dedupe;
 463                 }
 464         } elsif ($lse) {
 465                 my $delete_mic;
 466                 $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 467                                         $lei, $lse, \$delete_mic);
 468                 $delete_mic->expunge if $delete_mic;
 469         } elsif (!$self->{-wq_worker_nr}) { # undef or 0
 470                 # clobber existing IMAP folder
 471                 $net->imap_delete_all($self->{uri});
 472         }
 473 }
 474
 475 sub _pre_augment_text {
 476         my ($self, $lei) = @_;
 477         my $dst = $lei->{ovv}->{dst};
 478         my $out;
 479         my $devfd = $lei->path_to_fd($dst) // die "bad $dst";
 480         if ($devfd >= 0) {
 481                 $out = $lei->{$devfd};
 482         } else { # normal-looking path
 483                 if (-p $dst) {
 484                         open $out, '>', $dst or die "open($dst): $!";
 485                 } elsif (-f _ || !-e _) {
 486                         # text allows augment, HTML/Atom won't
 487                         my $mode = $lei->{opt}->{augment} ? '>>' : '>';
 488                         open $out, $mode, $dst or die "open($mode, $dst): $!";
 489                 } else {
 490                         die "$dst is not a file or FIFO\n";
 491                 }
 492         }
 493         $lei->{ovv}->ovv_out_lk_init if !$lei->{ovv}->{lock_path};
 494         $lei->{1} = $out;
 495         undef;
 496 }
 497
 498 sub _pre_augment_mbox {
 499         my ($self, $lei) = @_;
 500         my $dst = $lei->{ovv}->{dst};
 501         my $out;
 502         my $devfd = $lei->path_to_fd($dst) // die "bad $dst";
 503         if ($devfd >= 0) {
 504                 $out = $lei->{$devfd};
 505         } else { # normal-looking path
 506                 if (-p $dst) {
 507                         open $out, '>', $dst or die "open($dst): $!";
 508                 } elsif (-f _ || !-e _) {
 509                         require PublicInbox::MboxLock;
 510                         my $m = $lei->{opt}->{'lock'} //
 511                                         PublicInbox::MboxLock->defaults;
 512                         $self->{mbl} = PublicInbox::MboxLock->acq($dst, 1, $m);
 513                         $out = $self->{mbl}->{fh};
 514                 } else {
 515                         die "$dst is not a file or FIFO\n";
 516                 }
 517                 $lei->{old_1} = $lei->{1}; # keep for spawning MUA
 518         }
 519         # Perl does SEEK_END even with O_APPEND :<
 520         $self->{seekable} = seek($out, 0, SEEK_SET);
 521         if (!$self->{seekable} && !$!{ESPIPE} && !defined($devfd)) {
 522                 die "seek($dst): $!\n";
 523         }
 524         if (!$self->{seekable}) {
 525                 my $imp_before = $lei->{opt}->{'import-before'};
 526                 die "--import-before specified but $dst is not seekable\n"
 527                         if $imp_before && !ref($imp_before);
 528                 die "--augment specified but $dst is not seekable\n" if
 529                         $lei->{opt}->{augment};
 530         }
 531         if ($self->{zsfx} = PublicInbox::MboxReader::zsfx($dst)) {
 532                 pipe(my ($r, $w)) or die "pipe: $!";
 533                 $lei->{zpipe} = [ $r, $w ];
 534                 $lei->{ovv}->{lock_path} and
 535                         die 'BUG: unexpected {ovv}->{lock_path}';
 536                 $lei->{ovv}->ovv_out_lk_init;
 537         } elsif (!$self->{seekable} && !$lei->{ovv}->{lock_path}) {
 538                 $lei->{ovv}->ovv_out_lk_init;
 539         }
 540         $lei->{1} = $out;
 541         undef;
 542 }
 543
 544 sub _do_augment_mbox {
 545         my ($self, $lei) = @_;
 546         return unless $self->{seekable};
 547         my $opt = $lei->{opt};
 548         return if ($opt->{save} // 0) < 0;
 549         my $out = $lei->{1};
 550         my ($fmt, $dst) = @{$lei->{ovv}}{qw(fmt dst)};
 551         return unless -s $out;
 552         unless ($opt->{augment} || $opt->{'import-before'}) {
 553                 truncate($out, 0) or die "truncate($dst): $!";
 554                 return;
 555         }
 556         my $rd;
 557         if (my $zsfx = $self->{zsfx}) {
 558                 $rd = PublicInbox::MboxReader::zsfxcat($out, $zsfx, $lei);
 559         } else {
 560                 open($rd, '+>>&', $out) or die "dup: $!";
 561         }
 562         my $dedupe;
 563         if ($opt->{augment}) {
 564                 $dedupe = $lei->{dedupe};
 565                 $dedupe->prepare_dedupe if $dedupe;
 566         }
 567         if ($opt->{'import-before'}) { # the default
 568                 my $lse = $lei->{lse};
 569                 PublicInbox::MboxReader->$fmt($rd, \&_mbox_augment_kw_maybe,
 570                                                 $lei, $lse, $opt->{augment});
 571                 if (!$opt->{augment} and !truncate($out, 0)) {
 572                         die "truncate($dst): $!";
 573                 }
 574         } else { # --augment --no-import-before
 575                 PublicInbox::MboxReader->$fmt($rd, \&_augment, $lei);
 576         }
 577         # maybe some systems don't honor O_APPEND, Perl does this:
 578         seek($out, 0, SEEK_END) or die "seek $dst: $!";
 579         $dedupe->pause_dedupe if $dedupe;
 580 }
 581
 582 sub pre_augment { # fast (1 disk seek), runs in same process as post_augment
 583         my ($self, $lei) = @_;
 584         # _pre_augment_maildir, _pre_augment_mbox
 585         my $m = $self->can("_pre_augment_$self->{base_type}") or return;
 586         $m->($self, $lei);
 587 }
 588
 589 sub do_augment { # slow, runs in wq worker
 590         my ($self, $lei) = @_;
 591         # _do_augment_maildir, _do_augment_mbox, or _do_augment_imap
 592         my $m = $self->can("_do_augment_$self->{base_type}") or return;
 593         $m->($self, $lei);
 594 }
 595
 596 # fast (spawn compressor or mkdir), runs in same process as pre_augment
 597 sub post_augment {
 598         my ($self, $lei, @args) = @_;
 599         my $wait = $lei->{opt}->{'import-before'} ?
 600                         $lei->{sto}->ipc_do('checkpoint', 1) : 0;
 601         # _post_augment_mbox
 602         my $m = $self->can("_post_augment_$self->{base_type}") or return;
 603         $m->($self, $lei, @args);
 604 }
 605
 606 # called by every single l2m worker process
 607 sub do_post_auth {
 608         my ($self) = @_;
 609         my $lei = $self->{lei};
 610         # lei_xsearch can start as soon as all l2m workers get here
 611         pkt_do($lei->{pkt_op_p}, 'incr_start_query') or
 612                 die "incr_start_query: $!";
 613         my $aug;
 614         if (lock_free($self)) { # all workers do_augment
 615                 my $mod = $self->{-wq_nr_workers};
 616                 my $shard = $self->{-wq_worker_nr};
 617                 if (my $net = $lei->{net}) {
 618                         $net->{shard_info} = [ $mod, $shard ];
 619                 } else { # Maildir
 620                         $self->{shard_info} = [ $mod, $shard ];
 621                 }
 622                 $aug = '+'; # incr_post_augment
 623         } elsif ($self->{-wq_worker_nr} == 0) { # 1st worker do_augment
 624                 $aug = '.'; # do_post_augment
 625         }
 626         if ($aug) {
 627                 local $0 = 'do_augment';
 628                 eval { do_augment($self, $lei) };
 629                 $lei->fail($@) if $@;
 630                 pkt_do($lei->{pkt_op_p}, $aug) == 1 or
 631                                 die "do_post_augment trigger: $!";
 632         }
 633         # done augmenting, connect the compressor pipe for each worker
 634         if (my $zpipe = delete $lei->{zpipe}) {
 635                 $lei->{1} = $zpipe->[1];
 636                 close $zpipe->[0];
 637         }
 638         $self->{wcb} = $self->write_cb($lei);
 639 }
 640
 641 sub ipc_atfork_child {
 642         my ($self) = @_;
 643         my $lei = $self->{lei};
 644         $lei->_lei_atfork_child;
 645         $lei->{auth}->do_auth_atfork($self) if $lei->{auth};
 646         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 647         $self->SUPER::ipc_atfork_child;
 648 }
 649
 650 sub lock_free {
 651         $_[0]->{base_type} =~ /\A(?:maildir|imap|jmap)\z/ ? 1 : 0;
 652 }
 653
 654 # wakes up the MUA when complete so it can refresh messages list
 655 sub poke_dst {
 656         my ($self) = @_;
 657         if ($self->{base_type} eq 'maildir') {
 658                 my $t = time + 1;
 659                 utime($t, $t, $self->{poke_dh}) or warn "futimes: $!";
 660         }
 661 }
 662
 663 sub write_mail { # via ->wq_io_do
 664         my ($self, $smsg, $eml) = @_;
 665         return $self->{wcb}->(undef, $smsg, $eml) if $eml;
 666         $self->{lei}->{ale}->git->cat_async($smsg->{blob}, \&git_to_mail,
 667                                 [$self->{wcb}, $smsg]);
 668 }
 669
 670 sub wq_atexit_child {
 671         my ($self) = @_;
 672         delete $self->{wcb};
 673         my $lei = $self->{lei};
 674         $lei->{ale}->git->async_wait_all;
 675         my $nr = delete($lei->{-nr_write}) or return;
 676         return if $lei->{early_mua} || !$lei->{-progress} || !$lei->{pkt_op_p};
 677         require PublicInbox::PktOp;
 678         PublicInbox::PktOp::pkt_do($lei->{pkt_op_p}, 'l2m_progress', $nr);
 679 }
 680
 681 # called in top-level lei-daemon when LeiAuth is done
 682 sub net_merge_all_done {
 683         my ($self) = @_;
 684         $self->wq_broadcast('do_post_auth');
 685         $self->wq_close(1);
 686 }
 687
 688 no warnings 'once'; # the following works even when LeiAuth is lazy-loaded
 689 *net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
 690 1;