lib/PublicInbox/Msgmap.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # bidirectional Message-ID <-> Article Number mapping for the NNTP
   5 # and web interfaces.  This is required for implementing stable article
   6 # numbers for NNTP and allows prefix lookups for partial Message-IDs
   7 # in case URLs get truncated from copy-n-paste errors by users.
   8 #
   9 # This is maintained by ::SearchIdx
  10 package PublicInbox::Msgmap;
  11 use strict;
  12 use warnings;
  13 use DBI;
  14 use DBD::SQLite;
  15 use File::Temp qw(tempfile);
  16
  17 sub new {
  18         my ($class, $git_dir, $writable) = @_;
  19         my $d = "$git_dir/public-inbox";
  20         if ($writable && !-d $d && !mkdir $d) {
  21                 my $err = $!;
  22                 -d $d or die "$d not created: $err";
  23         }
  24         new_file($class, "$d/msgmap.sqlite3", $writable);
  25 }
  26
  27 sub dbh_new {
  28         my ($f, $writable) = @_;
  29         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  30                 AutoCommit => 1,
  31                 RaiseError => 1,
  32                 PrintError => 0,
  33                 ReadOnly => !$writable,
  34                 sqlite_use_immediate_transaction => 1,
  35         });
  36         $dbh->do('PRAGMA case_sensitive_like = ON');
  37         $dbh;
  38 }
  39
  40 sub new_file {
  41         my ($class, $f, $writable) = @_;
  42         return if !$writable && !-r $f;
  43
  44         my $dbh = dbh_new($f, $writable);
  45         my $self = bless { dbh => $dbh }, $class;
  46
  47         if ($writable) {
  48                 create_tables($dbh);
  49                 $dbh->begin_work;
  50                 $self->created_at(time) unless $self->created_at;
  51                 $dbh->commit;
  52         }
  53         $self;
  54 }
  55
  56 # used to keep track of used numeric mappings for v2 reindex
  57 sub tmp_clone {
  58         my ($self) = @_;
  59         my ($fh, $fn) = tempfile('msgmap-XXXXXXXX', EXLOCK => 0, TMPDIR => 1);
  60         $self->{dbh}->sqlite_backup_to_file($fn);
  61         my $tmp = ref($self)->new_file($fn, 1);
  62         $tmp->{dbh}->do('PRAGMA synchronous = OFF');
  63         $tmp->{tmp_name} = $fn; # SQLite won't work if unlinked, apparently
  64         $tmp->{pid} = $$;
  65         close $fh or die "failed to close $fn: $!";
  66         $tmp;
  67 }
  68
  69 # n.b. invoked directly by scripts/xhdr-num2mid
  70 sub meta_accessor {
  71         my ($self, $key, $value) = @_;
  72
  73         my $sql = 'SELECT val FROM meta WHERE key = ? LIMIT 1';
  74         my $dbh = $self->{dbh};
  75         my $prev;
  76         defined $value or return $dbh->selectrow_array($sql, undef, $key);
  77
  78         $prev = $dbh->selectrow_array($sql, undef, $key);
  79
  80         if (defined $prev) {
  81                 $sql = 'UPDATE meta SET val = ? WHERE key = ? LIMIT 1';
  82                 $dbh->do($sql, undef, $value, $key);
  83         } else {
  84                 $sql = 'INSERT INTO meta (key,val) VALUES (?,?)';
  85                 $dbh->do($sql, undef, $key, $value);
  86         }
  87         $prev;
  88 }
  89
  90 sub last_commit {
  91         my ($self, $commit) = @_;
  92         $self->meta_accessor('last_commit', $commit);
  93 }
  94
  95 sub created_at {
  96         my ($self, $second) = @_;
  97         $self->meta_accessor('created_at', $second);
  98 }
  99
 100 sub mid_insert {
 101         my ($self, $mid) = @_;
 102         my $dbh = $self->{dbh};
 103         my $sql = 'INSERT OR IGNORE INTO msgmap (mid) VALUES (?)';
 104         my $sth = $self->{mid_insert} ||= $dbh->prepare($sql);
 105         $sth->bind_param(1, $mid);
 106         return if $sth->execute == 0;
 107         $dbh->last_insert_id(undef, undef, 'msgmap', 'num');
 108 }
 109
 110 sub mid_for {
 111         my ($self, $num) = @_;
 112         my $dbh = $self->{dbh};
 113         my $sth = $self->{mid_for} ||=
 114                 $dbh->prepare('SELECT mid FROM msgmap WHERE num = ? LIMIT 1');
 115         $sth->bind_param(1, $num);
 116         $sth->execute;
 117         $sth->fetchrow_array;
 118 }
 119
 120 sub num_for {
 121         my ($self, $mid) = @_;
 122         my $dbh = $self->{dbh};
 123         my $sth = $self->{num_for} ||=
 124                 $dbh->prepare('SELECT num FROM msgmap WHERE mid = ? LIMIT 1');
 125         $sth->bind_param(1, $mid);
 126         $sth->execute;
 127         $sth->fetchrow_array;
 128 }
 129
 130 sub minmax {
 131         my ($self) = @_;
 132         my $dbh = $self->{dbh};
 133         my $sth = $self->{num_minmax} ||=
 134                 $dbh->prepare('SELECT MIN(num),MAX(num) FROM msgmap');
 135         $sth->execute;
 136         $sth->fetchrow_array;
 137 }
 138
 139 sub mid_prefixes {
 140         my ($self, $pfx, $limit) = @_;
 141
 142         die "No prefix given" unless (defined $pfx && $pfx ne '');
 143         $pfx =~ s/([%_])/\\$1/g;
 144         $pfx .= '%';
 145
 146         $limit ||= 100;
 147         $limit += 0; # force to integer
 148         $limit ||= 100;
 149
 150         $self->{dbh}->selectcol_arrayref('SELECT mid FROM msgmap ' .
 151                                          'WHERE mid LIKE ? ESCAPE ? ' .
 152                                          "ORDER BY num DESC LIMIT $limit",
 153                                          undef, $pfx, '\\');
 154 }
 155
 156 sub mid_delete {
 157         my ($self, $mid) = @_;
 158         my $dbh = $self->{dbh};
 159         my $sth = $dbh->prepare('DELETE FROM msgmap WHERE mid = ?');
 160         $sth->bind_param(1, $mid);
 161         $sth->execute;
 162 }
 163
 164 sub num_delete {
 165         my ($self, $num) = @_;
 166         my $dbh = $self->{dbh};
 167         my $sth = $dbh->prepare('DELETE FROM msgmap WHERE num = ?');
 168         $sth->bind_param(1, $num);
 169         $sth->execute;
 170 }
 171
 172 sub create_tables {
 173         my ($dbh) = @_;
 174         my $e;
 175
 176         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM msgmap;') };
 177         defined $e or $dbh->do('CREATE TABLE msgmap (' .
 178                         'num INTEGER PRIMARY KEY AUTOINCREMENT, '.
 179                         'mid VARCHAR(1000) NOT NULL, ' .
 180                         'UNIQUE (mid) )');
 181
 182         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM meta') };
 183         defined $e or $dbh->do('CREATE TABLE meta (' .
 184                         'key VARCHAR(32) PRIMARY KEY, '.
 185                         'val VARCHAR(255) NOT NULL)');
 186 }
 187
 188 # used by NNTP.pm
 189 sub ids_after {
 190         my ($self, $num) = @_;
 191         my $ids = $self->{dbh}->selectcol_arrayref(<<'', undef, $$num);
 192 SELECT num FROM msgmap WHERE num > ?
 193 ORDER BY num ASC LIMIT 1000
 194
 195         $$num = $ids->[-1] if @$ids;
 196         $ids;
 197 }
 198
 199 sub msg_range {
 200         my ($self, $beg, $end) = @_;
 201         my $dbh = $self->{dbh};
 202         my $attr = { Columns => [] };
 203         my $mids = $dbh->selectall_arrayref(<<'', $attr, $$beg, $end);
 204 SELECT num,mid FROM msgmap WHERE num >= ? AND num <= ?
 205 ORDER BY num ASC
 206
 207         $$beg = $mids->[-1]->[0] + 1 if @$mids;
 208         $mids
 209 }
 210
 211 # only used for mapping external serial numbers (e.g. articles from gmane)
 212 # see scripts/xhdr-num2mid or PublicInbox::Filter::RubyLang for usage
 213 sub mid_set {
 214         my ($self, $num, $mid) = @_;
 215         my $sth = $self->{mid_set} ||= do {
 216                 $self->{dbh}->prepare(
 217                         'INSERT OR IGNORE INTO msgmap (num,mid) VALUES (?,?)');
 218         };
 219         $sth->execute($num, $mid);
 220 }
 221
 222 sub DESTROY {
 223         my ($self) = @_;
 224         delete $self->{dbh};
 225         my $f = delete $self->{tmp_name};
 226         if (defined $f && $self->{pid} == $$) {
 227                 unlink $f or warn "failed to unlink $f: $!\n";
 228         }
 229 }
 230
 231 sub atfork_parent {
 232         my ($self) = @_;
 233         my $f = $self->{tmp_name} or die "not a temporary clone\n";
 234         delete $self->{dbh} and die "tmp_clone dbh not prepared for parent";
 235         my $dbh = $self->{dbh} = dbh_new($f, 1);
 236         $dbh->do('PRAGMA synchronous = OFF');
 237 }
 238
 239 sub atfork_prepare {
 240         my ($self) = @_;
 241         my $f = $self->{tmp_name} or die "not a temporary clone\n";
 242         $self->{pid} == $$ or
 243                 die "BUG: atfork_prepare not called from $self->{pid}\n";
 244         $self->{dbh} or die "temporary clone not open\n";
 245         # must clobber prepared statements
 246         %$self = (tmp_name => $f, pid => $$);
 247 }
 248
 249 1;