lib/PublicInbox/LeiXSearch.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Combine any combination of PublicInbox::Search,
   5 # PublicInbox::ExtSearch, and PublicInbox::LeiSearch objects
   6 # into one Xapian DB
   7 package PublicInbox::LeiXSearch;
   8 use strict;
   9 use v5.10.1;
  10 use parent qw(PublicInbox::LeiSearch PublicInbox::IPC);
  11 use PublicInbox::DS qw(now);
  12 use File::Temp 0.19 (); # 0.19 for ->newdir
  13 use File::Spec ();
  14 use PublicInbox::Search qw(xap_terms);
  15 use PublicInbox::Spawn qw(popen_rd spawn which);
  16 use PublicInbox::MID qw(mids);
  17 use PublicInbox::Smsg;
  18 use PublicInbox::Eml;
  19 use PublicInbox::LEI;
  20 use Fcntl qw(SEEK_SET F_SETFL O_APPEND O_RDWR);
  21 use PublicInbox::ContentHash qw(git_sha);
  22 use POSIX qw(strftime);
  23
  24 sub new {
  25         my ($class) = @_;
  26         PublicInbox::Search::load_xapian();
  27         bless {
  28                 qp_flags => $PublicInbox::Search::QP_FLAGS |
  29                                 PublicInbox::Search::FLAG_PURE_NOT(),
  30         }, $class
  31 }
  32
  33 sub attach_external {
  34         my ($self, $ibxish) = @_; # ibxish = ExtSearch or Inbox
  35         my $desc = $ibxish->{inboxdir} // $ibxish->{topdir};
  36         my $srch = $ibxish->search //
  37                 return warn("$desc not indexed for Xapian ($@ $!)\n");
  38         my @shards = $srch->xdb_shards_flat or
  39                 return warn("$desc has no Xapian shards\n");
  40
  41         if (delete $self->{xdb}) { # XXX: do we need this?
  42                 # clobber existing {xdb} if amending
  43                 my $expect = delete $self->{nshard};
  44                 my $shards = delete $self->{shards_flat};
  45                 scalar(@$shards) == $expect or die
  46                         "BUG: {nshard}$expect != shards=".scalar(@$shards);
  47
  48                 my $prev = {};
  49                 for my $old_ibxish (@{$self->{shard2ibx}}) {
  50                         next if $prev == $old_ibxish;
  51                         $prev = $old_ibxish;
  52                         my @shards = $old_ibxish->search->xdb_shards_flat;
  53                         push @{$self->{shards_flat}}, @shards;
  54                 }
  55                 my $nr = scalar(@{$self->{shards_flat}});
  56                 $nr == $expect or die
  57                         "BUG: reloaded $nr shards, expected $expect"
  58         }
  59         push @{$self->{shards_flat}}, @shards;
  60         push(@{$self->{shard2ibx}}, $ibxish) for (@shards);
  61 }
  62
  63 # returns a list of local inboxes (or count in scalar context)
  64 sub locals { @{$_[0]->{locals} // []} }
  65
  66 sub remotes { @{$_[0]->{remotes} // []} }
  67
  68 # called by PublicInbox::Search::xdb (usually via ->mset)
  69 sub xdb_shards_flat { @{$_[0]->{shards_flat} // []} }
  70
  71 sub _mitem_kw { # retry_reopen callback
  72         my ($srch, $smsg, $mitem, $flagged) = @_;
  73         my $doc = $mitem->get_document;
  74         my $kw = xap_terms('K', $doc);
  75         $kw->{flagged} = 1 if $flagged;
  76         my @L = xap_terms('L', $doc);
  77         # we keep the empty {kw} array here to prevent expensive work in
  78         # ->xsmsg_vmd, _unbless_smsg will clobber it iff it's empty
  79         $smsg->{kw} = [ sort keys %$kw ];
  80         $smsg->{L} = \@L if scalar(@L);
  81 }
  82
  83 sub mitem_kw ($$$;$) {
  84         my ($srch, $smsg, $mitem, $flagged) = @_;
  85         $srch->retry_reopen(\&_mitem_kw, $smsg, $mitem, $flagged);
  86 }
  87
  88 # like over->get_art
  89 sub smsg_for {
  90         my ($self, $mitem) = @_;
  91         # cf. https://trac.xapian.org/wiki/FAQ/MultiDatabaseDocumentID
  92         my $nshard = $self->{nshard};
  93         my $docid = $mitem->get_docid;
  94         my $shard = ($docid - 1) % $nshard;
  95         my $num = int(($docid - 1) / $nshard) + 1;
  96         my $ibx = $self->{shard2ibx}->[$shard];
  97         my $smsg = $ibx->over->get_art($num);
  98         return if $smsg->{bytes} == 0; # external message
  99         if ($ibx->can('msg_keywords')) {
 100                 mitem_kw($self, $smsg, $mitem);
 101         }
 102         $smsg;
 103 }
 104
 105 sub recent {
 106         my ($self, $qstr, $opt) = @_;
 107         $opt //= {};
 108         $opt->{relevance} //= -2;
 109         $self->mset($qstr //= 'z:1..', $opt);
 110 }
 111
 112 sub over {}
 113
 114 sub _check_mset_limit ($$$) {
 115         my ($lei, $desc, $mset) = @_;
 116         return if defined($lei->{opt}->{limit}); # user requested limit
 117         my $est = $mset->get_matches_estimated;
 118         my $tot = $lei->{mset_opt}->{total};
 119         $est > $tot and $lei->qerr(<<"");
 120 # $desc estimated matches ($est) exceeds default --limit=$tot
 121
 122 }
 123
 124 sub _mset_more ($$) {
 125         my ($mset, $mo) = @_;
 126         my $size = $mset->size;
 127         $size >= $mo->{limit} && (($mo->{offset} += $size) < $mo->{total});
 128 }
 129
 130 # $startq will EOF when do_augment is done augmenting and allow
 131 # query_combined_mset and query_thread_mset to proceed.
 132 sub wait_startq ($) {
 133         my ($lei) = @_;
 134         my $startq = delete $lei->{startq} or return;
 135         while (1) {
 136                 my $n = sysread($startq, my $do_augment_done, 1);
 137                 if (defined $n) {
 138                         return if $n == 0; # no MUA
 139                         if ($do_augment_done eq 'q') {
 140                                 $lei->{opt}->{quiet} = 1;
 141                                 delete $lei->{opt}->{verbose};
 142                                 delete $lei->{-progress};
 143                         } else {
 144                                 $lei->fail("$$ WTF `$do_augment_done'");
 145                         }
 146                         return;
 147                 }
 148                 return $lei->fail("$$ wait_startq: $!") unless $!{EINTR};
 149         }
 150 }
 151
 152 sub mset_progress {
 153         my $lei = shift;
 154         return if $lei->{early_mua} || !$lei->{-progress};
 155         if ($lei->{pkt_op_p}) {
 156                 $lei->{pkt_op_p}->pkt_do('mset_progress', @_);
 157         } else { # single lei-daemon consumer
 158                 my ($desc, $mset_size, $mset_total_est) = @_;
 159                 $lei->{-mset_total} += $mset_size if $mset_total_est ne '?';
 160                 $lei->qerr("# $desc $mset_size/$mset_total_est");
 161         }
 162 }
 163
 164 sub l2m_progress {
 165         my ($lei, $nr) = @_;
 166         $lei->{-nr_write} += $nr;
 167 }
 168
 169 sub query_one_mset { # for --threads and l2m w/o sort
 170         my ($self, $ibxish) = @_;
 171         local $0 = "$0 query_one_mset";
 172         my $lei = $self->{lei};
 173         my ($srch, $over) = ($ibxish->search, $ibxish->over);
 174         my $dir = $ibxish->{inboxdir} // $ibxish->{topdir};
 175         return warn("$dir not indexed by Xapian\n") unless ($srch && $over);
 176         bless $srch, 'PublicInbox::LeiSearch'; # for ->qparse_new
 177         my $mo = { %{$lei->{mset_opt}} }; # copy
 178         my $mset;
 179         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 180         my $can_kw = !!$ibxish->can('msg_keywords');
 181         my $threads = $lei->{opt}->{threads} // 0;
 182         my $fl = $threads > 1 ? 1 : undef;
 183         my $lss = $lei->{lss};
 184         my $maxk = "external.$dir.maxuid";
 185         my $stop_at = $lss ? $lss->{-cfg}->{$maxk} : undef;
 186         if (defined $stop_at) {
 187                 ref($stop_at) and
 188                         return warn("$maxk=$stop_at has multiple values\n");
 189                 ($stop_at =~ /[^0-9]/) and
 190                         return warn("$maxk=$stop_at not numeric\n");
 191         }
 192         my $first_ids;
 193         do {
 194                 $mset = $srch->mset($mo->{qstr}, $mo);
 195                 mset_progress($lei, $dir, $mo->{offset} + $mset->size,
 196                                 $mset->get_matches_estimated);
 197                 wait_startq($lei); # wait for keyword updates
 198                 my $ids = $srch->mset_to_artnums($mset, $mo);
 199                 @$ids = grep { $_ > $stop_at } @$ids if defined($stop_at);
 200                 my $i = 0;
 201                 if ($threads) {
 202                         # copy $ids if $lss since over->expand_thread
 203                         # shifts @{$ctx->{ids}}
 204                         $first_ids = [ @$ids ] if $lss;
 205                         my $ctx = { ids => $ids };
 206                         my %n2item = map { ($ids->[$i++], $_) } $mset->items;
 207                         while ($over->expand_thread($ctx)) {
 208                                 for my $n (@{$ctx->{xids}}) {
 209                                         my $smsg = $over->get_art($n) or next;
 210                                         my $mitem = delete $n2item{$n};
 211                                         next if $smsg->{bytes} == 0;
 212                                         if ($mitem && $can_kw) {
 213                                                 mitem_kw($srch, $smsg, $mitem,
 214                                                         $fl);
 215                                         } elsif ($mitem && $fl) {
 216                                                 # call ->xsmsg_vmd, later
 217                                                 $smsg->{lei_q_tt_flagged} = 1;
 218                                         }
 219                                         $each_smsg->($smsg, $mitem);
 220                                 }
 221                                 @{$ctx->{xids}} = ();
 222                         }
 223                 } else {
 224                         $first_ids = $ids;
 225                         my @items = $mset->items;
 226                         for my $n (@$ids) {
 227                                 my $mitem = $items[$i++];
 228                                 my $smsg = $over->get_art($n) or next;
 229                                 next if $smsg->{bytes} == 0;
 230                                 mitem_kw($srch, $smsg, $mitem, $fl) if $can_kw;
 231                                 $each_smsg->($smsg, $mitem);
 232                         }
 233                 }
 234         } while (_mset_more($mset, $mo));
 235         _check_mset_limit($lei, $dir, $mset);
 236         if ($lss && scalar(@$first_ids)) {
 237                 undef $stop_at;
 238                 my $max = $first_ids->[0];
 239                 $lss->cfg_set($maxk, $max);
 240                 undef $lss;
 241         }
 242         undef $each_smsg; # may commit
 243         $lei->{ovv}->ovv_atexit_child($lei);
 244 }
 245
 246 sub query_combined_mset { # non-parallel for non-"--threads" users
 247         my ($self) = @_;
 248         local $0 = "$0 query_combined_mset";
 249         my $lei = $self->{lei};
 250         my $mo = { %{$lei->{mset_opt}} };
 251         my $mset;
 252         for my $loc (locals($self)) {
 253                 attach_external($self, $loc);
 254         }
 255         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 256         do {
 257                 $mset = $self->mset($mo->{qstr}, $mo);
 258                 mset_progress($lei, 'xsearch', $mo->{offset} + $mset->size,
 259                                 $mset->get_matches_estimated);
 260                 wait_startq($lei); # wait for keyword updates
 261                 for my $mitem ($mset->items) {
 262                         my $smsg = smsg_for($self, $mitem) or next;
 263                         $each_smsg->($smsg, $mitem);
 264                 }
 265         } while (_mset_more($mset, $mo));
 266         _check_mset_limit($lei, 'xsearch', $mset);
 267         undef $each_smsg; # may commit
 268         $lei->{ovv}->ovv_atexit_child($lei);
 269 }
 270
 271 sub _smsg_fill ($$) {
 272         my ($smsg, $eml) = @_;
 273         $smsg->populate($eml);
 274         $smsg->parse_references($eml, mids($eml));
 275         $smsg->{$_} //= '' for qw(from to cc ds subject references mid);
 276         delete @$smsg{qw(From Subject -ds -ts)};
 277 }
 278
 279 sub each_remote_eml { # callback for MboxReader->mboxrd
 280         my ($eml, $self, $lei, $each_smsg) = @_;
 281         my $xoids = $lei->{ale}->xoids_for($eml, 1);
 282         my $smsg = bless {}, 'PublicInbox::Smsg';
 283         if ($self->{import_sto} && !$xoids) {
 284                 my $res = $self->{import_sto}->wq_do('add_eml', $eml);
 285                 if (ref($res) eq ref($smsg)) { # totally new message
 286                         $smsg = $res;
 287                         $smsg->{kw} = []; # short-circuit xsmsg_vmd
 288                 }
 289         }
 290         $smsg->{blob} //= $xoids ? (keys(%$xoids))[0]
 291                                 : $lei->git_oid($eml)->hexdigest;
 292         _smsg_fill($smsg, $eml);
 293         wait_startq($lei);
 294         if ($lei->{-progress}) {
 295                 ++$lei->{-nr_remote_eml};
 296                 my $now = now();
 297                 my $next = $lei->{-next_progress} //= ($now + 1);
 298                 if ($now > $next) {
 299                         $lei->{-next_progress} = $now + 1;
 300                         my $nr = $lei->{-nr_remote_eml};
 301                         mset_progress($lei, $lei->{-current_url}, $nr, '?');
 302                 }
 303         }
 304         $each_smsg->($smsg, undef, $eml);
 305 }
 306
 307 sub fudge_qstr_time ($$$) {
 308         my ($lei, $uri, $qstr) = @_;
 309         return ($qstr, undef) unless $lei->{lss};
 310         my $cfg = $lei->{lss}->{-cfg} // die 'BUG: no lss->{-cfg}';
 311         my $cfg_key = "external.$uri.lastresult";
 312         my $lr = $cfg->{$cfg_key} or return ($qstr, $cfg_key);
 313         if ($lr !~ /\A\-?[0-9]+\z/) {
 314                 $lei->child_error(0,
 315                         "$cfg->{-f}: $cfg_key=$lr not an integer, ignoring");
 316                 return ($qstr, $cfg_key);
 317         }
 318         my $rft = $lei->{opt}->{'remote-fudge-time'};
 319         if ($rft && $rft !~ /\A-?[0-9]+\z/) {
 320                 my @t = $lei->{lss}->git->date_parse($rft);
 321                 my $diff = time - $t[0];
 322                 $lei->qerr("# $rft => $diff seconds");
 323                 $rft = $diff;
 324         }
 325         $lr -= ($rft || (48 * 60 * 60));
 326         $lei->qerr("# $uri limiting to ".
 327                 strftime('%Y-%m-%d %k:%M %z', localtime($lr)). ' and newer');
 328         # this should really be rt: (received-time), but no stable
 329         # public-inbox releases support it, yet.
 330         my $dt = 'dt:'.strftime('%Y%m%d%H%M%S', gmtime($lr)).'..';
 331         if ($qstr =~ /\S/) {
 332                 substr($qstr, 0, 0, '(');
 333                 $qstr .= ') AND ';
 334         }
 335         ($qstr .= $dt, $cfg_key);
 336 }
 337
 338 sub query_remote_mboxrd {
 339         my ($self, $uris) = @_;
 340         local $0 = "$0 query_remote_mboxrd";
 341         local $SIG{TERM} = sub { exit(0) }; # for DESTROY (File::Temp, $reap)
 342         my $lei = $self->{lei};
 343         my $opt = $lei->{opt};
 344         my $qstr = $lei->{mset_opt}->{qstr};
 345         $qstr =~ s/[ \n\t]+/ /sg; # make URLs less ugly
 346         my @qform = (x => 'm');
 347         push(@qform, t => 1) if $opt->{threads};
 348         my $verbose = $opt->{verbose};
 349         my ($reap_tail, $reap_curl);
 350         my $cerr = File::Temp->new(TEMPLATE => 'curl.err-XXXX', TMPDIR => 1);
 351         fcntl($cerr, F_SETFL, O_APPEND|O_RDWR) or warn "set O_APPEND: $!";
 352         my $rdr = { 2 => $cerr, pgid => 0 };
 353         my $sigint_reap = $lei->can('sigint_reap');
 354         if ($verbose) {
 355                 # spawn a process to force line-buffering, otherwise curl
 356                 # will write 1 character at-a-time and parallel outputs
 357                 # mmmaaayyy llloookkk llliiikkkeee ttthhhiiisss
 358                 my $o = { 1 => $lei->{2}, 2 => $lei->{2}, pgid => 0 };
 359                 my $pid = spawn(['tail', '-f', $cerr->filename], undef, $o);
 360                 $reap_tail = PublicInbox::OnDestroy->new($sigint_reap, $pid);
 361         }
 362         my $curl = PublicInbox::LeiCurl->new($lei, $self->{curl}) or return;
 363         push @$curl, '-s', '-d', '';
 364         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 365         $self->{import_sto} = $lei->{sto} if $lei->{opt}->{'import-remote'};
 366         for my $uri (@$uris) {
 367                 $lei->{-current_url} = $uri->as_string;
 368                 $lei->{-nr_remote_eml} = 0;
 369                 my $start = time;
 370                 my ($q, $key) = fudge_qstr_time($lei, $uri, $qstr);
 371                 $uri->query_form(@qform, q => $q);
 372                 my $cmd = $curl->for_uri($lei, $uri);
 373                 $lei->qerr("# $cmd");
 374                 my ($fh, $pid) = popen_rd($cmd, undef, $rdr);
 375                 $reap_curl = PublicInbox::OnDestroy->new($sigint_reap, $pid);
 376                 $fh = IO::Uncompress::Gunzip->new($fh, MultiStream => 1);
 377                 PublicInbox::MboxReader->mboxrd($fh, \&each_remote_eml, $self,
 378                                                 $lei, $each_smsg);
 379                 my $err = waitpid($pid, 0) == $pid ? undef
 380                                                 : "BUG: waitpid($cmd): $!";
 381                 @$reap_curl = (); # cancel OnDestroy
 382                 die $err if $err;
 383                 my $nr = $lei->{-nr_remote_eml};
 384                 my $wait = $lei->{sto}->wq_do('done') if $nr && $lei->{sto};
 385                 if ($? == 0) {
 386                         # don't update if no results, maybe MTA is down
 387                         $key && $nr and
 388                                 $lei->{lss}->cfg_set($key, $start);
 389                         mset_progress($lei, $lei->{-current_url}, $nr, $nr);
 390                         next;
 391                 }
 392                 $err = '';
 393                 if (-s $cerr) {
 394                         seek($cerr, 0, SEEK_SET) //
 395                                         warn "seek($cmd stderr): $!";
 396                         $err = do { local $/; <$cerr> } //
 397                                         warn "read($cmd stderr): $!";
 398                         truncate($cerr, 0) // warn "truncate($cmd stderr): $!";
 399                 }
 400                 next if (($? >> 8) == 22 && $err =~ /\b404\b/);
 401                 $uri->query_form(q => $qstr);
 402                 $lei->child_error($?, "E: <$uri> $err");
 403         }
 404         undef $each_smsg;
 405         $lei->{ovv}->ovv_atexit_child($lei);
 406 }
 407
 408 sub git { $_[0]->{git} // die 'BUG: git uninitialized' }
 409
 410 sub xsearch_done_wait { # dwaitpid callback
 411         my ($arg, $pid) = @_;
 412         my ($wq, $lei) = @$arg;
 413         $lei->child_error($?, 'non-fatal error from '.ref($wq)) if $?;
 414 }
 415
 416 sub query_done { # EOF callback for main daemon
 417         my ($lei) = @_;
 418         local $PublicInbox::LEI::current_lei = $lei;
 419         my $l2m = delete $lei->{l2m};
 420         $l2m->wq_wait_old(\&xsearch_done_wait, $lei) if $l2m;
 421         if (my $lxs = delete $lei->{lxs}) {
 422                 $lxs->wq_wait_old(\&xsearch_done_wait, $lei);
 423         }
 424         ($lei->{opt}->{'mail-sync'} && !$lei->{sto}) and
 425                 warn "BUG: {sto} missing with --mail-sync";
 426         $lei->sto_done_request if $lei->{sto};
 427         my $wait = $lei->{v2w} ? $lei->{v2w}->wq_do('done') : undef;
 428         $lei->{ovv}->ovv_end($lei);
 429         my $start_mua;
 430         if ($l2m) { # close() calls LeiToMail reap_compress
 431                 if (my $out = delete $lei->{old_1}) {
 432                         if (my $mbout = $lei->{1}) {
 433                                 close($mbout) or return $lei->fail(<<"");
 434 Error closing $lei->{ovv}->{dst}: $!
 435
 436                         }
 437                         $lei->{1} = $out;
 438                 }
 439                 if ($l2m->lock_free) {
 440                         $l2m->poke_dst;
 441                         $lei->poke_mua;
 442                 } else { # mbox users
 443                         delete $l2m->{mbl}; # drop dotlock
 444                         $start_mua = 1;
 445                 }
 446         }
 447         if ($lei->{-progress}) {
 448                 my $tot = $lei->{-mset_total} // 0;
 449                 my $nr = $lei->{-nr_write} // 0;
 450                 if ($l2m) {
 451                         my $m = "# $nr written to " .
 452                                 "$lei->{ovv}->{dst} ($tot matches)";
 453                         $nr ? $lei->qfin($m) : $lei->qerr($m);
 454                 } else {
 455                         $lei->qerr("# $tot matches");
 456                 }
 457         }
 458         $lei->start_mua if $start_mua;
 459         $lei->dclose;
 460 }
 461
 462 sub do_post_augment {
 463         my ($lei) = @_;
 464         local $PublicInbox::LEI::current_lei = $lei;
 465         my $l2m = $lei->{l2m} or return; # client disconnected
 466         $lei->fchdir or return;
 467         my $err;
 468         eval { $l2m->post_augment($lei) };
 469         $err = $@;
 470         if ($err) {
 471                 if (my $lxs = delete $lei->{lxs}) {
 472                         $lxs->wq_kill('-TERM');
 473                         $lxs->wq_close(0, undef, $lei);
 474                 }
 475                 $lei->fail("$err");
 476         }
 477         if (!$err && delete $lei->{early_mua}) { # non-augment case
 478                 $lei->start_mua;
 479         }
 480         close(delete $lei->{au_done}); # triggers wait_startq in lei_xsearch
 481 }
 482
 483 sub incr_post_augment { # called whenever an l2m shard finishes augment
 484         my ($lei) = @_;
 485         my $l2m = $lei->{l2m} or return; # client disconnected
 486         return if ++$lei->{nr_post_augment} != $l2m->{-wq_nr_workers};
 487         do_post_augment($lei);
 488 }
 489
 490 my $MAX_PER_HOST = 4;
 491
 492 sub concurrency {
 493         my ($self, $opt) = @_;
 494         my $nl = $opt->{threads} ? locals($self) : 1;
 495         my $nr = remotes($self);
 496         $nr = $MAX_PER_HOST if $nr > $MAX_PER_HOST;
 497         $nl + $nr;
 498 }
 499
 500 sub start_query ($$) { # always runs in main (lei-daemon) process
 501         my ($self, $lei) = @_;
 502         local $PublicInbox::LEI::current_lei = $lei;
 503         if ($self->{opt_threads} || ($lei->{l2m} && !$self->{opt_sort})) {
 504                 for my $ibxish (locals($self)) {
 505                         $self->wq_io_do('query_one_mset', [], $ibxish);
 506                 }
 507         } elsif (locals($self)) {
 508                 $self->wq_io_do('query_combined_mset', []);
 509         }
 510         my $i = 0;
 511         my $q = [];
 512         for my $uri (remotes($self)) {
 513                 push @{$q->[$i++ % $MAX_PER_HOST]}, $uri;
 514         }
 515         for my $uris (@$q) {
 516                 $self->wq_io_do('query_remote_mboxrd', [], $uris);
 517         }
 518         if ($self->{-do_lcat}) {
 519                 $self->wq_io_do('lcat_dump', []);
 520         }
 521         $self->wq_close(1); # lei_xsearch workers stop when done
 522 }
 523
 524 sub incr_start_query { # called whenever an l2m shard starts do_post_auth
 525         my ($self, $lei) = @_;
 526         my $l2m = $lei->{l2m};
 527         return if ++$self->{nr_start_query} != $l2m->{-wq_nr_workers};
 528         start_query($self, $lei);
 529 }
 530
 531 sub ipc_atfork_child {
 532         my ($self) = @_;
 533         $self->{lei}->_lei_atfork_child;
 534         $self->SUPER::ipc_atfork_child;
 535 }
 536
 537 sub do_query {
 538         my ($self, $lei) = @_;
 539         my $l2m = $lei->{l2m};
 540         my $ops = {
 541                 'sigpipe_handler' => [ $lei ],
 542                 'fail_handler' => [ $lei ],
 543                 'do_post_augment' => [ \&do_post_augment, $lei ],
 544                 'incr_post_augment' => [ \&incr_post_augment, $lei ],
 545                 '' => [ \&query_done, $lei ],
 546                 'mset_progress' => [ \&mset_progress, $lei ],
 547                 'l2m_progress' => [ \&l2m_progress, $lei ],
 548                 'x_it' => [ $lei ],
 549                 'child_error' => [ $lei ],
 550                 'incr_start_query' => [ $self, $lei ],
 551         };
 552         $lei->{auth}->op_merge($ops, $l2m) if $l2m && $lei->{auth};
 553         my $end = $lei->pkt_op_pair;
 554         $lei->{1}->autoflush(1);
 555         $lei->start_pager if delete $lei->{need_pager};
 556         $lei->{ovv}->ovv_begin($lei);
 557         die 'BUG: xdb|over open' if $lei->{lse}->{xdb} || $lei->{lse}->{over};
 558         if ($l2m) {
 559                 $l2m->pre_augment($lei);
 560                 if ($lei->{opt}->{augment} && delete $lei->{early_mua}) {
 561                         $lei->start_mua;
 562                 }
 563                 my $F_SETPIPE_SZ = $^O eq 'linux' ? 1031 : undef;
 564                 if ($l2m->{-wq_nr_workers} > 1 &&
 565                                 $l2m->{base_type} =~ /\A(?:maildir|mbox)\z/) {
 566                         # setup two barriers to coordinate ->has_entries
 567                         # between l2m workers
 568                         pipe(my ($a_r, $a_w)) or die "pipe: $!";
 569                         fcntl($a_r, $F_SETPIPE_SZ, 4096) if $F_SETPIPE_SZ;
 570                         pipe(my ($b_r, $b_w)) or die "pipe: $!";
 571                         fcntl($b_r, $F_SETPIPE_SZ, 4096) if $F_SETPIPE_SZ;
 572                         $l2m->{au_peers} = [ $a_r, $a_w, $b_r, $b_w ];
 573                 }
 574                 $l2m->wq_workers_start('lei2mail', undef,
 575                                         $lei->oldset, { lei => $lei });
 576                 pipe($lei->{startq}, $lei->{au_done}) or die "pipe: $!";
 577                 fcntl($lei->{startq}, $F_SETPIPE_SZ, 4096) if $F_SETPIPE_SZ;
 578                 delete $l2m->{au_peers};
 579         }
 580         $self->wq_workers_start('lei_xsearch', undef,
 581                                 $lei->oldset, { lei => $lei });
 582         my $op_c = delete $lei->{pkt_op_c};
 583         delete $lei->{pkt_op_p};
 584         @$end = ();
 585         $self->{opt_threads} = $lei->{opt}->{threads};
 586         $self->{opt_sort} = $lei->{opt}->{'sort'};
 587         $self->{-do_lcat} = !!(delete $lei->{lcat_todo});
 588         if ($l2m) {
 589                 $l2m->net_merge_all_done($lei) unless $lei->{auth};
 590         } else {
 591                 start_query($self, $lei);
 592         }
 593         $lei->event_step_init; # wait for shutdowns
 594         $lei->wait_wq_events($op_c, $ops);
 595 }
 596
 597 sub add_uri {
 598         my ($self, $uri) = @_;
 599         if (my $curl = $self->{curl} //= which('curl') // 0) {
 600                 require PublicInbox::MboxReader;
 601                 require IO::Uncompress::Gunzip;
 602                 require PublicInbox::LeiCurl;
 603                 push @{$self->{remotes}}, $uri;
 604         } else {
 605                 warn "curl missing, ignoring $uri\n";
 606         }
 607 }
 608
 609 sub prepare_external {
 610         my ($self, $loc, $boost) = @_; # n.b. already ordered by boost
 611         if (ref $loc) { # already a URI, or PublicInbox::Inbox-like object
 612                 return add_uri($self, $loc) if $loc->can('scheme');
 613         } elsif ($loc =~ m!\Ahttps?://!) {
 614                 require URI;
 615                 return add_uri($self, URI->new($loc));
 616         } elsif (-f "$loc/ei.lock") {
 617                 require PublicInbox::ExtSearch;
 618                 die "`\\n' not allowed in `$loc'\n" if index($loc, "\n") >= 0;
 619                 $loc = PublicInbox::ExtSearch->new($loc);
 620         } elsif (-f "$loc/inbox.lock" || -d "$loc/public-inbox") {
 621                 die "`\\n' not allowed in `$loc'\n" if index($loc, "\n") >= 0;
 622                 require PublicInbox::Inbox; # v2, v1
 623                 $loc = bless { inboxdir => $loc }, 'PublicInbox::Inbox';
 624         } elsif (!-e $loc) {
 625                 warn "W: $loc gone, perhaps run: lei forget-external $loc\n";
 626                 return;
 627         } else {
 628                 warn "W: $loc ignored, unable to determine external type\n";
 629                 return;
 630         }
 631         push @{$self->{locals}}, $loc;
 632 }
 633
 634 sub _lcat_i { # LeiMailSync->each_src iterator callback
 635         my ($oidbin, $id, $each_smsg) = @_;
 636         $each_smsg->({blob => unpack('H*', $oidbin), pct => 100});
 637 }
 638
 639 sub _lcat2smsg { # git->cat_async callback
 640         my ($bref, $oid, $type, $size, $smsg) = @_;
 641         if ($bref) {
 642                 my $eml = PublicInbox::Eml->new($bref);
 643                 my $json_dump = delete $smsg->{-json_dump};
 644                 bless $smsg, 'PublicInbox::Smsg';
 645                 _smsg_fill($smsg, $eml);
 646                 $json_dump->($smsg, undef, $eml);
 647         }
 648 }
 649
 650 sub lcat_dump { # via wq_io_do
 651         my ($self) = @_;
 652         my $lei = $self->{lei};
 653         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 654         my $git = $lei->{ale}->git;
 655         if (!$lei->{l2m}) {
 656                 my $json_dump = $each_smsg;
 657                 $each_smsg = sub {
 658                         my ($smsg) = @_;
 659                         $smsg->{-json_dump} = $json_dump;
 660                         $git->cat_async($smsg->{blob}, \&_lcat2smsg, $smsg);
 661                 };
 662         }
 663         my $lms;
 664         for my $ent (@{$lei->{lcat_todo}}) {
 665                 if (ref $ent eq 'HASH') { # { fid => $fid ,.. }
 666                         $lms //= $lei->{lse}->lms;
 667                         $lms->each_src($ent, \&_lcat_i, $each_smsg);
 668                 } else { # oidhex
 669                         $each_smsg->({ blob => $ent, pct => 100 });
 670                 }
 671         }
 672         $git->async_wait_all;
 673         undef $each_smsg; # may commit
 674         $lei->{ovv}->ovv_atexit_child($lei);
 675 }
 676
 677 1;