lib/PublicInbox/Msgmap.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # bidirectional Message-ID <-> Article Number mapping for the NNTP
   5 # and web interfaces.  This is required for implementing stable article
   6 # numbers for NNTP and allows prefix lookups for partial Message-IDs
   7 # in case URLs get truncated from copy-n-paste errors by users.
   8 #
   9 # This is maintained by ::SearchIdx
  10 package PublicInbox::Msgmap;
  11 use strict;
  12 use warnings;
  13 use DBI;
  14 use DBD::SQLite;
  15 use File::Temp qw(tempfile);
  16
  17 sub new {
  18         my ($class, $git_dir, $writable) = @_;
  19         my $d = "$git_dir/public-inbox";
  20         if ($writable && !-d $d && !mkdir $d) {
  21                 my $err = $!;
  22                 -d $d or die "$d not created: $err";
  23         }
  24         new_file($class, "$d/msgmap.sqlite3", $writable);
  25 }
  26
  27 sub dbh_new {
  28         my ($f, $writable) = @_;
  29         if ($writable && !-f $f) { # SQLite defaults mode to 0644, we want 0666
  30                 open my $fh, '+>>', $f or die "failed to open $f: $!";
  31         }
  32         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  33                 AutoCommit => 1,
  34                 RaiseError => 1,
  35                 PrintError => 0,
  36                 ReadOnly => !$writable,
  37                 sqlite_use_immediate_transaction => 1,
  38         });
  39         $dbh;
  40 }
  41
  42 sub new_file {
  43         my ($class, $f, $writable) = @_;
  44         return if !$writable && !-r $f;
  45
  46         my $dbh = dbh_new($f, $writable);
  47         my $self = bless { dbh => $dbh }, $class;
  48
  49         if ($writable) {
  50                 create_tables($dbh);
  51                 $dbh->begin_work;
  52                 $self->created_at(time) unless $self->created_at;
  53                 $dbh->commit;
  54         }
  55         $self;
  56 }
  57
  58 # used to keep track of used numeric mappings for v2 reindex
  59 sub tmp_clone {
  60         my ($self) = @_;
  61         my ($fh, $fn) = tempfile('msgmap-XXXXXXXX', EXLOCK => 0, TMPDIR => 1);
  62         $self->{dbh}->sqlite_backup_to_file($fn);
  63         my $tmp = ref($self)->new_file($fn, 1);
  64         $tmp->{dbh}->do('PRAGMA synchronous = OFF');
  65         $tmp->{tmp_name} = $fn; # SQLite won't work if unlinked, apparently
  66         $tmp->{pid} = $$;
  67         close $fh or die "failed to close $fn: $!";
  68         $tmp;
  69 }
  70
  71 # n.b. invoked directly by scripts/xhdr-num2mid
  72 sub meta_accessor {
  73         my ($self, $key, $value) = @_;
  74
  75         my $sql = 'SELECT val FROM meta WHERE key = ? LIMIT 1';
  76         my $dbh = $self->{dbh};
  77         my $prev;
  78         defined $value or return $dbh->selectrow_array($sql, undef, $key);
  79
  80         $prev = $dbh->selectrow_array($sql, undef, $key);
  81
  82         if (defined $prev) {
  83                 $sql = 'UPDATE meta SET val = ? WHERE key = ?';
  84                 $dbh->do($sql, undef, $value, $key);
  85         } else {
  86                 $sql = 'INSERT INTO meta (key,val) VALUES (?,?)';
  87                 $dbh->do($sql, undef, $key, $value);
  88         }
  89         $prev;
  90 }
  91
  92 sub last_commit {
  93         my ($self, $commit) = @_;
  94         $self->meta_accessor('last_commit', $commit);
  95 }
  96
  97 # v2 uses this to keep track of how up-to-date Xapian is
  98 # old versions may be automatically GC'ed away in the future,
  99 # but it's a trivial amount of storage.
 100 sub last_commit_xap {
 101         my ($self, $version, $i, $commit) = @_;
 102         $self->meta_accessor("last_xap$version-$i", $commit);
 103 }
 104
 105 sub created_at {
 106         my ($self, $second) = @_;
 107         $self->meta_accessor('created_at', $second);
 108 }
 109
 110 sub mid_insert {
 111         my ($self, $mid) = @_;
 112         my $dbh = $self->{dbh};
 113         my $sth = $dbh->prepare_cached(<<'');
 114 INSERT OR IGNORE INTO msgmap (mid) VALUES (?)
 115
 116         return if $sth->execute($mid) == 0;
 117         $dbh->last_insert_id(undef, undef, 'msgmap', 'num');
 118 }
 119
 120 sub mid_for {
 121         my ($self, $num) = @_;
 122         my $dbh = $self->{dbh};
 123         my $sth = $self->{mid_for} ||=
 124                 $dbh->prepare('SELECT mid FROM msgmap WHERE num = ? LIMIT 1');
 125         $sth->bind_param(1, $num);
 126         $sth->execute;
 127         $sth->fetchrow_array;
 128 }
 129
 130 sub num_for {
 131         my ($self, $mid) = @_;
 132         my $dbh = $self->{dbh};
 133         my $sth = $self->{num_for} ||=
 134                 $dbh->prepare('SELECT num FROM msgmap WHERE mid = ? LIMIT 1');
 135         $sth->bind_param(1, $mid);
 136         $sth->execute;
 137         $sth->fetchrow_array;
 138 }
 139
 140 sub minmax {
 141         my ($self) = @_;
 142         my $dbh = $self->{dbh};
 143         # breaking MIN and MAX into separate queries speeds up from 250ms
 144         # to around 700us with 2.7million messages.
 145         my $sth = $dbh->prepare_cached('SELECT MIN(num) FROM msgmap', undef, 1);
 146         $sth->execute;
 147         my $min = $sth->fetchrow_array;
 148         $sth = $dbh->prepare_cached('SELECT MAX(num) FROM msgmap', undef, 1);
 149         $sth->execute;
 150         ($min, $sth->fetchrow_array);
 151 }
 152
 153 sub mid_delete {
 154         my ($self, $mid) = @_;
 155         my $dbh = $self->{dbh};
 156         my $sth = $dbh->prepare('DELETE FROM msgmap WHERE mid = ?');
 157         $sth->bind_param(1, $mid);
 158         $sth->execute;
 159 }
 160
 161 sub num_delete {
 162         my ($self, $num) = @_;
 163         my $dbh = $self->{dbh};
 164         my $sth = $dbh->prepare('DELETE FROM msgmap WHERE num = ?');
 165         $sth->bind_param(1, $num);
 166         $sth->execute;
 167 }
 168
 169 sub create_tables {
 170         my ($dbh) = @_;
 171         my $e;
 172
 173         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM msgmap;') };
 174         defined $e or $dbh->do('CREATE TABLE msgmap (' .
 175                         'num INTEGER PRIMARY KEY AUTOINCREMENT, '.
 176                         'mid VARCHAR(1000) NOT NULL, ' .
 177                         'UNIQUE (mid) )');
 178
 179         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM meta') };
 180         defined $e or $dbh->do('CREATE TABLE meta (' .
 181                         'key VARCHAR(32) PRIMARY KEY, '.
 182                         'val VARCHAR(255) NOT NULL)');
 183 }
 184
 185 # used by NNTP.pm
 186 sub ids_after {
 187         my ($self, $num) = @_;
 188         my $ids = $self->{dbh}->selectcol_arrayref(<<'', undef, $$num);
 189 SELECT num FROM msgmap WHERE num > ?
 190 ORDER BY num ASC LIMIT 1000
 191
 192         $$num = $ids->[-1] if @$ids;
 193         $ids;
 194 }
 195
 196 sub msg_range {
 197         my ($self, $beg, $end) = @_;
 198         my $dbh = $self->{dbh};
 199         my $attr = { Columns => [] };
 200         my $mids = $dbh->selectall_arrayref(<<'', $attr, $$beg, $end);
 201 SELECT num,mid FROM msgmap WHERE num >= ? AND num <= ?
 202 ORDER BY num ASC
 203
 204         $$beg = $mids->[-1]->[0] + 1 if @$mids;
 205         $mids
 206 }
 207
 208 # only used for mapping external serial numbers (e.g. articles from gmane)
 209 # see scripts/xhdr-num2mid or PublicInbox::Filter::RubyLang for usage
 210 sub mid_set {
 211         my ($self, $num, $mid) = @_;
 212         my $sth = $self->{mid_set} ||= do {
 213                 $self->{dbh}->prepare(
 214                         'INSERT OR IGNORE INTO msgmap (num,mid) VALUES (?,?)');
 215         };
 216         $sth->execute($num, $mid);
 217 }
 218
 219 sub DESTROY {
 220         my ($self) = @_;
 221         delete $self->{dbh};
 222         my $f = delete $self->{tmp_name};
 223         if (defined $f && $self->{pid} == $$) {
 224                 unlink $f or warn "failed to unlink $f: $!\n";
 225         }
 226 }
 227
 228 sub atfork_parent {
 229         my ($self) = @_;
 230         my $f = $self->{tmp_name} or die "not a temporary clone\n";
 231         delete $self->{dbh} and die "tmp_clone dbh not prepared for parent";
 232         my $dbh = $self->{dbh} = dbh_new($f, 1);
 233         $dbh->do('PRAGMA synchronous = OFF');
 234 }
 235
 236 sub atfork_prepare {
 237         my ($self) = @_;
 238         my $f = $self->{tmp_name} or die "not a temporary clone\n";
 239         $self->{pid} == $$ or
 240                 die "BUG: atfork_prepare not called from $self->{pid}\n";
 241         $self->{dbh} or die "temporary clone not open\n";
 242         # must clobber prepared statements
 243         %$self = (tmp_name => $f, pid => $$);
 244 }
 245
 246 1;