lib/PublicInbox/LeiXSearch.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Combine any combination of PublicInbox::Search,
   5 # PublicInbox::ExtSearch, and PublicInbox::LeiSearch objects
   6 # into one Xapian DB
   7 package PublicInbox::LeiXSearch;
   8 use strict;
   9 use v5.10.1;
  10 use parent qw(PublicInbox::LeiSearch PublicInbox::IPC);
  11 use PublicInbox::DS qw(now);
  12 use PublicInbox::PktOp qw(pkt_do);
  13 use File::Temp 0.19 (); # 0.19 for ->newdir
  14 use File::Spec ();
  15 use PublicInbox::Search qw(xap_terms);
  16 use PublicInbox::Spawn qw(popen_rd spawn which);
  17 use PublicInbox::MID qw(mids);
  18 use PublicInbox::Smsg;
  19 use PublicInbox::Eml;
  20 use Fcntl qw(SEEK_SET F_SETFL O_APPEND O_RDWR);
  21 use PublicInbox::ContentHash qw(git_sha);
  22
  23 sub new {
  24         my ($class) = @_;
  25         PublicInbox::Search::load_xapian();
  26         bless {
  27                 qp_flags => $PublicInbox::Search::QP_FLAGS |
  28                                 PublicInbox::Search::FLAG_PURE_NOT(),
  29         }, $class
  30 }
  31
  32 sub attach_external {
  33         my ($self, $ibxish) = @_; # ibxish = ExtSearch or Inbox
  34         my $desc = $ibxish->{inboxdir} // $ibxish->{topdir};
  35         my $srch = $ibxish->search or
  36                 return warn("$desc not indexed for Xapian\n");
  37         my @shards = $srch->xdb_shards_flat or
  38                 return warn("$desc has no Xapian shards\n");
  39
  40         if (delete $self->{xdb}) { # XXX: do we need this?
  41                 # clobber existing {xdb} if amending
  42                 my $expect = delete $self->{nshard};
  43                 my $shards = delete $self->{shards_flat};
  44                 scalar(@$shards) == $expect or die
  45                         "BUG: {nshard}$expect != shards=".scalar(@$shards);
  46
  47                 my $prev = {};
  48                 for my $old_ibxish (@{$self->{shard2ibx}}) {
  49                         next if $prev == $old_ibxish;
  50                         $prev = $old_ibxish;
  51                         my @shards = $old_ibxish->search->xdb_shards_flat;
  52                         push @{$self->{shards_flat}}, @shards;
  53                 }
  54                 my $nr = scalar(@{$self->{shards_flat}});
  55                 $nr == $expect or die
  56                         "BUG: reloaded $nr shards, expected $expect"
  57         }
  58         push @{$self->{shards_flat}}, @shards;
  59         push(@{$self->{shard2ibx}}, $ibxish) for (@shards);
  60 }
  61
  62 # returns a list of local inboxes (or count in scalar context)
  63 sub locals { @{$_[0]->{locals} // []} }
  64
  65 sub remotes { @{$_[0]->{remotes} // []} }
  66
  67 # called by PublicInbox::Search::xdb (usually via ->mset)
  68 sub xdb_shards_flat { @{$_[0]->{shards_flat} // []} }
  69
  70 sub mitem_kw ($$;$) {
  71         my ($smsg, $mitem, $flagged) = @_;
  72         my $kw = xap_terms('K', my $doc = $mitem->get_document);
  73         $kw->{flagged} = 1 if $flagged;
  74         # we keep the empty {kw} array here to prevent expensive work in
  75         # ->xsmsg_vmd, _unbless_smsg will clobber it iff it's empty
  76         $smsg->{kw} = [ sort keys %$kw ];
  77         my $L = xap_terms('L', $doc);
  78         $smsg->{L} = [ sort keys %$L ] if scalar(keys %$L);
  79 }
  80
  81 # like over->get_art
  82 sub smsg_for {
  83         my ($self, $mitem) = @_;
  84         # cf. https://trac.xapian.org/wiki/FAQ/MultiDatabaseDocumentID
  85         my $nshard = $self->{nshard};
  86         my $docid = $mitem->get_docid;
  87         my $shard = ($docid - 1) % $nshard;
  88         my $num = int(($docid - 1) / $nshard) + 1;
  89         my $ibx = $self->{shard2ibx}->[$shard];
  90         my $smsg = $ibx->over->get_art($num);
  91         return if $smsg->{bytes} == 0; # external message
  92         if ($ibx->can('msg_keywords')) {
  93                 mitem_kw($smsg, $mitem);
  94         }
  95         $smsg;
  96 }
  97
  98 sub recent {
  99         my ($self, $qstr, $opt) = @_;
 100         $opt //= {};
 101         $opt->{relevance} //= -2;
 102         $self->mset($qstr //= 'z:1..', $opt);
 103 }
 104
 105 sub over {}
 106
 107 sub _mset_more ($$) {
 108         my ($mset, $mo) = @_;
 109         my $size = $mset->size;
 110         $size >= $mo->{limit} && (($mo->{offset} += $size) < $mo->{limit});
 111 }
 112
 113 # $startq will EOF when do_augment is done augmenting and allow
 114 # query_combined_mset and query_thread_mset to proceed.
 115 sub wait_startq ($) {
 116         my ($lei) = @_;
 117         my $startq = delete $lei->{startq} or return;
 118         while (1) {
 119                 my $n = sysread($startq, my $do_augment_done, 1);
 120                 if (defined $n) {
 121                         return if $n == 0; # no MUA
 122                         if ($do_augment_done eq 'q') {
 123                                 $lei->{opt}->{quiet} = 1;
 124                                 delete $lei->{opt}->{verbose};
 125                                 delete $lei->{-progress};
 126                         } else {
 127                                 $lei->fail("$$ WTF `$do_augment_done'");
 128                         }
 129                         return;
 130                 }
 131                 return $lei->fail("$$ wait_startq: $!") unless $!{EINTR};
 132         }
 133 }
 134
 135 sub mset_progress {
 136         my $lei = shift;
 137         return if $lei->{early_mua} || !$lei->{-progress};
 138         if ($lei->{pkt_op_p}) {
 139                 pkt_do($lei->{pkt_op_p}, 'mset_progress', @_);
 140         } else { # single lei-daemon consumer
 141                 my ($desc, $mset_size, $mset_total_est) = @_;
 142                 $lei->{-mset_total} += $mset_size;
 143                 $lei->qerr("# $desc $mset_size/$mset_total_est");
 144         }
 145 }
 146
 147 sub query_one_mset { # for --threads and l2m w/o sort
 148         my ($self, $ibxish) = @_;
 149         local $0 = "$0 query_one_mset";
 150         my $lei = $self->{lei};
 151         my ($srch, $over) = ($ibxish->search, $ibxish->over);
 152         my $dir = $ibxish->{inboxdir} // $ibxish->{topdir};
 153         return warn("$dir not indexed by Xapian\n") unless ($srch && $over);
 154         my $mo = { %{$lei->{mset_opt}} }; # copy
 155         my $mset;
 156         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 157         my $can_kw = !!$ibxish->can('msg_keywords');
 158         my $threads = $lei->{opt}->{threads} // 0;
 159         my $fl = $threads > 1 ? 1 : undef;
 160         my $lss = $lei->{dedupe};
 161         $lss = undef unless $lss && $lss->can('cfg_set'); # saved search
 162         my $maxk = "external.$dir.maxuid";
 163         my $stop_at = $lss ? $lss->{-cfg}->{$maxk} : undef;
 164         if (defined $stop_at) {
 165                 die "$maxk=$stop_at has multiple values" if ref $stop_at;
 166                 my @e;
 167                 local $SIG{__WARN__} = sub { push @e, @_ };
 168                 $stop_at += 0;
 169                 return warn("$maxk=$stop_at: @e") if @e;
 170         }
 171         my $first_ids;
 172         do {
 173                 $mset = $srch->mset($mo->{qstr}, $mo);
 174                 mset_progress($lei, $dir, $mset->size,
 175                                 $mset->get_matches_estimated);
 176                 wait_startq($lei); # wait for keyword updates
 177                 my $ids = $srch->mset_to_artnums($mset, $mo);
 178                 @$ids = grep { $_ > $stop_at } @$ids if defined($stop_at);
 179                 my $i = 0;
 180                 if ($threads) {
 181                         # copy $ids if $lss since over->expand_thread
 182                         # shifts @{$ctx->{ids}}
 183                         $first_ids = [ @$ids ] if $lss;
 184                         my $ctx = { ids => $ids };
 185                         my %n2item = map { ($ids->[$i++], $_) } $mset->items;
 186                         while ($over->expand_thread($ctx)) {
 187                                 for my $n (@{$ctx->{xids}}) {
 188                                         my $smsg = $over->get_art($n) or next;
 189                                         my $mitem = delete $n2item{$n};
 190                                         next if $smsg->{bytes} == 0;
 191                                         if ($mitem && $can_kw) {
 192                                                 mitem_kw($smsg, $mitem, $fl);
 193                                         } elsif ($mitem && $fl) {
 194                                                 # call ->xsmsg_vmd, later
 195                                                 $smsg->{lei_q_tt_flagged} = 1;
 196                                         }
 197                                         $each_smsg->($smsg, $mitem);
 198                                 }
 199                                 @{$ctx->{xids}} = ();
 200                         }
 201                 } else {
 202                         $first_ids = $ids;
 203                         my @items = $mset->items;
 204                         for my $n (@$ids) {
 205                                 my $mitem = $items[$i++];
 206                                 my $smsg = $over->get_art($n) or next;
 207                                 next if $smsg->{bytes} == 0;
 208                                 mitem_kw($smsg, $mitem, $fl) if $can_kw;
 209                                 $each_smsg->($smsg, $mitem);
 210                         }
 211                 }
 212         } while (_mset_more($mset, $mo));
 213         if ($lss && scalar(@$first_ids)) {
 214                 undef $stop_at;
 215                 my $max = $first_ids->[0];
 216                 $lss->cfg_set($maxk, $max);
 217                 undef $lss;
 218         }
 219         undef $each_smsg; # may commit
 220         $lei->{ovv}->ovv_atexit_child($lei);
 221 }
 222
 223 sub query_combined_mset { # non-parallel for non-"--threads" users
 224         my ($self) = @_;
 225         local $0 = "$0 query_combined_mset";
 226         my $lei = $self->{lei};
 227         my $mo = { %{$lei->{mset_opt}} };
 228         my $mset;
 229         for my $loc (locals($self)) {
 230                 attach_external($self, $loc);
 231         }
 232         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 233         do {
 234                 $mset = $self->mset($mo->{qstr}, $mo);
 235                 mset_progress($lei, 'xsearch', $mset->size,
 236                                 $mset->size, $mset->get_matches_estimated);
 237                 wait_startq($lei); # wait for keyword updates
 238                 for my $mitem ($mset->items) {
 239                         my $smsg = smsg_for($self, $mitem) or next;
 240                         $each_smsg->($smsg, $mitem);
 241                 }
 242         } while (_mset_more($mset, $mo));
 243         undef $each_smsg; # may commit
 244         $lei->{ovv}->ovv_atexit_child($lei);
 245 }
 246
 247 sub each_remote_eml { # callback for MboxReader->mboxrd
 248         my ($eml, $self, $lei, $each_smsg) = @_;
 249         my $xoids = $lei->{ale}->xoids_for($eml, 1);
 250         if ($self->{import_sto} && !$xoids) {
 251                 $self->{import_sto}->ipc_do('add_eml', $eml);
 252         }
 253         my $smsg = bless {}, 'PublicInbox::Smsg';
 254         $smsg->{blob} = $xoids ? (keys(%$xoids))[0]
 255                                 : git_sha(1, $eml)->hexdigest;
 256         $smsg->populate($eml);
 257         $smsg->parse_references($eml, mids($eml));
 258         $smsg->{$_} //= '' for qw(from to cc ds subject references mid);
 259         delete @$smsg{qw(From Subject -ds -ts)};
 260         wait_startq($lei);
 261         if ($lei->{-progress}) {
 262                 ++$lei->{-nr_remote_eml};
 263                 my $now = now();
 264                 my $next = $lei->{-next_progress} //= ($now + 1);
 265                 if ($now > $next) {
 266                         $lei->{-next_progress} = $now + 1;
 267                         my $nr = $lei->{-nr_remote_eml};
 268                         mset_progress($lei, $lei->{-current_url}, $nr, '?');
 269                 }
 270         }
 271         $each_smsg->($smsg, undef, $eml);
 272 }
 273
 274 sub query_remote_mboxrd {
 275         my ($self, $uris) = @_;
 276         local $0 = "$0 query_remote_mboxrd";
 277         local $SIG{TERM} = sub { exit(0) }; # for DESTROY (File::Temp, $reap)
 278         my $lei = $self->{lei};
 279         my $opt = $lei->{opt};
 280         my @qform = (q => $lei->{mset_opt}->{qstr}, x => 'm');
 281         push(@qform, t => 1) if $opt->{threads};
 282         my $verbose = $opt->{verbose};
 283         my ($reap_tail, $reap_curl);
 284         my $cerr = File::Temp->new(TEMPLATE => 'curl.err-XXXX', TMPDIR => 1);
 285         fcntl($cerr, F_SETFL, O_APPEND|O_RDWR) or warn "set O_APPEND: $!";
 286         my $rdr = { 2 => $cerr, pgid => 0 };
 287         my $sigint_reap = $lei->can('sigint_reap');
 288         if ($verbose) {
 289                 # spawn a process to force line-buffering, otherwise curl
 290                 # will write 1 character at-a-time and parallel outputs
 291                 # mmmaaayyy llloookkk llliiikkkeee ttthhhiiisss
 292                 my $o = { 1 => $lei->{2}, 2 => $lei->{2}, pgid => 0 };
 293                 my $pid = spawn(['tail', '-f', $cerr->filename], undef, $o);
 294                 $reap_tail = PublicInbox::OnDestroy->new($sigint_reap, $pid);
 295         }
 296         my $curl = PublicInbox::LeiCurl->new($lei, $self->{curl}) or return;
 297         push @$curl, '-s', '-d', '';
 298         my $each_smsg = $lei->{ovv}->ovv_each_smsg_cb($lei);
 299         $self->{import_sto} = $lei->{sto} if $lei->{opt}->{'import-remote'};
 300         for my $uri (@$uris) {
 301                 $lei->{-current_url} = $uri->as_string;
 302                 $lei->{-nr_remote_eml} = 0;
 303                 $uri->query_form(@qform);
 304                 my $cmd = $curl->for_uri($lei, $uri);
 305                 $lei->qerr("# $cmd");
 306                 my ($fh, $pid) = popen_rd($cmd, undef, $rdr);
 307                 $reap_curl = PublicInbox::OnDestroy->new($sigint_reap, $pid);
 308                 $fh = IO::Uncompress::Gunzip->new($fh, MultiStream => 1);
 309                 PublicInbox::MboxReader->mboxrd($fh, \&each_remote_eml, $self,
 310                                                 $lei, $each_smsg);
 311                 my $err = waitpid($pid, 0) == $pid ? undef
 312                                                 : "BUG: waitpid($cmd): $!";
 313                 @$reap_curl = (); # cancel OnDestroy
 314                 die $err if $err;
 315                 my $nr = $lei->{-nr_remote_eml};
 316                 if ($nr && $lei->{sto}) {
 317                         my $wait = $lei->{sto}->ipc_do('done');
 318                 }
 319                 if ($? == 0) {
 320                         mset_progress($lei, $lei->{-current_url}, $nr, $nr);
 321                         next;
 322                 }
 323                 $err = '';
 324                 if (-s $cerr) {
 325                         seek($cerr, 0, SEEK_SET) or
 326                                         $lei->err("seek($cmd stderr): $!");
 327                         $err = do { local $/; <$cerr> } //
 328                                         "read($cmd stderr): $!";
 329                         truncate($cerr, 0) or
 330                                         $lei->err("truncate($cmd stderr): $!");
 331                 }
 332                 next if (($? >> 8) == 22 && $err =~ /\b404\b/);
 333                 $uri->query_form(q => $lei->{mset_opt}->{qstr});
 334                 $lei->child_error($?, "E: <$uri> $err");
 335         }
 336         undef $each_smsg;
 337         $lei->{ovv}->ovv_atexit_child($lei);
 338 }
 339
 340 sub git { $_[0]->{git} // die 'BUG: git uninitialized' }
 341
 342 sub xsearch_done_wait { # dwaitpid callback
 343         my ($arg, $pid) = @_;
 344         my ($wq, $lei) = @$arg;
 345         $lei->child_error($?, 'non-fatal error from '.ref($wq)) if $?;
 346 }
 347
 348 sub query_done { # EOF callback for main daemon
 349         my ($lei) = @_;
 350         my $l2m = delete $lei->{l2m};
 351         $l2m->wq_wait_old(\&xsearch_done_wait, $lei) if $l2m;
 352         if (my $lxs = delete $lei->{lxs}) {
 353                 $lxs->wq_wait_old(\&xsearch_done_wait, $lei);
 354         }
 355         my $wait = $lei->{sto} ? $lei->{sto}->ipc_do('done') : undef;
 356         $lei->{ovv}->ovv_end($lei);
 357         if ($l2m) { # close() calls LeiToMail reap_compress
 358                 if (my $out = delete $lei->{old_1}) {
 359                         if (my $mbout = $lei->{1}) {
 360                                 close($mbout) or return $lei->fail(<<"");
 361 Error closing $lei->{ovv}->{dst}: $!
 362
 363                         }
 364                         $lei->{1} = $out;
 365                 }
 366                 if ($l2m->lock_free) {
 367                         $l2m->poke_dst;
 368                         $lei->poke_mua;
 369                 } else { # mbox users
 370                         delete $l2m->{mbl}; # drop dotlock
 371                         $lei->start_mua;
 372                 }
 373         }
 374         $lei->{-progress} and
 375                 $lei->err('# ', $lei->{-mset_total} // 0, " matches");
 376         $lei->dclose;
 377 }
 378
 379 sub do_post_augment {
 380         my ($lei) = @_;
 381         my $l2m = $lei->{l2m} or return; # client disconnected
 382         my $err;
 383         eval { $l2m->post_augment($lei) };
 384         $err = $@;
 385         if ($err) {
 386                 if (my $lxs = delete $lei->{lxs}) {
 387                         $lxs->wq_kill;
 388                         $lxs->wq_close(0, undef, $lei);
 389                 }
 390                 $lei->fail("$err");
 391         }
 392         if (!$err && delete $lei->{early_mua}) { # non-augment case
 393                 $lei->start_mua;
 394         }
 395         close(delete $lei->{au_done}); # triggers wait_startq in lei_xsearch
 396 }
 397
 398 sub incr_post_augment { # called whenever an l2m shard finishes augment
 399         my ($lei) = @_;
 400         my $l2m = $lei->{l2m} or return; # client disconnected
 401         return if ++$lei->{nr_post_augment} != $l2m->{-wq_nr_workers};
 402         do_post_augment($lei);
 403 }
 404
 405 my $MAX_PER_HOST = 4;
 406
 407 sub concurrency {
 408         my ($self, $opt) = @_;
 409         my $nl = $opt->{threads} ? locals($self) : 1;
 410         my $nr = remotes($self);
 411         $nr = $MAX_PER_HOST if $nr > $MAX_PER_HOST;
 412         $nl + $nr;
 413 }
 414
 415 sub start_query ($;$) { # always runs in main (lei-daemon) process
 416         my ($self, $l2m) = @_;
 417         if ($self->{opt_threads} || ($l2m && !$self->{opt_sort})) {
 418                 for my $ibxish (locals($self)) {
 419                         $self->wq_io_do('query_one_mset', [], $ibxish);
 420                 }
 421         } elsif (locals($self)) {
 422                 $self->wq_io_do('query_combined_mset', []);
 423         }
 424         my $i = 0;
 425         my $q = [];
 426         for my $uri (remotes($self)) {
 427                 push @{$q->[$i++ % $MAX_PER_HOST]}, $uri;
 428         }
 429         for my $uris (@$q) {
 430                 $self->wq_io_do('query_remote_mboxrd', [], $uris);
 431         }
 432         $self->wq_close(1); # lei_xsearch workers stop when done
 433 }
 434
 435 sub incr_start_query { # called whenever an l2m shard starts do_post_auth
 436         my ($self, $l2m) = @_;
 437         return if ++$self->{nr_start_query} != $l2m->{-wq_nr_workers};
 438         start_query($self, $l2m);
 439 }
 440
 441 sub ipc_atfork_child {
 442         my ($self) = @_;
 443         $self->{lei}->_lei_atfork_child;
 444         $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 445         $self->SUPER::ipc_atfork_child;
 446 }
 447
 448 sub do_query {
 449         my ($self, $lei) = @_;
 450         my $l2m = $lei->{l2m};
 451         my $ops = {
 452                 '|' => [ $lei->can('sigpipe_handler'), $lei ],
 453                 '!' => [ $lei->can('fail_handler'), $lei ],
 454                 '.' => [ \&do_post_augment, $lei ],
 455                 '+' => [ \&incr_post_augment, $lei ],
 456                 '' => [ \&query_done, $lei ],
 457                 'mset_progress' => [ \&mset_progress, $lei ],
 458                 'x_it' => [ $lei->can('x_it'), $lei ],
 459                 'child_error' => [ $lei->can('child_error'), $lei ],
 460                 'incr_start_query' => [ \&incr_start_query, $self, $l2m ],
 461         };
 462         $lei->{auth}->op_merge($ops, $l2m) if $l2m && $lei->{auth};
 463         my $end = $lei->pkt_op_pair;
 464         $lei->{1}->autoflush(1);
 465         $lei->start_pager if delete $lei->{need_pager};
 466         $lei->{ovv}->ovv_begin($lei);
 467         die 'BUG: xdb|over open' if $lei->{lse}->{xdb} || $lei->{lse}->{over};
 468         if ($l2m) {
 469                 $l2m->pre_augment($lei);
 470                 if ($lei->{opt}->{augment} && delete $lei->{early_mua}) {
 471                         $lei->start_mua;
 472                 }
 473                 $l2m->wq_workers_start('lei2mail', undef,
 474                                         $lei->oldset, { lei => $lei });
 475                 pipe($lei->{startq}, $lei->{au_done}) or die "pipe: $!";
 476                 # 1031: F_SETPIPE_SZ
 477                 fcntl($lei->{startq}, 1031, 4096) if $^O eq 'linux';
 478         }
 479         $self->wq_workers_start('lei_xsearch', undef,
 480                                 $lei->oldset, { lei => $lei });
 481         my $op_c = delete $lei->{pkt_op_c};
 482         delete $lei->{pkt_op_p};
 483         @$end = ();
 484         $self->{opt_threads} = $lei->{opt}->{threads};
 485         $self->{opt_sort} = $lei->{opt}->{'sort'};
 486         if ($l2m) {
 487                 $l2m->net_merge_complete unless $lei->{auth};
 488         } else {
 489                 start_query($self);
 490         }
 491         $lei->event_step_init; # wait for shutdowns
 492         $op_c->op_wait_event($ops);
 493 }
 494
 495 sub add_uri {
 496         my ($self, $uri) = @_;
 497         if (my $curl = $self->{curl} //= which('curl') // 0) {
 498                 require PublicInbox::MboxReader;
 499                 require IO::Uncompress::Gunzip;
 500                 require PublicInbox::LeiCurl;
 501                 push @{$self->{remotes}}, $uri;
 502         } else {
 503                 warn "curl missing, ignoring $uri\n";
 504         }
 505 }
 506
 507 sub prepare_external {
 508         my ($self, $loc, $boost) = @_; # n.b. already ordered by boost
 509         if (ref $loc) { # already a URI, or PublicInbox::Inbox-like object
 510                 return add_uri($self, $loc) if $loc->can('scheme');
 511         } elsif ($loc =~ m!\Ahttps?://!) {
 512                 require URI;
 513                 return add_uri($self, URI->new($loc));
 514         } elsif (-f "$loc/ei.lock") {
 515                 require PublicInbox::ExtSearch;
 516                 die "`\\n' not allowed in `$loc'\n" if index($loc, "\n") >= 0;
 517                 $loc = PublicInbox::ExtSearch->new($loc);
 518         } elsif (-f "$loc/inbox.lock" || -d "$loc/public-inbox") {
 519                 die "`\\n' not allowed in `$loc'\n" if index($loc, "\n") >= 0;
 520                 require PublicInbox::Inbox; # v2, v1
 521                 $loc = bless { inboxdir => $loc }, 'PublicInbox::Inbox';
 522         } else {
 523                 warn "W: ignoring $loc, unable to determine type\n";
 524                 return;
 525         }
 526         push @{$self->{locals}}, $loc;
 527 }
 528
 529
 530 1;