lib/PublicInbox/MboxReader.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # reader for mbox variants we support
   5 package PublicInbox::MboxReader;
   6 use strict;
   7 use v5.10.1;
   8 use Data::Dumper;
   9 $Data::Dumper::Useqq = 1; # should've been the default, for bad data
  10
  11 my $from_strict =
  12         qr/^From \S+ +\S+ \S+ +\S+ [^\n:]+:[^\n:]+:[^\n:]+ [^\n:]+\n/sm;
  13
  14 sub _mbox_from {
  15         my ($mbfh, $from_re, $eml_cb, @arg) = @_;
  16         my $buf = '';
  17         my @raw;
  18         while (defined(my $r = read($mbfh, $buf, 65536, length($buf)))) {
  19                 if ($r == 0) { # close here to check for "curl --fail"
  20                         close($mbfh) or die "error closing mbox: \$?=$? $!";
  21                         @raw = ($buf);
  22                 } else {
  23                         @raw = split(/$from_strict/mos, $buf, -1);
  24                         next if scalar(@raw) == 0;
  25                         $buf = pop(@raw); # last bit may be incomplete
  26                 }
  27                 @raw = grep /[^ \t\r\n]/s, @raw; # skip empty messages
  28                 while (defined(my $raw = shift @raw)) {
  29                         $raw =~ s/^\r?\n\z//ms;
  30                         $raw =~ s/$from_re/$1/gms;
  31                         my $eml = PublicInbox::Eml->new(\$raw);
  32                         $eml_cb->($eml, @arg);
  33                 }
  34                 return if $r == 0; # EOF
  35         }
  36         die "error reading mboxo/mboxrd handle: $!";
  37 }
  38
  39 sub mboxrd {
  40         my (undef, $mbfh, $eml_cb, @arg) = @_;
  41         _mbox_from($mbfh, qr/^>(>*From )/ms, $eml_cb, @arg);
  42 }
  43
  44 sub mboxo {
  45         my (undef, $mbfh, $eml_cb, @arg) = @_;
  46         _mbox_from($mbfh, qr/^>(From )/ms, $eml_cb, @arg);
  47 }
  48
  49 sub _cl_body {
  50         my ($mbfh, $bref, $cl) = @_;
  51         my $body = substr($$bref, 0, $cl, '');
  52         my $need = $cl - length($body);
  53         if ($need > 0) {
  54                 $mbfh or die "E: needed $need bytes after EOF";
  55                 defined(my $r = read($mbfh, $body, $need, length($body))) or
  56                         die "E: read error: $!\n";
  57                 $r == $need or die "E: read $r of $need bytes\n";
  58         }
  59         \$body;
  60 }
  61
  62 sub _extract_hdr {
  63         my ($ref) = @_;
  64         if (index($$ref, "\r\n") < 0 && (my $pos = index($$ref, "\n\n")) >= 0) {
  65                 # likely on *nix
  66                 \substr($$ref, 0, $pos + 2, ''); # sv_chop on $$ref
  67         } elsif ($$ref =~ /\r?\n\r?\n/s) {
  68                 \substr($$ref, 0, $+[0], ''); # sv_chop on $$ref
  69         } else {
  70                 undef
  71         }
  72 }
  73
  74 sub _mbox_cl ($$$;@) {
  75         my ($mbfh, $uxs_from, $eml_cb, @arg) = @_;
  76         my $buf = '';
  77         while (defined(my $r = read($mbfh, $buf, 65536, length($buf)))) {
  78                 if ($r == 0) { # detect "curl --fail"
  79                         close($mbfh) or
  80                                 die "error closing mboxcl/mboxcl2: \$?=$? $!";
  81                         undef $mbfh;
  82                 }
  83                 while (my $hdr = _extract_hdr(\$buf)) {
  84                         $$hdr =~ s/\A[\r\n]*From [^\n]*\n//s or
  85                                 die "E: no 'From ' line in:\n", Dumper($hdr);
  86                         my $eml = PublicInbox::Eml->new($hdr);
  87                         my @cl = $eml->header_raw('Content-Length');
  88                         my $n = scalar(@cl);
  89                         $n == 0 and die "E: Content-Length missing in:\n",
  90                                         Dumper($eml->as_string);
  91                         $n == 1 or die "E: multiple ($n) Content-Length in:\n",
  92                                         Dumper($eml->as_string);
  93                         $cl[0] =~ /\A[0-9]+\z/ or die
  94                                 "E: Content-Length `$cl[0]' invalid\n",
  95                                         Dumper($eml->as_string);
  96                         if (($eml->{bdy} = _cl_body($mbfh, \$buf, $cl[0]))) {
  97                                 $uxs_from and
  98                                         ${$eml->{bdy}} =~ s/^>From /From /sgm;
  99                         }
 100                         $eml_cb->($eml, @arg);
 101                 }
 102                 if ($r == 0) {
 103                         $buf =~ /[^ \r\n\t]/ and
 104                                 warn "W: leftover at end of mboxcl/mboxcl2:\n",
 105                                         Dumper(\$buf);
 106                         return;
 107                 }
 108         }
 109         die "error reading mboxcl/mboxcl2 handle: $!";
 110 }
 111
 112 sub mboxcl {
 113         my (undef, $mbfh, $eml_cb, @arg) = @_;
 114         _mbox_cl($mbfh, 1, $eml_cb, @arg);
 115 }
 116
 117 sub mboxcl2 {
 118         my (undef, $mbfh, $eml_cb, @arg) = @_;
 119         _mbox_cl($mbfh, undef, $eml_cb, @arg);
 120 }
 121
 122 sub new { bless \(my $x), __PACKAGE__ }
 123
 124 1;