lib/PublicInbox/Mbox.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Streaming interface for mboxrd HTTP responses
   5 # See PublicInbox::GzipFilter for details.
   6 package PublicInbox::Mbox;
   7 use strict;
   8 use parent 'PublicInbox::GzipFilter';
   9 use PublicInbox::MID qw/mid_escape/;
  10 use PublicInbox::Hval qw/to_filename/;
  11 use PublicInbox::Smsg;
  12 use PublicInbox::Eml;
  13
  14 # called by PSGI server as body response
  15 # this gets called twice for every message, once to return the header,
  16 # once to retrieve the body
  17 sub getline {
  18         my ($ctx) = @_; # ctx
  19         my $smsg = $ctx->{smsg} or return;
  20         my $ibx = $ctx->{ibx};
  21         my $eml = $ibx->smsg_eml($smsg) or return;
  22         my $n = $ctx->{smsg} = $ibx->over->next_by_mid(@{$ctx->{next_arg}});
  23         $ctx->zmore(msg_hdr($ctx, $eml));
  24         if ($n) {
  25                 $ctx->translate(msg_body($eml));
  26         } else { # last message
  27                 $ctx->zmore(msg_body($eml));
  28                 $ctx->zflush;
  29         }
  30 }
  31
  32 # called by PublicInbox::DS::write after http->next_step
  33 sub async_next {
  34         my ($http) = @_; # PublicInbox::HTTP
  35         my $ctx = $http->{forward} or return; # client aborted
  36         eval {
  37                 my $smsg = $ctx->{smsg} or return $ctx->close;
  38                 $ctx->smsg_blob($smsg);
  39         };
  40         warn "E: $@" if $@;
  41 }
  42
  43 sub async_eml { # for async_blob_cb
  44         my ($ctx, $eml) = @_;
  45         my $smsg = delete $ctx->{smsg};
  46         # next message
  47         $ctx->{smsg} = $ctx->{ibx}->over->next_by_mid(@{$ctx->{next_arg}});
  48
  49         $ctx->zmore(msg_hdr($ctx, $eml));
  50         $ctx->{http_out}->write($ctx->translate(msg_body($eml)));
  51 }
  52
  53 sub res_hdr ($$) {
  54         my ($ctx, $subject) = @_;
  55         my $fn = $subject // '';
  56         $fn =~ s/^re:\s+//i;
  57         $fn = to_filename($fn) // 'no-subject';
  58         my @hdr = ('Content-Type');
  59         if ($ctx->{ibx}->{obfuscate}) {
  60                 # obfuscation is stupid, but maybe scrapers are, too...
  61                 push @hdr, 'application/mbox';
  62                 $fn .= '.mbox';
  63         } else {
  64                 push @hdr, 'text/plain';
  65                 $fn .= '.txt';
  66         }
  67         push @hdr, 'Content-Disposition', "inline; filename=$fn";
  68         \@hdr;
  69 }
  70
  71 # for rare cases where v1 inboxes aren't indexed w/ ->over at all
  72 sub no_over_raw ($) {
  73         my ($ctx) = @_;
  74         my $mref = $ctx->{ibx}->msg_by_mid($ctx->{mid}) or return;
  75         my $eml = PublicInbox::Eml->new($mref);
  76         [ 200, res_hdr($ctx, $eml->header_str('Subject')),
  77                 [ msg_hdr($ctx, $eml) . msg_body($eml) ] ]
  78 }
  79
  80 # /$INBOX/$MESSAGE_ID/raw
  81 sub emit_raw {
  82         my ($ctx) = @_;
  83         $ctx->{base_url} = $ctx->{ibx}->base_url($ctx->{env});
  84         my $over = $ctx->{ibx}->over or return no_over_raw($ctx);
  85         my ($id, $prev);
  86         my $mip = $ctx->{next_arg} = [ $ctx->{mid}, \$id, \$prev ];
  87         my $smsg = $ctx->{smsg} = $over->next_by_mid(@$mip) or return;
  88         my $res_hdr = res_hdr($ctx, $smsg->{subject});
  89         bless $ctx, __PACKAGE__;
  90         $ctx->psgi_response(200, $res_hdr);
  91 }
  92
  93 sub msg_hdr ($$) {
  94         my ($ctx, $eml) = @_;
  95         my $header_obj = $eml->header_obj;
  96
  97         # drop potentially confusing headers, ssoma already should've dropped
  98         # Lines and Content-Length
  99         foreach my $d (qw(Lines Bytes Content-Length Status)) {
 100                 $header_obj->header_set($d);
 101         }
 102         my $crlf = $header_obj->crlf;
 103         my $buf = $header_obj->as_string;
 104         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 105         $buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 106         "From mboxrd\@z Thu Jan  1 00:00:00 1970" . $crlf . $buf . $crlf;
 107 }
 108
 109 sub msg_body ($) {
 110         my $bdy = $_[0]->{bdy} // return "\n";
 111         # mboxrd quoting style
 112         # https://en.wikipedia.org/wiki/Mbox#Modified_mbox
 113         # https://www.loc.gov/preservation/digital/formats/fdd/fdd000385.shtml
 114         # https://web.archive.org/http://www.qmail.org/man/man5/mbox.html
 115         $$bdy =~ s/^(>*From )/>$1/gm;
 116         $$bdy .= "\n";
 117 }
 118
 119 sub thread_cb {
 120         my ($ctx) = @_;
 121         my $msgs = $ctx->{msgs};
 122         while (1) {
 123                 if (my $smsg = shift @$msgs) {
 124                         return $smsg;
 125                 }
 126                 # refill result set
 127                 $ctx->{msgs} = $msgs = $ctx->{over}->get_thread($ctx->{mid},
 128                                                                 $ctx->{prev});
 129                 return unless @$msgs;
 130                 $ctx->{prev} = $msgs->[-1];
 131         }
 132 }
 133
 134 sub thread_mbox {
 135         my ($ctx, $over, $sfx) = @_;
 136         my $msgs = $ctx->{msgs} = $over->get_thread($ctx->{mid}, {});
 137         return [404, [qw(Content-Type text/plain)], []] if !@$msgs;
 138         $ctx->{prev} = $msgs->[-1];
 139         $ctx->{over} = $over; # bump refcnt
 140         require PublicInbox::MboxGz;
 141         PublicInbox::MboxGz::mbox_gz($ctx, \&thread_cb, $msgs->[0]->{subject});
 142 }
 143
 144 sub emit_range {
 145         my ($ctx, $range) = @_;
 146
 147         my $q;
 148         if ($range eq 'all') { # TODO: YYYY[-MM]
 149                 $q = '';
 150         } else {
 151                 return [404, [qw(Content-Type text/plain)], []];
 152         }
 153         mbox_all($ctx, { q => $q });
 154 }
 155
 156 sub all_ids_cb {
 157         my ($ctx) = @_;
 158         my $ids = $ctx->{ids};
 159         do {
 160                 while ((my $num = shift @$ids)) {
 161                         my $smsg = $ctx->{over}->get_art($num) or next;
 162                         return $smsg;
 163                 }
 164                 $ctx->{ids} = $ids = $ctx->{mm}->ids_after(\($ctx->{prev}));
 165         } while (@$ids);
 166 }
 167
 168 sub mbox_all_ids {
 169         my ($ctx) = @_;
 170         my $ibx = $ctx->{ibx};
 171         my $prev = 0;
 172         my $mm = $ctx->{mm} = $ibx->mm;
 173         my $ids = $mm->ids_after(\$prev) or return
 174                 [404, [qw(Content-Type text/plain)], ["No results found\n"]];
 175         $ctx->{over} = $ibx->over or
 176                 return PublicInbox::WWW::need($ctx, 'Overview');
 177         $ctx->{ids} = $ids;
 178         $ctx->{prev} = $prev;
 179         require PublicInbox::MboxGz;
 180         PublicInbox::MboxGz::mbox_gz($ctx, \&all_ids_cb, 'all');
 181 }
 182
 183 sub gone ($$) {
 184         my ($ctx, $what) = @_;
 185         warn "W: `$ctx->{ibx}->{inboxdir}' $what went away unexpectedly\n";
 186         undef;
 187 }
 188
 189 sub results_cb {
 190         my ($ctx) = @_;
 191         my $over = $ctx->{ibx}->over or return gone($ctx, 'over');
 192         while (1) {
 193                 while (defined(my $num = shift(@{$ctx->{ids}}))) {
 194                         my $smsg = $over->get_art($num) or next;
 195                         return $smsg;
 196                 }
 197                 # refill result set
 198                 my $srch = $ctx->{ibx}->isrch or return gone($ctx, 'search');
 199                 my $mset = $srch->mset($ctx->{query}, $ctx->{qopts});
 200                 my $size = $mset->size or return;
 201                 $ctx->{qopts}->{offset} += $size;
 202                 $ctx->{ids} = $srch->mset_to_artnums($mset, $ctx->{qopts});
 203         }
 204 }
 205
 206 sub results_thread_cb {
 207         my ($ctx) = @_;
 208
 209         my $over = $ctx->{ibx}->over or return gone($ctx, 'over');
 210         while (1) {
 211                 while (defined(my $num = shift(@{$ctx->{xids}}))) {
 212                         my $smsg = $over->get_art($num) or next;
 213                         return $smsg;
 214                 }
 215
 216                 # refills ctx->{xids}
 217                 next if $over->expand_thread($ctx);
 218
 219                 # refill result set
 220                 my $srch = $ctx->{ibx}->isrch or return gone($ctx, 'search');
 221                 my $mset = $srch->mset($ctx->{query}, $ctx->{qopts});
 222                 my $size = $mset->size or return;
 223                 $ctx->{qopts}->{offset} += $size;
 224                 $ctx->{ids} = $srch->mset_to_artnums($mset, $ctx->{qopts});
 225         }
 226
 227 }
 228
 229 sub mbox_all {
 230         my ($ctx, $q) = @_;
 231         my $q_string = $q->{'q'};
 232         return mbox_all_ids($ctx) if $q_string !~ /\S/;
 233         my $srch = $ctx->{ibx}->isrch or
 234                 return PublicInbox::WWW::need($ctx, 'Search');
 235         my $over = $ctx->{ibx}->over or
 236                 return PublicInbox::WWW::need($ctx, 'Overview');
 237
 238         my $qopts = $ctx->{qopts} = { relevance => -1 }; # ORDER BY docid ASC
 239         $qopts->{thread} = 1 if $q->{t};
 240         my $mset = $srch->mset($q_string, $qopts);
 241         $qopts->{offset} = $mset->size or
 242                         return [404, [qw(Content-Type text/plain)],
 243                                 ["No results found\n"]];
 244         $ctx->{query} = $q_string;
 245         $ctx->{ids} = $srch->mset_to_artnums($mset, $qopts);
 246         require PublicInbox::MboxGz;
 247         my $fn;
 248         if ($q->{t} && $srch->has_threadid) {
 249                 $fn = 'results-thread-'.$q_string;
 250                 PublicInbox::MboxGz::mbox_gz($ctx, \&results_thread_cb, $fn);
 251         } else {
 252                 $fn = 'results-'.$q_string;
 253                 PublicInbox::MboxGz::mbox_gz($ctx, \&results_cb, $fn);
 254         }
 255 }
 256
 257 1;