lib/PublicInbox/MID.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Various Message-ID-related functions.
   5 package PublicInbox::MID;
   6 use strict;
   7 use warnings;
   8 use base qw/Exporter/;
   9 our @EXPORT_OK = qw/mid_clean id_compress mid2path mid_mime mid_escape MID_ESC
  10         mids references/;
  11 use URI::Escape qw(uri_escape_utf8);
  12 use Digest::SHA qw/sha1_hex/;
  13 use constant MID_MAX => 40; # SHA-1 hex length
  14
  15 sub mid_clean {
  16         my ($mid) = @_;
  17         defined($mid) or die "no Message-ID";
  18         # MDA->precheck did more checking for us
  19         if ($mid =~ /<([^>]+)>/) {
  20                 $mid = $1;
  21         }
  22         $mid;
  23 }
  24
  25 # this is idempotent
  26 sub id_compress {
  27         my ($id, $force) = @_;
  28
  29         if ($force || $id =~ /[^\w\-]/ || length($id) > MID_MAX) {
  30                 utf8::encode($id);
  31                 return sha1_hex($id);
  32         }
  33         $id;
  34 }
  35
  36 sub mid2path {
  37         my ($mid) = @_;
  38         my ($x2, $x38) = ($mid =~ /\A([a-f0-9]{2})([a-f0-9]{38})\z/);
  39
  40         unless (defined $x38) {
  41                 # compatibility with old links (or short Message-IDs :)
  42                 $mid = mid_clean($mid);
  43                 utf8::encode($mid);
  44                 $mid = sha1_hex($mid);
  45                 ($x2, $x38) = ($mid =~ /\A([a-f0-9]{2})([a-f0-9]{38})\z/);
  46         }
  47         "$x2/$x38";
  48 }
  49
  50 sub mid_mime ($) { $_[0]->header_obj->header_raw('Message-ID') }
  51
  52 sub uniq_mids {
  53         my ($hdr, @fields) = @_;
  54         my %seen;
  55         my @raw;
  56         foreach my $f (@fields) {
  57                 push @raw, $hdr->header_raw($f);
  58         }
  59         my @mids = (join(' ', @raw) =~ /<([^>]+)>/g);
  60         my $mids = scalar(@mids) == 0 ? \@raw: \@mids;
  61         my @ret;
  62         foreach (@$mids) {
  63                 next if $seen{$_};
  64                 push @ret, $_;
  65                 $seen{$_} = 1;
  66         }
  67         \@ret;
  68 }
  69
  70 sub mids { uniq_mids($_[0], 'Message-Id') }
  71
  72 # last References should be IRT, but some mail clients do things
  73 # out of order, so trust IRT over References iff IRT exists
  74 sub references { uniq_mids($_[0], 'References', 'In-Reply-To') }
  75
  76 # RFC3986, section 3.3:
  77 sub MID_ESC () { '^A-Za-z0-9\-\._~!\$\&\';\(\)\*\+,;=:@' }
  78 sub mid_escape ($) { uri_escape_utf8($_[0], MID_ESC) }
  79
  80 1;