lib/PublicInbox/MIME.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # The license for this file differs from the rest of public-inbox.
   5 #
   6 # It monkey patches the "parts_multipart" subroutine with patches
   7 # from Matthew Horsfall <wolfsage@gmail.com> at:
   8 #
   9 # git clone --mirror https://github.com/rjbs/Email-MIME.git refs/pull/28/head
  10 #
  11 # commit fe0eb870ab732507aa39a1070a2fd9435c7e4877
  12 # ("Make sure we don't modify the body of a message when injecting a header.")
  13 # commit 981d8201a7239b02114489529fd366c4c576a146
  14 # ("GH #14 - Handle CRLF emails properly.")
  15 # commit 2338d93598b5e8432df24bda8dfdc231bdeb666e
  16 # ("GH #14 - Support multipart messages without content-type in subparts.")
  17 #
  18 # For Email::MIME >= 1.923 && < 1.935,
  19 # commit dcef9be66c49ae89c7a5027a789bbbac544499ce
  20 # ("removing all trailing newlines was too much")
  21 # is also included
  22 package PublicInbox::MIME;
  23 use strict;
  24 use warnings;
  25 use base qw(Email::MIME);
  26 use Email::MIME::ContentType;
  27 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  28
  29 if ($Email::MIME::VERSION <= 1.937) {
  30 sub parts_multipart {
  31   my $self     = shift;
  32   my $boundary = $self->{ct}->{attributes}->{boundary};
  33
  34   # Take a message, join all its lines together.  Now try to Email::MIME->new
  35   # it with 1.861 or earlier.  Death!  It tries to recurse endlessly on the
  36   # body, because every time it splits on boundary it gets itself. Obviously
  37   # that means it's a bogus message, but a mangled result (or exception) is
  38   # better than endless recursion. -- rjbs, 2008-01-07
  39   return $self->parts_single_part
  40     unless $boundary and $self->body_raw =~ /^--\Q$boundary\E\s*$/sm;
  41
  42   $self->{body_raw} = Email::Simple::body($self);
  43
  44   # rfc1521 7.2.1
  45   my ($body, $epilogue) = split /^--\Q$boundary\E--\s*$/sm, $self->body_raw, 2;
  46
  47   # Split on boundaries, but keep blank lines after them intact
  48   my @bits = split /^--\Q$boundary\E\s*?(?=$self->{mycrlf})/m, ($body || '');
  49
  50   Email::Simple::body_set($self, undef);
  51
  52   # If there are no headers in the potential MIME part, it's just part of the
  53   # body.  This is a horrible hack, although it's debatable whether it was
  54   # better or worse when it was $self->{body} = shift @bits ... -- rjbs,
  55   # 2006-11-27
  56   Email::Simple::body_set($self, shift @bits) if ($bits[0] || '') !~ /.*:.*/;
  57
  58   my $bits = @bits;
  59
  60   my @parts;
  61   for my $bit (@bits) {
  62     # Parts don't need headers. If they don't have them, they look like this:
  63     #
  64     #   --90e6ba6e8d06f1723604fc1b809a
  65     #
  66     #   Part 2
  67     #
  68     #   Part 2a
  69     #
  70     # $bit will contain two new lines before Part 2.
  71     #
  72     # Anything with headers will only have one new line.
  73     #
  74     # RFC 1341 Section 7.2 says parts without headers are to be considered
  75     # plain US-ASCII text. -- alh
  76     # 2016-08-01
  77     my $added_header;
  78
  79     if ($bit =~ /^(?:$self->{mycrlf}){2}/) {
  80       $bit = "Content-type: text/plain; charset=us-ascii" . $bit;
  81
  82       $added_header = 1;
  83     }
  84
  85     $bit =~ s/\A[\n\r]+//smg;
  86     $bit =~ s/(?<!\x0d)$self->{mycrlf}\Z//sm;
  87
  88     my $email = (ref $self)->new($bit);
  89
  90     if ($added_header) {
  91       # Remove our changes so we don't change the raw email content
  92       $email->header_str_set('Content-Type');
  93     }
  94
  95     push @parts, $email;
  96   }
  97
  98   $self->{parts} = \@parts;
  99
 100   return @{ $self->{parts} };
 101 }
 102 }
 103
 104 1;