lib/PublicInbox/MsgIter.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 package PublicInbox::MsgIter;
   5 use strict;
   6 use warnings;
   7 use base qw(Exporter);
   8 our @EXPORT = qw(msg_iter);
   9 use Email::MIME;
  10
  11 # Workaround Email::MIME versions without
  12 # commit dcef9be66c49ae89c7a5027a789bbbac544499ce
  13 # ("removing all trailing newlines was too much")
  14 # This is necessary for Debian jessie
  15 my $bad = 1.923;
  16 my $good = 1.935;
  17 my $ver = $Email::MIME::VERSION;
  18 my $extra_nl = 1 if ($ver >= $bad && $ver < $good);
  19
  20 # Like Email::MIME::walk_parts, but this is:
  21 # * non-recursive
  22 # * passes depth and indices to the iterator callback
  23 sub msg_iter ($$) {
  24         my ($mime, $cb) = @_;
  25         my @parts = $mime->subparts;
  26         if (@parts) {
  27                 my $i = 0;
  28                 @parts = map { [ $_, 1, ++$i ] } @parts;
  29                 while (my $p = shift @parts) {
  30                         my ($part, $depth, @idx) = @$p;
  31                         my @sub = $part->subparts;
  32                         if (@sub) {
  33                                 $depth++;
  34                                 $i = 0;
  35                                 @sub = map { [ $_, $depth, @idx, ++$i ] } @sub;
  36                                 @parts = (@sub, @parts);
  37                         } else {
  38                                 if ($extra_nl) {
  39                                         ${$part->{body}} .= $part->{mycrlf};
  40                                 }
  41                                 $cb->($p);
  42                         }
  43                 }
  44         } else {
  45                 $cb->([$mime, 0, 0]);
  46         }
  47 }
  48
  49 1;