lib/PublicInbox/Listener.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used by -nntpd for listen sockets
   5 package PublicInbox::Listener;
   6 use strict;
   7 use warnings;
   8 use base 'PublicInbox::DS';
   9 use Socket qw(SOL_SOCKET SO_KEEPALIVE IPPROTO_TCP TCP_NODELAY);
  10 use fields qw(post_accept);
  11 use IO::Handle;
  12 use PublicInbox::Syscall qw(EPOLLIN EPOLLEXCLUSIVE EPOLLET);
  13 use Errno qw(EAGAIN ECONNABORTED EPERM);
  14
  15 # Warn on transient errors, mostly resource limitations.
  16 # EINTR would indicate the failure to set NonBlocking in systemd or similar
  17 my %ERR_WARN = map {;
  18         eval("Errno::$_()") => $_
  19 } qw(EMFILE ENFILE ENOBUFS ENOMEM EINTR);
  20
  21 sub new ($$$) {
  22         my ($class, $s, $cb) = @_;
  23         setsockopt($s, SOL_SOCKET, SO_KEEPALIVE, 1);
  24         setsockopt($s, IPPROTO_TCP, TCP_NODELAY, 1); # ignore errors on non-TCP
  25         listen($s, 1024);
  26         my $self = fields::new($class);
  27         $self->SUPER::new($s, EPOLLIN|EPOLLET|EPOLLEXCLUSIVE);
  28         $self->{post_accept} = $cb;
  29         $self
  30 }
  31
  32 sub event_step {
  33         my ($self) = @_;
  34         my $sock = $self->{sock} or return;
  35
  36         # no loop here, we want to fairly distribute clients
  37         # between multiple processes sharing the same socket
  38         # XXX our event loop needs better granularity for
  39         # a single accept() here to be, umm..., acceptable
  40         # on high-traffic sites.
  41         if (my $addr = accept(my $c, $sock)) {
  42                 IO::Handle::blocking($c, 0); # no accept4 :<
  43                 $self->{post_accept}->($c, $addr, $sock);
  44                 $self->requeue;
  45         } elsif ($! == EAGAIN || $! == ECONNABORTED || $! == EPERM) {
  46                 # EAGAIN is common and likely
  47                 # ECONNABORTED is common with bad connections
  48                 # EPERM happens if firewall rules prevent a connection
  49                 # on Linux (and everything that emulates Linux).
  50                 # Firewall rules are sometimes intentional, so we don't
  51                 # warn on EPERM to avoid being too noisy...
  52                 return;
  53         } elsif (my $sym = $ERR_WARN{int($!)}) {
  54                 warn "W: accept(): $! ($sym)\n";
  55         } else {
  56                 warn "BUG?: accept(): $!\n";
  57         }
  58 }
  59
  60 1;