lib/PublicInbox/LeiUp.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei up" - updates the result of "lei q --save"
   5 package PublicInbox::LeiUp;
   6 use strict;
   7 use v5.10.1;
   8 use PublicInbox::LeiSavedSearch;
   9 use parent qw(PublicInbox::IPC);
  10
  11 sub up1 ($$) {
  12         my ($lei, $out) = @_;
  13         my $lss = PublicInbox::LeiSavedSearch->up($lei, $out) or return;
  14         my $f = $lss->{'-f'};
  15         my $mset_opt = $lei->{mset_opt} = { relevance => -2 };
  16         $mset_opt->{limit} = $lei->{opt}->{limit} // 10000;
  17         my $q = $mset_opt->{q_raw} = $lss->{-cfg}->{'lei.q'} //
  18                                 return $lei->fail("lei.q unset in $f");
  19         my $lse = $lei->{lse} // die 'BUG: {lse} missing';
  20         if (ref($q)) {
  21                 $mset_opt->{qstr} = $lse->query_argv_to_string($lse->git, $q);
  22         } else {
  23                 $lse->query_approxidate($lse->git, $mset_opt->{qstr} = $q);
  24         }
  25         my $o = $lei->{opt}->{output} = $lss->{-cfg}->{'lei.q.output'} //
  26                 return $lei->fail("lei.q.output unset in $f");
  27         ref($o) and return $lei->fail("multiple values of lei.q.output in $f");
  28         if (defined(my $dd = $lss->{-cfg}->{'lei.q.dedupe'})) {
  29                 $lss->translate_dedupe($lei, $dd) or return;
  30                 $lei->{opt}->{dedupe} = $dd;
  31         }
  32         for my $k (qw(only include exclude)) {
  33                 my $v = $lss->{-cfg}->get_all("lei.q.$k") // next;
  34                 $lei->{opt}->{$k} = $v;
  35         }
  36         for my $k (qw(external local remote
  37                         import-remote import-before threads)) {
  38                 my $c = "lei.q.$k";
  39                 my $v = $lss->{-cfg}->{$c} // next;
  40                 ref($v) and return $lei->fail("multiple values of $c in $f");
  41                 $lei->{opt}->{$k} = $v;
  42         }
  43         $lei->{lss} = $lss; # for LeiOverview->new
  44         my $lxs = $lei->lxs_prepare or return;
  45         $lei->ale->refresh_externals($lxs);
  46         $lei->_start_query;
  47 }
  48
  49 sub up1_redispatch {
  50         my ($lei, $out, $op_p) = @_;
  51         my $l = bless { %$lei }, ref($lei);
  52         $l->{opt} = { %{$l->{opt}} };
  53         delete $l->{sock};
  54         $l->{''} = $op_p; # daemon only
  55         eval {
  56                 $l->qerr("# updating $out");
  57                 up1($l, $out);
  58                 $l->qerr("# $out done");
  59         };
  60         $l->err($@) if $@;
  61 }
  62
  63 sub lei_up {
  64         my ($lei, $out) = @_;
  65         $lei->{lse} = $lei->_lei_store(1)->search;
  66         my $opt = $lei->{opt};
  67         $opt->{save} = -1;
  68         if (defined $opt->{all}) {
  69                 length($opt->{mua}//'') and return
  70                         $lei->fail('--all and --mua= are incompatible');
  71
  72                 # supporting IMAP outputs is more involved due to
  73                 # git-credential prompts.  TODO: add this in 1.8
  74                 $opt->{all} eq 'local' or return
  75                         $lei->fail('only --all=local works at the moment');
  76                 my @all = PublicInbox::LeiSavedSearch::list($lei);
  77                 my @local = grep(!m!\Aimaps?://!i, @all);
  78                 $lei->_lei_store->write_prepare($lei); # share early
  79                 if ($lei->{oneshot}) { # synchronous
  80                         up1_redispatch($lei, $_) for @local;
  81                 } else {
  82                         # daemon mode, re-dispatch into our event loop w/o
  83                         # creating an extra fork-level
  84                         require PublicInbox::DS;
  85                         require PublicInbox::PktOp;
  86                         my ($op_c, $op_p) = PublicInbox::PktOp->pair;
  87                         for my $o (@local) {
  88                                 PublicInbox::DS::requeue(sub {
  89                                         up1_redispatch($lei, $o, $op_p);
  90                                 });
  91                         }
  92                         $lei->event_step_init;
  93                         $op_c->{ops} = { '' => [$lei->can('dclose'), $lei] };
  94                 }
  95         } else {
  96                 up1($lei, $out);
  97         }
  98 }
  99
 100 sub _complete_up {
 101         my ($lei, @argv) = @_;
 102         my $match_cb = $lei->complete_url_prepare(\@argv);
 103         map { $match_cb->($_) } PublicInbox::LeiSavedSearch::list($lei);
 104 }
 105
 106 1;