lib/PublicInbox/Msgmap.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # bidirectional Message-ID <-> Article Number mapping for the NNTP
   5 # and web interfaces.  This is required for implementing stable article
   6 # numbers for NNTP and allows prefix lookups for partial Message-IDs
   7 # in case URLs get truncated from copy-n-paste errors by users.
   8 #
   9 # This is maintained by ::SearchIdx
  10 package PublicInbox::Msgmap;
  11 use strict;
  12 use warnings;
  13 use DBI;
  14 use DBD::SQLite;
  15 use File::Temp qw(tempfile);
  16
  17 sub new {
  18         my ($class, $git_dir, $writable) = @_;
  19         my $d = "$git_dir/public-inbox";
  20         if ($writable && !-d $d && !mkdir $d) {
  21                 my $err = $!;
  22                 -d $d or die "$d not created: $err";
  23         }
  24         new_file($class, "$d/msgmap.sqlite3", $writable);
  25 }
  26
  27 sub new_file {
  28         my ($class, $f, $writable) = @_;
  29
  30         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  31                 AutoCommit => 1,
  32                 RaiseError => 1,
  33                 PrintError => 0,
  34                 ReadOnly => !$writable,
  35                 sqlite_use_immediate_transaction => 1,
  36         });
  37         $dbh->do('PRAGMA case_sensitive_like = ON');
  38         my $self = bless { dbh => $dbh }, $class;
  39
  40         if ($writable) {
  41                 create_tables($dbh);
  42                 $dbh->begin_work;
  43                 $self->created_at(time) unless $self->created_at;
  44                 $dbh->commit;
  45         }
  46         $self;
  47 }
  48
  49 # used to keep track of used numeric mappings for v2 reindex
  50 sub tmp_clone {
  51         my ($self) = @_;
  52         my ($fh, $fn) = tempfile(EXLOCK => 0);
  53         $self->{dbh}->sqlite_backup_to_file($fn);
  54         my $tmp = ref($self)->new_file($fn, 1);
  55         $tmp->{dbh}->do('PRAGMA synchronous = OFF');
  56         $tmp->{tmp_name} = $fn; # SQLite won't work if unlinked, apparently
  57         $fh = undef;
  58         $tmp;
  59 }
  60
  61 # n.b. invoked directly by scripts/xhdr-num2mid
  62 sub meta_accessor {
  63         my ($self, $key, $value) = @_;
  64
  65         my $sql = 'SELECT val FROM meta WHERE key = ? LIMIT 1';
  66         my $dbh = $self->{dbh};
  67         my $prev;
  68         defined $value or return $dbh->selectrow_array($sql, undef, $key);
  69
  70         $prev = $dbh->selectrow_array($sql, undef, $key);
  71
  72         if (defined $prev) {
  73                 $sql = 'UPDATE meta SET val = ? WHERE key = ? LIMIT 1';
  74                 $dbh->do($sql, undef, $value, $key);
  75         } else {
  76                 $sql = 'INSERT INTO meta (key,val) VALUES (?,?)';
  77                 $dbh->do($sql, undef, $key, $value);
  78         }
  79         $prev;
  80 }
  81
  82 sub last_commit {
  83         my ($self, $commit) = @_;
  84         $self->meta_accessor('last_commit', $commit);
  85 }
  86
  87 sub created_at {
  88         my ($self, $second) = @_;
  89         $self->meta_accessor('created_at', $second);
  90 }
  91
  92 sub mid_insert {
  93         my ($self, $mid) = @_;
  94         my $dbh = $self->{dbh};
  95         my $sql = 'INSERT OR IGNORE INTO msgmap (mid) VALUES (?)';
  96         my $sth = $self->{mid_insert} ||= $dbh->prepare($sql);
  97         $sth->bind_param(1, $mid);
  98         return if $sth->execute == 0;
  99         $dbh->last_insert_id(undef, undef, 'msgmap', 'num');
 100 }
 101
 102 sub mid_for {
 103         my ($self, $num) = @_;
 104         my $dbh = $self->{dbh};
 105         my $sth = $self->{mid_for} ||=
 106                 $dbh->prepare('SELECT mid FROM msgmap WHERE num = ? LIMIT 1');
 107         $sth->bind_param(1, $num);
 108         $sth->execute;
 109         $sth->fetchrow_array;
 110 }
 111
 112 sub num_for {
 113         my ($self, $mid) = @_;
 114         my $dbh = $self->{dbh};
 115         my $sth = $self->{num_for} ||=
 116                 $dbh->prepare('SELECT num FROM msgmap WHERE mid = ? LIMIT 1');
 117         $sth->bind_param(1, $mid);
 118         $sth->execute;
 119         $sth->fetchrow_array;
 120 }
 121
 122 sub minmax {
 123         my ($self) = @_;
 124         my $dbh = $self->{dbh};
 125         my $sth = $self->{num_minmax} ||=
 126                 $dbh->prepare('SELECT MIN(num),MAX(num) FROM msgmap');
 127         $sth->execute;
 128         $sth->fetchrow_array;
 129 }
 130
 131 sub mid_prefixes {
 132         my ($self, $pfx, $limit) = @_;
 133
 134         die "No prefix given" unless (defined $pfx && $pfx ne '');
 135         $pfx =~ s/([%_])/\\$1/g;
 136         $pfx .= '%';
 137
 138         $limit ||= 100;
 139         $limit += 0; # force to integer
 140         $limit ||= 100;
 141
 142         $self->{dbh}->selectcol_arrayref('SELECT mid FROM msgmap ' .
 143                                          'WHERE mid LIKE ? ESCAPE ? ' .
 144                                          "ORDER BY num DESC LIMIT $limit",
 145                                          undef, $pfx, '\\');
 146 }
 147
 148 sub mid_delete {
 149         my ($self, $mid) = @_;
 150         my $dbh = $self->{dbh};
 151         my $sth = $dbh->prepare('DELETE FROM msgmap WHERE mid = ?');
 152         $sth->bind_param(1, $mid);
 153         $sth->execute;
 154 }
 155
 156 sub num_delete {
 157         my ($self, $num) = @_;
 158         my $dbh = $self->{dbh};
 159         my $sth = $dbh->prepare('DELETE FROM msgmap WHERE num = ?');
 160         $sth->bind_param(1, $num);
 161         $sth->execute;
 162 }
 163
 164 sub create_tables {
 165         my ($dbh) = @_;
 166         my $e;
 167
 168         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM msgmap;') };
 169         defined $e or $dbh->do('CREATE TABLE msgmap (' .
 170                         'num INTEGER PRIMARY KEY AUTOINCREMENT, '.
 171                         'mid VARCHAR(1000) NOT NULL, ' .
 172                         'UNIQUE (mid) )');
 173
 174         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM meta') };
 175         defined $e or $dbh->do('CREATE TABLE meta (' .
 176                         'key VARCHAR(32) PRIMARY KEY, '.
 177                         'val VARCHAR(255) NOT NULL)');
 178 }
 179
 180 # used by NNTP.pm
 181 sub id_batch {
 182         my ($self, $num, $cb) = @_;
 183         my $dbh = $self->{dbh};
 184         my $sth = $dbh->prepare('SELECT num FROM msgmap WHERE num > ? '.
 185                                 'ORDER BY num ASC LIMIT 1000');
 186         $sth->execute($num);
 187         my $ary = $sth->fetchall_arrayref;
 188         @$ary = map { $_->[0] } @$ary;
 189         my $nr = scalar @$ary;
 190         $cb->($ary) if $nr;
 191         $nr;
 192 }
 193
 194 # only used for mapping external serial numbers (e.g. articles from gmane)
 195 # see scripts/xhdr-num2mid or PublicInbox::Filter::RubyLang for usage
 196 sub mid_set {
 197         my ($self, $num, $mid) = @_;
 198         my $sth = $self->{mid_set} ||= do {
 199                 $self->{dbh}->prepare(
 200                         'INSERT OR IGNORE INTO msgmap (num,mid) VALUES (?,?)');
 201         };
 202         $sth->execute($num, $mid);
 203 }
 204
 205 sub DESTROY {
 206         my ($self) = @_;
 207         delete $self->{dbh};
 208         unlink $self->{tmp_name} if defined $self->{tmp_name};
 209 }
 210
 211 1;