lib/PublicInbox/MboxGz.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::MboxGz;
   4 use strict;
   5 use warnings;
   6 use Email::Simple;
   7 use PublicInbox::Hval qw/to_filename/;
   8 use PublicInbox::Mbox;
   9 use Compress::Raw::Zlib qw(Z_FINISH Z_OK);
  10 my %OPT = (-WindowBits => 15 + 16, -AppendOutput => 1);
  11
  12 sub new {
  13         my ($class, $ctx, $cb) = @_;
  14         $ctx->{base_url} = $ctx->{-inbox}->base_url($ctx->{env});
  15         my ($gz, $err) = Compress::Raw::Zlib::Deflate->new(%OPT);
  16         $err == Z_OK or die "Deflate->new failed: $err";
  17         bless { gz => $gz, cb => $cb, ctx => $ctx }, $class;
  18 }
  19
  20 sub response {
  21         my ($class, $ctx, $cb, $fn) = @_;
  22         my $body = $class->new($ctx, $cb);
  23         # http://www.iana.org/assignments/media-types/application/gzip
  24         $fn = defined($fn) && $fn ne '' ? to_filename($fn) : 'no-subject';
  25         my $h = [ qw(Content-Type application/gzip),
  26                 'Content-Disposition', "inline; filename=$fn.mbox.gz" ];
  27         [ 200, $h, $body ];
  28 }
  29
  30 sub gzip_fail ($$) {
  31         my ($ctx, $err) = @_;
  32         $ctx->{env}->{'psgi.errors'}->print("deflate failed: $err\n");
  33         '';
  34 }
  35
  36 # called by Plack::Util::foreach or similar
  37 sub getline {
  38         my ($self) = @_;
  39         my $ctx = $self->{ctx} or return;
  40         my $gz = $self->{gz};
  41         my $buf = delete($self->{buf});
  42         while (my $smsg = $self->{cb}->($ctx)) {
  43                 my $mref = $ctx->{-inbox}->msg_by_smsg($smsg) or next;
  44                 my $h = Email::Simple->new($mref)->header_obj;
  45
  46                 my $err = $gz->deflate(
  47                         PublicInbox::Mbox::msg_hdr($ctx, $h, $smsg->{mid}),
  48                         $buf);
  49                 return gzip_fail($ctx, $err) if $err != Z_OK;
  50
  51                 $err = $gz->deflate(PublicInbox::Mbox::msg_body($$mref), $buf);
  52                 return gzip_fail($ctx, $err) if $err != Z_OK;
  53
  54                 return $buf if length($buf) >= 8192;
  55
  56                 # be fair to other clients on public-inbox-httpd:
  57                 $self->{buf} = $buf;
  58                 return '';
  59         }
  60         # signal that we're done and can return undef next call:
  61         delete $self->{ctx};
  62         my $err = $gz->flush($buf, Z_FINISH);
  63         ($err == Z_OK) ? $buf : gzip_fail($ctx, $err);
  64 }
  65
  66 sub close {} # noop
  67
  68 1;