lib/PublicInbox/Mbox.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Streaming interface for mboxrd HTTP responses
   5 # See PublicInbox::GzipFilter for details.
   6 package PublicInbox::Mbox;
   7 use strict;
   8 use parent 'PublicInbox::GzipFilter';
   9 use PublicInbox::MID qw/mid_escape/;
  10 use PublicInbox::Hval qw/to_filename/;
  11 use PublicInbox::Smsg;
  12 use PublicInbox::Eml;
  13
  14 # called by PSGI server as body response
  15 # this gets called twice for every message, once to return the header,
  16 # once to retrieve the body
  17 sub getline {
  18         my ($ctx) = @_; # ctx
  19         my $smsg = $ctx->{smsg} or return;
  20         my $ibx = $ctx->{ibx};
  21         my $eml = $ibx->smsg_eml($smsg) or return;
  22         my $n = $ctx->{smsg} = $ibx->over->next_by_mid(@{$ctx->{next_arg}});
  23         $ctx->zmore(msg_hdr($ctx, $eml, $smsg->{mid}));
  24         if ($n) {
  25                 $ctx->translate(msg_body($eml));
  26         } else { # last message
  27                 $ctx->zmore(msg_body($eml));
  28                 $ctx->zflush;
  29         }
  30 }
  31
  32 # called by PublicInbox::DS::write after http->next_step
  33 sub async_next {
  34         my ($http) = @_; # PublicInbox::HTTP
  35         my $ctx = $http->{forward} or return; # client aborted
  36         eval {
  37                 my $smsg = $ctx->{smsg} or return $ctx->close;
  38                 $ctx->smsg_blob($smsg);
  39         };
  40         warn "E: $@" if $@;
  41 }
  42
  43 sub async_eml { # for async_blob_cb
  44         my ($ctx, $eml) = @_;
  45         my $smsg = delete $ctx->{smsg};
  46         # next message
  47         $ctx->{smsg} = $ctx->{ibx}->over->next_by_mid(@{$ctx->{next_arg}});
  48
  49         $ctx->zmore(msg_hdr($ctx, $eml, $smsg->{mid}));
  50         $ctx->{http_out}->write($ctx->translate(msg_body($eml)));
  51 }
  52
  53 sub res_hdr ($$) {
  54         my ($ctx, $subject) = @_;
  55         my $fn = $subject // '';
  56         $fn =~ s/^re:\s+//i;
  57         $fn = to_filename($fn) // 'no-subject';
  58         my @hdr = ('Content-Type');
  59         if ($ctx->{ibx}->{obfuscate}) {
  60                 # obfuscation is stupid, but maybe scrapers are, too...
  61                 push @hdr, 'application/mbox';
  62                 $fn .= '.mbox';
  63         } else {
  64                 push @hdr, 'text/plain';
  65                 $fn .= '.txt';
  66         }
  67         push @hdr, 'Content-Disposition', "inline; filename=$fn";
  68         \@hdr;
  69 }
  70
  71 # for rare cases where v1 inboxes aren't indexed w/ ->over at all
  72 sub no_over_raw ($) {
  73         my ($ctx) = @_;
  74         my $mref = $ctx->{ibx}->msg_by_mid($ctx->{mid}) or return;
  75         my $eml = PublicInbox::Eml->new($mref);
  76         [ 200, res_hdr($ctx, $eml->header_str('Subject')),
  77                 [ msg_hdr($ctx, $eml, $ctx->{mid}) . msg_body($eml) ] ]
  78 }
  79
  80 # /$INBOX/$MESSAGE_ID/raw
  81 sub emit_raw {
  82         my ($ctx) = @_;
  83         $ctx->{base_url} = $ctx->{ibx}->base_url($ctx->{env});
  84         my $over = $ctx->{ibx}->over or return no_over_raw($ctx);
  85         my ($id, $prev);
  86         my $mip = $ctx->{next_arg} = [ $ctx->{mid}, \$id, \$prev ];
  87         my $smsg = $ctx->{smsg} = $over->next_by_mid(@$mip) or return;
  88         my $res_hdr = res_hdr($ctx, $smsg->{subject});
  89         bless $ctx, __PACKAGE__;
  90         $ctx->psgi_response(200, $res_hdr);
  91 }
  92
  93 sub msg_hdr ($$;$) {
  94         my ($ctx, $eml, $mid) = @_;
  95         my $header_obj = $eml->header_obj;
  96
  97         # drop potentially confusing headers, ssoma already should've dropped
  98         # Lines and Content-Length
  99         foreach my $d (qw(Lines Bytes Content-Length Status)) {
 100                 $header_obj->header_set($d);
 101         }
 102         my $ibx = $ctx->{ibx};
 103         my $base = $ctx->{base_url};
 104         $mid = $ctx->{mid} unless defined $mid;
 105         $mid = mid_escape($mid);
 106         my @append = (
 107                 'Archived-At', "<$base$mid/>",
 108                 'List-Archive', "<$base>",
 109         );
 110         my $crlf = $header_obj->crlf;
 111         my $buf = $header_obj->as_string;
 112         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 113         $buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 114         $buf = "From mboxrd\@z Thu Jan  1 00:00:00 1970" . $crlf . $buf;
 115
 116         for (my $i = 0; $i < @append; $i += 2) {
 117                 my $k = $append[$i];
 118                 my $v = $append[$i + 1];
 119                 my @v = $header_obj->header_raw($k);
 120                 $buf .= "$k: $v$crlf" if !grep(/\A\Q$v\E\z/, @v);
 121         }
 122         my $post_addr = $ibx->{-primary_address};
 123         if ($post_addr && $header_obj->header_raw('List-Post')) {
 124                 $buf .= "List-Post: <mailto:$post_addr>$crlf";
 125         }
 126         $buf .= $crlf;
 127 }
 128
 129 sub msg_body ($) {
 130         my $bdy = $_[0]->{bdy} // return "\n";
 131         # mboxrd quoting style
 132         # https://en.wikipedia.org/wiki/Mbox#Modified_mbox
 133         # https://www.loc.gov/preservation/digital/formats/fdd/fdd000385.shtml
 134         # https://web.archive.org/http://www.qmail.org/man/man5/mbox.html
 135         $$bdy =~ s/^(>*From )/>$1/gm;
 136         $$bdy .= "\n";
 137 }
 138
 139 sub thread_cb {
 140         my ($ctx) = @_;
 141         my $msgs = $ctx->{msgs};
 142         while (1) {
 143                 if (my $smsg = shift @$msgs) {
 144                         return $smsg;
 145                 }
 146                 # refill result set
 147                 $ctx->{msgs} = $msgs = $ctx->{over}->get_thread($ctx->{mid},
 148                                                                 $ctx->{prev});
 149                 return unless @$msgs;
 150                 $ctx->{prev} = $msgs->[-1];
 151         }
 152 }
 153
 154 sub thread_mbox {
 155         my ($ctx, $over, $sfx) = @_;
 156         my $msgs = $ctx->{msgs} = $over->get_thread($ctx->{mid}, {});
 157         return [404, [qw(Content-Type text/plain)], []] if !@$msgs;
 158         $ctx->{prev} = $msgs->[-1];
 159         $ctx->{over} = $over; # bump refcnt
 160         require PublicInbox::MboxGz;
 161         PublicInbox::MboxGz::mbox_gz($ctx, \&thread_cb, $msgs->[0]->{subject});
 162 }
 163
 164 sub emit_range {
 165         my ($ctx, $range) = @_;
 166
 167         my $q;
 168         if ($range eq 'all') { # TODO: YYYY[-MM]
 169                 $q = '';
 170         } else {
 171                 return [404, [qw(Content-Type text/plain)], []];
 172         }
 173         mbox_all($ctx, { q => $q });
 174 }
 175
 176 sub all_ids_cb {
 177         my ($ctx) = @_;
 178         my $ids = $ctx->{ids};
 179         do {
 180                 while ((my $num = shift @$ids)) {
 181                         my $smsg = $ctx->{over}->get_art($num) or next;
 182                         return $smsg;
 183                 }
 184                 $ctx->{ids} = $ids = $ctx->{mm}->ids_after(\($ctx->{prev}));
 185         } while (@$ids);
 186 }
 187
 188 sub mbox_all_ids {
 189         my ($ctx) = @_;
 190         my $ibx = $ctx->{ibx};
 191         my $prev = 0;
 192         my $mm = $ctx->{mm} = $ibx->mm;
 193         my $ids = $mm->ids_after(\$prev) or return
 194                 [404, [qw(Content-Type text/plain)], ["No results found\n"]];
 195         $ctx->{over} = $ibx->over or
 196                 return PublicInbox::WWW::need($ctx, 'Overview');
 197         $ctx->{ids} = $ids;
 198         $ctx->{prev} = $prev;
 199         require PublicInbox::MboxGz;
 200         PublicInbox::MboxGz::mbox_gz($ctx, \&all_ids_cb, 'all');
 201 }
 202
 203 sub gone ($$) {
 204         my ($ctx, $what) = @_;
 205         warn "W: `$ctx->{ibx}->{inboxdir}' $what went away unexpectedly\n";
 206         undef;
 207 }
 208
 209 sub results_cb {
 210         my ($ctx) = @_;
 211         my $over = $ctx->{ibx}->over or return gone($ctx, 'over');
 212         while (1) {
 213                 while (defined(my $num = shift(@{$ctx->{ids}}))) {
 214                         my $smsg = $over->get_art($num) or next;
 215                         return $smsg;
 216                 }
 217                 # refill result set
 218                 my $srch = $ctx->{ibx}->isrch or return gone($ctx, 'search');
 219                 my $mset = $srch->mset($ctx->{query}, $ctx->{qopts});
 220                 my $size = $mset->size or return;
 221                 $ctx->{qopts}->{offset} += $size;
 222                 $ctx->{ids} = $srch->mset_to_artnums($mset, $ctx->{qopts});
 223         }
 224 }
 225
 226 sub results_thread_cb {
 227         my ($ctx) = @_;
 228
 229         my $over = $ctx->{ibx}->over or return gone($ctx, 'over');
 230         while (1) {
 231                 while (defined(my $num = shift(@{$ctx->{xids}}))) {
 232                         my $smsg = $over->get_art($num) or next;
 233                         return $smsg;
 234                 }
 235
 236                 # refills ctx->{xids}
 237                 next if $over->expand_thread($ctx);
 238
 239                 # refill result set
 240                 my $srch = $ctx->{ibx}->isrch or return gone($ctx, 'search');
 241                 my $mset = $srch->mset($ctx->{query}, $ctx->{qopts});
 242                 my $size = $mset->size or return;
 243                 $ctx->{qopts}->{offset} += $size;
 244                 $ctx->{ids} = $srch->mset_to_artnums($mset, $ctx->{qopts});
 245         }
 246
 247 }
 248
 249 sub mbox_all {
 250         my ($ctx, $q) = @_;
 251         my $q_string = $q->{'q'};
 252         return mbox_all_ids($ctx) if $q_string !~ /\S/;
 253         my $srch = $ctx->{ibx}->isrch or
 254                 return PublicInbox::WWW::need($ctx, 'Search');
 255         my $over = $ctx->{ibx}->over or
 256                 return PublicInbox::WWW::need($ctx, 'Overview');
 257
 258         my $qopts = $ctx->{qopts} = { mset => 2 }; # order by docid
 259         $qopts->{thread} = 1 if $q->{t};
 260         my $mset = $srch->mset($q_string, $qopts);
 261         $qopts->{offset} = $mset->size or
 262                         return [404, [qw(Content-Type text/plain)],
 263                                 ["No results found\n"]];
 264         $ctx->{query} = $q_string;
 265         $ctx->{ids} = $srch->mset_to_artnums($mset, $qopts);
 266         require PublicInbox::MboxGz;
 267         my $fn;
 268         if ($q->{t} && $srch->has_threadid) {
 269                 $fn = 'results-thread-'.$q_string;
 270                 PublicInbox::MboxGz::mbox_gz($ctx, \&results_thread_cb, $fn);
 271         } else {
 272                 $fn = 'results-'.$q_string;
 273                 PublicInbox::MboxGz::mbox_gz($ctx, \&results_cb, $fn);
 274         }
 275 }
 276
 277 1;