lib/PublicInbox/Linkify.pm

   1 # Copyright (C) 2014-2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # two-step linkification.
   5 # intended usage is in the following order:
   6 #
   7 #   linkify_1
   8 #   <escape unsafe chars for HTML>
   9 #   linkify_2
  10 #
  11 # Maybe this could be done more efficiently...
  12 package PublicInbox::Linkify;
  13 use strict;
  14 use warnings;
  15 use Digest::SHA qw/sha1_hex/;
  16
  17 my $SALT = rand;
  18 my $LINK_RE = qr{\b((?:ftps?|https?|nntps?|gopher)://
  19                  [\@:\w\.-]+/
  20                  (?:[a-z0-9\-\._~!\$\&\';\(\)\*\+,;=:@/%]*)
  21                  (?:\?[a-z0-9\-\._~!\$\&\';\(\)\*\+,;=:@/%]+)?
  22                  (?:\#[a-z0-9\-\._~!\$\&\';\(\)\*\+,;=:@/%\?]+)?
  23                  )}xi;
  24
  25 sub new { bless {}, shift }
  26
  27 sub linkify_1 {
  28         my ($self, $s) = @_;
  29         $s =~ s!$LINK_RE!
  30                 my $url = $1;
  31                 my $end = '';
  32
  33                 # it's fairly common to end URLs in messages with
  34                 # '.', ',' or ';' to denote the end of a statement;
  35                 # assume the intent was to end the statement/sentence
  36                 # in English
  37                 if ($url =~ s/([\.,;])\z//) {
  38                         $end = $1;
  39                 }
  40
  41                 # salt this, as this could be exploited to show
  42                 # links in the HTML which don't show up in the raw mail.
  43                 my $key = sha1_hex($url . $SALT);
  44
  45                 # only escape ampersands, others do not match LINK_RE
  46                 $url =~ s/&/&#38;/g;
  47                 $self->{$key} = $url;
  48                 'PI-LINK-'. $key . $end;
  49         !ge;
  50         $s;
  51 }
  52
  53 sub linkify_2 {
  54         my ($self, $s) = @_;
  55
  56         # Added "PI-LINK-" prefix to avoid false-positives on git commits
  57         $s =~ s!\bPI-LINK-([a-f0-9]{40})\b!
  58                 my $key = $1;
  59                 my $url = $self->{$key};
  60                 if (defined $url) {
  61                         "<a\nhref=\"$url\">$url</a>";
  62                 } else {
  63                         # false positive or somebody tried to mess with us
  64                         $key;
  65                 }
  66         !ge;
  67         $s;
  68 }
  69
  70 1;