lib/PublicInbox/Lock.pm

   1 # Copyright (C) 2018-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Base class for per-inbox locking
   5 package PublicInbox::Lock;
   6 use strict;
   7 use v5.10.1;
   8 use Fcntl qw(:flock :DEFAULT);
   9 use Carp qw(croak);
  10 use PublicInbox::OnDestroy;
  11 use File::Temp ();
  12
  13 # we only acquire the flock if creating or reindexing;
  14 # PublicInbox::Import already has the lock on its own.
  15 sub lock_acquire {
  16         my ($self) = @_;
  17         my $lock_path = $self->{lock_path};
  18         croak 'already locked '.($lock_path // '(undef)') if $self->{lockfh};
  19         return unless defined($lock_path);
  20         sysopen(my $lockfh, $lock_path, O_WRONLY|O_CREAT) or
  21                 croak "failed to open $lock_path: $!\n";
  22         flock($lockfh, LOCK_EX) or croak "lock $lock_path failed: $!\n";
  23         $self->{lockfh} = $lockfh;
  24 }
  25
  26 sub lock_release {
  27         my ($self, $wake) = @_;
  28         defined(my $lock_path = $self->{lock_path}) or return;
  29         my $lockfh = delete $self->{lockfh} or croak "not locked: $lock_path";
  30
  31         syswrite($lockfh, '.') if $wake;
  32
  33         flock($lockfh, LOCK_UN) or croak "unlock $lock_path failed: $!\n";
  34         close $lockfh or croak "close $lock_path failed: $!\n";
  35 }
  36
  37 # caller must use return value
  38 sub lock_for_scope {
  39         my ($self, @single_pid) = @_;
  40         lock_acquire($self) or return; # lock_path not set
  41         PublicInbox::OnDestroy->new(@single_pid, \&lock_release, $self);
  42 }
  43
  44 sub lock_acquire_fast {
  45         $_[0]->{lockfh} or return lock_acquire($_[0]);
  46         flock($_[0]->{lockfh}, LOCK_EX) or croak "lock (fast) failed: $!";
  47 }
  48
  49 sub lock_release_fast {
  50         flock($_[0]->{lockfh} // return, LOCK_UN) or
  51                         croak "unlock (fast) $_[0]->{lock_path}: $!";
  52 }
  53
  54 # caller must use return value
  55 sub lock_for_scope_fast {
  56         my ($self, @single_pid) = @_;
  57         lock_acquire_fast($self) or return; # lock_path not set
  58         PublicInbox::OnDestroy->new(@single_pid, \&lock_release_fast, $self);
  59 }
  60
  61 sub new_tmp {
  62         my ($cls, $ident) = @_;
  63         my $tmp = File::Temp->new("$ident.lock-XXXXXX", TMPDIR => 1);
  64         bless { lock_path => $tmp->filename, tmp => $tmp }, $cls;
  65 }
  66
  67 1;