lib/PublicInbox/Mbox.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Streaming interface for formatting messages as an mboxrd.
   5 # Used by the web interface
   6 package PublicInbox::Mbox;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MID qw/mid_clean mid_escape/;
  10 use PublicInbox::Hval qw/to_filename/;
  11 use Email::Simple;
  12 use Email::MIME::Encode;
  13
  14 sub subject_fn ($) {
  15         my ($simple) = @_;
  16         my $fn = $simple->header('Subject');
  17         return 'no-subject' unless defined($fn);
  18
  19         # no need for full Email::MIME, here
  20         if ($fn =~ /=\?/) {
  21                 eval { $fn = Encode::decode('MIME-Header', $fn) };
  22                 $fn = 'no-subject' if $@;
  23         }
  24         $fn =~ s/^re:\s+//i;
  25         $fn = to_filename($fn);
  26         $fn eq '' ? 'no-subject' : $fn;
  27 }
  28
  29 sub mb_stream {
  30         my ($more) = @_;
  31         bless $more, 'PublicInbox::Mbox';
  32 }
  33
  34 # called by PSGI server as body response
  35 sub getline {
  36         my ($more) = @_; # self
  37         my ($ctx, $head, $tail, $db, $cur) = @$more;
  38         if ($cur) {
  39                 pop @$more;
  40                 return msg_str($ctx, $cur);
  41         }
  42         for (; !defined($cur) && $head != $tail; $head++) {
  43                 my $smsg = PublicInbox::SearchMsg->get($head, $db, $ctx->{mid});
  44                 my $mref = $ctx->{-inbox}->msg_by_smsg($smsg) or next;
  45                 $cur = Email::Simple->new($mref);
  46                 $cur = msg_str($ctx, $cur);
  47         }
  48         $more->[1] = $head;
  49         $cur;
  50 }
  51
  52 sub close {} # noop
  53
  54 sub emit_raw {
  55         my ($ctx) = @_;
  56         my $mid = $ctx->{mid};
  57         my $ibx = $ctx->{-inbox};
  58         my $first;
  59         my $more;
  60         my ($head, $tail, $db);
  61         my %seen;
  62         if (my $srch = $ibx->search) {
  63                 $srch->retry_reopen(sub {
  64                         ($head, $tail, $db) = $srch->each_smsg_by_mid($mid);
  65                         for (; !defined($first) && $head != $tail; $head++) {
  66                                 my @args = ($head, $db, $mid);
  67                                 my $smsg = PublicInbox::SearchMsg->get(@args);
  68                                 my $mref = $ibx->msg_by_smsg($smsg) or next;
  69                                 $first = Email::Simple->new($mref);
  70                         }
  71                         if ($head != $tail) {
  72                                 $more = [ $ctx, $head, $tail, $db, $first ];
  73                         }
  74                 });
  75         } else {
  76                 my $mref = $ibx->msg_by_mid($mid) or return;
  77                 $first = Email::Simple->new($mref);
  78         }
  79         return unless defined $first;
  80         my $fn = subject_fn($first);
  81         my @hdr = ('Content-Type');
  82         if ($ibx->{obfuscate}) {
  83                 # obfuscation is stupid, but maybe scrapers are, too...
  84                 push @hdr, 'application/mbox';
  85                 $fn .= '.mbox';
  86         } else {
  87                 push @hdr, 'text/plain';
  88                 $fn .= '.txt';
  89         }
  90         push @hdr, 'Content-Disposition', "inline; filename=$fn";
  91         [ 200, \@hdr, $more ? mb_stream($more) : [ msg_str($ctx, $first) ] ];
  92 }
  93
  94 sub msg_str {
  95         my ($ctx, $simple, $mid) = @_; # Email::Simple object
  96         my $header_obj = $simple->header_obj;
  97
  98         # drop potentially confusing headers, ssoma already should've dropped
  99         # Lines and Content-Length
 100         foreach my $d (qw(Lines Bytes Content-Length Status)) {
 101                 $header_obj->header_set($d);
 102         }
 103         my $ibx = $ctx->{-inbox};
 104         my $base = $ibx->base_url($ctx->{env});
 105         $mid = $ctx->{mid} unless defined $mid;
 106         $mid = mid_escape($mid);
 107         my @append = (
 108                 'Archived-At', "<$base$mid/>",
 109                 'List-Archive', "<$base>",
 110                 'List-Post', "<mailto:$ibx->{-primary_address}>",
 111         );
 112         my $crlf = $simple->crlf;
 113         my $buf = "From mboxrd\@z Thu Jan  1 00:00:00 1970\n" .
 114                         $header_obj->as_string;
 115         for (my $i = 0; $i < @append; $i += 2) {
 116                 my $k = $append[$i];
 117                 my $v = $append[$i + 1];
 118                 my @v = $header_obj->header($k);
 119                 foreach (@v) {
 120                         if ($v eq $_) {
 121                                 $v = undef;
 122                                 last;
 123                         }
 124                 }
 125                 $buf .= "$k: $v$crlf" if defined $v;
 126         }
 127         $buf .= $crlf;
 128
 129         # mboxrd quoting style
 130         # ref: http://www.qmail.org/man/man5/mbox.html
 131         my $body = $simple->body;
 132         $body =~ s/^(>*From )/>$1/gm;
 133         $buf .= $body;
 134         $buf .= "\n";
 135 }
 136
 137 sub thread_mbox {
 138         my ($ctx, $srch, $sfx) = @_;
 139         eval { require IO::Compress::Gzip };
 140         return sub { need_gzip(@_) } if $@;
 141
 142         my $cb = sub { $srch->get_thread($ctx->{mid}, @_) };
 143         PublicInbox::MboxGz->response($ctx, $cb);
 144 }
 145
 146 sub emit_range {
 147         my ($ctx, $range) = @_;
 148
 149         my $query;
 150         if ($range eq 'all') { # TODO: YYYY[-MM]
 151                 $query = '';
 152         } else {
 153                 return [404, [qw(Content-Type text/plain)], []];
 154         }
 155         mbox_all($ctx, $query);
 156 }
 157
 158 sub mbox_all {
 159         my ($ctx, $query) = @_;
 160
 161         eval { require IO::Compress::Gzip };
 162         return sub { need_gzip(@_) } if $@;
 163         my $cb = sub { $ctx->{srch}->query($query, @_) };
 164         PublicInbox::MboxGz->response($ctx, $cb, 'results-'.$query);
 165 }
 166
 167 sub need_gzip {
 168         my $fh = $_[0]->([501, ['Content-Type' => 'text/html']]);
 169         my $title = 'gzipped mbox not available';
 170         $fh->write(<<EOF);
 171 <html><head><title>$title</title><body><pre>$title
 172 The administrator needs to install the IO::Compress::Gzip Perl module
 173 to support gzipped mboxes.
 174 <a href="../">Return to index</a></pre></body></html>
 175 EOF
 176         $fh->close;
 177 }
 178
 179 1;
 180
 181 package PublicInbox::MboxGz;
 182 use strict;
 183 use warnings;
 184 use PublicInbox::Hval qw/to_filename/;
 185
 186 sub new {
 187         my ($class, $ctx, $cb) = @_;
 188         my $buf = '';
 189         bless {
 190                 buf => \$buf,
 191                 gz => IO::Compress::Gzip->new(\$buf, Time => 0),
 192                 cb => $cb,
 193                 ctx => $ctx,
 194                 msgs => [],
 195                 opts => { offset => 0 },
 196         }, $class;
 197 }
 198
 199 sub response {
 200         my ($class, $ctx, $cb, $fn) = @_;
 201         my $body = $class->new($ctx, $cb);
 202         # http://www.iana.org/assignments/media-types/application/gzip
 203         $body->{hdr} = [ 'Content-Type', 'application/gzip' ];
 204         $body->{fn} = $fn;
 205         my $hdr = $body->getline; # fill in Content-Disposition filename
 206         [ 200, $hdr, $body ];
 207 }
 208
 209 sub set_filename ($$) {
 210         my ($fn, $msg) = @_;
 211         return to_filename($fn) if defined($fn);
 212
 213         PublicInbox::Mbox::subject_fn($msg);
 214 }
 215
 216 # called by Plack::Util::foreach or similar
 217 sub getline {
 218         my ($self) = @_;
 219         my $ctx = $self->{ctx} or return;
 220         my $ibx = $ctx->{-inbox};
 221         my $gz = $self->{gz};
 222         my $msgs = $self->{msgs};
 223         do {
 224                 # work on existing result set
 225                 while (defined(my $smsg = shift @$msgs)) {
 226                         my $msg = eval { $ibx->msg_by_smsg($smsg) } or next;
 227                         $msg = Email::Simple->new($msg);
 228                         $gz->write(PublicInbox::Mbox::msg_str($ctx, $msg,
 229                                                                 $smsg->mid));
 230
 231                         # use subject of first message as subject
 232                         if (my $hdr = delete $self->{hdr}) {
 233                                 my $fn = set_filename($self->{fn}, $msg);
 234                                 push @$hdr, 'Content-Disposition',
 235                                                 "inline; filename=$fn.mbox.gz";
 236                                 return $hdr;
 237                         }
 238                         my $bref = $self->{buf};
 239                         if (length($$bref) >= 8192) {
 240                                 my $ret = $$bref; # copy :<
 241                                 ${$self->{buf}} = '';
 242                                 return $ret;
 243                         }
 244
 245                         # be fair to other clients on public-inbox-httpd:
 246                         return '';
 247                 }
 248
 249                 # refill result set
 250                 $msgs = $self->{msgs} = $self->{cb}->($self->{opts});
 251                 $self->{opts}->{offset} += scalar @$msgs;
 252         } while (@$msgs);
 253         $gz->close;
 254         delete $self->{ctx};
 255         ${delete $self->{buf}};
 256 }
 257
 258 sub close {} # noop
 259
 260 1;