lib/PublicInbox/Mbox.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Streaming interface for mboxrd HTTP responses
   5 # See PublicInbox::GzipFilter for details.
   6 package PublicInbox::Mbox;
   7 use strict;
   8 use parent 'PublicInbox::GzipFilter';
   9 use PublicInbox::MID qw/mid_escape/;
  10 use PublicInbox::Hval qw/to_filename/;
  11 use PublicInbox::Smsg;
  12 use PublicInbox::Eml;
  13
  14 # called by PSGI server as body response
  15 # this gets called twice for every message, once to return the header,
  16 # once to retrieve the body
  17 sub getline {
  18         my ($ctx) = @_; # ctx
  19         my $smsg = $ctx->{smsg} or return;
  20         my $ibx = $ctx->{ibx};
  21         my $eml = delete($ctx->{eml}) // $ibx->smsg_eml($smsg) // return;
  22         if (($ctx->{smsg} = $ibx->over->next_by_mid(@{$ctx->{next_arg}}))) {
  23                 $ctx->translate(msg_hdr($ctx, $eml), msg_body($eml));
  24         } else { # last message
  25                 $ctx->zflush(msg_hdr($ctx, $eml), msg_body($eml));
  26         }
  27 }
  28
  29 # called by PublicInbox::DS::write after http->next_step
  30 sub async_next {
  31         my ($http) = @_; # PublicInbox::HTTP
  32         my $ctx = $http->{forward} or return; # client aborted
  33         eval {
  34                 my $smsg = $ctx->{smsg} or return $ctx->close;
  35                 $ctx->smsg_blob($smsg);
  36         };
  37         warn "E: $@" if $@;
  38 }
  39
  40 sub async_eml { # for async_blob_cb
  41         my ($ctx, $eml) = @_;
  42         my $smsg = delete $ctx->{smsg};
  43         # next message
  44         $ctx->{smsg} = $ctx->{ibx}->over->next_by_mid(@{$ctx->{next_arg}});
  45         local $ctx->{eml} = $eml; # for mbox_hdr
  46         $ctx->write(msg_hdr($ctx, $eml), msg_body($eml));
  47 }
  48
  49 sub mbox_hdr ($) {
  50         my ($ctx) = @_;
  51         my $eml = $ctx->{eml} //= $ctx->{ibx}->smsg_eml($ctx->{smsg});
  52         my $fn = $eml->header_str('Subject') // '';
  53         $fn =~ s/^re:\s+//i;
  54         $fn = to_filename($fn) // 'no-subject';
  55         my @hdr = ('Content-Type');
  56         if ($ctx->{ibx}->{obfuscate}) {
  57                 # obfuscation is stupid, but maybe scrapers are, too...
  58                 push @hdr, 'application/mbox';
  59                 $fn .= '.mbox';
  60         } else {
  61                 push @hdr, 'text/plain';
  62                 $fn .= '.txt';
  63         }
  64         my $cs = $ctx->{eml}->ct->{attributes}->{charset} // 'UTF-8';
  65         $cs = 'UTF-8' if $cs =~ /[^a-zA-Z0-9\-\_]/; # avoid header injection
  66         $hdr[-1] .= "; charset=$cs";
  67         push @hdr, 'Content-Disposition', "inline; filename=$fn";
  68         [ 200, \@hdr ];
  69 }
  70
  71 # for rare cases where v1 inboxes aren't indexed w/ ->over at all
  72 sub no_over_raw ($) {
  73         my ($ctx) = @_;
  74         my $mref = $ctx->{ibx}->msg_by_mid($ctx->{mid}) or return;
  75         my $eml = $ctx->{eml} = PublicInbox::Eml->new($mref);
  76         [ @{mbox_hdr($ctx)}, [ msg_hdr($ctx, $eml) . msg_body($eml) ] ]
  77 }
  78
  79 # /$INBOX/$MESSAGE_ID/raw
  80 sub emit_raw {
  81         my ($ctx) = @_;
  82         my $over = $ctx->{ibx}->over or return no_over_raw($ctx);
  83         my ($id, $prev);
  84         my $mip = $ctx->{next_arg} = [ $ctx->{mid}, \$id, \$prev ];
  85         my $smsg = $ctx->{smsg} = $over->next_by_mid(@$mip) or return;
  86         bless $ctx, __PACKAGE__;
  87         $ctx->psgi_response(\&mbox_hdr);
  88 }
  89
  90 sub msg_hdr ($$) {
  91         my ($ctx, $eml) = @_;
  92         my $header_obj = $eml->header_obj;
  93
  94         # drop potentially confusing headers, ssoma already should've dropped
  95         # Lines and Content-Length
  96         foreach my $d (qw(Lines Bytes Content-Length Status)) {
  97                 $header_obj->header_set($d);
  98         }
  99         my $crlf = $header_obj->crlf;
 100         my $buf = $header_obj->as_string;
 101         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 102         $buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 103         "From mboxrd\@z Thu Jan  1 00:00:00 1970" . $crlf . $buf . $crlf;
 104 }
 105
 106 sub msg_body ($) {
 107         my $bdy = $_[0]->{bdy} // return "\n";
 108         # mboxrd quoting style
 109         # https://en.wikipedia.org/wiki/Mbox#Modified_mbox
 110         # https://www.loc.gov/preservation/digital/formats/fdd/fdd000385.shtml
 111         # https://web.archive.org/http://www.qmail.org/man/man5/mbox.html
 112         $$bdy =~ s/^(>*From )/>$1/gm;
 113         $$bdy .= "\n";
 114 }
 115
 116 sub thread_cb {
 117         my ($ctx) = @_;
 118         my $msgs = $ctx->{msgs};
 119         while (1) {
 120                 if (my $smsg = shift @$msgs) {
 121                         return $smsg;
 122                 }
 123                 # refill result set
 124                 my $over = $ctx->{ibx}->over or return $ctx->gone('over');
 125                 $ctx->{msgs} = $msgs = $over->get_thread($ctx->{mid},
 126                                                         $ctx->{prev});
 127                 return unless @$msgs;
 128                 $ctx->{prev} = $msgs->[-1];
 129         }
 130 }
 131
 132 sub thread_mbox {
 133         my ($ctx, $over, $sfx) = @_;
 134         my $msgs = $ctx->{msgs} = $over->get_thread($ctx->{mid}, {});
 135         return [404, [qw(Content-Type text/plain)], []] if !@$msgs;
 136         $ctx->{prev} = $msgs->[-1];
 137         require PublicInbox::MboxGz;
 138         PublicInbox::MboxGz::mbox_gz($ctx, \&thread_cb, $msgs->[0]->{subject});
 139 }
 140
 141 sub emit_range {
 142         my ($ctx, $range) = @_;
 143
 144         my $q;
 145         if ($range eq 'all') { # TODO: YYYY[-MM]
 146                 $q = '';
 147         } else {
 148                 return [404, [qw(Content-Type text/plain)], []];
 149         }
 150         mbox_all($ctx, { q => $q });
 151 }
 152
 153 sub all_ids_cb {
 154         my ($ctx) = @_;
 155         my $over = $ctx->{ibx}->over or return $ctx->gone('over');
 156         my $ids = $ctx->{ids};
 157         do {
 158                 while ((my $num = shift @$ids)) {
 159                         my $smsg = $over->get_art($num) or next;
 160                         return $smsg;
 161                 }
 162                 $ctx->{ids} = $ids = $over->ids_after(\($ctx->{prev}));
 163         } while (@$ids);
 164 }
 165
 166 sub mbox_all_ids {
 167         my ($ctx) = @_;
 168         my $prev = 0;
 169         my $over = $ctx->{ibx}->over or
 170                 return PublicInbox::WWW::need($ctx, 'Overview');
 171         my $ids = $over->ids_after(\$prev) or return
 172                 [404, [qw(Content-Type text/plain)], ["No results found\n"]];
 173         $ctx->{ids} = $ids;
 174         $ctx->{prev} = $prev;
 175         $ctx->{-low_prio} = 1;
 176         require PublicInbox::MboxGz;
 177         PublicInbox::MboxGz::mbox_gz($ctx, \&all_ids_cb, 'all');
 178 }
 179
 180 sub results_cb {
 181         my ($ctx) = @_;
 182         my $over = $ctx->{ibx}->over or return $ctx->gone('over');
 183         while (1) {
 184                 while (defined(my $num = shift(@{$ctx->{ids}}))) {
 185                         my $smsg = $over->get_art($num) or next;
 186                         return $smsg;
 187                 }
 188                 # refill result set, deprioritize since there's many results
 189                 my $srch = $ctx->{ibx}->isrch or return $ctx->gone('search');
 190                 my $mset = $srch->mset($ctx->{query}, $ctx->{qopts});
 191                 my $size = $mset->size or return;
 192                 $ctx->{qopts}->{offset} += $size;
 193                 $ctx->{ids} = $srch->mset_to_artnums($mset, $ctx->{qopts});
 194                 $ctx->{-low_prio} = 1;
 195         }
 196 }
 197
 198 sub results_thread_cb {
 199         my ($ctx) = @_;
 200
 201         my $over = $ctx->{ibx}->over or return $ctx->gone('over');
 202         while (1) {
 203                 while (defined(my $num = shift(@{$ctx->{xids}}))) {
 204                         my $smsg = $over->get_art($num) or next;
 205                         return $smsg;
 206                 }
 207
 208                 # refills ctx->{xids}
 209                 next if $over->expand_thread($ctx);
 210
 211                 # refill result set, deprioritize since there's many results
 212                 my $srch = $ctx->{ibx}->isrch or return $ctx->gone('search');
 213                 my $mset = $srch->mset($ctx->{query}, $ctx->{qopts});
 214                 my $size = $mset->size or return;
 215                 $ctx->{qopts}->{offset} += $size;
 216                 $ctx->{ids} = $srch->mset_to_artnums($mset, $ctx->{qopts});
 217                 $ctx->{-low_prio} = 1;
 218         }
 219
 220 }
 221
 222 sub mbox_all {
 223         my ($ctx, $q) = @_;
 224         my $q_string = $q->{'q'};
 225         return mbox_all_ids($ctx) if $q_string !~ /\S/;
 226         my $srch = $ctx->{ibx}->isrch or
 227                 return PublicInbox::WWW::need($ctx, 'Search');
 228         my $over = $ctx->{ibx}->over or
 229                 return PublicInbox::WWW::need($ctx, 'Overview');
 230
 231         my $qopts = $ctx->{qopts} = { relevance => -2 }; # ORDER BY docid DESC
 232         $qopts->{threads} = 1 if $q->{t};
 233         $srch->query_approxidate($ctx->{ibx}->git, $q_string);
 234         my $mset = $srch->mset($q_string, $qopts);
 235         $qopts->{offset} = $mset->size or
 236                         return [404, [qw(Content-Type text/plain)],
 237                                 ["No results found\n"]];
 238         $ctx->{query} = $q_string;
 239         $ctx->{ids} = $srch->mset_to_artnums($mset, $qopts);
 240         require PublicInbox::MboxGz;
 241         my $fn;
 242         if ($q->{t} && $srch->has_threadid) {
 243                 $fn = 'results-thread-'.$q_string;
 244                 PublicInbox::MboxGz::mbox_gz($ctx, \&results_thread_cb, $fn);
 245         } else {
 246                 $fn = 'results-'.$q_string;
 247                 PublicInbox::MboxGz::mbox_gz($ctx, \&results_cb, $fn);
 248         }
 249 }
 250
 251 1;