lib/PublicInbox/MIME.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # The license for this file differs from the rest of public-inbox.
   5 #
   6 # It monkey patches the "parts_multipart" subroutine with patches
   7 # from Matthew Horsfall <wolfsage@gmail.com> at:
   8 #
   9 # git clone --mirror https://github.com/rjbs/Email-MIME.git refs/pull/28/head
  10 #
  11 # commit fe0eb870ab732507aa39a1070a2fd9435c7e4877
  12 # ("Make sure we don't modify the body of a message when injecting a header.")
  13 # commit 981d8201a7239b02114489529fd366c4c576a146
  14 # ("GH #14 - Handle CRLF emails properly.")
  15 # commit 2338d93598b5e8432df24bda8dfdc231bdeb666e
  16 # ("GH #14 - Support multipart messages without content-type in subparts.")
  17 #
  18 # For Email::MIME >= 1.923 && < 1.935,
  19 # commit dcef9be66c49ae89c7a5027a789bbbac544499ce
  20 # ("removing all trailing newlines was too much")
  21 # is also included
  22 package PublicInbox::MIME;
  23 use strict;
  24 use warnings;
  25 use base qw(Email::MIME);
  26 use Email::MIME::ContentType;
  27 use PublicInbox::MsgIter ();
  28 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  29
  30 if ($Email::MIME::VERSION <= 1.937) {
  31 sub parts_multipart {
  32   my $self     = shift;
  33   my $boundary = $self->{ct}->{attributes}->{boundary};
  34
  35   # Take a message, join all its lines together.  Now try to Email::MIME->new
  36   # it with 1.861 or earlier.  Death!  It tries to recurse endlessly on the
  37   # body, because every time it splits on boundary it gets itself. Obviously
  38   # that means it's a bogus message, but a mangled result (or exception) is
  39   # better than endless recursion. -- rjbs, 2008-01-07
  40   return $self->parts_single_part
  41     unless $boundary and $self->body_raw =~ /^--\Q$boundary\E\s*$/sm;
  42
  43   $self->{body_raw} = Email::Simple::body($self);
  44
  45   # rfc1521 7.2.1
  46   my ($body, $epilogue) = split /^--\Q$boundary\E--\s*$/sm, $self->body_raw, 2;
  47
  48   # Split on boundaries, but keep blank lines after them intact
  49   my @bits = split /^--\Q$boundary\E\s*?(?=$self->{mycrlf})/m, ($body || '');
  50
  51   Email::Simple::body_set($self, undef);
  52
  53   # If there are no headers in the potential MIME part, it's just part of the
  54   # body.  This is a horrible hack, although it's debatable whether it was
  55   # better or worse when it was $self->{body} = shift @bits ... -- rjbs,
  56   # 2006-11-27
  57   Email::Simple::body_set($self, shift @bits) if ($bits[0] || '') !~ /.*:.*/;
  58
  59   my $bits = @bits;
  60
  61   my @parts;
  62   for my $bit (@bits) {
  63     # Parts don't need headers. If they don't have them, they look like this:
  64     #
  65     #   --90e6ba6e8d06f1723604fc1b809a
  66     #
  67     #   Part 2
  68     #
  69     #   Part 2a
  70     #
  71     # $bit will contain two new lines before Part 2.
  72     #
  73     # Anything with headers will only have one new line.
  74     #
  75     # RFC 1341 Section 7.2 says parts without headers are to be considered
  76     # plain US-ASCII text. -- alh
  77     # 2016-08-01
  78     my $added_header;
  79
  80     if ($bit =~ /^(?:$self->{mycrlf}){2}/) {
  81       $bit = "Content-type: text/plain; charset=us-ascii" . $bit;
  82
  83       $added_header = 1;
  84     }
  85
  86     $bit =~ s/\A[\n\r]+//smg;
  87     $bit =~ s/(?<!\x0d)$self->{mycrlf}\Z//sm;
  88
  89     my $email = (ref $self)->new($bit);
  90
  91     if ($added_header) {
  92       # Remove our changes so we don't change the raw email content
  93       $email->header_str_set('Content-Type');
  94     }
  95
  96     push @parts, $email;
  97   }
  98
  99   $self->{parts} = \@parts;
 100
 101   return @{ $self->{parts} };
 102 }
 103 }
 104
 105 no warnings 'once';
 106 *each_part = \&PublicInbox::MsgIter::em_each_part;
 107 1;