lib/PublicInbox/Msgmap.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # bidirectional Message-ID <-> Article Number mapping for the NNTP
   5 # and web interfaces.  This is required for implementing stable article
   6 # numbers for NNTP and allows prefix lookups for partial Message-IDs
   7 # in case URLs get truncated from copy-n-paste errors by users.
   8 #
   9 # This is maintained by ::SearchIdx
  10 package PublicInbox::Msgmap;
  11 use strict;
  12 use warnings;
  13 use DBI;
  14 use DBD::SQLite;
  15 use File::Temp qw(tempfile);
  16
  17 sub new {
  18         my ($class, $git_dir, $writable) = @_;
  19         my $d = "$git_dir/public-inbox";
  20         if ($writable && !-d $d && !mkdir $d) {
  21                 my $err = $!;
  22                 -d $d or die "$d not created: $err";
  23         }
  24         new_file($class, "$d/msgmap.sqlite3", $writable);
  25 }
  26
  27 sub dbh_new {
  28         my ($f, $writable) = @_;
  29         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  30                 AutoCommit => 1,
  31                 RaiseError => 1,
  32                 PrintError => 0,
  33                 ReadOnly => !$writable,
  34                 sqlite_use_immediate_transaction => 1,
  35         });
  36         $dbh->do('PRAGMA case_sensitive_like = ON');
  37         $dbh;
  38 }
  39
  40 sub new_file {
  41         my ($class, $f, $writable) = @_;
  42         return if !$writable && !-r $f;
  43
  44         my $dbh = dbh_new($f, $writable);
  45         my $self = bless { dbh => $dbh }, $class;
  46
  47         if ($writable) {
  48                 create_tables($dbh);
  49                 $dbh->begin_work;
  50                 $self->created_at(time) unless $self->created_at;
  51                 $dbh->commit;
  52         }
  53         $self;
  54 }
  55
  56 # used to keep track of used numeric mappings for v2 reindex
  57 sub tmp_clone {
  58         my ($self) = @_;
  59         my ($fh, $fn) = tempfile('msgmap-XXXXXXXX', EXLOCK => 0, TMPDIR => 1);
  60         $self->{dbh}->sqlite_backup_to_file($fn);
  61         my $tmp = ref($self)->new_file($fn, 1);
  62         $tmp->{dbh}->do('PRAGMA synchronous = OFF');
  63         $tmp->{tmp_name} = $fn; # SQLite won't work if unlinked, apparently
  64         $tmp->{pid} = $$;
  65         close $fh or die "failed to close $fn: $!";
  66         $tmp;
  67 }
  68
  69 # n.b. invoked directly by scripts/xhdr-num2mid
  70 sub meta_accessor {
  71         my ($self, $key, $value) = @_;
  72
  73         my $sql = 'SELECT val FROM meta WHERE key = ? LIMIT 1';
  74         my $dbh = $self->{dbh};
  75         my $prev;
  76         defined $value or return $dbh->selectrow_array($sql, undef, $key);
  77
  78         $prev = $dbh->selectrow_array($sql, undef, $key);
  79
  80         if (defined $prev) {
  81                 $sql = 'UPDATE meta SET val = ? WHERE key = ? LIMIT 1';
  82                 $dbh->do($sql, undef, $value, $key);
  83         } else {
  84                 $sql = 'INSERT INTO meta (key,val) VALUES (?,?)';
  85                 $dbh->do($sql, undef, $key, $value);
  86         }
  87         $prev;
  88 }
  89
  90 sub last_commit {
  91         my ($self, $commit) = @_;
  92         $self->meta_accessor('last_commit', $commit);
  93 }
  94
  95 sub last_commit_n {
  96         my ($self, $i, $commit) = @_;
  97         $self->meta_accessor('last_commit'.$i, $commit);
  98 }
  99
 100 sub created_at {
 101         my ($self, $second) = @_;
 102         $self->meta_accessor('created_at', $second);
 103 }
 104
 105 sub mid_insert {
 106         my ($self, $mid) = @_;
 107         my $dbh = $self->{dbh};
 108         my $sql = 'INSERT OR IGNORE INTO msgmap (mid) VALUES (?)';
 109         my $sth = $self->{mid_insert} ||= $dbh->prepare($sql);
 110         $sth->bind_param(1, $mid);
 111         return if $sth->execute == 0;
 112         $dbh->last_insert_id(undef, undef, 'msgmap', 'num');
 113 }
 114
 115 sub mid_for {
 116         my ($self, $num) = @_;
 117         my $dbh = $self->{dbh};
 118         my $sth = $self->{mid_for} ||=
 119                 $dbh->prepare('SELECT mid FROM msgmap WHERE num = ? LIMIT 1');
 120         $sth->bind_param(1, $num);
 121         $sth->execute;
 122         $sth->fetchrow_array;
 123 }
 124
 125 sub num_for {
 126         my ($self, $mid) = @_;
 127         my $dbh = $self->{dbh};
 128         my $sth = $self->{num_for} ||=
 129                 $dbh->prepare('SELECT num FROM msgmap WHERE mid = ? LIMIT 1');
 130         $sth->bind_param(1, $mid);
 131         $sth->execute;
 132         $sth->fetchrow_array;
 133 }
 134
 135 sub minmax {
 136         my ($self) = @_;
 137         my $dbh = $self->{dbh};
 138         my $sth = $self->{num_minmax} ||=
 139                 $dbh->prepare('SELECT MIN(num),MAX(num) FROM msgmap');
 140         $sth->execute;
 141         $sth->fetchrow_array;
 142 }
 143
 144 sub mid_prefixes {
 145         my ($self, $pfx, $limit) = @_;
 146
 147         die "No prefix given" unless (defined $pfx && $pfx ne '');
 148         $pfx =~ s/([%_])/\\$1/g;
 149         $pfx .= '%';
 150
 151         $limit ||= 100;
 152         $limit += 0; # force to integer
 153         $limit ||= 100;
 154
 155         $self->{dbh}->selectcol_arrayref('SELECT mid FROM msgmap ' .
 156                                          'WHERE mid LIKE ? ESCAPE ? ' .
 157                                          "ORDER BY num DESC LIMIT $limit",
 158                                          undef, $pfx, '\\');
 159 }
 160
 161 sub mid_delete {
 162         my ($self, $mid) = @_;
 163         my $dbh = $self->{dbh};
 164         my $sth = $dbh->prepare('DELETE FROM msgmap WHERE mid = ?');
 165         $sth->bind_param(1, $mid);
 166         $sth->execute;
 167 }
 168
 169 sub num_delete {
 170         my ($self, $num) = @_;
 171         my $dbh = $self->{dbh};
 172         my $sth = $dbh->prepare('DELETE FROM msgmap WHERE num = ?');
 173         $sth->bind_param(1, $num);
 174         $sth->execute;
 175 }
 176
 177 sub create_tables {
 178         my ($dbh) = @_;
 179         my $e;
 180
 181         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM msgmap;') };
 182         defined $e or $dbh->do('CREATE TABLE msgmap (' .
 183                         'num INTEGER PRIMARY KEY AUTOINCREMENT, '.
 184                         'mid VARCHAR(1000) NOT NULL, ' .
 185                         'UNIQUE (mid) )');
 186
 187         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM meta') };
 188         defined $e or $dbh->do('CREATE TABLE meta (' .
 189                         'key VARCHAR(32) PRIMARY KEY, '.
 190                         'val VARCHAR(255) NOT NULL)');
 191 }
 192
 193 # used by NNTP.pm
 194 sub ids_after {
 195         my ($self, $num) = @_;
 196         my $ids = $self->{dbh}->selectcol_arrayref(<<'', undef, $$num);
 197 SELECT num FROM msgmap WHERE num > ?
 198 ORDER BY num ASC LIMIT 1000
 199
 200         $$num = $ids->[-1] if @$ids;
 201         $ids;
 202 }
 203
 204 sub msg_range {
 205         my ($self, $beg, $end) = @_;
 206         my $dbh = $self->{dbh};
 207         my $attr = { Columns => [] };
 208         my $mids = $dbh->selectall_arrayref(<<'', $attr, $$beg, $end);
 209 SELECT num,mid FROM msgmap WHERE num >= ? AND num <= ?
 210 ORDER BY num ASC
 211
 212         $$beg = $mids->[-1]->[0] + 1 if @$mids;
 213         $mids
 214 }
 215
 216 # only used for mapping external serial numbers (e.g. articles from gmane)
 217 # see scripts/xhdr-num2mid or PublicInbox::Filter::RubyLang for usage
 218 sub mid_set {
 219         my ($self, $num, $mid) = @_;
 220         my $sth = $self->{mid_set} ||= do {
 221                 $self->{dbh}->prepare(
 222                         'INSERT OR IGNORE INTO msgmap (num,mid) VALUES (?,?)');
 223         };
 224         $sth->execute($num, $mid);
 225 }
 226
 227 sub DESTROY {
 228         my ($self) = @_;
 229         delete $self->{dbh};
 230         my $f = delete $self->{tmp_name};
 231         if (defined $f && $self->{pid} == $$) {
 232                 unlink $f or warn "failed to unlink $f: $!\n";
 233         }
 234 }
 235
 236 sub atfork_parent {
 237         my ($self) = @_;
 238         my $f = $self->{tmp_name} or die "not a temporary clone\n";
 239         delete $self->{dbh} and die "tmp_clone dbh not prepared for parent";
 240         my $dbh = $self->{dbh} = dbh_new($f, 1);
 241         $dbh->do('PRAGMA synchronous = OFF');
 242 }
 243
 244 sub atfork_prepare {
 245         my ($self) = @_;
 246         my $f = $self->{tmp_name} or die "not a temporary clone\n";
 247         $self->{pid} == $$ or
 248                 die "BUG: atfork_prepare not called from $self->{pid}\n";
 249         $self->{dbh} or die "temporary clone not open\n";
 250         # must clobber prepared statements
 251         %$self = (tmp_name => $f, pid => $$);
 252 }
 253
 254 1;