lib/PublicInbox/LeiXSearch.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Combine any combination of PublicInbox::Search,
   5 # PublicInbox::ExtSearch, and PublicInbox::LeiSearch objects
   6 # into one Xapian DB
   7 package PublicInbox::LeiXSearch;
   8 use strict;
   9 use v5.10.1;
  10 use parent qw(PublicInbox::LeiSearch PublicInbox::IPC);
  11 use PublicInbox::DS qw(now);
  12 use File::Temp 0.19 (); # 0.19 for ->newdir
  13 use File::Spec ();
  14 use PublicInbox::Search qw(xap_terms);
  15 use PublicInbox::Spawn qw(popen_rd spawn which);
  16 use PublicInbox::MID qw(mids);
  17 use PublicInbox::Smsg;
  18 use PublicInbox::Eml;
  19 use Fcntl qw(SEEK_SET F_SETFL O_APPEND O_RDWR);
  20 use PublicInbox::ContentHash qw(git_sha);
  21
  22 sub new {
  23         my ($class) = @_;
  24         PublicInbox::Search::load_xapian();
  25         bless {
  26                 qp_flags => $PublicInbox::Search::QP_FLAGS |
  27                                 PublicInbox::Search::FLAG_PURE_NOT(),
  28         }, $class
  29 }
  30
  31 sub attach_external {
  32         my ($self, $ibxish) = @_; # ibxish = ExtSearch or Inbox
  33         my $desc = $ibxish->{inboxdir} // $ibxish->{topdir};
  34         my $srch = $ibxish->search or
  35                 return warn("$desc not indexed for Xapian ($@ $!)\n");
  36         my @shards = $srch->xdb_shards_flat or
  37                 return warn("$desc has no Xapian shards\n");
  38
  39         if (delete $self->{xdb}) { # XXX: do we need this?
  40                 # clobber existing {xdb} if amending
  41                 my $expect = delete $self->{nshard};
  42                 my $shards = delete $self->{shards_flat};
  43                 scalar(@$shards) == $expect or die
  44                         "BUG: {nshard}$expect != shards=".scalar(@$shards);
  45
  46                 my $prev = {};
  47                 for my $old_ibxish (@{$self->{shard2ibx}}) {
  48                         next if $prev == $old_ibxish;
  49                         $prev = $old_ibxish;
  50                         my @shards = $old_ibxish->search->xdb_shards_flat;
  51                         push @{$self->{shards_flat}}, @shards;
  52                 }
  53                 my $nr = scalar(@{$self->{shards_flat}});
  54                 $nr == $expect or die
  55                         "BUG: reloaded $nr shards, expected $expect"
  56         }
  57         push @{$self->{shards_flat}}, @shards;
  58         push(@{$self->{shard2ibx}}, $ibxish) for (@shards);
  59 }
  60
  61 # returns a list of local inboxes (or count in scalar context)
  62 sub locals { @{$_[0]->{locals} // []} }
  63
  64 sub remotes { @{$_[0]->{remotes} // []} }
  65
  66 # called by PublicInbox::Search::xdb (usually via ->mset)
  67 sub xdb_shards_flat { @{$_[0]->{shards_flat} // []} }
  68
  69 sub _mitem_kw { # retry_reopen callback
  70         my ($srch, $smsg, $mitem, $flagged) = @_;
  71         my $doc = $mitem->get_document;
  72         my $kw = xap_terms('K', $doc);
  73         $kw->{flagged} = 1 if $flagged;
  74         my @L = xap_terms('L', $doc);
  75         # we keep the empty {kw} array here to prevent expensive work in
  76         # ->xsmsg_vmd, _unbless_smsg will clobber it iff it's empty
  77         $smsg->{kw} = [ sort keys %$kw ];
  78         $smsg->{L} = \@L if scalar(@L);
  79 }
  80
  81 sub mitem_kw ($$$;$) {
  82         my ($srch, $smsg, $mitem, $flagged) = @_;
  83         $srch->retry_reopen(\&_mitem_kw, $smsg, $mitem, $flagged);
  84 }
  85
  86 # like over->get_art
  87 sub smsg_for {
  88         my ($self, $mitem) = @_;
  89         # cf. https://trac.xapian.org/wiki/FAQ/MultiDatabaseDocumentID
  90         my $nshard = $self->{nshard};
  91         my $docid = $mitem->get_docid;
  92         my $shard = ($docid - 1) % $nshard;
  93         my $num = int(($docid - 1) / $nshard) + 1;
  94         my $ibx = $self->{shard2ibx}->[$shard];
  95         my $smsg = $ibx->over->get_art($num);
  96         return if $smsg->{bytes} == 0; # external message
  97         if ($ibx->can('msg_keywords')) {
  98                 mitem_kw($self, $smsg, $mitem);
  99         }
 100         $smsg;
 101 }
 102
 103 sub recent {
 104         my ($self, $qstr, $opt) = @_;
 105         $opt //= {};
 106         $opt->{relevance} //= -2;
 107         $self->mset($qstr //= 'z:1..', $opt);
 108 }
 109
 110 sub over {}
 111
 112 sub _mset_more ($$) {
 113         my ($mset, $mo) = @_;
 114         my $size = $mset->size;
 115         $size >= $mo->{limit} && (($mo->{offset} += $size) < $mo->{limit});
 116 }
 117
 118 # $startq will EOF when do_augment is done augmenting and allow
 119 # query_combined_mset and query_thread_mset to proceed.
 120 sub wait_startq ($) {
 121         my ($lei) = @_;
 122         my $startq = delete $lei->{startq} or return;
 123         while (1) {
 124                 my $n = sysread($startq, my $do_augment_done, 1);
 125                 if (defined $n) {
 126                         return if $n == 0; # no MUA
 127                         if ($do_augment_done eq 'q') {
 128                                 $lei->{opt}->{quiet} = 1;
 129                                 delete $lei->{opt}->{verbose};
 130                                 delete $lei->{-progress};
 131                         } else {
 132                                 $lei->fail("$$ WTF `$do_augment_done'");
 133                         }
 134                         return;
 135                 }
 136                 return $lei->fail("$$ wait_startq: $!") unless $!{EINTR};
 137         }
 138 }
 139
 140 sub mset_progress {
 141         my $lei = shift;
 142         return if $lei->{early_mua} || !$lei->{-progress};
 143         if ($lei->{pkt_op_p}) {
 144                 $lei->{pkt_op_p}->pkt_do('mset_progress', @_);
 145         } else { # single lei-daemon consumer
 146                 my ($desc, $mset_size, $mset_total_est) = @_;
 147                 $lei->{-mset_total} += $mset_size if $mset_total_est ne '?';
 148                 $lei->qerr("# $desc $mset_size/$mset_total_est");
 149         }
 150 }
 151
 152 sub l2m_progress {
 153         my ($lei, $nr) = @_;
 154         $lei->{-nr_write} += $nr;
 155 }
 156
 157 sub query_one_mset { # for --threads and l2m w/o sort
 158         my ($self, $ibxish) = @_;
 159         local $0 = "$0 query_one_mset";
 160         my $lei = $self->{lei};
 161         my ($srch, $over) = ($ibxish->search, $ibxish->over);
 162         my $dir = $ibxish->{inboxdir} // $ibxish->{topdir};
 163         return warn("$dir not indexed by Xapian\n") unless ($srch && $over);
 164         my $mo = { %{$lei->{mset_opt}} }; # copy
 165         my $mset;
 166         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 167         my $can_kw = !!$ibxish->can('msg_keywords');
 168         my $threads = $lei->{opt}->{threads} // 0;
 169         my $fl = $threads > 1 ? 1 : undef;
 170         my $lss = $lei->{dedupe};
 171         $lss = undef unless $lss && $lss->can('cfg_set'); # saved search
 172         my $maxk = "external.$dir.maxuid";
 173         my $stop_at = $lss ? $lss->{-cfg}->{$maxk} : undef;
 174         if (defined $stop_at) {
 175                 die "$maxk=$stop_at has multiple values" if ref $stop_at;
 176                 my @e;
 177                 local $SIG{__WARN__} = sub { push @e, @_ };
 178                 $stop_at += 0;
 179                 return warn("$maxk=$stop_at: @e") if @e;
 180         }
 181         my $first_ids;
 182         do {
 183                 $mset = $srch->mset($mo->{qstr}, $mo);
 184                 mset_progress($lei, $dir, $mset->size,
 185                                 $mset->get_matches_estimated);
 186                 wait_startq($lei); # wait for keyword updates
 187                 my $ids = $srch->mset_to_artnums($mset, $mo);
 188                 @$ids = grep { $_ > $stop_at } @$ids if defined($stop_at);
 189                 my $i = 0;
 190                 if ($threads) {
 191                         # copy $ids if $lss since over->expand_thread
 192                         # shifts @{$ctx->{ids}}
 193                         $first_ids = [ @$ids ] if $lss;
 194                         my $ctx = { ids => $ids };
 195                         my %n2item = map { ($ids->[$i++], $_) } $mset->items;
 196                         while ($over->expand_thread($ctx)) {
 197                                 for my $n (@{$ctx->{xids}}) {
 198                                         my $smsg = $over->get_art($n) or next;
 199                                         my $mitem = delete $n2item{$n};
 200                                         next if $smsg->{bytes} == 0;
 201                                         if ($mitem && $can_kw) {
 202                                                 mitem_kw($srch, $smsg, $mitem,
 203                                                         $fl);
 204                                         } elsif ($mitem && $fl) {
 205                                                 # call ->xsmsg_vmd, later
 206                                                 $smsg->{lei_q_tt_flagged} = 1;
 207                                         }
 208                                         $each_smsg->($smsg, $mitem);
 209                                 }
 210                                 @{$ctx->{xids}} = ();
 211                         }
 212                 } else {
 213                         $first_ids = $ids;
 214                         my @items = $mset->items;
 215                         for my $n (@$ids) {
 216                                 my $mitem = $items[$i++];
 217                                 my $smsg = $over->get_art($n) or next;
 218                                 next if $smsg->{bytes} == 0;
 219                                 mitem_kw($srch, $smsg, $mitem, $fl) if $can_kw;
 220                                 $each_smsg->($smsg, $mitem);
 221                         }
 222                 }
 223         } while (_mset_more($mset, $mo));
 224         if ($lss && scalar(@$first_ids)) {
 225                 undef $stop_at;
 226                 my $max = $first_ids->[0];
 227                 $lss->cfg_set($maxk, $max);
 228                 undef $lss;
 229         }
 230         undef $each_smsg; # may commit
 231         $lei->{ovv}->ovv_atexit_child($lei);
 232 }
 233
 234 sub query_combined_mset { # non-parallel for non-"--threads" users
 235         my ($self) = @_;
 236         local $0 = "$0 query_combined_mset";
 237         my $lei = $self->{lei};
 238         my $mo = { %{$lei->{mset_opt}} };
 239         my $mset;
 240         for my $loc (locals($self)) {
 241                 attach_external($self, $loc);
 242         }
 243         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 244         do {
 245                 $mset = $self->mset($mo->{qstr}, $mo);
 246                 mset_progress($lei, 'xsearch', $mset->size,
 247                                 $mset->get_matches_estimated);
 248                 wait_startq($lei); # wait for keyword updates
 249                 for my $mitem ($mset->items) {
 250                         my $smsg = smsg_for($self, $mitem) or next;
 251                         $each_smsg->($smsg, $mitem);
 252                 }
 253         } while (_mset_more($mset, $mo));
 254         undef $each_smsg; # may commit
 255         $lei->{ovv}->ovv_atexit_child($lei);
 256 }
 257
 258 sub _smsg_fill ($$) {
 259         my ($smsg, $eml) = @_;
 260         $smsg->populate($eml);
 261         $smsg->parse_references($eml, mids($eml));
 262         $smsg->{$_} //= '' for qw(from to cc ds subject references mid);
 263         delete @$smsg{qw(From Subject -ds -ts)};
 264 }
 265
 266 sub each_remote_eml { # callback for MboxReader->mboxrd
 267         my ($eml, $self, $lei, $each_smsg) = @_;
 268         my $xoids = $lei->{ale}->xoids_for($eml, 1);
 269         my $smsg = bless {}, 'PublicInbox::Smsg';
 270         if ($self->{import_sto} && !$xoids) {
 271                 my $res = $self->{import_sto}->ipc_do('add_eml', $eml);
 272                 if (ref($res) eq ref($smsg)) { # totally new message
 273                         $smsg = $res;
 274                         $smsg->{kw} = []; # short-circuit xsmsg_vmd
 275                 }
 276         }
 277         $smsg->{blob} //= $xoids ? (keys(%$xoids))[0]
 278                                 : git_sha(1, $eml)->hexdigest;
 279         _smsg_fill($smsg, $eml);
 280         wait_startq($lei);
 281         if ($lei->{-progress}) {
 282                 ++$lei->{-nr_remote_eml};
 283                 my $now = now();
 284                 my $next = $lei->{-next_progress} //= ($now + 1);
 285                 if ($now > $next) {
 286                         $lei->{-next_progress} = $now + 1;
 287                         my $nr = $lei->{-nr_remote_eml};
 288                         mset_progress($lei, $lei->{-current_url}, $nr, '?');
 289                 }
 290         }
 291         $each_smsg->($smsg, undef, $eml);
 292 }
 293
 294 sub query_remote_mboxrd {
 295         my ($self, $uris) = @_;
 296         local $0 = "$0 query_remote_mboxrd";
 297         local $SIG{TERM} = sub { exit(0) }; # for DESTROY (File::Temp, $reap)
 298         my $lei = $self->{lei};
 299         my $opt = $lei->{opt};
 300         my @qform = (q => $lei->{mset_opt}->{qstr}, x => 'm');
 301         push(@qform, t => 1) if $opt->{threads};
 302         my $verbose = $opt->{verbose};
 303         my ($reap_tail, $reap_curl);
 304         my $cerr = File::Temp->new(TEMPLATE => 'curl.err-XXXX', TMPDIR => 1);
 305         fcntl($cerr, F_SETFL, O_APPEND|O_RDWR) or warn "set O_APPEND: $!";
 306         my $rdr = { 2 => $cerr, pgid => 0 };
 307         my $sigint_reap = $lei->can('sigint_reap');
 308         if ($verbose) {
 309                 # spawn a process to force line-buffering, otherwise curl
 310                 # will write 1 character at-a-time and parallel outputs
 311                 # mmmaaayyy llloookkk llliiikkkeee ttthhhiiisss
 312                 my $o = { 1 => $lei->{2}, 2 => $lei->{2}, pgid => 0 };
 313                 my $pid = spawn(['tail', '-f', $cerr->filename], undef, $o);
 314                 $reap_tail = PublicInbox::OnDestroy->new($sigint_reap, $pid);
 315         }
 316         my $curl = PublicInbox::LeiCurl->new($lei, $self->{curl}) or return;
 317         push @$curl, '-s', '-d', '';
 318         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 319         $self->{import_sto} = $lei->{sto} if $lei->{opt}->{'import-remote'};
 320         for my $uri (@$uris) {
 321                 $lei->{-current_url} = $uri->as_string;
 322                 $lei->{-nr_remote_eml} = 0;
 323                 $uri->query_form(@qform);
 324                 my $cmd = $curl->for_uri($lei, $uri);
 325                 $lei->qerr("# $cmd");
 326                 my ($fh, $pid) = popen_rd($cmd, undef, $rdr);
 327                 $reap_curl = PublicInbox::OnDestroy->new($sigint_reap, $pid);
 328                 $fh = IO::Uncompress::Gunzip->new($fh, MultiStream => 1);
 329                 PublicInbox::MboxReader->mboxrd($fh, \&each_remote_eml, $self,
 330                                                 $lei, $each_smsg);
 331                 my $err = waitpid($pid, 0) == $pid ? undef
 332                                                 : "BUG: waitpid($cmd): $!";
 333                 @$reap_curl = (); # cancel OnDestroy
 334                 die $err if $err;
 335                 my $nr = $lei->{-nr_remote_eml};
 336                 if ($nr && $lei->{sto}) {
 337                         my $wait = $lei->{sto}->ipc_do('done');
 338                 }
 339                 if ($? == 0) {
 340                         mset_progress($lei, $lei->{-current_url}, $nr, $nr);
 341                         next;
 342                 }
 343                 $err = '';
 344                 if (-s $cerr) {
 345                         seek($cerr, 0, SEEK_SET) or
 346                                         $lei->err("seek($cmd stderr): $!");
 347                         $err = do { local $/; <$cerr> } //
 348                                         "read($cmd stderr): $!";
 349                         truncate($cerr, 0) or
 350                                         $lei->err("truncate($cmd stderr): $!");
 351                 }
 352                 next if (($? >> 8) == 22 && $err =~ /\b404\b/);
 353                 $uri->query_form(q => $lei->{mset_opt}->{qstr});
 354                 $lei->child_error($?, "E: <$uri> $err");
 355         }
 356         undef $each_smsg;
 357         $lei->{ovv}->ovv_atexit_child($lei);
 358 }
 359
 360 sub git { $_[0]->{git} // die 'BUG: git uninitialized' }
 361
 362 sub xsearch_done_wait { # dwaitpid callback
 363         my ($arg, $pid) = @_;
 364         my ($wq, $lei) = @$arg;
 365         $lei->child_error($?, 'non-fatal error from '.ref($wq)) if $?;
 366 }
 367
 368 sub query_done { # EOF callback for main daemon
 369         my ($lei) = @_;
 370         my $l2m = delete $lei->{l2m};
 371         $l2m->wq_wait_old(\&xsearch_done_wait, $lei) if $l2m;
 372         if (my $lxs = delete $lei->{lxs}) {
 373                 $lxs->wq_wait_old(\&xsearch_done_wait, $lei);
 374         }
 375         if ($lei->{opt}->{'mail-sync'} && !$lei->{sto}) {
 376                 warn "BUG: {sto} missing with --mail-sync";
 377         }
 378         my $wait = $lei->{sto} ? $lei->{sto}->ipc_do('done') : undef;
 379         $wait = $lei->{v2w} ? $lei->{v2w}->ipc_do('done') : undef;
 380         $lei->{ovv}->ovv_end($lei);
 381         my $start_mua;
 382         if ($l2m) { # close() calls LeiToMail reap_compress
 383                 if (my $out = delete $lei->{old_1}) {
 384                         if (my $mbout = $lei->{1}) {
 385                                 close($mbout) or return $lei->fail(<<"");
 386 Error closing $lei->{ovv}->{dst}: $!
 387
 388                         }
 389                         $lei->{1} = $out;
 390                 }
 391                 if ($l2m->lock_free) {
 392                         $l2m->poke_dst;
 393                         $lei->poke_mua;
 394                 } else { # mbox users
 395                         delete $l2m->{mbl}; # drop dotlock
 396                         $start_mua = 1;
 397                 }
 398         }
 399         if ($lei->{-progress}) {
 400                 my $tot = $lei->{-mset_total} // 0;
 401                 my $nr = $lei->{-nr_write} // 0;
 402                 $lei->qerr($l2m ?
 403                         "# $nr written to $lei->{ovv}->{dst} ($tot matches)" :
 404                         "# $tot matches");
 405         }
 406         $lei->start_mua if $start_mua;
 407         $lei->dclose;
 408 }
 409
 410 sub do_post_augment {
 411         my ($lei) = @_;
 412         my $l2m = $lei->{l2m} or return; # client disconnected
 413         $lei->fchdir or return;
 414         my $err;
 415         eval { $l2m->post_augment($lei) };
 416         $err = $@;
 417         if ($err) {
 418                 if (my $lxs = delete $lei->{lxs}) {
 419                         $lxs->wq_kill;
 420                         $lxs->wq_close(0, undef, $lei);
 421                 }
 422                 $lei->fail("$err");
 423         }
 424         if (!$err && delete $lei->{early_mua}) { # non-augment case
 425                 $lei->start_mua;
 426         }
 427         close(delete $lei->{au_done}); # triggers wait_startq in lei_xsearch
 428 }
 429
 430 sub incr_post_augment { # called whenever an l2m shard finishes augment
 431         my ($lei) = @_;
 432         my $l2m = $lei->{l2m} or return; # client disconnected
 433         return if ++$lei->{nr_post_augment} != $l2m->{-wq_nr_workers};
 434         do_post_augment($lei);
 435 }
 436
 437 my $MAX_PER_HOST = 4;
 438
 439 sub concurrency {
 440         my ($self, $opt) = @_;
 441         my $nl = $opt->{threads} ? locals($self) : 1;
 442         my $nr = remotes($self);
 443         $nr = $MAX_PER_HOST if $nr > $MAX_PER_HOST;
 444         $nl + $nr;
 445 }
 446
 447 sub start_query ($;$) { # always runs in main (lei-daemon) process
 448         my ($self, $l2m) = @_;
 449         if ($self->{opt_threads} || ($l2m && !$self->{opt_sort})) {
 450                 for my $ibxish (locals($self)) {
 451                         $self->wq_io_do('query_one_mset', [], $ibxish);
 452                 }
 453         } elsif (locals($self)) {
 454                 $self->wq_io_do('query_combined_mset', []);
 455         }
 456         my $i = 0;
 457         my $q = [];
 458         for my $uri (remotes($self)) {
 459                 push @{$q->[$i++ % $MAX_PER_HOST]}, $uri;
 460         }
 461         for my $uris (@$q) {
 462                 $self->wq_io_do('query_remote_mboxrd', [], $uris);
 463         }
 464         if ($self->{-do_lcat}) {
 465                 $self->wq_io_do('lcat_dump', []);
 466         }
 467         $self->wq_close(1); # lei_xsearch workers stop when done
 468 }
 469
 470 sub incr_start_query { # called whenever an l2m shard starts do_post_auth
 471         my ($self, $l2m) = @_;
 472         return if ++$self->{nr_start_query} != $l2m->{-wq_nr_workers};
 473         start_query($self, $l2m);
 474 }
 475
 476 sub ipc_atfork_child {
 477         my ($self) = @_;
 478         $self->{lei}->_lei_atfork_child;
 479         $self->SUPER::ipc_atfork_child;
 480 }
 481
 482 sub do_query {
 483         my ($self, $lei) = @_;
 484         my $l2m = $lei->{l2m};
 485         my $ops = {
 486                 '|' => [ $lei->can('sigpipe_handler'), $lei ],
 487                 '!' => [ $lei->can('fail_handler'), $lei ],
 488                 '.' => [ \&do_post_augment, $lei ],
 489                 '+' => [ \&incr_post_augment, $lei ],
 490                 '' => [ \&query_done, $lei ],
 491                 'mset_progress' => [ \&mset_progress, $lei ],
 492                 'l2m_progress' => [ \&l2m_progress, $lei ],
 493                 'x_it' => [ $lei->can('x_it'), $lei ],
 494                 'child_error' => [ $lei->can('child_error'), $lei ],
 495                 'incr_start_query' => [ \&incr_start_query, $self, $l2m ],
 496         };
 497         $lei->{auth}->op_merge($ops, $l2m) if $l2m && $lei->{auth};
 498         my $end = $lei->pkt_op_pair;
 499         $lei->{1}->autoflush(1);
 500         $lei->start_pager if delete $lei->{need_pager};
 501         $lei->{ovv}->ovv_begin($lei);
 502         die 'BUG: xdb|over open' if $lei->{lse}->{xdb} || $lei->{lse}->{over};
 503         if ($l2m) {
 504                 $l2m->pre_augment($lei);
 505                 if ($lei->{opt}->{augment} && delete $lei->{early_mua}) {
 506                         $lei->start_mua;
 507                 }
 508                 my $F_SETPIPE_SZ = $^O eq 'linux' ? 1031 : undef;
 509                 if ($l2m->{-wq_nr_workers} > 1 &&
 510                                 $l2m->{base_type} =~ /\A(?:maildir|mbox)\z/) {
 511                         # setup two barriers to coordinate ->has_entries
 512                         # between l2m workers
 513                         pipe(my ($a_r, $a_w)) or die "pipe: $!";
 514                         fcntl($a_r, $F_SETPIPE_SZ, 4096) if $F_SETPIPE_SZ;
 515                         pipe(my ($b_r, $b_w)) or die "pipe: $!";
 516                         fcntl($b_r, $F_SETPIPE_SZ, 4096) if $F_SETPIPE_SZ;
 517                         $l2m->{au_peers} = [ $a_r, $a_w, $b_r, $b_w ];
 518                 }
 519                 $l2m->wq_workers_start('lei2mail', undef,
 520                                         $lei->oldset, { lei => $lei });
 521                 pipe($lei->{startq}, $lei->{au_done}) or die "pipe: $!";
 522                 fcntl($lei->{startq}, $F_SETPIPE_SZ, 4096) if $F_SETPIPE_SZ;
 523                 delete $l2m->{au_peers};
 524         }
 525         $self->wq_workers_start('lei_xsearch', undef,
 526                                 $lei->oldset, { lei => $lei });
 527         my $op_c = delete $lei->{pkt_op_c};
 528         delete $lei->{pkt_op_p};
 529         @$end = ();
 530         $self->{opt_threads} = $lei->{opt}->{threads};
 531         $self->{opt_sort} = $lei->{opt}->{'sort'};
 532         $self->{-do_lcat} = $lei->{lcat_blob} // $lei->{lcat_fid};
 533         if ($l2m) {
 534                 $l2m->net_merge_all_done unless $lei->{auth};
 535         } else {
 536                 start_query($self);
 537         }
 538         $lei->event_step_init; # wait for shutdowns
 539         $lei->wait_wq_events($op_c, $ops);
 540 }
 541
 542 sub add_uri {
 543         my ($self, $uri) = @_;
 544         if (my $curl = $self->{curl} //= which('curl') // 0) {
 545                 require PublicInbox::MboxReader;
 546                 require IO::Uncompress::Gunzip;
 547                 require PublicInbox::LeiCurl;
 548                 push @{$self->{remotes}}, $uri;
 549         } else {
 550                 warn "curl missing, ignoring $uri\n";
 551         }
 552 }
 553
 554 sub prepare_external {
 555         my ($self, $loc, $boost) = @_; # n.b. already ordered by boost
 556         if (ref $loc) { # already a URI, or PublicInbox::Inbox-like object
 557                 return add_uri($self, $loc) if $loc->can('scheme');
 558         } elsif ($loc =~ m!\Ahttps?://!) {
 559                 require URI;
 560                 return add_uri($self, URI->new($loc));
 561         } elsif (-f "$loc/ei.lock") {
 562                 require PublicInbox::ExtSearch;
 563                 die "`\\n' not allowed in `$loc'\n" if index($loc, "\n") >= 0;
 564                 $loc = PublicInbox::ExtSearch->new($loc);
 565         } elsif (-f "$loc/inbox.lock" || -d "$loc/public-inbox") {
 566                 die "`\\n' not allowed in `$loc'\n" if index($loc, "\n") >= 0;
 567                 require PublicInbox::Inbox; # v2, v1
 568                 $loc = bless { inboxdir => $loc }, 'PublicInbox::Inbox';
 569         } else {
 570                 warn "W: ignoring $loc, unable to determine type\n";
 571                 return;
 572         }
 573         push @{$self->{locals}}, $loc;
 574 }
 575
 576 sub _lcat_i { # LeiMailSync->each_src iterator callback
 577         my ($oidbin, $id, $each_smsg) = @_;
 578         $each_smsg->({blob => unpack('H*', $oidbin), pct => 100});
 579 }
 580
 581 sub _lcat2smsg { # git->cat_async callback
 582         my ($bref, $oid, $type, $size, $smsg) = @_;
 583         if ($bref) {
 584                 my $eml = PublicInbox::Eml->new($bref);
 585                 my $json_dump = delete $smsg->{-json_dump};
 586                 bless $smsg, 'PublicInbox::Smsg';
 587                 _smsg_fill($smsg, $eml);
 588                 $json_dump->($smsg, undef, $eml);
 589         }
 590 }
 591
 592 sub lcat_dump {
 593         my ($self) = @_;
 594         my $lei = $self->{lei};
 595         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 596         my $git = $lei->{ale}->git;
 597         if (!$lei->{l2m}) {
 598                 my $json_dump = $each_smsg;
 599                 $each_smsg = sub {
 600                         my ($smsg) = @_;
 601                         use Data::Dumper;
 602                         $smsg->{-json_dump} = $json_dump;
 603                         $git->cat_async($smsg->{blob}, \&_lcat2smsg, $smsg);
 604                 };
 605         }
 606         for my $oid (@{$lei->{lcat_blob} // []}) {
 607                 $each_smsg->({ blob => $oid, pct => 100 });
 608         }
 609         if (my $fids = delete $lei->{lcat_fid}) {
 610                 my $lms = $lei->{lse}->lms;
 611                 for my $fid (@$fids) {
 612                         $lms->each_src({fid => $fid}, \&_lcat_i, $each_smsg);
 613                 }
 614         }
 615         $git->async_wait_all;
 616         undef $each_smsg; # may commit
 617         $lei->{ovv}->ovv_atexit_child($lei);
 618 }
 619
 620 1;