lib/PublicInbox/LeiToMail.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Writes PublicInbox::Eml objects atomically to a mbox variant or Maildir
   5 package PublicInbox::LeiToMail;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Lock;
  11 use PublicInbox::ProcessPipe;
  12 use PublicInbox::Spawn qw(which spawn popen_rd);
  13 use PublicInbox::LeiDedupe;
  14 use PublicInbox::Git;
  15 use PublicInbox::GitAsyncCat;
  16 use PublicInbox::PktOp qw(pkt_do);
  17 use Symbol qw(gensym);
  18 use IO::Handle; # ->autoflush
  19 use Fcntl qw(SEEK_SET SEEK_END O_CREAT O_EXCL O_WRONLY);
  20 use Errno qw(EEXIST ESPIPE ENOENT EPIPE);
  21 use Digest::SHA qw(sha256_hex);
  22
  23 # struggles with short-lived repos, Gcf2Client makes little sense with lei;
  24 # but we may use in-process libgit2 in the future.
  25 $PublicInbox::GitAsyncCat::GCF2C = 0;
  26
  27 my %kw2char = ( # Maildir characters
  28         draft => 'D',
  29         flagged => 'F',
  30         answered => 'R',
  31         seen => 'S'
  32 );
  33
  34 my %kw2status = (
  35         flagged => [ 'X-Status' => 'F' ],
  36         answered => [ 'X-Status' => 'A' ],
  37         seen => [ 'Status' => 'R' ],
  38         draft => [ 'X-Status' => 'T' ],
  39 );
  40
  41 sub _mbox_hdr_buf ($$$) {
  42         my ($eml, $type, $smsg) = @_;
  43         $eml->header_set($_) for (qw(Lines Bytes Content-Length));
  44
  45         # Messages are always 'O' (non-\Recent in IMAP), it saves
  46         # MUAs the trouble of rewriting the mbox if no other
  47         # changes are made
  48         my %hdr = (Status => [ 'O' ]); # set Status, X-Status
  49         for my $k (@{$smsg->{kw} // []}) {
  50                 if (my $ent = $kw2status{$k}) {
  51                         push @{$hdr{$ent->[0]}}, $ent->[1];
  52                 } else { # X-Label?
  53                         warn "TODO: keyword `$k' not supported for mbox\n";
  54                 }
  55         }
  56         while (my ($name, $chars) = each %hdr) {
  57                 $eml->header_set($name, join('', sort @$chars));
  58         }
  59         my $buf = delete $eml->{hdr};
  60
  61         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
  62         $$buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  63         my $ident = $smsg->{blob} // 'lei';
  64         if (defined(my $pct = $smsg->{pct})) { $ident .= "=$pct" }
  65
  66         substr($$buf, 0, 0, # prepend From line
  67                 "From $ident\@$type Thu Jan  1 00:00:00 1970$eml->{crlf}");
  68         $buf;
  69 }
  70
  71 sub atomic_append { # for on-disk destinations (O_APPEND, or O_EXCL)
  72         my ($lei, $buf) = @_;
  73         if (defined(my $w = syswrite($lei->{1} // return, $$buf))) {
  74                 return if $w == length($$buf);
  75                 $buf = "short atomic write: $w != ".length($$buf);
  76         } elsif ($! == EPIPE) {
  77                 return $lei->note_sigpipe(1);
  78         } else {
  79                 $buf = "atomic write: $!";
  80         }
  81         $lei->fail($buf);
  82 }
  83
  84 sub eml2mboxrd ($;$) {
  85         my ($eml, $smsg) = @_;
  86         my $buf = _mbox_hdr_buf($eml, 'mboxrd', $smsg);
  87         if (my $bdy = delete $eml->{bdy}) {
  88                 $$bdy =~ s/^(>*From )/>$1/gm;
  89                 $$buf .= $eml->{crlf};
  90                 substr($$bdy, 0, 0, $$buf); # prepend header
  91                 $buf = $bdy;
  92         }
  93         $$buf .= $eml->{crlf};
  94         $buf;
  95 }
  96
  97 sub eml2mboxo {
  98         my ($eml, $smsg) = @_;
  99         my $buf = _mbox_hdr_buf($eml, 'mboxo', $smsg);
 100         if (my $bdy = delete $eml->{bdy}) {
 101                 $$bdy =~ s/^From />From /gm;
 102                 $$buf .= $eml->{crlf};
 103                 substr($$bdy, 0, 0, $$buf); # prepend header
 104                 $buf = $bdy;
 105         }
 106         $$buf .= $eml->{crlf};
 107         $buf;
 108 }
 109
 110 sub _mboxcl_common ($$$) {
 111         my ($buf, $bdy, $crlf) = @_;
 112         # add Lines: so mutt won't have to add it on MUA close
 113         my $lines = $$bdy =~ tr!\n!\n!;
 114         $$buf .= 'Content-Length: '.length($$bdy).$crlf.
 115                 'Lines: '.$lines.$crlf.$crlf;
 116         substr($$bdy, 0, 0, $$buf); # prepend header
 117         $_[0] = $bdy;
 118 }
 119
 120 # mboxcl still escapes "From " lines
 121 sub eml2mboxcl {
 122         my ($eml, $smsg) = @_;
 123         my $buf = _mbox_hdr_buf($eml, 'mboxcl', $smsg);
 124         my $crlf = $eml->{crlf};
 125         if (my $bdy = delete $eml->{bdy}) {
 126                 $$bdy =~ s/^From />From /gm;
 127                 _mboxcl_common($buf, $bdy, $crlf);
 128         }
 129         $$buf .= $crlf;
 130         $buf;
 131 }
 132
 133 # mboxcl2 has no "From " escaping
 134 sub eml2mboxcl2 {
 135         my ($eml, $smsg) = @_;
 136         my $buf = _mbox_hdr_buf($eml, 'mboxcl2', $smsg);
 137         my $crlf = $eml->{crlf};
 138         if (my $bdy = delete $eml->{bdy}) {
 139                 _mboxcl_common($buf, $bdy, $crlf);
 140         }
 141         $$buf .= $crlf;
 142         $buf;
 143 }
 144
 145 sub git_to_mail { # git->cat_async callback
 146         my ($bref, $oid, $type, $size, $arg) = @_;
 147         if ($type ne 'blob') {
 148                 if ($type eq 'missing') {
 149                         warn "missing $oid\n";
 150                 } else {
 151                         warn "unexpected type=$type for $oid\n";
 152                 }
 153         }
 154         my ($write_cb, $smsg) = @$arg;
 155         if ($smsg->{blob} ne $oid) {
 156                 die "BUG: expected=$smsg->{blob} got=$oid";
 157         }
 158         $write_cb->($bref, $smsg) if $size > 0;
 159 }
 160
 161 sub reap_compress { # dwaitpid callback
 162         my ($lei, $pid) = @_;
 163         my $cmd = delete $lei->{"pid.$pid"};
 164         return if $? == 0;
 165         $lei->fail("@$cmd failed", $? >> 8);
 166 }
 167
 168 # all of these support -c for stdout and -d for decompression,
 169 # mutt is commonly distributed with hooks for gz, bz2 and xz, at least
 170 # { foo => '' } means "--foo" is passed to the command-line,
 171 # otherwise { foo => '--bar' } passes "--bar"
 172 our %zsfx2cmd = (
 173         gz => [ qw(GZIP pigz gzip), { rsyncable => '', threads => '-p' } ],
 174         bz2 => [ 'bzip2', {} ],
 175         xz => [ 'xz', { threads => '-T' } ],
 176         # XXX does anybody care for these?  I prefer zstd on entire FSes,
 177         # so it's probably not necessary on a per-file basis
 178         # zst => [ 'zstd', { -default => [ qw(-q) ], # it's noisy by default
 179         #       rsyncable => '', threads => '-T' } ],
 180         # zz => [ 'pigz', { -default => [ '--zlib' ],
 181         #       rsyncable => '', threads => '-p' }],
 182         # lzo => [ 'lzop', {} ],
 183         # lzma => [ 'lzma', {} ],
 184 );
 185
 186 sub zsfx2cmd ($$$) {
 187         my ($zsfx, $decompress, $lei) = @_;
 188         my $x = $zsfx2cmd{$zsfx} // die "no support for suffix=.$zsfx";
 189         my @info = @$x;
 190         my $cmd_opt = pop @info;
 191         my @cmd = (undef, $decompress ? qw(-dc) : qw(-c));
 192         for my $exe (@info) {
 193                 # I think respecting client's ENV{GZIP} is OK, not sure
 194                 # about ENV overrides for other, less-common compressors
 195                 if ($exe eq uc($exe)) {
 196                         $exe = $lei->{env}->{$exe} or next;
 197                 }
 198                 $cmd[0] = which($exe) and last;
 199         }
 200         $cmd[0] // die join(' or ', @info)." missing for .$zsfx";
 201         # push @cmd, @{$cmd_opt->{-default}} if $cmd_opt->{-default};
 202         for my $bool (qw(rsyncable)) {
 203                 my $switch = $cmd_opt->{rsyncable} // next;
 204                 push @cmd, '--'.($switch || $bool);
 205         }
 206         for my $key (qw(threads)) { # support compression level?
 207                 my $switch = $cmd_opt->{$key} // next;
 208                 my $val = $lei->{opt}->{$key} // next;
 209                 push @cmd, $switch, $val;
 210         }
 211         \@cmd;
 212 }
 213
 214 sub _post_augment_mbox { # open a compressor process
 215         my ($self, $lei) = @_;
 216         my $zsfx = $self->{zsfx} or return;
 217         my $cmd = zsfx2cmd($zsfx, undef, $lei);
 218         my ($r, $w) = @{delete $lei->{zpipe}};
 219         my $rdr = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
 220         my $pid = spawn($cmd, undef, $rdr);
 221         my $pp = gensym;
 222         my $dup = bless { "pid.$pid" => $cmd }, ref($lei);
 223         $dup->{$_} = $lei->{$_} for qw(2 sock);
 224         tie *$pp, 'PublicInbox::ProcessPipe', $pid, $w, \&reap_compress, $dup;
 225         $lei->{1} = $pp;
 226         die 'BUG: unexpected {ovv}->{lock_path}' if $lei->{ovv}->{lock_path};
 227         $lei->{ovv}->ovv_out_lk_init;
 228 }
 229
 230 sub decompress_src ($$$) {
 231         my ($in, $zsfx, $lei) = @_;
 232         my $cmd = zsfx2cmd($zsfx, 1, $lei);
 233         popen_rd($cmd, undef, { 0 => $in, 2 => $lei->{2} });
 234 }
 235
 236 sub dup_src ($) {
 237         my ($in) = @_;
 238         open my $dup, '+>>&', $in or die "dup: $!";
 239         $dup;
 240 }
 241
 242 # --augment existing output destination, with deduplication
 243 sub _augment { # MboxReader eml_cb
 244         my ($eml, $lei) = @_;
 245         # ignore return value, just populate the skv
 246         $lei->{dedupe}->is_dup($eml);
 247 }
 248
 249 sub _mbox_augment_kw_maybe {
 250         my ($eml, $lei, $lse, $augment) = @_;
 251         my @kw = PublicInbox::LeiStore::mbox_keywords($eml);
 252         update_kw_maybe($lei, $lse, $eml, \@kw);
 253         _augment($eml, $lei) if $augment;
 254 }
 255
 256 sub _mbox_write_cb ($$) {
 257         my ($self, $lei) = @_;
 258         my $ovv = $lei->{ovv};
 259         my $m = 'eml2'.$ovv->{fmt};
 260         my $eml2mbox = $self->can($m) or die "$self->$m missing";
 261         $lei->{1} // die "no stdout ($m, $ovv->{dst})"; # redirected earlier
 262         $lei->{1}->autoflush(1);
 263         my $atomic_append = !defined($ovv->{lock_path});
 264         my $dedupe = $lei->{dedupe};
 265         $dedupe->prepare_dedupe;
 266         sub { # for git_to_mail
 267                 my ($buf, $smsg, $eml) = @_;
 268                 $eml //= PublicInbox::Eml->new($buf);
 269                 return if $dedupe->is_dup($eml, $smsg->{blob});
 270                 $buf = $eml2mbox->($eml, $smsg);
 271                 return atomic_append($lei, $buf) if $atomic_append;
 272                 my $lk = $ovv->lock_for_scope;
 273                 $lei->out($$buf);
 274         }
 275 }
 276
 277 sub update_kw_maybe ($$$$) {
 278         my ($lei, $lse, $eml, $kw) = @_;
 279         return unless $lse;
 280         my $x = $lse->kw_changed($eml, $kw);
 281         if ($x) {
 282                 $lei->{sto}->ipc_do('set_eml', $eml, @$kw);
 283         } elsif (!defined($x)) {
 284                 # TODO: xkw
 285         }
 286 }
 287
 288 sub _augment_or_unlink { # maildir_each_eml cb
 289         my ($f, $kw, $eml, $lei, $lse, $mod, $shard, $unlink) = @_;
 290         if ($mod) {
 291                 # can't get dirent.d_ino w/ pure Perl, so we extract the OID
 292                 # if it looks like one:
 293                 my $hex = $f =~ m!\b([a-f0-9]{40,})[^/]*\z! ?
 294                                 $1 : sha256_hex($f);
 295                 my $recno = hex(substr($hex, 0, 8));
 296                 return if ($recno % $mod) != $shard;
 297                 update_kw_maybe($lei, $lse, $eml, $kw);
 298         }
 299         $unlink ? unlink($f) : _augment($eml, $lei);
 300 }
 301
 302 # maildir_each_file callback, \&CORE::unlink doesn't work with it
 303 sub _unlink { unlink($_[0]) }
 304
 305 sub _rand () {
 306         state $seq = 0;
 307         sprintf('%x,%x,%x,%x', rand(0xffffffff), time, $$, ++$seq);
 308 }
 309
 310 sub _buf2maildir {
 311         my ($dst, $buf, $smsg) = @_;
 312         my $kw = $smsg->{kw} // [];
 313         my $sfx = join('', sort(map { $kw2char{$_} // () } @$kw));
 314         my $rand = ''; # chosen by die roll :P
 315         my ($tmp, $fh, $final, $ok);
 316         my $common = $smsg->{blob} // _rand;
 317         if (defined(my $pct = $smsg->{pct})) { $common .= "=$pct" }
 318         do {
 319                 $tmp = $dst.'tmp/'.$rand.$common;
 320         } while (!($ok = sysopen($fh, $tmp, O_CREAT|O_EXCL|O_WRONLY)) &&
 321                 $! == EEXIST && ($rand = _rand.','));
 322         if ($ok && print $fh $$buf and close($fh)) {
 323                 # ignore new/ and write only to cur/, otherwise MUAs
 324                 # with R/W access to the Maildir will end up doing
 325                 # a mass rename which can take a while with thousands
 326                 # of messages.
 327                 $dst .= 'cur/';
 328                 $rand = '';
 329                 do {
 330                         $final = $dst.$rand.$common.':2,'.$sfx;
 331                 } while (!($ok = link($tmp, $final)) && $! == EEXIST &&
 332                         ($rand = _rand.','));
 333                 die "link($tmp, $final): $!" unless $ok;
 334                 unlink($tmp) or warn "W: failed to unlink $tmp: $!\n";
 335         } else {
 336                 my $err = "Error writing $smsg->{blob} to $dst: $!\n";
 337                 $_[0] = undef; # clobber dst
 338                 unlink($tmp);
 339                 die $err;
 340         }
 341 }
 342
 343 sub _maildir_write_cb ($$) {
 344         my ($self, $lei) = @_;
 345         my $dedupe = $lei->{dedupe};
 346         $dedupe->prepare_dedupe if $dedupe;
 347         my $dst = $lei->{ovv}->{dst};
 348         sub { # for git_to_mail
 349                 my ($buf, $smsg, $eml) = @_;
 350                 $dst // return $lei->fail; # dst may be undef-ed in last run
 351                 $buf //= \($eml->as_string);
 352                 return _buf2maildir($dst, $buf, $smsg) if !$dedupe;
 353                 $eml //= PublicInbox::Eml->new($$buf); # copy buf
 354                 return if $dedupe->is_dup($eml, $smsg->{blob});
 355                 undef $eml;
 356                 _buf2maildir($dst, $buf, $smsg);
 357         }
 358 }
 359
 360 sub _imap_write_cb ($$) {
 361         my ($self, $lei) = @_;
 362         my $dedupe = $lei->{dedupe};
 363         $dedupe->prepare_dedupe if $dedupe;
 364         my $imap_append = $lei->{net}->can('imap_append');
 365         my $mic = $lei->{net}->mic_get($self->{uri});
 366         my $folder = $self->{uri}->mailbox;
 367         sub { # for git_to_mail
 368                 my ($bref, $smsg, $eml) = @_;
 369                 $mic // return $lei->fail; # dst may be undef-ed in last run
 370                 if ($dedupe) {
 371                         $eml //= PublicInbox::Eml->new($$bref); # copy bref
 372                         return if $dedupe->is_dup($eml, $smsg->{blob});
 373                 }
 374                 eval { $imap_append->($mic, $folder, $bref, $smsg, $eml) };
 375                 if (my $err = $@) {
 376                         undef $mic;
 377                         die $err;
 378                 }
 379         }
 380 }
 381
 382 sub write_cb { # returns a callback for git_to_mail
 383         my ($self, $lei) = @_;
 384         # _mbox_write_cb, _maildir_write_cb or _imap_write_cb
 385         my $m = "_$self->{base_type}_write_cb";
 386         $self->$m($lei);
 387 }
 388
 389 sub new {
 390         my ($cls, $lei) = @_;
 391         my $fmt = $lei->{ovv}->{fmt};
 392         my $dst = $lei->{ovv}->{dst};
 393         my $self = bless {}, $cls;
 394         if ($fmt eq 'maildir') {
 395                 require PublicInbox::MdirReader;
 396                 $self->{base_type} = 'maildir';
 397                 -e $dst && !-d _ and die
 398                                 "$dst exists and is not a directory\n";
 399                 $lei->{ovv}->{dst} = $dst .= '/' if substr($dst, -1) ne '/';
 400         } elsif (substr($fmt, 0, 4) eq 'mbox') {
 401                 require PublicInbox::MboxReader;
 402                 (-d $dst || (-e _ && !-w _)) and die
 403                         "$dst exists and is not a writable file\n";
 404                 $self->can("eml2$fmt") or die "bad mbox format: $fmt\n";
 405                 $self->{base_type} = 'mbox';
 406         } elsif ($fmt =~ /\Aimaps?\z/) { # TODO .onion support
 407                 require PublicInbox::NetWriter;
 408                 my $net = PublicInbox::NetWriter->new;
 409                 $net->add_url($dst);
 410                 $net->{quiet} = $lei->{opt}->{quiet};
 411                 my $err = $net->errors($dst);
 412                 return $lei->fail($err) if $err;
 413                 require PublicInbox::URIimap; # TODO: URI cast early
 414                 $self->{uri} = PublicInbox::URIimap->new($dst);
 415                 $self->{uri}->mailbox or die "No mailbox: $dst";
 416                 $lei->{net} = $net;
 417                 $self->{base_type} = 'imap';
 418         } else {
 419                 die "bad mail --format=$fmt\n";
 420         }
 421         $self->{dst} = $dst;
 422         $lei->{dedupe} = PublicInbox::LeiDedupe->new($lei);
 423         $self;
 424 }
 425
 426 sub _pre_augment_maildir {
 427         my ($self, $lei) = @_;
 428         my $dst = $lei->{ovv}->{dst};
 429         for my $x (qw(tmp new cur)) {
 430                 my $d = $dst.$x;
 431                 next if -d $d;
 432                 require File::Path;
 433                 File::Path::mkpath($d);
 434                 -d $d or die "$d is not a directory";
 435         }
 436 }
 437
 438 sub _do_augment_maildir {
 439         my ($self, $lei) = @_;
 440         my $dst = $lei->{ovv}->{dst};
 441         my $lse = $lei->{sto}->search if $lei->{opt}->{'import-before'};
 442         my ($mod, $shard) = @{$self->{shard_info} // []};
 443         if ($lei->{opt}->{augment}) {
 444                 my $dedupe = $lei->{dedupe};
 445                 if ($dedupe && $dedupe->prepare_dedupe) {
 446                         PublicInbox::MdirReader::maildir_each_eml($dst,
 447                                                 \&_augment_or_unlink,
 448                                                 $lei, $lse, $mod, $shard);
 449                         $dedupe->pause_dedupe;
 450                 }
 451         } elsif ($lse) {
 452                 PublicInbox::MdirReader::maildir_each_eml($dst,
 453                                         \&_augment_or_unlink,
 454                                         $lei, $lse, $mod, $shard, 1);
 455         } else {# clobber existing Maildir
 456                 PublicInbox::MdirReader::maildir_each_file($dst, \&_unlink);
 457         }
 458 }
 459
 460 sub _imap_augment_or_delete { # PublicInbox::NetReader::imap_each cb
 461         my ($url, $uid, $kw, $eml, $lei, $lse, $delete_mic) = @_;
 462         update_kw_maybe($lei, $lse, $eml, $kw);
 463         if ($delete_mic) {
 464                 $lei->{net}->imap_delete_1($url, $uid, $delete_mic);
 465         } else {
 466                 _augment($eml, $lei);
 467         }
 468 }
 469
 470 sub _do_augment_imap {
 471         my ($self, $lei) = @_;
 472         my $net = $lei->{net};
 473         my $lse = $lei->{sto}->search if $lei->{opt}->{'import-before'};
 474         if ($lei->{opt}->{augment}) {
 475                 my $dedupe = $lei->{dedupe};
 476                 if ($dedupe && $dedupe->prepare_dedupe) {
 477                         $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 478                                         $lei, $lse);
 479                         $dedupe->pause_dedupe;
 480                 }
 481         } elsif ($lse) {
 482                 my $delete_mic;
 483                 $net->imap_each($self->{uri}, \&_imap_augment_or_delete,
 484                                         $lei, $lse, \$delete_mic);
 485                 $delete_mic->expunge if $delete_mic;
 486         } elsif (!$self->{-wq_worker_nr}) { # undef or 0
 487                 # clobber existing IMAP folder
 488                 $net->imap_delete_all($self->{uri});
 489         }
 490 }
 491
 492 sub _pre_augment_mbox {
 493         my ($self, $lei) = @_;
 494         my $dst = $lei->{ovv}->{dst};
 495         my $out = $lei->{1};
 496         if ($dst ne '/dev/stdout') {
 497                 if (-p $dst) {
 498                         open $out, '>', $dst or die "open($dst): $!";
 499                 } elsif (-f _ || !-e _) {
 500                         require PublicInbox::MboxLock;
 501                         my $m = $lei->{opt}->{'lock'} //
 502                                         PublicInbox::MboxLock->defaults;
 503                         $self->{mbl} = PublicInbox::MboxLock->acq($dst, 1, $m);
 504                         $out = $self->{mbl}->{fh};
 505                 }
 506                 $lei->{old_1} = $lei->{1}; # keep for spawning MUA
 507         }
 508         # Perl does SEEK_END even with O_APPEND :<
 509         $self->{seekable} = seek($out, 0, SEEK_SET);
 510         if (!$self->{seekable} && $! != ESPIPE && $dst ne '/dev/stdout') {
 511                 die "seek($dst): $!\n";
 512         }
 513         if (!$self->{seekable}) {
 514                 my $ia = $lei->{opt}->{'import-before'};
 515                 die "--import-before specified but $dst is not seekable\n"
 516                         if $ia && !ref($ia);
 517                 die "--augment specified but $dst is not seekable\n" if
 518                         $lei->{opt}->{augment};
 519         }
 520         state $zsfx_allow = join('|', keys %zsfx2cmd);
 521         if (($self->{zsfx}) = ($dst =~ /\.($zsfx_allow)\z/)) {
 522                 pipe(my ($r, $w)) or die "pipe: $!";
 523                 $lei->{zpipe} = [ $r, $w ];
 524         }
 525         $lei->{1} = $out;
 526         undef;
 527 }
 528
 529 sub _do_augment_mbox {
 530         my ($self, $lei) = @_;
 531         return unless $self->{seekable};
 532         my $opt = $lei->{opt};
 533         my $out = $lei->{1};
 534         my ($fmt, $dst) = @{$lei->{ovv}}{qw(fmt dst)};
 535         return unless -s $out;
 536         unless ($opt->{augment} || $opt->{'import-before'}) {
 537                 truncate($out, 0) or die "truncate($dst): $!";
 538                 return;
 539         }
 540         my $zsfx = $self->{zsfx};
 541         my $rd = $zsfx ? decompress_src($out, $zsfx, $lei) : dup_src($out);
 542         my $dedupe;
 543         if ($opt->{augment}) {
 544                 $dedupe = $lei->{dedupe};
 545                 $dedupe->prepare_dedupe if $dedupe;
 546         }
 547         if ($opt->{'import-before'}) { # the default
 548                 my $lse = $lei->{sto}->search;
 549                 PublicInbox::MboxReader->$fmt($rd, \&_mbox_augment_kw_maybe,
 550                                                 $lei, $lse, $opt->{augment});
 551                 if (!$opt->{augment} and !truncate($out, 0)) {
 552                         die "truncate($dst): $!";
 553                 }
 554         } else { # --augment --no-import-before
 555                 PublicInbox::MboxReader->$fmt($rd, \&_augment, $lei);
 556         }
 557         # maybe some systems don't honor O_APPEND, Perl does this:
 558         seek($out, 0, SEEK_END) or die "seek $dst: $!";
 559         $dedupe->pause_dedupe if $dedupe;
 560 }
 561
 562 sub pre_augment { # fast (1 disk seek), runs in same process as post_augment
 563         my ($self, $lei) = @_;
 564         # _pre_augment_maildir, _pre_augment_mbox
 565         my $m = $self->can("_pre_augment_$self->{base_type}") or return;
 566         $m->($self, $lei);
 567 }
 568
 569 sub do_augment { # slow, runs in wq worker
 570         my ($self, $lei) = @_;
 571         # _do_augment_maildir, _do_augment_mbox, or _do_augment_imap
 572         my $m = "_do_augment_$self->{base_type}";
 573         $self->$m($lei);
 574 }
 575
 576 # fast (spawn compressor or mkdir), runs in same process as pre_augment
 577 sub post_augment {
 578         my ($self, $lei, @args) = @_;
 579         my $wait = $lei->{opt}->{'import-before'} ?
 580                         $lei->{sto}->ipc_do('checkpoint', 1) : 0;
 581         # _post_augment_mbox
 582         my $m = $self->can("_post_augment_$self->{base_type}") or return;
 583         $m->($self, $lei, @args);
 584 }
 585
 586 sub do_post_auth {
 587         my ($self) = @_;
 588         my $lei = $self->{lei};
 589         # lei_xsearch can start as soon as all l2m workers get here
 590         pkt_do($lei->{pkt_op_p}, 'incr_start_query') or
 591                 die "incr_start_query: $!";
 592         my $aug;
 593         if (lock_free($self)) {
 594                 my $mod = $self->{-wq_nr_workers};
 595                 my $shard = $self->{-wq_worker_nr};
 596                 if (my $net = $lei->{net}) {
 597                         $net->{shard_info} = [ $mod, $shard ];
 598                 } else { # Maildir (MH?)
 599                         $self->{shard_info} = [ $mod, $shard ];
 600                 }
 601                 $aug = '+'; # incr_post_augment
 602         } elsif ($self->{-wq_worker_nr} == 0) {
 603                 $aug = '.'; # do_post_augment
 604         }
 605         if ($aug) {
 606                 local $0 = 'do_augment';
 607                 eval { do_augment($self, $lei) };
 608                 $lei->fail($@) if $@;
 609                 pkt_do($lei->{pkt_op_p}, $aug) == 1 or
 610                                 die "do_post_augment trigger: $!";
 611         }
 612         if (my $zpipe = delete $lei->{zpipe}) {
 613                 $lei->{1} = $zpipe->[1];
 614                 close $zpipe->[0];
 615         }
 616         $self->{wcb} = $self->write_cb($lei);
 617 }
 618
 619 sub ipc_atfork_child {
 620         my ($self) = @_;
 621         my $lei = $self->{lei};
 622         $lei->lei_atfork_child;
 623         $lei->{auth}->do_auth_atfork($self) if $lei->{auth};
 624         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 625         $self->SUPER::ipc_atfork_child;
 626 }
 627
 628 sub lock_free {
 629         $_[0]->{base_type} =~ /\A(?:maildir|mh|imap|jmap)\z/ ? 1 : 0;
 630 }
 631
 632 sub poke_dst {
 633         my ($self) = @_;
 634         if ($self->{base_type} eq 'maildir') {
 635                 my $t = time + 1;
 636                 utime($t, $t, "$self->{dst}/cur");
 637         }
 638 }
 639
 640 sub write_mail { # via ->wq_io_do
 641         my ($self, $git_dir, $smsg) = @_;
 642         my $git = $self->{"$$\0$git_dir"} //= PublicInbox::Git->new($git_dir);
 643         git_async_cat($git, $smsg->{blob}, \&git_to_mail,
 644                                 [$self->{wcb}, $smsg]);
 645 }
 646
 647 sub wq_atexit_child {
 648         my ($self) = @_;
 649         delete $self->{wcb};
 650         for my $git (delete @$self{grep(/\A$$\0/, keys %$self)}) {
 651                 $git->async_wait_all;
 652         }
 653         $SIG{__WARN__} = 'DEFAULT';
 654 }
 655
 656 # called in top-level lei-daemon when LeiAuth is done
 657 sub net_merge_complete {
 658         my ($self) = @_;
 659         $self->wq_broadcast('do_post_auth');
 660         $self->wq_close(1);
 661 }
 662
 663 no warnings 'once'; # the following works even when LeiAuth is lazy-loaded
 664 *net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
 665 1;