lib/PublicInbox/LeiUp.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei up" - updates the result of "lei q --save"
   5 package PublicInbox::LeiUp;
   6 use strict;
   7 use v5.10.1;
   8 # n.b. we use LeiInput to setup IMAP auth
   9 use parent qw(PublicInbox::IPC PublicInbox::LeiInput);
  10 use PublicInbox::LeiSavedSearch;
  11 use PublicInbox::DS;
  12 use PublicInbox::PktOp;
  13 use PublicInbox::LeiFinmsg;
  14 use PublicInbox::LEI;
  15 my $REMOTE_RE = qr!\A(?:imap|http)s?://!i; # http(s) will be for JMAP
  16
  17 sub up1 ($$) {
  18         my ($lei, $out) = @_;
  19         my $lss = PublicInbox::LeiSavedSearch->up($lei, $out) or return;
  20         my $f = $lss->{'-f'};
  21         my $mset_opt = $lei->{mset_opt} = { relevance => -2 };
  22         $mset_opt->{limit} = $lei->{opt}->{limit} // 10000;
  23         my $q = $mset_opt->{q_raw} = $lss->{-cfg}->{'lei.q'} //
  24                                 return $lei->fail("lei.q unset in $f");
  25         my $lse = $lei->{lse} // die 'BUG: {lse} missing';
  26         if (ref($q)) {
  27                 $mset_opt->{qstr} = $lse->query_argv_to_string($lse->git, $q);
  28         } else {
  29                 $lse->query_approxidate($lse->git, $mset_opt->{qstr} = $q);
  30         }
  31         my $o = $lei->{opt}->{output} = $lss->{-cfg}->{'lei.q.output'} //
  32                 return $lei->fail("lei.q.output unset in $f");
  33         ref($o) and return $lei->fail("multiple values of lei.q.output in $f");
  34         if (defined(my $dd = $lss->{-cfg}->{'lei.q.dedupe'})) {
  35                 $lss->translate_dedupe($lei, $dd) or return;
  36                 $lei->{opt}->{dedupe} = $dd;
  37         }
  38         for my $k (qw(only include exclude)) {
  39                 my $v = $lss->{-cfg}->get_all("lei.q.$k") // next;
  40                 $lei->{opt}->{$k} = $v;
  41         }
  42         for my $k (qw(external local remote
  43                         import-remote import-before threads)) {
  44                 my $c = "lei.q.$k";
  45                 my $v = $lss->{-cfg}->{$c} // next;
  46                 ref($v) and return $lei->fail("multiple values of $c in $f");
  47                 $lei->{opt}->{$k} = $v;
  48         }
  49         $lei->{lss} = $lss; # for LeiOverview->new
  50         my $lxs = $lei->lxs_prepare or return;
  51         $lei->ale->refresh_externals($lxs, $lei);
  52         $lei->_start_query;
  53 }
  54
  55 sub up1_redispatch {
  56         my ($lei, $out, $op_p) = @_;
  57         my $l = bless { %$lei }, ref($lei);
  58         $l->{opt} = { %{$l->{opt}} };
  59         delete $l->{sock}; # do not close
  60         $l->{''} = $op_p; # daemon only ($l => $lei => script/lei)
  61
  62         # make close($l->{1}) happy in lei->dclose
  63         open my $fh, '>&', $l->{1} or return $l->child_error(0, "dup: $!");
  64         local $PublicInbox::LEI::current_lei = $l;
  65         $l->{1} = $fh;
  66         eval {
  67                 $l->qerr("# updating $out");
  68                 up1($l, $out);
  69         };
  70         $lei->child_error(0, $@) if $@ || $l->{failed}; # lei->fail()
  71 }
  72
  73 sub redispatch_all ($$) {
  74         my ($self, $lei) = @_;
  75         # re-dispatch into our event loop w/o creating an extra fork-level
  76         $lei->{fmsg} = PublicInbox::LeiFinmsg->new($lei->{2});
  77         my ($op_c, $op_p) = PublicInbox::PktOp->pair;
  78         for my $o (@{$self->{local} // []}, @{$self->{remote} // []}) {
  79                 PublicInbox::DS::requeue(sub {
  80                         up1_redispatch($lei, $o, $op_p);
  81                 });
  82         }
  83         $lei->event_step_init;
  84         $lei->pkt_ops($op_c->{ops} = { '' => [$lei->can('dclose'), $lei] });
  85 }
  86
  87 sub lei_up {
  88         my ($lei, @outs) = @_;
  89         my $opt = $lei->{opt};
  90         my $self = bless { -mail_sync => 1 }, __PACKAGE__;
  91         $lei->{lse} = $lei->_lei_store(1)->write_prepare($lei)->search;
  92         if (defined(my $all = $opt->{all})) {
  93                 return $lei->fail("--all and @outs incompatible") if @outs;
  94                 length($opt->{mua}//'') and return
  95                         $lei->fail('--all and --mua= are incompatible');
  96                 @outs = PublicInbox::LeiSavedSearch::list($lei);
  97                 if ($all eq 'local') {
  98                         $self->{local} = [ grep(!/$REMOTE_RE/, @outs) ];
  99                 } elsif ($all eq 'remote') {
 100                         $self->{remote} = [ grep(/$REMOTE_RE/, @outs) ];
 101                 } elsif ($all eq '') {
 102                         $self->{remote} = [ grep(/$REMOTE_RE/, @outs) ];
 103                         $self->{local} = [ grep(!/$REMOTE_RE/, @outs) ];
 104                 } else {
 105                         $lei->fail("only --all=$all not understood");
 106                 }
 107         } else {
 108                 $self->{remote} = [ grep(/$REMOTE_RE/, @outs) ];
 109                 $self->{local} = [ grep(!/$REMOTE_RE/, @outs) ];
 110         }
 111         ((@{$self->{local} // []} + @{$self->{remote} // []}) > 1 &&
 112                 length($opt->{mua} // '')) and return $lei->fail(<<EOM);
 113 multiple outputs and --mua= are incompatible
 114 EOM
 115         if ($self->{remote}) { # setup lei->{auth}
 116                 $self->prepare_inputs($lei, $self->{remote}) or return;
 117         }
 118         if ($lei->{auth}) { # start auth worker
 119                 require PublicInbox::NetWriter;
 120                 bless $lei->{net}, 'PublicInbox::NetWriter';
 121                 $lei->{auth}->op_merge(my $ops = {}, $self, $lei);
 122                 (my $op_c, $ops) = $lei->workers_start($self, 1, $ops);
 123                 $lei->{wq1} = $self;
 124                 $lei->wait_wq_events($op_c, $ops);
 125                 # net_merge_all_done will fire when auth is done
 126         } else {
 127                 redispatch_all($self, $lei); # see below
 128         }
 129 }
 130
 131 # called in top-level lei-daemon when LeiAuth is done
 132 sub net_merge_all_done {
 133         my ($self, $lei) = @_;
 134         $lei->{net} = delete($self->{-net_new}) if $self->{-net_new};
 135         $self->wq_close(1);
 136         redispatch_all($self, $lei);
 137 }
 138
 139 sub _complete_up {
 140         my ($lei, @argv) = @_;
 141         my $match_cb = $lei->complete_url_prepare(\@argv);
 142         map { $match_cb->($_) } PublicInbox::LeiSavedSearch::list($lei);
 143 }
 144
 145 no warnings 'once';
 146 *ipc_atfork_child = \&PublicInbox::LeiInput::input_only_atfork_child;
 147
 148 1;