lib/PublicInbox/Msgmap.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # bidirectional Message-ID <-> Article Number mapping for the NNTP
   5 # and web interfaces.  This is required for implementing stable article
   6 # numbers for NNTP and allows prefix lookups for partial Message-IDs
   7 # in case URLs get truncated from copy-n-paste errors by users.
   8 #
   9 # This is maintained by ::SearchIdx
  10 package PublicInbox::Msgmap;
  11 use strict;
  12 use warnings;
  13 use DBI;
  14 use DBD::SQLite;
  15 use File::Temp qw(tempfile);
  16
  17 sub new {
  18         my ($class, $git_dir, $writable) = @_;
  19         my $d = "$git_dir/public-inbox";
  20         if ($writable && !-d $d && !mkdir $d) {
  21                 my $err = $!;
  22                 -d $d or die "$d not created: $err";
  23         }
  24         new_file($class, "$d/msgmap.sqlite3", $writable);
  25 }
  26
  27 sub dbh_new {
  28         my ($f, $writable) = @_;
  29         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  30                 AutoCommit => 1,
  31                 RaiseError => 1,
  32                 PrintError => 0,
  33                 ReadOnly => !$writable,
  34                 sqlite_use_immediate_transaction => 1,
  35         });
  36         $dbh->do('PRAGMA case_sensitive_like = ON');
  37         $dbh;
  38 }
  39
  40 sub new_file {
  41         my ($class, $f, $writable) = @_;
  42
  43         my $dbh = dbh_new($f, $writable);
  44         my $self = bless { dbh => $dbh }, $class;
  45
  46         if ($writable) {
  47                 create_tables($dbh);
  48                 $dbh->begin_work;
  49                 $self->created_at(time) unless $self->created_at;
  50                 $dbh->commit;
  51         }
  52         $self;
  53 }
  54
  55 # used to keep track of used numeric mappings for v2 reindex
  56 sub tmp_clone {
  57         my ($self) = @_;
  58         my ($fh, $fn) = tempfile('msgmap-XXXXXXXX', EXLOCK => 0, TMPDIR => 1);
  59         $self->{dbh}->sqlite_backup_to_file($fn);
  60         my $tmp = ref($self)->new_file($fn, 1);
  61         $tmp->{dbh}->do('PRAGMA synchronous = OFF');
  62         $tmp->{tmp_name} = $fn; # SQLite won't work if unlinked, apparently
  63         $tmp->{pid} = $$;
  64         close $fh or die "failed to close $fn: $!";
  65         $tmp;
  66 }
  67
  68 # n.b. invoked directly by scripts/xhdr-num2mid
  69 sub meta_accessor {
  70         my ($self, $key, $value) = @_;
  71
  72         my $sql = 'SELECT val FROM meta WHERE key = ? LIMIT 1';
  73         my $dbh = $self->{dbh};
  74         my $prev;
  75         defined $value or return $dbh->selectrow_array($sql, undef, $key);
  76
  77         $prev = $dbh->selectrow_array($sql, undef, $key);
  78
  79         if (defined $prev) {
  80                 $sql = 'UPDATE meta SET val = ? WHERE key = ? LIMIT 1';
  81                 $dbh->do($sql, undef, $value, $key);
  82         } else {
  83                 $sql = 'INSERT INTO meta (key,val) VALUES (?,?)';
  84                 $dbh->do($sql, undef, $key, $value);
  85         }
  86         $prev;
  87 }
  88
  89 sub last_commit {
  90         my ($self, $commit) = @_;
  91         $self->meta_accessor('last_commit', $commit);
  92 }
  93
  94 sub created_at {
  95         my ($self, $second) = @_;
  96         $self->meta_accessor('created_at', $second);
  97 }
  98
  99 sub mid_insert {
 100         my ($self, $mid) = @_;
 101         my $dbh = $self->{dbh};
 102         my $sql = 'INSERT OR IGNORE INTO msgmap (mid) VALUES (?)';
 103         my $sth = $self->{mid_insert} ||= $dbh->prepare($sql);
 104         $sth->bind_param(1, $mid);
 105         return if $sth->execute == 0;
 106         $dbh->last_insert_id(undef, undef, 'msgmap', 'num');
 107 }
 108
 109 sub mid_for {
 110         my ($self, $num) = @_;
 111         my $dbh = $self->{dbh};
 112         my $sth = $self->{mid_for} ||=
 113                 $dbh->prepare('SELECT mid FROM msgmap WHERE num = ? LIMIT 1');
 114         $sth->bind_param(1, $num);
 115         $sth->execute;
 116         $sth->fetchrow_array;
 117 }
 118
 119 sub num_for {
 120         my ($self, $mid) = @_;
 121         my $dbh = $self->{dbh};
 122         my $sth = $self->{num_for} ||=
 123                 $dbh->prepare('SELECT num FROM msgmap WHERE mid = ? LIMIT 1');
 124         $sth->bind_param(1, $mid);
 125         $sth->execute;
 126         $sth->fetchrow_array;
 127 }
 128
 129 sub minmax {
 130         my ($self) = @_;
 131         my $dbh = $self->{dbh};
 132         my $sth = $self->{num_minmax} ||=
 133                 $dbh->prepare('SELECT MIN(num),MAX(num) FROM msgmap');
 134         $sth->execute;
 135         $sth->fetchrow_array;
 136 }
 137
 138 sub mid_prefixes {
 139         my ($self, $pfx, $limit) = @_;
 140
 141         die "No prefix given" unless (defined $pfx && $pfx ne '');
 142         $pfx =~ s/([%_])/\\$1/g;
 143         $pfx .= '%';
 144
 145         $limit ||= 100;
 146         $limit += 0; # force to integer
 147         $limit ||= 100;
 148
 149         $self->{dbh}->selectcol_arrayref('SELECT mid FROM msgmap ' .
 150                                          'WHERE mid LIKE ? ESCAPE ? ' .
 151                                          "ORDER BY num DESC LIMIT $limit",
 152                                          undef, $pfx, '\\');
 153 }
 154
 155 sub mid_delete {
 156         my ($self, $mid) = @_;
 157         my $dbh = $self->{dbh};
 158         my $sth = $dbh->prepare('DELETE FROM msgmap WHERE mid = ?');
 159         $sth->bind_param(1, $mid);
 160         $sth->execute;
 161 }
 162
 163 sub num_delete {
 164         my ($self, $num) = @_;
 165         my $dbh = $self->{dbh};
 166         my $sth = $dbh->prepare('DELETE FROM msgmap WHERE num = ?');
 167         $sth->bind_param(1, $num);
 168         $sth->execute;
 169 }
 170
 171 sub create_tables {
 172         my ($dbh) = @_;
 173         my $e;
 174
 175         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM msgmap;') };
 176         defined $e or $dbh->do('CREATE TABLE msgmap (' .
 177                         'num INTEGER PRIMARY KEY AUTOINCREMENT, '.
 178                         'mid VARCHAR(1000) NOT NULL, ' .
 179                         'UNIQUE (mid) )');
 180
 181         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM meta') };
 182         defined $e or $dbh->do('CREATE TABLE meta (' .
 183                         'key VARCHAR(32) PRIMARY KEY, '.
 184                         'val VARCHAR(255) NOT NULL)');
 185 }
 186
 187 # used by NNTP.pm
 188 sub id_batch {
 189         my ($self, $num, $cb) = @_;
 190         my $dbh = $self->{dbh};
 191         my $sth = $dbh->prepare('SELECT num FROM msgmap WHERE num > ? '.
 192                                 'ORDER BY num ASC LIMIT 1000');
 193         $sth->execute($num);
 194         my $ary = $sth->fetchall_arrayref;
 195         @$ary = map { $_->[0] } @$ary;
 196         my $nr = scalar @$ary;
 197         $cb->($ary) if $nr;
 198         $nr;
 199 }
 200
 201 # only used for mapping external serial numbers (e.g. articles from gmane)
 202 # see scripts/xhdr-num2mid or PublicInbox::Filter::RubyLang for usage
 203 sub mid_set {
 204         my ($self, $num, $mid) = @_;
 205         my $sth = $self->{mid_set} ||= do {
 206                 $self->{dbh}->prepare(
 207                         'INSERT OR IGNORE INTO msgmap (num,mid) VALUES (?,?)');
 208         };
 209         $sth->execute($num, $mid);
 210 }
 211
 212 sub DESTROY {
 213         my ($self) = @_;
 214         delete $self->{dbh};
 215         my $f = delete $self->{tmp_name};
 216         if (defined $f && $self->{pid} == $$) {
 217                 unlink $f or warn "failed to unlink $f: $!\n";
 218         }
 219 }
 220
 221 sub atfork_parent {
 222         my ($self) = @_;
 223         my $f = $self->{tmp_name} or die "not a temporary clone\n";
 224         delete $self->{dbh} and die "tmp_clone dbh not prepared for parent";
 225         my $dbh = $self->{dbh} = dbh_new($f, 1);
 226         $dbh->do('PRAGMA synchronous = OFF');
 227 }
 228
 229 sub atfork_prepare {
 230         my ($self) = @_;
 231         my $f = $self->{tmp_name} or die "not a temporary clone\n";
 232         $self->{pid} == $$ or
 233                 die "BUG: atfork_prepare not called from $self->{pid}\n";
 234         $self->{dbh} or die "temporary clone not open\n";
 235         # must clobber prepared statements
 236         %$self = (tmp_name => $f, pid => $$);
 237 }
 238
 239 1;