lib/PublicInbox/LeiXSearch.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Combine any combination of PublicInbox::Search,
   5 # PublicInbox::ExtSearch, and PublicInbox::LeiSearch objects
   6 # into one Xapian DB
   7 package PublicInbox::LeiXSearch;
   8 use strict;
   9 use v5.10.1;
  10 use parent qw(PublicInbox::LeiSearch PublicInbox::IPC);
  11 use PublicInbox::DS qw(now);
  12 use File::Temp 0.19 (); # 0.19 for ->newdir
  13 use File::Spec ();
  14 use PublicInbox::Search qw(xap_terms);
  15 use PublicInbox::Spawn qw(popen_rd spawn which);
  16 use PublicInbox::MID qw(mids);
  17 use PublicInbox::Smsg;
  18 use PublicInbox::Eml;
  19 use Fcntl qw(SEEK_SET F_SETFL O_APPEND O_RDWR);
  20 use PublicInbox::ContentHash qw(git_sha);
  21 use POSIX qw(strftime);
  22
  23 sub new {
  24         my ($class) = @_;
  25         PublicInbox::Search::load_xapian();
  26         bless {
  27                 qp_flags => $PublicInbox::Search::QP_FLAGS |
  28                                 PublicInbox::Search::FLAG_PURE_NOT(),
  29         }, $class
  30 }
  31
  32 sub attach_external {
  33         my ($self, $ibxish) = @_; # ibxish = ExtSearch or Inbox
  34         my $desc = $ibxish->{inboxdir} // $ibxish->{topdir};
  35         my $srch = $ibxish->search or
  36                 return warn("$desc not indexed for Xapian ($@ $!)\n");
  37         my @shards = $srch->xdb_shards_flat or
  38                 return warn("$desc has no Xapian shards\n");
  39
  40         if (delete $self->{xdb}) { # XXX: do we need this?
  41                 # clobber existing {xdb} if amending
  42                 my $expect = delete $self->{nshard};
  43                 my $shards = delete $self->{shards_flat};
  44                 scalar(@$shards) == $expect or die
  45                         "BUG: {nshard}$expect != shards=".scalar(@$shards);
  46
  47                 my $prev = {};
  48                 for my $old_ibxish (@{$self->{shard2ibx}}) {
  49                         next if $prev == $old_ibxish;
  50                         $prev = $old_ibxish;
  51                         my @shards = $old_ibxish->search->xdb_shards_flat;
  52                         push @{$self->{shards_flat}}, @shards;
  53                 }
  54                 my $nr = scalar(@{$self->{shards_flat}});
  55                 $nr == $expect or die
  56                         "BUG: reloaded $nr shards, expected $expect"
  57         }
  58         push @{$self->{shards_flat}}, @shards;
  59         push(@{$self->{shard2ibx}}, $ibxish) for (@shards);
  60 }
  61
  62 # returns a list of local inboxes (or count in scalar context)
  63 sub locals { @{$_[0]->{locals} // []} }
  64
  65 sub remotes { @{$_[0]->{remotes} // []} }
  66
  67 # called by PublicInbox::Search::xdb (usually via ->mset)
  68 sub xdb_shards_flat { @{$_[0]->{shards_flat} // []} }
  69
  70 sub _mitem_kw { # retry_reopen callback
  71         my ($srch, $smsg, $mitem, $flagged) = @_;
  72         my $doc = $mitem->get_document;
  73         my $kw = xap_terms('K', $doc);
  74         $kw->{flagged} = 1 if $flagged;
  75         my @L = xap_terms('L', $doc);
  76         # we keep the empty {kw} array here to prevent expensive work in
  77         # ->xsmsg_vmd, _unbless_smsg will clobber it iff it's empty
  78         $smsg->{kw} = [ sort keys %$kw ];
  79         $smsg->{L} = \@L if scalar(@L);
  80 }
  81
  82 sub mitem_kw ($$$;$) {
  83         my ($srch, $smsg, $mitem, $flagged) = @_;
  84         $srch->retry_reopen(\&_mitem_kw, $smsg, $mitem, $flagged);
  85 }
  86
  87 # like over->get_art
  88 sub smsg_for {
  89         my ($self, $mitem) = @_;
  90         # cf. https://trac.xapian.org/wiki/FAQ/MultiDatabaseDocumentID
  91         my $nshard = $self->{nshard};
  92         my $docid = $mitem->get_docid;
  93         my $shard = ($docid - 1) % $nshard;
  94         my $num = int(($docid - 1) / $nshard) + 1;
  95         my $ibx = $self->{shard2ibx}->[$shard];
  96         my $smsg = $ibx->over->get_art($num);
  97         return if $smsg->{bytes} == 0; # external message
  98         if ($ibx->can('msg_keywords')) {
  99                 mitem_kw($self, $smsg, $mitem);
 100         }
 101         $smsg;
 102 }
 103
 104 sub recent {
 105         my ($self, $qstr, $opt) = @_;
 106         $opt //= {};
 107         $opt->{relevance} //= -2;
 108         $self->mset($qstr //= 'z:1..', $opt);
 109 }
 110
 111 sub over {}
 112
 113 sub _mset_more ($$) {
 114         my ($mset, $mo) = @_;
 115         my $size = $mset->size;
 116         $size >= $mo->{limit} && (($mo->{offset} += $size) < $mo->{limit});
 117 }
 118
 119 # $startq will EOF when do_augment is done augmenting and allow
 120 # query_combined_mset and query_thread_mset to proceed.
 121 sub wait_startq ($) {
 122         my ($lei) = @_;
 123         my $startq = delete $lei->{startq} or return;
 124         while (1) {
 125                 my $n = sysread($startq, my $do_augment_done, 1);
 126                 if (defined $n) {
 127                         return if $n == 0; # no MUA
 128                         if ($do_augment_done eq 'q') {
 129                                 $lei->{opt}->{quiet} = 1;
 130                                 delete $lei->{opt}->{verbose};
 131                                 delete $lei->{-progress};
 132                         } else {
 133                                 $lei->fail("$$ WTF `$do_augment_done'");
 134                         }
 135                         return;
 136                 }
 137                 return $lei->fail("$$ wait_startq: $!") unless $!{EINTR};
 138         }
 139 }
 140
 141 sub mset_progress {
 142         my $lei = shift;
 143         return if $lei->{early_mua} || !$lei->{-progress};
 144         if ($lei->{pkt_op_p}) {
 145                 $lei->{pkt_op_p}->pkt_do('mset_progress', @_);
 146         } else { # single lei-daemon consumer
 147                 my ($desc, $mset_size, $mset_total_est) = @_;
 148                 $lei->{-mset_total} += $mset_size if $mset_total_est ne '?';
 149                 $lei->qerr("# $desc $mset_size/$mset_total_est");
 150         }
 151 }
 152
 153 sub l2m_progress {
 154         my ($lei, $nr) = @_;
 155         $lei->{-nr_write} += $nr;
 156 }
 157
 158 sub query_one_mset { # for --threads and l2m w/o sort
 159         my ($self, $ibxish) = @_;
 160         local $0 = "$0 query_one_mset";
 161         my $lei = $self->{lei};
 162         my ($srch, $over) = ($ibxish->search, $ibxish->over);
 163         my $dir = $ibxish->{inboxdir} // $ibxish->{topdir};
 164         return warn("$dir not indexed by Xapian\n") unless ($srch && $over);
 165         bless $srch, 'PublicInbox::LeiSearch'; # for ->qparse_new
 166         my $mo = { %{$lei->{mset_opt}} }; # copy
 167         my $mset;
 168         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 169         my $can_kw = !!$ibxish->can('msg_keywords');
 170         my $threads = $lei->{opt}->{threads} // 0;
 171         my $fl = $threads > 1 ? 1 : undef;
 172         my $lss = $lei->{lss};
 173         my $maxk = "external.$dir.maxuid";
 174         my $stop_at = $lss ? $lss->{-cfg}->{$maxk} : undef;
 175         if (defined $stop_at) {
 176                 die "$maxk=$stop_at has multiple values" if ref $stop_at;
 177                 my @e;
 178                 local $SIG{__WARN__} = sub { push @e, @_ };
 179                 $stop_at += 0;
 180                 return warn("$maxk=$stop_at: @e") if @e;
 181         }
 182         my $first_ids;
 183         do {
 184                 $mset = $srch->mset($mo->{qstr}, $mo);
 185                 mset_progress($lei, $dir, $mset->size,
 186                                 $mset->get_matches_estimated);
 187                 wait_startq($lei); # wait for keyword updates
 188                 my $ids = $srch->mset_to_artnums($mset, $mo);
 189                 @$ids = grep { $_ > $stop_at } @$ids if defined($stop_at);
 190                 my $i = 0;
 191                 if ($threads) {
 192                         # copy $ids if $lss since over->expand_thread
 193                         # shifts @{$ctx->{ids}}
 194                         $first_ids = [ @$ids ] if $lss;
 195                         my $ctx = { ids => $ids };
 196                         my %n2item = map { ($ids->[$i++], $_) } $mset->items;
 197                         while ($over->expand_thread($ctx)) {
 198                                 for my $n (@{$ctx->{xids}}) {
 199                                         my $smsg = $over->get_art($n) or next;
 200                                         my $mitem = delete $n2item{$n};
 201                                         next if $smsg->{bytes} == 0;
 202                                         if ($mitem && $can_kw) {
 203                                                 mitem_kw($srch, $smsg, $mitem,
 204                                                         $fl);
 205                                         } elsif ($mitem && $fl) {
 206                                                 # call ->xsmsg_vmd, later
 207                                                 $smsg->{lei_q_tt_flagged} = 1;
 208                                         }
 209                                         $each_smsg->($smsg, $mitem);
 210                                 }
 211                                 @{$ctx->{xids}} = ();
 212                         }
 213                 } else {
 214                         $first_ids = $ids;
 215                         my @items = $mset->items;
 216                         for my $n (@$ids) {
 217                                 my $mitem = $items[$i++];
 218                                 my $smsg = $over->get_art($n) or next;
 219                                 next if $smsg->{bytes} == 0;
 220                                 mitem_kw($srch, $smsg, $mitem, $fl) if $can_kw;
 221                                 $each_smsg->($smsg, $mitem);
 222                         }
 223                 }
 224         } while (_mset_more($mset, $mo));
 225         if ($lss && scalar(@$first_ids)) {
 226                 undef $stop_at;
 227                 my $max = $first_ids->[0];
 228                 $lss->cfg_set($maxk, $max);
 229                 undef $lss;
 230         }
 231         undef $each_smsg; # may commit
 232         $lei->{ovv}->ovv_atexit_child($lei);
 233 }
 234
 235 sub query_combined_mset { # non-parallel for non-"--threads" users
 236         my ($self) = @_;
 237         local $0 = "$0 query_combined_mset";
 238         my $lei = $self->{lei};
 239         my $mo = { %{$lei->{mset_opt}} };
 240         my $mset;
 241         for my $loc (locals($self)) {
 242                 attach_external($self, $loc);
 243         }
 244         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 245         do {
 246                 $mset = $self->mset($mo->{qstr}, $mo);
 247                 mset_progress($lei, 'xsearch', $mset->size,
 248                                 $mset->get_matches_estimated);
 249                 wait_startq($lei); # wait for keyword updates
 250                 for my $mitem ($mset->items) {
 251                         my $smsg = smsg_for($self, $mitem) or next;
 252                         $each_smsg->($smsg, $mitem);
 253                 }
 254         } while (_mset_more($mset, $mo));
 255         undef $each_smsg; # may commit
 256         $lei->{ovv}->ovv_atexit_child($lei);
 257 }
 258
 259 sub _smsg_fill ($$) {
 260         my ($smsg, $eml) = @_;
 261         $smsg->populate($eml);
 262         $smsg->parse_references($eml, mids($eml));
 263         $smsg->{$_} //= '' for qw(from to cc ds subject references mid);
 264         delete @$smsg{qw(From Subject -ds -ts)};
 265 }
 266
 267 sub each_remote_eml { # callback for MboxReader->mboxrd
 268         my ($eml, $self, $lei, $each_smsg) = @_;
 269         my $xoids = $lei->{ale}->xoids_for($eml, 1);
 270         my $smsg = bless {}, 'PublicInbox::Smsg';
 271         if ($self->{import_sto} && !$xoids) {
 272                 my $res = $self->{import_sto}->ipc_do('add_eml', $eml);
 273                 if (ref($res) eq ref($smsg)) { # totally new message
 274                         $smsg = $res;
 275                         $smsg->{kw} = []; # short-circuit xsmsg_vmd
 276                 }
 277         }
 278         $smsg->{blob} //= $xoids ? (keys(%$xoids))[0]
 279                                 : $lei->git_oid($eml)->hexdigest;
 280         _smsg_fill($smsg, $eml);
 281         wait_startq($lei);
 282         if ($lei->{-progress}) {
 283                 ++$lei->{-nr_remote_eml};
 284                 my $now = now();
 285                 my $next = $lei->{-next_progress} //= ($now + 1);
 286                 if ($now > $next) {
 287                         $lei->{-next_progress} = $now + 1;
 288                         my $nr = $lei->{-nr_remote_eml};
 289                         mset_progress($lei, $lei->{-current_url}, $nr, '?');
 290                 }
 291         }
 292         $each_smsg->($smsg, undef, $eml);
 293 }
 294
 295 sub fudge_qstr_time ($$$) {
 296         my ($lei, $uri, $qstr) = @_;
 297         return ($qstr, undef) unless $lei->{lss};
 298         my $cfg = $lei->{lss}->{-cfg} // die 'BUG: no lss->{-cfg}';
 299         my $cfg_key = "external.$uri.lastresult";
 300         my $lr = $cfg->{$cfg_key} or return ($qstr, $cfg_key);
 301         if ($lr !~ /\A\-?[0-9]+\z/) {
 302                 $lei->child_error(0,
 303                         "$cfg->{-f}: $cfg_key=$lr not an integer, ignoring");
 304                 return ($qstr, $cfg_key);
 305         }
 306         my $rft = $lei->{opt}->{'remote-fudge-time'};
 307         if ($rft && $rft !~ /\A-?[0-9]+\z/) {
 308                 my @t = $lei->{lss}->git->date_parse($rft);
 309                 my $diff = time - $t[0];
 310                 $lei->qerr("# $rft => $diff seconds");
 311                 $rft = $diff;
 312         }
 313         $lr -= ($rft || (48 * 60 * 60));
 314         $lei->qerr("# $uri limiting to ".
 315                 strftime('%Y-%m-%d %k:%M', gmtime($lr)). ' and newer');
 316         # this should really be rt: (received-time), but no stable
 317         # public-inbox releases support it, yet.
 318         my $dt = 'dt:'.strftime('%Y%m%d%H%M%S', gmtime($lr)).'..';
 319         if ($qstr =~ /\S/) {
 320                 substr($qstr, 0, 0, '(');
 321                 $qstr .= ') AND ';
 322         }
 323         ($qstr .= $dt, $cfg_key);
 324 }
 325
 326 sub query_remote_mboxrd {
 327         my ($self, $uris) = @_;
 328         local $0 = "$0 query_remote_mboxrd";
 329         local $SIG{TERM} = sub { exit(0) }; # for DESTROY (File::Temp, $reap)
 330         my $lei = $self->{lei};
 331         my $opt = $lei->{opt};
 332         my $qstr = $lei->{mset_opt}->{qstr};
 333         $qstr =~ s/[ \n\t]+/ /sg; # make URLs less ugly
 334         my @qform = (x => 'm');
 335         push(@qform, t => 1) if $opt->{threads};
 336         my $verbose = $opt->{verbose};
 337         my ($reap_tail, $reap_curl);
 338         my $cerr = File::Temp->new(TEMPLATE => 'curl.err-XXXX', TMPDIR => 1);
 339         fcntl($cerr, F_SETFL, O_APPEND|O_RDWR) or warn "set O_APPEND: $!";
 340         my $rdr = { 2 => $cerr, pgid => 0 };
 341         my $sigint_reap = $lei->can('sigint_reap');
 342         if ($verbose) {
 343                 # spawn a process to force line-buffering, otherwise curl
 344                 # will write 1 character at-a-time and parallel outputs
 345                 # mmmaaayyy llloookkk llliiikkkeee ttthhhiiisss
 346                 my $o = { 1 => $lei->{2}, 2 => $lei->{2}, pgid => 0 };
 347                 my $pid = spawn(['tail', '-f', $cerr->filename], undef, $o);
 348                 $reap_tail = PublicInbox::OnDestroy->new($sigint_reap, $pid);
 349         }
 350         my $curl = PublicInbox::LeiCurl->new($lei, $self->{curl}) or return;
 351         push @$curl, '-s', '-d', '';
 352         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 353         $self->{import_sto} = $lei->{sto} if $lei->{opt}->{'import-remote'};
 354         for my $uri (@$uris) {
 355                 $lei->{-current_url} = $uri->as_string;
 356                 $lei->{-nr_remote_eml} = 0;
 357                 my $start = time;
 358                 my ($q, $key) = fudge_qstr_time($lei, $uri, $qstr);
 359                 $uri->query_form(@qform, q => $q);
 360                 my $cmd = $curl->for_uri($lei, $uri);
 361                 $lei->qerr("# $cmd");
 362                 my ($fh, $pid) = popen_rd($cmd, undef, $rdr);
 363                 $reap_curl = PublicInbox::OnDestroy->new($sigint_reap, $pid);
 364                 $fh = IO::Uncompress::Gunzip->new($fh, MultiStream => 1);
 365                 PublicInbox::MboxReader->mboxrd($fh, \&each_remote_eml, $self,
 366                                                 $lei, $each_smsg);
 367                 my $err = waitpid($pid, 0) == $pid ? undef
 368                                                 : "BUG: waitpid($cmd): $!";
 369                 @$reap_curl = (); # cancel OnDestroy
 370                 die $err if $err;
 371                 my $nr = $lei->{-nr_remote_eml};
 372                 my $wait = $lei->{sto}->ipc_do('done') if $nr && $lei->{sto};
 373                 if ($? == 0) {
 374                         # don't update if no results, maybe MTA is down
 375                         $key && $nr and
 376                                 $lei->{lss}->cfg_set($key, $start);
 377                         mset_progress($lei, $lei->{-current_url}, $nr, $nr);
 378                         next;
 379                 }
 380                 $err = '';
 381                 if (-s $cerr) {
 382                         seek($cerr, 0, SEEK_SET) or
 383                                         $lei->err("seek($cmd stderr): $!");
 384                         $err = do { local $/; <$cerr> } //
 385                                         "read($cmd stderr): $!";
 386                         truncate($cerr, 0) or
 387                                         $lei->err("truncate($cmd stderr): $!");
 388                 }
 389                 next if (($? >> 8) == 22 && $err =~ /\b404\b/);
 390                 $uri->query_form(q => $qstr);
 391                 $lei->child_error($?, "E: <$uri> $err");
 392         }
 393         undef $each_smsg;
 394         $lei->{ovv}->ovv_atexit_child($lei);
 395 }
 396
 397 sub git { $_[0]->{git} // die 'BUG: git uninitialized' }
 398
 399 sub xsearch_done_wait { # dwaitpid callback
 400         my ($arg, $pid) = @_;
 401         my ($wq, $lei) = @$arg;
 402         $lei->child_error($?, 'non-fatal error from '.ref($wq)) if $?;
 403 }
 404
 405 sub query_done { # EOF callback for main daemon
 406         my ($lei) = @_;
 407         my $l2m = delete $lei->{l2m};
 408         $l2m->wq_wait_old(\&xsearch_done_wait, $lei) if $l2m;
 409         if (my $lxs = delete $lei->{lxs}) {
 410                 $lxs->wq_wait_old(\&xsearch_done_wait, $lei);
 411         }
 412         if ($lei->{opt}->{'mail-sync'} && !$lei->{sto}) {
 413                 warn "BUG: {sto} missing with --mail-sync";
 414         }
 415         $lei->sto_done_request if $lei->{sto};
 416         my $wait = $lei->{v2w} ? $lei->{v2w}->ipc_do('done') : undef;
 417         $lei->{ovv}->ovv_end($lei);
 418         my $start_mua;
 419         if ($l2m) { # close() calls LeiToMail reap_compress
 420                 if (my $out = delete $lei->{old_1}) {
 421                         if (my $mbout = $lei->{1}) {
 422                                 close($mbout) or return $lei->fail(<<"");
 423 Error closing $lei->{ovv}->{dst}: $!
 424
 425                         }
 426                         $lei->{1} = $out;
 427                 }
 428                 if ($l2m->lock_free) {
 429                         $l2m->poke_dst;
 430                         $lei->poke_mua;
 431                 } else { # mbox users
 432                         delete $l2m->{mbl}; # drop dotlock
 433                         $start_mua = 1;
 434                 }
 435         }
 436         if ($lei->{-progress}) {
 437                 my $tot = $lei->{-mset_total} // 0;
 438                 my $nr = $lei->{-nr_write} // 0;
 439                 if ($l2m) {
 440                         my $m = "# $nr written to " .
 441                                 "$lei->{ovv}->{dst} ($tot matches)";
 442                         $nr ? $lei->qfin($m) : $lei->qerr($m);
 443                 } else {
 444                         $lei->qerr("# $tot matches");
 445                 }
 446         }
 447         $lei->start_mua if $start_mua;
 448         $lei->dclose;
 449 }
 450
 451 sub do_post_augment {
 452         my ($lei) = @_;
 453         my $l2m = $lei->{l2m} or return; # client disconnected
 454         $lei->fchdir or return;
 455         my $err;
 456         eval { $l2m->post_augment($lei) };
 457         $err = $@;
 458         if ($err) {
 459                 if (my $lxs = delete $lei->{lxs}) {
 460                         $lxs->wq_kill;
 461                         $lxs->wq_close(0, undef, $lei);
 462                 }
 463                 $lei->fail("$err");
 464         }
 465         if (!$err && delete $lei->{early_mua}) { # non-augment case
 466                 $lei->start_mua;
 467         }
 468         close(delete $lei->{au_done}); # triggers wait_startq in lei_xsearch
 469 }
 470
 471 sub incr_post_augment { # called whenever an l2m shard finishes augment
 472         my ($lei) = @_;
 473         my $l2m = $lei->{l2m} or return; # client disconnected
 474         return if ++$lei->{nr_post_augment} != $l2m->{-wq_nr_workers};
 475         do_post_augment($lei);
 476 }
 477
 478 my $MAX_PER_HOST = 4;
 479
 480 sub concurrency {
 481         my ($self, $opt) = @_;
 482         my $nl = $opt->{threads} ? locals($self) : 1;
 483         my $nr = remotes($self);
 484         $nr = $MAX_PER_HOST if $nr > $MAX_PER_HOST;
 485         $nl + $nr;
 486 }
 487
 488 sub start_query ($;$) { # always runs in main (lei-daemon) process
 489         my ($self, $l2m) = @_;
 490         if ($self->{opt_threads} || ($l2m && !$self->{opt_sort})) {
 491                 for my $ibxish (locals($self)) {
 492                         $self->wq_io_do('query_one_mset', [], $ibxish);
 493                 }
 494         } elsif (locals($self)) {
 495                 $self->wq_io_do('query_combined_mset', []);
 496         }
 497         my $i = 0;
 498         my $q = [];
 499         for my $uri (remotes($self)) {
 500                 push @{$q->[$i++ % $MAX_PER_HOST]}, $uri;
 501         }
 502         for my $uris (@$q) {
 503                 $self->wq_io_do('query_remote_mboxrd', [], $uris);
 504         }
 505         if ($self->{-do_lcat}) {
 506                 $self->wq_io_do('lcat_dump', []);
 507         }
 508         $self->wq_close(1); # lei_xsearch workers stop when done
 509 }
 510
 511 sub incr_start_query { # called whenever an l2m shard starts do_post_auth
 512         my ($self, $l2m) = @_;
 513         return if ++$self->{nr_start_query} != $l2m->{-wq_nr_workers};
 514         start_query($self, $l2m);
 515 }
 516
 517 sub ipc_atfork_child {
 518         my ($self) = @_;
 519         $self->{lei}->_lei_atfork_child;
 520         $self->SUPER::ipc_atfork_child;
 521 }
 522
 523 sub do_query {
 524         my ($self, $lei) = @_;
 525         my $l2m = $lei->{l2m};
 526         my $ops = {
 527                 '|' => [ $lei->can('sigpipe_handler'), $lei ],
 528                 '!' => [ $lei->can('fail_handler'), $lei ],
 529                 '.' => [ \&do_post_augment, $lei ],
 530                 '+' => [ \&incr_post_augment, $lei ],
 531                 '' => [ \&query_done, $lei ],
 532                 'mset_progress' => [ \&mset_progress, $lei ],
 533                 'l2m_progress' => [ \&l2m_progress, $lei ],
 534                 'x_it' => [ $lei->can('x_it'), $lei ],
 535                 'child_error' => [ $lei->can('child_error'), $lei ],
 536                 'incr_start_query' => [ \&incr_start_query, $self, $l2m ],
 537         };
 538         $lei->{auth}->op_merge($ops, $l2m) if $l2m && $lei->{auth};
 539         my $end = $lei->pkt_op_pair;
 540         $lei->{1}->autoflush(1);
 541         $lei->start_pager if delete $lei->{need_pager};
 542         $lei->{ovv}->ovv_begin($lei);
 543         die 'BUG: xdb|over open' if $lei->{lse}->{xdb} || $lei->{lse}->{over};
 544         if ($l2m) {
 545                 $l2m->pre_augment($lei);
 546                 if ($lei->{opt}->{augment} && delete $lei->{early_mua}) {
 547                         $lei->start_mua;
 548                 }
 549                 my $F_SETPIPE_SZ = $^O eq 'linux' ? 1031 : undef;
 550                 if ($l2m->{-wq_nr_workers} > 1 &&
 551                                 $l2m->{base_type} =~ /\A(?:maildir|mbox)\z/) {
 552                         # setup two barriers to coordinate ->has_entries
 553                         # between l2m workers
 554                         pipe(my ($a_r, $a_w)) or die "pipe: $!";
 555                         fcntl($a_r, $F_SETPIPE_SZ, 4096) if $F_SETPIPE_SZ;
 556                         pipe(my ($b_r, $b_w)) or die "pipe: $!";
 557                         fcntl($b_r, $F_SETPIPE_SZ, 4096) if $F_SETPIPE_SZ;
 558                         $l2m->{au_peers} = [ $a_r, $a_w, $b_r, $b_w ];
 559                 }
 560                 $l2m->wq_workers_start('lei2mail', undef,
 561                                         $lei->oldset, { lei => $lei });
 562                 pipe($lei->{startq}, $lei->{au_done}) or die "pipe: $!";
 563                 fcntl($lei->{startq}, $F_SETPIPE_SZ, 4096) if $F_SETPIPE_SZ;
 564                 delete $l2m->{au_peers};
 565         }
 566         $self->wq_workers_start('lei_xsearch', undef,
 567                                 $lei->oldset, { lei => $lei });
 568         my $op_c = delete $lei->{pkt_op_c};
 569         delete $lei->{pkt_op_p};
 570         @$end = ();
 571         $self->{opt_threads} = $lei->{opt}->{threads};
 572         $self->{opt_sort} = $lei->{opt}->{'sort'};
 573         $self->{-do_lcat} = $lei->{lcat_blob} // $lei->{lcat_fid};
 574         if ($l2m) {
 575                 $l2m->net_merge_all_done unless $lei->{auth};
 576         } else {
 577                 start_query($self);
 578         }
 579         $lei->event_step_init; # wait for shutdowns
 580         $lei->wait_wq_events($op_c, $ops);
 581 }
 582
 583 sub add_uri {
 584         my ($self, $uri) = @_;
 585         if (my $curl = $self->{curl} //= which('curl') // 0) {
 586                 require PublicInbox::MboxReader;
 587                 require IO::Uncompress::Gunzip;
 588                 require PublicInbox::LeiCurl;
 589                 push @{$self->{remotes}}, $uri;
 590         } else {
 591                 warn "curl missing, ignoring $uri\n";
 592         }
 593 }
 594
 595 sub prepare_external {
 596         my ($self, $loc, $boost) = @_; # n.b. already ordered by boost
 597         if (ref $loc) { # already a URI, or PublicInbox::Inbox-like object
 598                 return add_uri($self, $loc) if $loc->can('scheme');
 599         } elsif ($loc =~ m!\Ahttps?://!) {
 600                 require URI;
 601                 return add_uri($self, URI->new($loc));
 602         } elsif (-f "$loc/ei.lock") {
 603                 require PublicInbox::ExtSearch;
 604                 die "`\\n' not allowed in `$loc'\n" if index($loc, "\n") >= 0;
 605                 $loc = PublicInbox::ExtSearch->new($loc);
 606         } elsif (-f "$loc/inbox.lock" || -d "$loc/public-inbox") {
 607                 die "`\\n' not allowed in `$loc'\n" if index($loc, "\n") >= 0;
 608                 require PublicInbox::Inbox; # v2, v1
 609                 $loc = bless { inboxdir => $loc }, 'PublicInbox::Inbox';
 610         } elsif (!-e $loc) {
 611                 warn "W: $loc gone, perhaps run: lei forget-external $loc\n";
 612                 return;
 613         } else {
 614                 warn "W: $loc ignored, unable to determine external type\n";
 615                 return;
 616         }
 617         push @{$self->{locals}}, $loc;
 618 }
 619
 620 sub _lcat_i { # LeiMailSync->each_src iterator callback
 621         my ($oidbin, $id, $each_smsg) = @_;
 622         $each_smsg->({blob => unpack('H*', $oidbin), pct => 100});
 623 }
 624
 625 sub _lcat2smsg { # git->cat_async callback
 626         my ($bref, $oid, $type, $size, $smsg) = @_;
 627         if ($bref) {
 628                 my $eml = PublicInbox::Eml->new($bref);
 629                 my $json_dump = delete $smsg->{-json_dump};
 630                 bless $smsg, 'PublicInbox::Smsg';
 631                 _smsg_fill($smsg, $eml);
 632                 $json_dump->($smsg, undef, $eml);
 633         }
 634 }
 635
 636 sub lcat_dump {
 637         my ($self) = @_;
 638         my $lei = $self->{lei};
 639         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 640         my $git = $lei->{ale}->git;
 641         if (!$lei->{l2m}) {
 642                 my $json_dump = $each_smsg;
 643                 $each_smsg = sub {
 644                         my ($smsg) = @_;
 645                         use Data::Dumper;
 646                         $smsg->{-json_dump} = $json_dump;
 647                         $git->cat_async($smsg->{blob}, \&_lcat2smsg, $smsg);
 648                 };
 649         }
 650         for my $oid (@{$lei->{lcat_blob} // []}) {
 651                 $each_smsg->({ blob => $oid, pct => 100 });
 652         }
 653         if (my $fids = delete $lei->{lcat_fid}) {
 654                 my $lms = $lei->{lse}->lms;
 655                 for my $fid (@$fids) {
 656                         $lms->each_src({fid => $fid}, \&_lcat_i, $each_smsg);
 657                 }
 658         }
 659         $git->async_wait_all;
 660         undef $each_smsg; # may commit
 661         $lei->{ovv}->ovv_atexit_child($lei);
 662 }
 663
 664 1;