lib/PublicInbox/Msgmap.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # bidirectional Message-ID <-> Article Number mapping
   4 package PublicInbox::Msgmap;
   5 use strict;
   6 use warnings;
   7 use DBI;
   8 use DBD::SQLite;
   9
  10 sub new {
  11         my ($class, $git_dir, $writable) = @_;
  12         my $d = "$git_dir/public-inbox";
  13         if ($writable && !-d $d && !mkdir $d) {
  14                 my $err = $!;
  15                 -d $d or die "$d not created: $err";
  16         }
  17         my $f = "$d/msgmap.sqlite3";
  18         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  19                 AutoCommit => 1,
  20                 RaiseError => 1,
  21                 PrintError => 0,
  22                 sqlite_use_immediate_transaction => 1,
  23         });
  24         $dbh->do('PRAGMA case_sensitive_like = ON');
  25         my $self = bless { dbh => $dbh }, $class;
  26
  27         if ($writable) {
  28                 create_tables($dbh);
  29                 $self->created_at(time) unless $self->created_at;
  30         }
  31         $self;
  32 }
  33
  34 sub meta_accessor {
  35         my ($self, $key, $value) = @_;
  36         use constant {
  37                 meta_select => 'SELECT val FROM meta WHERE key = ? LIMIT 1',
  38                 meta_update => 'UPDATE meta SET val = ? WHERE key = ? LIMIT 1',
  39                 meta_insert => 'INSERT INTO meta (key,val) VALUES (?,?)',
  40         };
  41
  42         my $dbh = $self->{dbh};
  43         my $prev;
  44         defined $value or
  45                 return $dbh->selectrow_array(meta_select, undef, $key);
  46
  47         $dbh->begin_work;
  48         eval {
  49                 $prev = $dbh->selectrow_array(meta_select, undef, $key);
  50
  51                 if (defined $prev) {
  52                         $dbh->do(meta_update, undef, $value, $key);
  53                 } else {
  54                         $dbh->do(meta_insert, undef, $key, $value);
  55                 }
  56                 $dbh->commit;
  57         };
  58         my $err = $@;
  59         return $prev unless $err;
  60
  61         $dbh->rollback;
  62         die $err;
  63 }
  64
  65 sub last_commit {
  66         my ($self, $commit) = @_;
  67         $self->meta_accessor('last_commit', $commit);
  68 }
  69
  70 sub created_at {
  71         my ($self, $second) = @_;
  72         $self->meta_accessor('created_at', $second);
  73 }
  74
  75 sub mid_insert {
  76         my ($self, $mid) = @_;
  77         my $dbh = $self->{dbh};
  78         use constant MID_INSERT => 'INSERT INTO msgmap (mid) VALUES (?)';
  79         my $sth = $self->{mid_insert} ||= $dbh->prepare(MID_INSERT);
  80         $sth->bind_param(1, $mid);
  81         $sth->execute;
  82         $dbh->last_insert_id(undef, undef, 'msgmap', 'num');
  83 }
  84
  85 sub mid_for {
  86         my ($self, $num) = @_;
  87         my $dbh = $self->{dbh};
  88         use constant MID_FOR => 'SELECT mid FROM msgmap WHERE num = ? LIMIT 1';
  89         my $sth = $self->{mid_for} ||= $dbh->prepare(MID_FOR);
  90         $sth->bind_param(1, $num);
  91         $sth->execute;
  92         $sth->fetchrow_array;
  93 }
  94
  95 sub num_for {
  96         my ($self, $mid) = @_;
  97         my $dbh = $self->{dbh};
  98         use constant NUM_FOR => 'SELECT num FROM msgmap WHERE mid = ? LIMIT 1';
  99         my $sth = $self->{num_for} ||= $dbh->prepare(NUM_FOR);
 100         $sth->bind_param(1, $mid);
 101         $sth->execute;
 102         $sth->fetchrow_array;
 103 }
 104
 105 sub minmax {
 106         my ($self) = @_;
 107         my $dbh = $self->{dbh};
 108         use constant NUM_MINMAX => 'SELECT MIN(num),MAX(num) FROM msgmap';
 109         my $sth = $self->{num_minmax} ||= $dbh->prepare(NUM_MINMAX);
 110         $sth->execute;
 111         $sth->fetchrow_array;
 112 }
 113
 114 sub mid_prefixes {
 115         my ($self, $pfx, $limit) = @_;
 116
 117         die "No prefix given" unless (defined $pfx && $pfx ne '');
 118         $pfx =~ s/([%_])/\\$1/g;
 119         $pfx .= '%';
 120
 121         $limit ||= 100;
 122         $limit += 0; # force to integer
 123         $limit ||= 100;
 124
 125         $self->{dbh}->selectcol_arrayref('SELECT mid FROM msgmap ' .
 126                                          'WHERE mid LIKE ? ESCAPE ? ' .
 127                                          "ORDER BY num DESC LIMIT $limit",
 128                                          undef, $pfx, '\\');
 129 }
 130
 131 sub mid_delete {
 132         my ($self, $mid) = @_;
 133         my $dbh = $self->{dbh};
 134         use constant MID_DELETE => 'DELETE FROM msgmap WHERE mid = ?';
 135         my $sth = $dbh->prepare(MID_DELETE);
 136         $sth->bind_param(1, $mid);
 137         $sth->execute;
 138 }
 139
 140 sub create_tables {
 141         my ($dbh) = @_;
 142         my $e;
 143
 144         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM msgmap;') };
 145         defined $e or $dbh->do('CREATE TABLE msgmap (' .
 146                         'num INTEGER PRIMARY KEY AUTOINCREMENT, '.
 147                         'mid VARCHAR(1000) NOT NULL, ' .
 148                         'UNIQUE (mid) )');
 149
 150         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM meta') };
 151         defined $e or $dbh->do('CREATE TABLE meta (' .
 152                         'key VARCHAR(32) PRIMARY KEY, '.
 153                         'val VARCHAR(255) NOT NULL)');
 154 }
 155
 156 sub id_batch {
 157         my ($self, $num, $cb) = @_;
 158         my $dbh = $self->{dbh};
 159         my $sth = $dbh->prepare('SELECT num FROM msgmap WHERE num > ? '.
 160                                 'ORDER BY num ASC LIMIT 1000');
 161         $sth->execute($num);
 162         my $ary = $sth->fetchall_arrayref;
 163         @$ary = map { $_->[0] } @$ary;
 164         my $nr = scalar @$ary;
 165         $cb->($ary) if $nr;
 166         $nr;
 167 }
 168
 169 1;