lib/PublicInbox/Mbox.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Streaming interface for mboxrd HTTP responses
   5 # See PublicInbox::GzipFilter for details.
   6 package PublicInbox::Mbox;
   7 use strict;
   8 use parent 'PublicInbox::GzipFilter';
   9 use PublicInbox::MID qw/mid_escape/;
  10 use PublicInbox::Hval qw/to_filename/;
  11 use PublicInbox::Smsg;
  12 use PublicInbox::Eml;
  13 use PublicInbox::Search qw(mdocid);
  14
  15 # called by PSGI server as body response
  16 # this gets called twice for every message, once to return the header,
  17 # once to retrieve the body
  18 sub getline {
  19         my ($ctx) = @_; # ctx
  20         my $smsg = $ctx->{smsg} or return;
  21         my $ibx = $ctx->{-inbox};
  22         my $eml = $ibx->smsg_eml($smsg) or return;
  23         my $n = $ctx->{smsg} = $ibx->over->next_by_mid(@{$ctx->{next_arg}});
  24         $ctx->zmore(msg_hdr($ctx, $eml, $smsg->{mid}));
  25         if ($n) {
  26                 $ctx->translate(msg_body($eml));
  27         } else { # last message
  28                 $ctx->zmore(msg_body($eml));
  29                 $ctx->zflush;
  30         }
  31 }
  32
  33 # called by PublicInbox::DS::write after http->next_step
  34 sub async_next {
  35         my ($http) = @_; # PublicInbox::HTTP
  36         my $ctx = $http->{forward} or return; # client aborted
  37         eval {
  38                 my $smsg = $ctx->{smsg} or return $ctx->close;
  39                 $ctx->smsg_blob($smsg);
  40         };
  41         warn "E: $@" if $@;
  42 }
  43
  44 sub async_eml { # for async_blob_cb
  45         my ($ctx, $eml) = @_;
  46         my $smsg = delete $ctx->{smsg};
  47         # next message
  48         $ctx->{smsg} = $ctx->{-inbox}->over->next_by_mid(@{$ctx->{next_arg}});
  49
  50         $ctx->zmore(msg_hdr($ctx, $eml, $smsg->{mid}));
  51         $ctx->{http_out}->write($ctx->translate(msg_body($eml)));
  52 }
  53
  54 sub res_hdr ($$) {
  55         my ($ctx, $subject) = @_;
  56         my $fn = $subject // '';
  57         $fn =~ s/^re:\s+//i;
  58         $fn = to_filename($fn) // 'no-subject';
  59         my @hdr = ('Content-Type');
  60         if ($ctx->{-inbox}->{obfuscate}) {
  61                 # obfuscation is stupid, but maybe scrapers are, too...
  62                 push @hdr, 'application/mbox';
  63                 $fn .= '.mbox';
  64         } else {
  65                 push @hdr, 'text/plain';
  66                 $fn .= '.txt';
  67         }
  68         push @hdr, 'Content-Disposition', "inline; filename=$fn";
  69         \@hdr;
  70 }
  71
  72 # for rare cases where v1 inboxes aren't indexed w/ ->over at all
  73 sub no_over_raw ($) {
  74         my ($ctx) = @_;
  75         my $mref = $ctx->{-inbox}->msg_by_mid($ctx->{mid}) or return;
  76         my $eml = PublicInbox::Eml->new($mref);
  77         [ 200, res_hdr($ctx, $eml->header_str('Subject')),
  78                 [ msg_hdr($ctx, $eml, $ctx->{mid}) . msg_body($eml) ] ]
  79 }
  80
  81 # /$INBOX/$MESSAGE_ID/raw
  82 sub emit_raw {
  83         my ($ctx) = @_;
  84         $ctx->{base_url} = $ctx->{-inbox}->base_url($ctx->{env});
  85         my $over = $ctx->{-inbox}->over or return no_over_raw($ctx);
  86         my ($id, $prev);
  87         my $mip = $ctx->{next_arg} = [ $ctx->{mid}, \$id, \$prev ];
  88         my $smsg = $ctx->{smsg} = $over->next_by_mid(@$mip) or return;
  89         my $res_hdr = res_hdr($ctx, $smsg->{subject});
  90         bless $ctx, __PACKAGE__;
  91         $ctx->psgi_response(200, $res_hdr);
  92 }
  93
  94 sub msg_hdr ($$;$) {
  95         my ($ctx, $eml, $mid) = @_;
  96         my $header_obj = $eml->header_obj;
  97
  98         # drop potentially confusing headers, ssoma already should've dropped
  99         # Lines and Content-Length
 100         foreach my $d (qw(Lines Bytes Content-Length Status)) {
 101                 $header_obj->header_set($d);
 102         }
 103         my $ibx = $ctx->{-inbox};
 104         my $base = $ctx->{base_url};
 105         $mid = $ctx->{mid} unless defined $mid;
 106         $mid = mid_escape($mid);
 107         my @append = (
 108                 'Archived-At', "<$base$mid/>",
 109                 'List-Archive', "<$base>",
 110                 'List-Post', "<mailto:$ibx->{-primary_address}>",
 111         );
 112         my $crlf = $header_obj->crlf;
 113         my $buf = $header_obj->as_string;
 114         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 115         $buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 116         $buf = "From mboxrd\@z Thu Jan  1 00:00:00 1970" . $crlf . $buf;
 117
 118         for (my $i = 0; $i < @append; $i += 2) {
 119                 my $k = $append[$i];
 120                 my $v = $append[$i + 1];
 121                 my @v = $header_obj->header_raw($k);
 122                 foreach (@v) {
 123                         if ($v eq $_) {
 124                                 $v = undef;
 125                                 last;
 126                         }
 127                 }
 128                 $buf .= "$k: $v$crlf" if defined $v;
 129         }
 130         $buf .= $crlf;
 131 }
 132
 133 sub msg_body ($) {
 134         my $bdy = $_[0]->{bdy} // return "\n";
 135         # mboxrd quoting style
 136         # https://en.wikipedia.org/wiki/Mbox#Modified_mbox
 137         # https://www.loc.gov/preservation/digital/formats/fdd/fdd000385.shtml
 138         # https://web.archive.org/http://www.qmail.org/man/man5/mbox.html
 139         $$bdy =~ s/^(>*From )/>$1/gm;
 140         $$bdy .= "\n";
 141 }
 142
 143 sub thread_cb {
 144         my ($ctx) = @_;
 145         my $msgs = $ctx->{msgs};
 146         while (1) {
 147                 if (my $smsg = shift @$msgs) {
 148                         return $smsg;
 149                 }
 150                 # refill result set
 151                 $ctx->{msgs} = $msgs = $ctx->{over}->get_thread($ctx->{mid},
 152                                                                 $ctx->{prev});
 153                 return unless @$msgs;
 154                 $ctx->{prev} = $msgs->[-1];
 155         }
 156 }
 157
 158 sub thread_mbox {
 159         my ($ctx, $over, $sfx) = @_;
 160         my $msgs = $ctx->{msgs} = $over->get_thread($ctx->{mid}, {});
 161         return [404, [qw(Content-Type text/plain)], []] if !@$msgs;
 162         $ctx->{prev} = $msgs->[-1];
 163         $ctx->{over} = $over; # bump refcnt
 164         require PublicInbox::MboxGz;
 165         PublicInbox::MboxGz::mbox_gz($ctx, \&thread_cb, $msgs->[0]->{subject});
 166 }
 167
 168 sub emit_range {
 169         my ($ctx, $range) = @_;
 170
 171         my $query;
 172         if ($range eq 'all') { # TODO: YYYY[-MM]
 173                 $query = '';
 174         } else {
 175                 return [404, [qw(Content-Type text/plain)], []];
 176         }
 177         mbox_all($ctx, $query);
 178 }
 179
 180 sub all_ids_cb {
 181         my ($ctx) = @_;
 182         my $ids = $ctx->{ids};
 183         do {
 184                 while ((my $num = shift @$ids)) {
 185                         my $smsg = $ctx->{over}->get_art($num) or next;
 186                         return $smsg;
 187                 }
 188                 $ctx->{ids} = $ids = $ctx->{mm}->ids_after(\($ctx->{prev}));
 189         } while (@$ids);
 190 }
 191
 192 sub mbox_all_ids {
 193         my ($ctx) = @_;
 194         my $ibx = $ctx->{-inbox};
 195         my $prev = 0;
 196         my $mm = $ctx->{mm} = $ibx->mm;
 197         my $ids = $mm->ids_after(\$prev) or return
 198                 [404, [qw(Content-Type text/plain)], ["No results found\n"]];
 199         $ctx->{over} = $ibx->over or
 200                 return PublicInbox::WWW::need($ctx, 'Overview');
 201         $ctx->{ids} = $ids;
 202         $ctx->{prev} = $prev;
 203         require PublicInbox::MboxGz;
 204         PublicInbox::MboxGz::mbox_gz($ctx, \&all_ids_cb, 'all');
 205 }
 206
 207 sub results_cb {
 208         my ($ctx) = @_;
 209         my $over = $ctx->{-inbox}->over or return;
 210         while (1) {
 211                 while (defined(my $num = shift(@{$ctx->{ids}}))) {
 212                         my $smsg = $over->get_art($num) or next;
 213                         return $smsg;
 214                 }
 215                 # refill result set
 216                 my $srch = $ctx->{-inbox}->search(undef, $ctx) or return;
 217                 my $mset = $srch->query($ctx->{query}, $ctx->{qopts});
 218                 my $size = $mset->size or return;
 219                 $ctx->{qopts}->{offset} += $size;
 220                 my $nshard = $srch->{nshard} // 1;
 221                 $ctx->{ids} = [ map { mdocid($nshard, $_) } $mset->items ];
 222         }
 223 }
 224
 225 sub mbox_all {
 226         my ($ctx, $query) = @_;
 227
 228         return mbox_all_ids($ctx) if $query eq '';
 229         my $qopts = $ctx->{qopts} = { mset => 2 }; # order by docid
 230         my $srch = $ctx->{-inbox}->search or
 231                 return PublicInbox::WWW::need($ctx, 'Search');
 232         my $mset = $srch->query($query, $qopts);
 233         $qopts->{offset} = $mset->size or
 234                         return [404, [qw(Content-Type text/plain)],
 235                                 ["No results found\n"]];
 236         $ctx->{query} = $query;
 237         my $nshard = $srch->{nshard} // 1;
 238         $ctx->{ids} = [ map { mdocid($nshard, $_) } $mset->items ];
 239         require PublicInbox::MboxGz;
 240         PublicInbox::MboxGz::mbox_gz($ctx, \&results_cb, 'results-'.$query);
 241 }
 242
 243 1;