lib/PublicInbox/MiscSearch.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # read-only counterpart to MiscIdx
   5 package PublicInbox::MiscSearch;
   6 use strict;
   7 use v5.10.1;
   8 use PublicInbox::Search qw(retry_reopen int_val xap_terms);
   9 my $json;
  10
  11 # Xapian value columns:
  12 our $MODIFIED = 0;
  13 our $UIDVALIDITY = 1; # (created time)
  14
  15 # avoid conflicting with message Search::prob_prefix for UI/UX reasons
  16 my %PROB_PREFIX = (
  17         description => 'S', # $INBOX_DIR/description
  18         address => 'A',
  19         listid => 'XLISTID',
  20         url => 'XURL',
  21         infourl => 'XINFOURL',
  22         name => 'XNAME',
  23         '' => 'S A XLISTID XNAME XURL XINFOURL'
  24 );
  25
  26 sub new {
  27         my ($class, $dir) = @_;
  28         PublicInbox::Search::load_xapian();
  29         $json //= PublicInbox::Config::json();
  30         bless {
  31                 xdb => $PublicInbox::Search::X{Database}->new($dir)
  32         }, $class;
  33 }
  34
  35 # read-only
  36 sub mi_qp_new ($) {
  37         my ($self) = @_;
  38         my $xdb = $self->{xdb};
  39         my $qp = $PublicInbox::Search::X{QueryParser}->new;
  40         $qp->set_default_op(PublicInbox::Search::OP_AND());
  41         $qp->set_database($xdb);
  42         $qp->set_stemmer(PublicInbox::Search::stemmer($self));
  43         $qp->set_stemming_strategy(PublicInbox::Search::STEM_SOME());
  44         my $cb = $qp->can('set_max_wildcard_expansion') //
  45                 $qp->can('set_max_expansion'); # Xapian 1.5.0+
  46         $cb->($qp, 100);
  47         $cb = $qp->can('add_valuerangeprocessor') //
  48                 $qp->can('add_rangeprocessor'); # Xapian 1.5.0+
  49         while (my ($name, $prefix) = each %PROB_PREFIX) {
  50                 $qp->add_prefix($name, $_) for split(/ /, $prefix);
  51         }
  52         $qp->add_boolean_prefix('type', 'T');
  53         $qp;
  54 }
  55
  56 sub misc_enquire_once { # retry_reopen callback
  57         my ($self, $qr, $opt) = @_;
  58         my $eq = $PublicInbox::Search::X{Enquire}->new($self->{xdb});
  59         $eq->set_query($qr);
  60         my $desc = !$opt->{asc};
  61         my $rel = $opt->{relevance} // 0;
  62         if ($rel == -1) { # ORDER BY docid
  63                 $eq->set_docid_order($PublicInbox::Search::ENQ_ASCENDING);
  64                 $eq->set_weighting_scheme($PublicInbox::Search::X{BoolWeight}->new);
  65         } elsif ($rel) {
  66                 $eq->set_sort_by_relevance_then_value($MODIFIED, $desc);
  67         } else {
  68                 $eq->set_sort_by_value_then_relevance($MODIFIED, $desc);
  69         }
  70         $eq->get_mset($opt->{offset} || 0, $opt->{limit} || 200);
  71 }
  72
  73 sub mset {
  74         my ($self, $qs, $opt) = @_;
  75         $opt ||= {};
  76         reopen($self);
  77         my $qp = $self->{qp} //= mi_qp_new($self);
  78         $qs = 'type:inbox' if $qs eq '';
  79         my $qr = $qp->parse_query($qs, $PublicInbox::Search::QP_FLAGS);
  80         $opt->{relevance} = 1 unless exists $opt->{relevance};
  81         retry_reopen($self, \&misc_enquire_once, $qr, $opt);
  82 }
  83
  84 sub ibx_data_once {
  85         my ($self, $ibx) = @_;
  86         my $xdb = $self->{xdb};
  87         my $term = 'Q'.$ibx->eidx_key; # may be {inboxdir}, so private
  88         my $head = $xdb->postlist_begin($term);
  89         my $tail = $xdb->postlist_end($term);
  90         if ($head != $tail) {
  91                 my $doc = $xdb->get_document($head->get_docid);
  92                 $ibx->{uidvalidity} //= int_val($doc, $UIDVALIDITY);
  93                 $ibx->{-modified} = int_val($doc, $MODIFIED);
  94                 $doc->get_data;
  95         } else {
  96                 undef;
  97         }
  98 }
  99
 100 sub doc2ibx_cache_ent { # @_ == ($self, $doc) OR ($doc)
 101         my ($doc) = $_[-1];
 102         my $d;
 103         my $data = $json->decode($doc->get_data);
 104         for (values %$data) {
 105                 $d = $_->{description} // next;
 106                 $d =~ s/ \[epoch [0-9]+\]\z// or next;
 107                 last;
 108         }
 109         {
 110                 uidvalidity => int_val($doc, $UIDVALIDITY),
 111                 -modified => int_val($doc, $MODIFIED),
 112                 # extract description from manifest.js.gz epoch description
 113                 description => $d
 114         };
 115 }
 116
 117 sub inbox_data {
 118         my ($self, $ibx) = @_;
 119         retry_reopen($self, \&ibx_data_once, $ibx);
 120 }
 121
 122 sub ibx_cache_load {
 123         my ($doc, $cache) = @_;
 124         my ($eidx_key) = xap_terms('Q', $doc);
 125         return unless defined($eidx_key); # expired
 126         $cache->{$eidx_key} = doc2ibx_cache_ent($doc);
 127 }
 128
 129 sub _nntpd_cache_load { # retry_reopen callback
 130         my ($self) = @_;
 131         my $opt = { limit => $self->{xdb}->get_doccount * 10, relevance => -1 };
 132         my $mset = mset($self, 'type:newsgroup type:inbox', $opt);
 133         my $cache = {};
 134         for my $it ($mset->items) {
 135                 ibx_cache_load($it->get_document, $cache);
 136         }
 137         $cache
 138 }
 139
 140 # returns { newsgroup => $cache_entry } mapping, $cache_entry contains
 141 # anything which may trigger seeks at startup, currently: description,
 142 # -modified, and uidvalidity.
 143 sub nntpd_cache_load {
 144         my ($self) = @_;
 145         retry_reopen($self, \&_nntpd_cache_load);
 146 }
 147
 148 no warnings 'once';
 149 *reopen = \&PublicInbox::Search::reopen;
 150
 151 1;