lib/PublicInbox/Mbox.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Streaming interface for formatting messages as an mboxrd.
   5 # Used by the web interface
   6 package PublicInbox::Mbox;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MID qw/mid_clean mid_escape/;
  10 use PublicInbox::Hval qw/to_filename/;
  11 use Email::Simple;
  12 use Email::MIME::Encode;
  13
  14 sub subject_fn ($) {
  15         my ($simple) = @_;
  16         my $fn = $simple->header('Subject');
  17         return 'no-subject' unless defined($fn);
  18
  19         # no need for full Email::MIME, here
  20         if ($fn =~ /=\?/) {
  21                 eval { $fn = Encode::decode('MIME-Header', $fn) };
  22                 $fn = 'no-subject' if $@;
  23         }
  24         $fn =~ s/^re:\s+//i;
  25         $fn = to_filename($fn);
  26         $fn eq '' ? 'no-subject' : $fn;
  27 }
  28
  29 sub mb_stream {
  30         my ($more) = @_;
  31         bless $more, 'PublicInbox::Mbox';
  32 }
  33
  34 # called by PSGI server as body response
  35 sub getline {
  36         my ($more) = @_; # self
  37         my ($ctx, $head, $tail, $db, $cur) = @$more;
  38         if ($cur) {
  39                 pop @$more;
  40                 return msg_str($ctx, $cur);
  41         }
  42         for (; !defined($cur) && $head != $tail; $head++) {
  43                 my $smsg = PublicInbox::SearchMsg->get($head, $db, $ctx->{mid});
  44                 my $mref = $ctx->{-inbox}->msg_by_smsg($smsg) or next;
  45                 $cur = Email::Simple->new($mref);
  46                 $cur = msg_str($ctx, $cur);
  47         }
  48         $more->[1] = $head;
  49         $cur;
  50 }
  51
  52 sub close {} # noop
  53
  54 sub emit_raw {
  55         my ($ctx) = @_;
  56         my $mid = $ctx->{mid};
  57         my $ibx = $ctx->{-inbox};
  58         my $first;
  59         my $more;
  60         my ($head, $tail, $db);
  61         my %seen;
  62         if (my $srch = $ibx->search) {
  63                 $srch->retry_reopen(sub {
  64                         ($head, $tail, $db) = $srch->each_smsg_by_mid($mid);
  65                         for (; !defined($first) && $head != $tail; $head++) {
  66                                 my @args = ($head, $db, $mid);
  67                                 my $smsg = PublicInbox::SearchMsg->get(@args);
  68                                 my $mref = $ibx->msg_by_smsg($smsg) or next;
  69                                 $first = Email::Simple->new($mref);
  70                         }
  71                         if ($head != $tail) {
  72                                 $more = [ $ctx, $head, $tail, $db, $first ];
  73                         }
  74                 });
  75         } else {
  76                 my $mref = $ibx->msg_by_mid($mid) or return;
  77                 $first = Email::Simple->new($mref);
  78         }
  79         return unless defined $first;
  80         my $fn = subject_fn($first);
  81         my @hdr = ('Content-Type');
  82         if ($ibx->{obfuscate}) {
  83                 # obfuscation is stupid, but maybe scrapers are, too...
  84                 push @hdr, 'application/mbox';
  85                 $fn .= '.mbox';
  86         } else {
  87                 push @hdr, 'text/plain';
  88                 $fn .= '.txt';
  89         }
  90         push @hdr, 'Content-Disposition', "inline; filename=$fn";
  91         [ 200, \@hdr, $more ? mb_stream($more) : [ msg_str($ctx, $first) ] ];
  92 }
  93
  94 sub msg_str {
  95         my ($ctx, $simple, $mid) = @_; # Email::Simple object
  96         my $header_obj = $simple->header_obj;
  97
  98         # drop potentially confusing headers, ssoma already should've dropped
  99         # Lines and Content-Length
 100         foreach my $d (qw(Lines Bytes Content-Length Status)) {
 101                 $header_obj->header_set($d);
 102         }
 103         my $ibx = $ctx->{-inbox};
 104         my $base = $ibx->base_url($ctx->{env});
 105         $mid = $ctx->{mid} unless defined $mid;
 106         $mid = mid_escape($mid);
 107         my @append = (
 108                 'Archived-At', "<$base$mid/>",
 109                 'List-Archive', "<$base>",
 110                 'List-Post', "<mailto:$ibx->{-primary_address}>",
 111         );
 112         my $crlf = $simple->crlf;
 113         my $buf = "From mboxrd\@z Thu Jan  1 00:00:00 1970\n" .
 114                         $header_obj->as_string;
 115         for (my $i = 0; $i < @append; $i += 2) {
 116                 my $k = $append[$i];
 117                 my $v = $append[$i + 1];
 118                 my @v = $header_obj->header($k);
 119                 foreach (@v) {
 120                         if ($v eq $_) {
 121                                 $v = undef;
 122                                 last;
 123                         }
 124                 }
 125                 $buf .= "$k: $v$crlf" if defined $v;
 126         }
 127         $buf .= $crlf;
 128
 129         # mboxrd quoting style
 130         # ref: http://www.qmail.org/man/man5/mbox.html
 131         my $body = $simple->body;
 132         $body =~ s/^(>*From )/>$1/gm;
 133         $buf .= $body;
 134         $buf .= "\n";
 135 }
 136
 137 sub thread_mbox {
 138         my ($ctx, $srch, $sfx) = @_;
 139         eval { require IO::Compress::Gzip };
 140         return sub { need_gzip(@_) } if $@;
 141         my $prev = 0;
 142         my $cb = sub {
 143                 my $msgs = $srch->get_thread($ctx->{mid}, $prev);
 144                 $prev = $msgs->[-1]->{num} if scalar(@$msgs);
 145                 $msgs;
 146         };
 147         PublicInbox::MboxGz->response($ctx, $cb);
 148 }
 149
 150 sub emit_range {
 151         my ($ctx, $range) = @_;
 152
 153         my $query;
 154         if ($range eq 'all') { # TODO: YYYY[-MM]
 155                 $query = '';
 156         } else {
 157                 return [404, [qw(Content-Type text/plain)], []];
 158         }
 159         mbox_all($ctx, $query);
 160 }
 161
 162 sub mbox_all {
 163         my ($ctx, $query) = @_;
 164
 165         eval { require IO::Compress::Gzip };
 166         return sub { need_gzip(@_) } if $@;
 167         if ($query eq '') {
 168                 my $prev = 0;
 169                 my $cb = sub { $ctx->{-inbox}->mm->ids_after(\$prev) };
 170                 return PublicInbox::MboxGz->response($ctx, $cb, 'all');
 171         }
 172         my $opts = { offset => 0 };
 173         my $srch = $ctx->{srch};
 174         my $cb = sub { # called by MboxGz->getline
 175                 my $msgs = $srch->query($query, $opts);
 176                 $opts->{offset} += scalar @$msgs;
 177                 $msgs;
 178         };
 179         PublicInbox::MboxGz->response($ctx, $cb, 'results-'.$query);
 180 }
 181
 182 sub need_gzip {
 183         my $fh = $_[0]->([501, ['Content-Type' => 'text/html']]);
 184         my $title = 'gzipped mbox not available';
 185         $fh->write(<<EOF);
 186 <html><head><title>$title</title><body><pre>$title
 187 The administrator needs to install the IO::Compress::Gzip Perl module
 188 to support gzipped mboxes.
 189 <a href="../">Return to index</a></pre></body></html>
 190 EOF
 191         $fh->close;
 192 }
 193
 194 1;
 195
 196 package PublicInbox::MboxGz;
 197 use strict;
 198 use warnings;
 199 use PublicInbox::Hval qw/to_filename/;
 200
 201 sub new {
 202         my ($class, $ctx, $cb) = @_;
 203         my $buf = '';
 204         bless {
 205                 buf => \$buf,
 206                 gz => IO::Compress::Gzip->new(\$buf, Time => 0),
 207                 cb => $cb,
 208                 ctx => $ctx,
 209                 msgs => [],
 210         }, $class;
 211 }
 212
 213 sub response {
 214         my ($class, $ctx, $cb, $fn) = @_;
 215         my $body = $class->new($ctx, $cb);
 216         # http://www.iana.org/assignments/media-types/application/gzip
 217         $body->{hdr} = [ 'Content-Type', 'application/gzip' ];
 218         $body->{fn} = $fn;
 219         my $hdr = $body->getline; # fill in Content-Disposition filename
 220         [ 200, $hdr, $body ];
 221 }
 222
 223 sub set_filename ($$) {
 224         my ($fn, $msg) = @_;
 225         return to_filename($fn) if defined($fn);
 226
 227         PublicInbox::Mbox::subject_fn($msg);
 228 }
 229
 230 # called by Plack::Util::foreach or similar
 231 sub getline {
 232         my ($self) = @_;
 233         my $ctx = $self->{ctx} or return;
 234         my $ibx = $ctx->{-inbox};
 235         my $gz = $self->{gz};
 236         my $msgs = $self->{msgs};
 237         do {
 238                 # work on existing result set
 239                 while (defined(my $smsg = shift @$msgs)) {
 240                         # ids_after may return integers
 241                         ref($smsg) or
 242                                 $smsg = $ctx->{srch}->{over_ro}->get_art($smsg);
 243
 244                         my $msg = eval { $ibx->msg_by_smsg($smsg) } or next;
 245                         $msg = Email::Simple->new($msg);
 246                         $gz->write(PublicInbox::Mbox::msg_str($ctx, $msg,
 247                                                                 $smsg->mid));
 248
 249                         # use subject of first message as subject
 250                         if (my $hdr = delete $self->{hdr}) {
 251                                 my $fn = set_filename($self->{fn}, $msg);
 252                                 push @$hdr, 'Content-Disposition',
 253                                                 "inline; filename=$fn.mbox.gz";
 254                                 return $hdr;
 255                         }
 256                         my $bref = $self->{buf};
 257                         if (length($$bref) >= 8192) {
 258                                 my $ret = $$bref; # copy :<
 259                                 ${$self->{buf}} = '';
 260                                 return $ret;
 261                         }
 262
 263                         # be fair to other clients on public-inbox-httpd:
 264                         return '';
 265                 }
 266
 267                 # refill result set
 268                 $msgs = $self->{msgs} = $self->{cb}->();
 269         } while (@$msgs);
 270         $gz->close;
 271         # signal that we're done and can return undef next call:
 272         delete $self->{ctx};
 273         ${delete $self->{buf}};
 274 }
 275
 276 sub close {} # noop
 277
 278 1;